configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([foobar],[m4_esyscmd(./version-gen.sh)],
   4                 [Sebastian Harl <sh@tokkee.org>])
   5 AC_CONFIG_SRCDIR([src/foobar.c])
   6 AC_CONFIG_HEADERS([src/config.h])
   7 AC_PREFIX_DEFAULT([/opt/foobar])
   8
   9 AM_INIT_AUTOMAKE([foreign -Wall])
  10
  11 AC_LANG(C)
  12
  13 AC_SYS_LARGEFILE
  14
  15 AC_PROG_CC
  16 AC_PROG_CPP
  17 AC_PROG_INSTALL
  18 AC_PROG_LN_S
  19 AC_PROG_MAKE_SET
  20
  21 AM_PROG_CC_C_O
  22
  23 AC_PROG_LIBTOOL
  24
  25 test_cc_flags() {
  26         AC_LANG_CONFTEST([int main() {}])
  27         $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  28         ret=$?
  29         rm -f conftest.o
  30         return $ret
  31 }
  32
  33 dnl Optionally stick to standard C99 and POSIX.1 2001 as close as possible.
  34 AC_ARG_ENABLE([standards],
  35                 AS_HELP_STRING([--enable-standards],
  36                                 [Enable standards compliance mode]),
  37                 [enable_standards="$enableval"],
  38                 [enable_standards="no"])
  39
  40 if test "x$enable_standards" = "xyes"; then
  41         AC_DEFINE([_ISOC99_SOURCE], 1,
  42                         [Define to enforce ISO/IEC 9899:1999 (C99) compliance.])
  43         AC_DEFINE([_POSIX_C_SOURCE], 200112L,
  44                         [Define to enforce IEEE 1003.1-2001 (POSIX:2001) compliance.])
  45         AC_DEFINE([_XOPEN_SOURCE], 600,
  46                         [Define to enforce X/Open 6 (XSI) compliance.])
  47         AC_DEFINE([_REENTRANT], 1,
  48                         [Define to enable reentrant interfaces.])
  49         AC_DEFINE([_THREAD_SAFE], 1,
  50                         [Define to enable reentrant interfaces.])
  51
  52         for flag in -std=c99 -pedantic; do
  53                 AC_MSG_CHECKING([whether $CC accepts $flag])
  54
  55                 if test_cc_flags $flag; then
  56                         CFLAGS="$CFLAGS $flag"
  57                         AC_MSG_RESULT([yes])
  58                 else
  59                         AC_MSG_RESULT([no])
  60                 fi
  61         done
  62 fi
  63
  64 for flag in -Wall -Wextra -Werror; do
  65         AC_MSG_CHECKING([whether $CC accepts $flag])
  66
  67         if test_cc_flags $flag; then
  68                 STRICT_CFLAGS="$STRICT_CFLAGS $flag"
  69                 AC_MSG_RESULT([yes])
  70         else
  71                 AC_MSG_RESULT([no])
  72         fi
  73 done
  74 AC_SUBST([STRICT_CFLAGS])
  75
  76 build_date="`date --utc '+%F %T'` (UTC)"
  77 AC_DEFINE_UNQUOTED([BUILD_DATE], ["$build_date"],
  78                 [Define to the date the package has been built on.])
  79
  80 AC_CHECK_HEADERS(libgen.h)
  81
  82 AC_CONFIG_FILES([Makefile src/Makefile])
  83 AC_OUTPUT
  84
  85 cat <<EOF;
  86
  87 $PACKAGE_NAME has been configured successfully.
  88
  89 Run 'make' to compile the software and use 'make install' to
  90 install the package into $prefix.
  91
  92 Configuration summary:
  93
  94   package version: $PACKAGE_VERSION
  95   build date: $build_date
  96
  97 Please report bugs to $PACKAGE_BUGREPORT.
  98
  99 EOF
 100