src/tools/sysdb/scanner.l

   1 /*
   2  * SysDB - src/tools/sysdb/scanner.l
   3  * Copyright (C) 2013 Sebastian 'tokkee' Harl <sh@tokkee.org>
   4  * All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  *
  15  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  16  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  17  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  18  * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
  19  * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  20  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  21  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  22  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  23  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  24  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  25  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26  */
  27
  28 %{
  29
  30 /*
  31  * This is a simplified version of frontend/scanner.l. The only purpose is to
  32  * find queries (terminated by semicolon).
  33  */
  34
  35 #if HAVE_CONFIG_H
  36 #       include "config.h"
  37 #endif /* HAVE_CONFIG_H */
  38
  39 #include "tools/sysdb/input.h"
  40
  41 #include <ctype.h>
  42 #include <string.h>
  43
  44 #ifdef YY_INPUT
  45 #       undef YY_INPUT
  46 #endif
  47 #define YY_INPUT(buf, result, max_size) \
  48         sdb_input_readline((buf), (size_t *)&(result), (max_size))
  49
  50 #define APPEND() \
  51         do { \
  52                 if (! isspace((int)yytext[0])) \
  53                         sysdb_input->have_input = 1; \
  54                 sysdb_input->query_len += strlen(yytext); \
  55         } while (0)
  56
  57 %}
  58
  59 %option interactive
  60 %option 8bit
  61 %option yylineno
  62 %option nodefault
  63 %option noyywrap
  64 %option verbose
  65 %option warn
  66
  67 %x CSC
  68
  69 newline                 (\n|\r\n)
  70 simple_comment  ("--"[^\n\r]*)
  71
  72 /*
  73  * C style comments
  74  */
  75 csc_start       \/\*
  76 csc_inside      ([^*/]+|[^*]\/|\*[^/])
  77 csc_end         \*\/
  78
  79 /*
  80  * Strings.
  81  */
  82 /* TODO: fully support SQL strings */
  83 string          ('([^']|'')*')
  84
  85 %%
  86
  87         /*
  88          * Here, we only care about syntax elements that may include semicolons
  89          * and escape their meaning as a query terminator.
  90          */
  91
  92 {simple_comment}        { APPEND(); }
  93
  94 {csc_start}                     { APPEND(); BEGIN(CSC); }
  95 <CSC>{csc_inside}       { APPEND(); }
  96 <CSC>{csc_end}          { APPEND(); BEGIN(INITIAL); }
  97 <CSC><<EOF>>            { return -1; }
  98
  99 {string}                        { APPEND(); }
 100
 101         /*
 102          * The following rules are specific to the command line tool.
 103          */
 104
 105 ";\n"           { APPEND(); sdb_input_exec_query(); }
 106 ";"                     { APPEND(); sdb_input_exec_query(); }
 107
 108 {newline}       {
 109                                 APPEND();
 110                                 if (! sysdb_input->have_input)
 111                                         /* give the input module a chance to do stuff on empty lines */
 112                                         sdb_input_exec_query();
 113                         }
 114
 115 .                       { APPEND(); }
 116
 117 %%
 118
 119 /* vim: set tw=78 sw=4 ts=4 noexpandtab : */
 120