src/tools/sysdb/scanner.l

   1 /*
   2  * SysDB - src/tools/sysdb/scanner.l
   3  * Copyright (C) 2013 Sebastian 'tokkee' Harl <sh@tokkee.org>
   4  * All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  *
  15  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  16  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  17  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  18  * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
  19  * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  20  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  21  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  22  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  23  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  24  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  25  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26  */
  27
  28 %{
  29
  30 /*
  31  * This is a simplified version of frontend/scanner.l. The only purpose is to
  32  * find queries (terminated by semicolon).
  33  */
  34
  35 #include "tools/sysdb/input.h"
  36
  37 #include <string.h>
  38
  39 #ifdef YY_INPUT
  40 #       undef YY_INPUT
  41 #endif
  42 #define YY_INPUT(buf, result, max_size) \
  43         sdb_input_readline(sdb_input, (buf), &(result), (max_size))
  44
  45 #define APPEND() \
  46         do { \
  47                 sdb_input->query_len += strlen(yytext); \
  48         } while (0)
  49
  50 static sdb_input_t *sdb_input;
  51
  52 %}
  53
  54 %option interactive
  55 %option 8bit
  56 %option yylineno
  57 %option nodefault
  58 %option noyywrap
  59 %option verbose
  60 %option warn
  61
  62 %x CSC
  63
  64 whitespace              ([ \t\n\r\f]+)
  65 simple_comment  ("--"[^\n\r]*)
  66
  67 /*
  68  * C style comments
  69  */
  70 csc_start       \/\*
  71 csc_inside      ([^*/]+|[^*]\/|\*[^/])
  72 csc_end         \*\/
  73
  74 identifier      ([A-Za-z_][A-Za-z_0-9$]*)
  75
  76 %%
  77
  78 {whitespace}            { APPEND(); }
  79 {simple_comment}        { APPEND(); }
  80
  81 {csc_start}                     { APPEND(); BEGIN(CSC); }
  82 <CSC>{csc_inside}       { APPEND(); }
  83 <CSC>{csc_end}          { APPEND(); BEGIN(INITIAL); }
  84 <CSC><<EOF>>            { return -1; }
  85
  86 {identifier}            { APPEND(); }
  87
  88         /*
  89          * The following rules are specific to the command line tool.
  90          */
  91
  92 ";"     { APPEND(); sdb_input_exec_query(sdb_input); }
  93
  94 .       { APPEND(); }
  95
  96 %%
  97
  98 void
  99 sdb_input_set(sdb_input_t *new_input)
 100 {
 101         sdb_input = new_input;
 102 } /* sdb_input_set */
 103
 104 /* vim: set tw=78 sw=4 ts=4 noexpandtab : */
 105