src/frontend/grammar.y

   1 /*
   2  * SysDB - src/frontend/grammar.y
   3  * Copyright (C) 2013 Sebastian 'tokkee' Harl <sh@tokkee.org>
   4  * All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  *
  15  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  16  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  17  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  18  * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
  19  * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  20  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  21  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  22  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  23  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  24  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  25  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26  */
  27
  28 %{
  29
  30 #include "frontend/connection-private.h"
  31 #include "frontend/parser.h"
  32 #include "frontend/grammar.h"
  33
  34 #include "core/store.h"
  35 #include "core/store-private.h"
  36
  37 #include "utils/error.h"
  38 #include "utils/llist.h"
  39
  40 #include <stdio.h>
  41 #include <string.h>
  42
  43 int
  44 sdb_fe_yylex(YYSTYPE *yylval, YYLTYPE *yylloc, sdb_fe_yyscan_t yyscanner);
  45
  46 sdb_fe_yyextra_t *
  47 sdb_fe_yyget_extra(sdb_fe_yyscan_t scanner);
  48
  49 void
  50 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg);
  51
  52 /* quick access to the current parse tree */
  53 #define pt sdb_fe_yyget_extra(scanner)->parsetree
  54
  55 /* quick access to the parser mode */
  56 #define parser_mode sdb_fe_yyget_extra(scanner)->mode
  57
  58 %}
  59
  60 %pure-parser
  61 %lex-param {sdb_fe_yyscan_t scanner}
  62 %parse-param {sdb_fe_yyscan_t scanner}
  63 %locations
  64 %error-verbose
  65 %expect 0
  66 %name-prefix "sdb_fe_yy"
  67
  68 %union {
  69         const char *sstr; /* static string */
  70         char *str;
  71
  72         sdb_data_t data;
  73
  74         sdb_llist_t     *list;
  75         sdb_conn_node_t *node;
  76
  77         sdb_store_matcher_t *m;
  78         sdb_store_expr_t *expr;
  79 }
  80
  81 %start statements
  82
  83 %token SCANNER_ERROR
  84
  85 %token AND OR IS NOT MATCHING FILTER
  86 %token CMP_EQUAL CMP_NEQUAL CMP_REGEX CMP_NREGEX
  87 %token CMP_LT CMP_LE CMP_GE CMP_GT
  88 %token CONCAT
  89
  90 /* NULL token */
  91 %token NULL_T
  92
  93 %token FETCH LIST LOOKUP
  94
  95 %token <str> IDENTIFIER STRING
  96
  97 %token <data> INTEGER FLOAT
  98
  99 /* Precedence (lowest first): */
 100 %left OR
 101 %left AND
 102 %right NOT
 103 %left CMP_EQUAL CMP_NEQUAL
 104 %left CMP_LT CMP_LE CMP_GE CMP_GT
 105 %nonassoc CMP_REGEX CMP_NREGEX
 106 %left CONCAT
 107 %nonassoc IS
 108 %left '+' '-'
 109 %left '*' '/' '%'
 110 %left '(' ')'
 111 %left '.'
 112
 113 %type <list> statements
 114 %type <node> statement
 115         fetch_statement
 116         list_statement
 117         lookup_statement
 118         matching_clause
 119         filter_clause
 120         condition
 121
 122 %type <m> matcher
 123         compare_matcher
 124
 125 %type <expr> expression
 126
 127 %type <sstr> op
 128
 129 %type <data> data
 130         interval interval_elem
 131
 132 %destructor { free($$); } <str>
 133 %destructor { sdb_object_deref(SDB_OBJ($$)); } <node> <m> <expr>
 134
 135 %%
 136
 137 statements:
 138         statements ';' statement
 139                 {
 140                         /* only accept this in default parse mode */
 141                         if (parser_mode != SDB_PARSE_DEFAULT) {
 142                                 sdb_fe_yyerror(&yylloc, scanner,
 143                                                 YY_("syntax error, unexpected statement, "
 144                                                         "expecting condition"));
 145                                 sdb_object_deref(SDB_OBJ($3));
 146                                 YYABORT;
 147                         }
 148
 149                         if ($3) {
 150                                 sdb_llist_append(pt, SDB_OBJ($3));
 151                                 sdb_object_deref(SDB_OBJ($3));
 152                         }
 153                 }
 154         |
 155         statement
 156                 {
 157                         /* only accept this in default parse mode */
 158                         if (parser_mode != SDB_PARSE_DEFAULT) {
 159                                 sdb_fe_yyerror(&yylloc, scanner,
 160                                                 YY_("syntax error, unexpected statement, "
 161                                                         "expecting condition"));
 162                                 sdb_object_deref(SDB_OBJ($1));
 163                                 YYABORT;
 164                         }
 165
 166                         if ($1) {
 167                                 sdb_llist_append(pt, SDB_OBJ($1));
 168                                 sdb_object_deref(SDB_OBJ($1));
 169                         }
 170                 }
 171         |
 172         condition
 173                 {
 174                         /* only accept this in condition parse mode */
 175                         if (! (parser_mode & SDB_PARSE_COND)) {
 176                                 sdb_fe_yyerror(&yylloc, scanner,
 177                                                 YY_("syntax error, unexpected condition, "
 178                                                         "expecting statement"));
 179                                 sdb_object_deref(SDB_OBJ($1));
 180                                 YYABORT;
 181                         }
 182
 183                         if ($1) {
 184                                 sdb_llist_append(pt, SDB_OBJ($1));
 185                                 sdb_object_deref(SDB_OBJ($1));
 186                         }
 187                 }
 188         ;
 189
 190 statement:
 191         fetch_statement
 192         |
 193         list_statement
 194         |
 195         lookup_statement
 196         |
 197         /* empty */
 198                 {
 199                         $$ = NULL;
 200                 }
 201         ;
 202
 203 /*
 204  * FETCH <hostname>;
 205  *
 206  * Retrieve detailed information about a single host.
 207  */
 208 fetch_statement:
 209         FETCH STRING
 210                 {
 211                         $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
 212                                                 conn_fetch_t, conn_fetch_destroy));
 213                         CONN_FETCH($$)->name = strdup($2);
 214                         $$->cmd = CONNECTION_FETCH;
 215                         free($2); $2 = NULL;
 216                 }
 217         ;
 218
 219 /*
 220  * LIST;
 221  *
 222  * Returns a list of all hosts in the store.
 223  */
 224 list_statement:
 225         LIST
 226                 {
 227                         $$ = SDB_CONN_NODE(sdb_object_create_T(/* name = */ NULL,
 228                                                 sdb_conn_node_t));
 229                         $$->cmd = CONNECTION_LIST;
 230                 }
 231         ;
 232
 233 /*
 234  * LOOKUP <type> MATCHING <condition> [FILTER <condition>];
 235  *
 236  * Returns detailed information about <type> matching condition.
 237  */
 238 lookup_statement:
 239         LOOKUP IDENTIFIER matching_clause filter_clause
 240                 {
 241                         /* TODO: support other types as well */
 242                         if (strcasecmp($2, "hosts")) {
 243                                 char errmsg[strlen($2) + 32];
 244                                 snprintf(errmsg, sizeof(errmsg),
 245                                                 YY_("unknown data-source %s"), $2);
 246                                 sdb_fe_yyerror(&yylloc, scanner, errmsg);
 247                                 free($2); $2 = NULL;
 248                                 sdb_object_deref(SDB_OBJ($3));
 249                                 sdb_object_deref(SDB_OBJ($4));
 250                                 YYABORT;
 251                         }
 252
 253                         $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
 254                                                 conn_lookup_t, conn_lookup_destroy));
 255                         CONN_LOOKUP($$)->matcher = CONN_MATCHER($3);
 256                         CONN_LOOKUP($$)->filter = CONN_MATCHER($4);
 257                         $$->cmd = CONNECTION_LOOKUP;
 258                         free($2); $2 = NULL;
 259                 }
 260         ;
 261
 262 matching_clause:
 263         MATCHING condition { $$ = $2; }
 264         |
 265         /* empty */ { $$ = NULL; }
 266
 267 filter_clause:
 268         FILTER condition { $$ = $2; }
 269         |
 270         /* empty */ { $$ = NULL; }
 271
 272 /*
 273  * Basic expressions.
 274  */
 275
 276 condition:
 277         matcher
 278                 {
 279                         if (! $1) {
 280                                 /* TODO: improve error reporting */
 281                                 sdb_fe_yyerror(&yylloc, scanner,
 282                                                 YY_("syntax error, invalid condition"));
 283                                 YYABORT;
 284                         }
 285
 286                         $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
 287                                                 conn_matcher_t, conn_matcher_destroy));
 288                         $$->cmd = CONNECTION_EXPR;
 289                         CONN_MATCHER($$)->matcher = $1;
 290                 }
 291         ;
 292
 293 matcher:
 294         '(' matcher ')'
 295                 {
 296                         $$ = $2;
 297                 }
 298         |
 299         matcher AND matcher
 300                 {
 301                         $$ = sdb_store_con_matcher($1, $3);
 302                         sdb_object_deref(SDB_OBJ($1));
 303                         sdb_object_deref(SDB_OBJ($3));
 304                 }
 305         |
 306         matcher OR matcher
 307                 {
 308                         $$ = sdb_store_dis_matcher($1, $3);
 309                         sdb_object_deref(SDB_OBJ($1));
 310                         sdb_object_deref(SDB_OBJ($3));
 311                 }
 312         |
 313         NOT matcher
 314                 {
 315                         $$ = sdb_store_inv_matcher($2);
 316                         sdb_object_deref(SDB_OBJ($2));
 317                 }
 318         |
 319         compare_matcher
 320                 {
 321                         $$ = $1;
 322                 }
 323         ;
 324
 325 /*
 326  * <object_type>.<object_attr> <op> <value>
 327  *
 328  * Parse matchers comparing object attributes with a value.
 329  */
 330 compare_matcher:
 331         ':' IDENTIFIER op expression
 332                 {
 333                         $$ = sdb_store_matcher_parse_field_cmp($2, $3, $4);
 334                         free($2); $2 = NULL;
 335                         sdb_object_deref(SDB_OBJ($4));
 336                 }
 337         |
 338         IDENTIFIER op expression
 339                 {
 340                         $$ = sdb_store_matcher_parse_cmp($1, NULL, $2, $3);
 341                         free($1); $1 = NULL;
 342                         sdb_object_deref(SDB_OBJ($3));
 343                 }
 344         |
 345         IDENTIFIER '.' IDENTIFIER op expression
 346                 {
 347                         $$ = sdb_store_matcher_parse_cmp($1, $3, $4, $5);
 348                         free($1); $1 = NULL;
 349                         free($3); $3 = NULL;
 350                         sdb_object_deref(SDB_OBJ($5));
 351                 }
 352         |
 353         IDENTIFIER '.' IDENTIFIER IS NULL_T
 354                 {
 355                         $$ = sdb_store_matcher_parse_cmp($1, $3, "IS", NULL);
 356                         free($1); $1 = NULL;
 357                         free($3); $3 = NULL;
 358                 }
 359         |
 360         IDENTIFIER '.' IDENTIFIER IS NOT NULL_T
 361                 {
 362                         sdb_store_matcher_t *m;
 363                         m = sdb_store_matcher_parse_cmp($1, $3, "IS", NULL);
 364                         free($1); $1 = NULL;
 365                         free($3); $3 = NULL;
 366
 367                         /* sdb_store_inv_matcher return NULL if m==NULL */
 368                         $$ = sdb_store_inv_matcher(m);
 369                         sdb_object_deref(SDB_OBJ(m));
 370                 }
 371         ;
 372
 373 expression:
 374         '(' expression ')'
 375                 {
 376                         $$ = $2;
 377                 }
 378         |
 379         expression '+' expression
 380                 {
 381                         $$ = sdb_store_expr_create(SDB_DATA_ADD, $1, $3);
 382                         sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
 383                         sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
 384                 }
 385         |
 386         expression '-' expression
 387                 {
 388                         $$ = sdb_store_expr_create(SDB_DATA_SUB, $1, $3);
 389                         sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
 390                         sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
 391                 }
 392         |
 393         expression '*' expression
 394                 {
 395                         $$ = sdb_store_expr_create(SDB_DATA_MUL, $1, $3);
 396                         sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
 397                         sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
 398                 }
 399         |
 400         expression '/' expression
 401                 {
 402                         $$ = sdb_store_expr_create(SDB_DATA_DIV, $1, $3);
 403                         sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
 404                         sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
 405                 }
 406         |
 407         expression '%' expression
 408                 {
 409                         $$ = sdb_store_expr_create(SDB_DATA_MOD, $1, $3);
 410                         sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
 411                         sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
 412                 }
 413         |
 414         ':' IDENTIFIER
 415                 {
 416                         int field = sdb_store_parse_field_name($2);
 417                         free($2); $2 = NULL;
 418                         $$ = sdb_store_expr_fieldvalue(field);
 419                 }
 420         |
 421         data
 422                 {
 423                         $$ = sdb_store_expr_constvalue(&$1);
 424                         sdb_data_free_datum(&$1);
 425                 }
 426         ;
 427
 428 op:
 429         CMP_EQUAL { $$ = "="; }
 430         |
 431         CMP_NEQUAL { $$ = "!="; }
 432         |
 433         CMP_REGEX { $$ = "=~"; }
 434         |
 435         CMP_NREGEX { $$ = "!~"; }
 436         |
 437         CMP_LT { $$ = "<"; }
 438         |
 439         CMP_LE { $$ = "<="; }
 440         |
 441         CMP_GE { $$ = ">="; }
 442         |
 443         CMP_GT { $$ = ">"; }
 444         ;
 445
 446 data:
 447         STRING { $$.type = SDB_TYPE_STRING; $$.data.string = $1; }
 448         |
 449         INTEGER { $$ = $1; }
 450         |
 451         FLOAT { $$ = $1; }
 452         |
 453         interval { $$ = $1; }
 454         ;
 455
 456 interval:
 457         interval interval_elem
 458                 {
 459                         $$.data.datetime = $1.data.datetime + $2.data.datetime;
 460                 }
 461         |
 462         interval_elem { $$ = $1; }
 463         ;
 464
 465 interval_elem:
 466         INTEGER IDENTIFIER
 467                 {
 468                         sdb_time_t unit = 1;
 469
 470                         unit = sdb_strpunit($2);
 471                         if (! unit) {
 472                                 char errmsg[strlen($2) + 32];
 473                                 snprintf(errmsg, sizeof(errmsg),
 474                                                 YY_("invalid time unit %s"), $2);
 475                                 sdb_fe_yyerror(&yylloc, scanner, errmsg);
 476                                 free($2); $2 = NULL;
 477                                 YYABORT;
 478                         }
 479                         free($2); $2 = NULL;
 480
 481                         $$.type = SDB_TYPE_DATETIME;
 482                         $$.data.datetime = (sdb_time_t)$1.data.integer * unit;
 483
 484                         if ($1.data.integer < 0) {
 485                                 sdb_fe_yyerror(&yylloc, scanner,
 486                                                 YY_("syntax error, negative intervals not supported"));
 487                                 YYABORT;
 488                         }
 489                 }
 490         ;
 491
 492 %%
 493
 494 void
 495 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg)
 496 {
 497         sdb_log(SDB_LOG_ERR, "frontend: parse error: %s", msg);
 498 } /* sdb_fe_yyerror */
 499
 500 /* vim: set tw=78 sw=4 ts=4 noexpandtab : */
 501