57174290b00dc97c00aa50d9e1d6841ff45f3dad
1 /*
2 * SysDB - src/frontend/grammar.y
3 * Copyright (C) 2013 Sebastian 'tokkee' Harl <sh@tokkee.org>
4 * All rights reserved.
5 *
6 * Redistribution and use in source and binary forms, with or without
7 * modification, are permitted provided that the following conditions
8 * are met:
9 * 1. Redistributions of source code must retain the above copyright
10 * notice, this list of conditions and the following disclaimer.
11 * 2. Redistributions in binary form must reproduce the above copyright
12 * notice, this list of conditions and the following disclaimer in the
13 * documentation and/or other materials provided with the distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
17 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
18 * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19 * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
20 * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
21 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
22 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
23 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
24 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
25 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
26 */
28 %{
30 #include "frontend/connection-private.h"
31 #include "frontend/parser.h"
32 #include "frontend/grammar.h"
34 #include "core/store.h"
35 #include "core/store-private.h"
37 #include "utils/error.h"
38 #include "utils/llist.h"
40 #include <stdio.h>
41 #include <string.h>
43 int
44 sdb_fe_yylex(YYSTYPE *yylval, YYLTYPE *yylloc, sdb_fe_yyscan_t yyscanner);
46 sdb_fe_yyextra_t *
47 sdb_fe_yyget_extra(sdb_fe_yyscan_t scanner);
49 void
50 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg);
52 /* quick access to the current parse tree */
53 #define pt sdb_fe_yyget_extra(scanner)->parsetree
55 /* quick access to the parser mode */
56 #define parser_mode sdb_fe_yyget_extra(scanner)->mode
58 %}
60 %pure-parser
61 %lex-param {sdb_fe_yyscan_t scanner}
62 %parse-param {sdb_fe_yyscan_t scanner}
63 %locations
64 %error-verbose
65 %expect 0
66 %name-prefix "sdb_fe_yy"
68 %union {
69 const char *sstr; /* static string */
70 char *str;
72 sdb_data_t data;
74 sdb_llist_t *list;
75 sdb_conn_node_t *node;
77 sdb_store_matcher_t *m;
78 sdb_store_expr_t *expr;
79 }
81 %start statements
83 %token SCANNER_ERROR
85 %token AND OR IS NOT MATCHING
86 %token CMP_EQUAL CMP_NEQUAL CMP_REGEX CMP_NREGEX
87 %token CMP_LT CMP_LE CMP_GE CMP_GT
88 %token CONCAT
90 /* NULL token */
91 %token NULL_T
93 %token FETCH LIST LOOKUP
95 %token <str> IDENTIFIER STRING
97 %token <data> INTEGER FLOAT
99 /* Precedence (lowest first): */
100 %left OR
101 %left AND
102 %right NOT
103 %left CMP_EQUAL CMP_NEQUAL
104 %left CMP_LT CMP_LE CMP_GE CMP_GT
105 %nonassoc CMP_REGEX CMP_NREGEX
106 %left CONCAT
107 %nonassoc IS
108 %left '+' '-'
109 %left '*' '/' '%'
110 %left '(' ')'
111 %left '.'
113 %type <list> statements
114 %type <node> statement
115 fetch_statement
116 list_statement
117 lookup_statement
118 condition
120 %type <m> matcher
121 compare_matcher
123 %type <expr> expression
125 %type <sstr> op
127 %type <data> data
128 interval interval_elem
130 %destructor { free($$); } <str>
131 %destructor { sdb_object_deref(SDB_OBJ($$)); } <node> <m> <expr>
133 %%
135 statements:
136 statements ';' statement
137 {
138 /* only accept this in default parse mode */
139 if (parser_mode != SDB_PARSE_DEFAULT) {
140 sdb_fe_yyerror(&yylloc, scanner,
141 YY_("syntax error, unexpected statement, "
142 "expecting condition"));
143 sdb_object_deref(SDB_OBJ($3));
144 YYABORT;
145 }
147 if ($3) {
148 sdb_llist_append(pt, SDB_OBJ($3));
149 sdb_object_deref(SDB_OBJ($3));
150 }
151 }
152 |
153 statement
154 {
155 /* only accept this in default parse mode */
156 if (parser_mode != SDB_PARSE_DEFAULT) {
157 sdb_fe_yyerror(&yylloc, scanner,
158 YY_("syntax error, unexpected statement, "
159 "expecting condition"));
160 sdb_object_deref(SDB_OBJ($1));
161 YYABORT;
162 }
164 if ($1) {
165 sdb_llist_append(pt, SDB_OBJ($1));
166 sdb_object_deref(SDB_OBJ($1));
167 }
168 }
169 |
170 condition
171 {
172 /* only accept this in condition parse mode */
173 if (! (parser_mode & SDB_PARSE_COND)) {
174 sdb_fe_yyerror(&yylloc, scanner,
175 YY_("syntax error, unexpected condition, "
176 "expecting statement"));
177 sdb_object_deref(SDB_OBJ($1));
178 YYABORT;
179 }
181 if ($1) {
182 sdb_llist_append(pt, SDB_OBJ($1));
183 sdb_object_deref(SDB_OBJ($1));
184 }
185 }
186 ;
188 statement:
189 fetch_statement
190 |
191 list_statement
192 |
193 lookup_statement
194 |
195 /* empty */
196 {
197 $$ = NULL;
198 }
199 ;
201 /*
202 * FETCH <hostname>;
203 *
204 * Retrieve detailed information about a single host.
205 */
206 fetch_statement:
207 FETCH STRING
208 {
209 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
210 conn_fetch_t, conn_fetch_destroy));
211 CONN_FETCH($$)->name = strdup($2);
212 $$->cmd = CONNECTION_FETCH;
213 free($2); $2 = NULL;
214 }
215 ;
217 /*
218 * LIST;
219 *
220 * Returns a list of all hosts in the store.
221 */
222 list_statement:
223 LIST
224 {
225 $$ = SDB_CONN_NODE(sdb_object_create_T(/* name = */ NULL,
226 sdb_conn_node_t));
227 $$->cmd = CONNECTION_LIST;
228 }
229 ;
231 /*
232 * LOOKUP <type> MATCHING <condition>;
233 *
234 * Returns detailed information about <type> matching condition.
235 */
236 lookup_statement:
237 LOOKUP IDENTIFIER MATCHING condition
238 {
239 /* TODO: support other types as well */
240 if (strcasecmp($2, "hosts")) {
241 char errmsg[strlen($2) + 32];
242 snprintf(errmsg, sizeof(errmsg),
243 YY_("unknown table %s"), $2);
244 sdb_fe_yyerror(&yylloc, scanner, errmsg);
245 free($2); $2 = NULL;
246 sdb_object_deref(SDB_OBJ($4));
247 YYABORT;
248 }
250 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
251 conn_lookup_t, conn_lookup_destroy));
252 CONN_LOOKUP($$)->matcher = CONN_MATCHER($4);
253 $$->cmd = CONNECTION_LOOKUP;
254 free($2); $2 = NULL;
255 }
256 ;
258 condition:
259 matcher
260 {
261 if (! $1) {
262 /* TODO: improve error reporting */
263 sdb_fe_yyerror(&yylloc, scanner,
264 YY_("syntax error, invalid condition"));
265 YYABORT;
266 }
268 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
269 conn_node_matcher_t, conn_matcher_destroy));
270 $$->cmd = CONNECTION_EXPR;
271 CONN_MATCHER($$)->matcher = $1;
272 }
273 ;
275 matcher:
276 '(' matcher ')'
277 {
278 $$ = $2;
279 }
280 |
281 matcher AND matcher
282 {
283 $$ = sdb_store_con_matcher($1, $3);
284 sdb_object_deref(SDB_OBJ($1));
285 sdb_object_deref(SDB_OBJ($3));
286 }
287 |
288 matcher OR matcher
289 {
290 $$ = sdb_store_dis_matcher($1, $3);
291 sdb_object_deref(SDB_OBJ($1));
292 sdb_object_deref(SDB_OBJ($3));
293 }
294 |
295 NOT matcher
296 {
297 $$ = sdb_store_inv_matcher($2);
298 sdb_object_deref(SDB_OBJ($2));
299 }
300 |
301 compare_matcher
302 {
303 $$ = $1;
304 }
305 ;
307 /*
308 * <object_type>.<object_attr> <op> <value>
309 *
310 * Parse matchers comparing object attributes with a value.
311 */
312 compare_matcher:
313 ':' IDENTIFIER op expression
314 {
315 $$ = sdb_store_matcher_parse_field_cmp($2, $3, $4);
316 free($2); $2 = NULL;
317 sdb_object_deref(SDB_OBJ($4));
318 }
319 |
320 IDENTIFIER op expression
321 {
322 $$ = sdb_store_matcher_parse_cmp($1, NULL, $2, $3);
323 free($1); $1 = NULL;
324 sdb_object_deref(SDB_OBJ($3));
325 }
326 |
327 IDENTIFIER '.' IDENTIFIER op expression
328 {
329 $$ = sdb_store_matcher_parse_cmp($1, $3, $4, $5);
330 free($1); $1 = NULL;
331 free($3); $3 = NULL;
332 sdb_object_deref(SDB_OBJ($5));
333 }
334 |
335 IDENTIFIER '.' IDENTIFIER IS NULL_T
336 {
337 $$ = sdb_store_matcher_parse_cmp($1, $3, "IS", NULL);
338 free($1); $1 = NULL;
339 free($3); $3 = NULL;
340 }
341 |
342 IDENTIFIER '.' IDENTIFIER IS NOT NULL_T
343 {
344 sdb_store_matcher_t *m;
345 m = sdb_store_matcher_parse_cmp($1, $3, "IS", NULL);
346 free($1); $1 = NULL;
347 free($3); $3 = NULL;
349 /* sdb_store_inv_matcher return NULL if m==NULL */
350 $$ = sdb_store_inv_matcher(m);
351 sdb_object_deref(SDB_OBJ(m));
352 }
353 ;
355 expression:
356 '(' expression ')'
357 {
358 $$ = $2;
359 }
360 |
361 expression '+' expression
362 {
363 $$ = sdb_store_expr_create(SDB_DATA_ADD, $1, $3);
364 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
365 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
366 }
367 |
368 expression '-' expression
369 {
370 $$ = sdb_store_expr_create(SDB_DATA_SUB, $1, $3);
371 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
372 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
373 }
374 |
375 expression '*' expression
376 {
377 $$ = sdb_store_expr_create(SDB_DATA_MUL, $1, $3);
378 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
379 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
380 }
381 |
382 expression '/' expression
383 {
384 $$ = sdb_store_expr_create(SDB_DATA_DIV, $1, $3);
385 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
386 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
387 }
388 |
389 expression '%' expression
390 {
391 $$ = sdb_store_expr_create(SDB_DATA_MOD, $1, $3);
392 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
393 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
394 }
395 |
396 data
397 {
398 $$ = sdb_store_expr_constvalue(&$1);
399 sdb_data_free_datum(&$1);
400 }
401 ;
403 op:
404 CMP_EQUAL { $$ = "="; }
405 |
406 CMP_NEQUAL { $$ = "!="; }
407 |
408 CMP_REGEX { $$ = "=~"; }
409 |
410 CMP_NREGEX { $$ = "!~"; }
411 |
412 CMP_LT { $$ = "<"; }
413 |
414 CMP_LE { $$ = "<="; }
415 |
416 CMP_GE { $$ = ">="; }
417 |
418 CMP_GT { $$ = ">"; }
419 ;
421 data:
422 STRING { $$.type = SDB_TYPE_STRING; $$.data.string = $1; }
423 |
424 INTEGER { $$ = $1; }
425 |
426 FLOAT { $$ = $1; }
427 |
428 interval { $$ = $1; }
429 ;
431 interval:
432 interval interval_elem
433 {
434 $$.data.datetime = $1.data.datetime + $2.data.datetime;
435 }
436 |
437 interval_elem { $$ = $1; }
438 ;
440 interval_elem:
441 INTEGER IDENTIFIER
442 {
443 sdb_time_t unit = 1;
445 unit = sdb_strpunit($2);
446 if (! unit) {
447 char errmsg[strlen($2) + 32];
448 snprintf(errmsg, sizeof(errmsg),
449 YY_("invalid time unit %s"), $2);
450 sdb_fe_yyerror(&yylloc, scanner, errmsg);
451 free($2); $2 = NULL;
452 YYABORT;
453 }
454 free($2); $2 = NULL;
456 $$.type = SDB_TYPE_DATETIME;
457 $$.data.datetime = (sdb_time_t)$1.data.integer * unit;
459 if ($1.data.integer < 0) {
460 sdb_fe_yyerror(&yylloc, scanner,
461 YY_("syntax error, negative intervals not supported"));
462 YYABORT;
463 }
464 }
465 ;
467 %%
469 void
470 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg)
471 {
472 sdb_log(SDB_LOG_ERR, "frontend: parse error: %s", msg);
473 } /* sdb_fe_yyerror */
475 /* vim: set tw=78 sw=4 ts=4 noexpandtab : */