configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.5])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3005
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which versions the library are compatible with
  23 dnl each other we must keep a separate library version cout of the format c:r:a.
  24 dnl - if only implementation changed but all interfaces are kept, do r++
  25 dnl - if only functionality was added do c++,r=0,a++
  26 dnl - if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=4:4:0
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AM_INIT_AUTOMAKE
  35 AM_MAINTAINER_MODE
  36
  37 AC_CONFIG_HEADERS([rrd_config.h])
  38
  39 dnl all our local stuff like install scripts and include files
  40 dnl is in there
  41
  42
  43 dnl determine the type of system we are running on
  44
  45 AC_SUBST(VERSION)
  46
  47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  48
  49 dnl Minimum Autoconf version required.
  50 AC_PREREQ(2.59)
  51
  52 dnl At the TOP of the HEADER
  53
  54 AH_TOP([
  55 #ifndef RRD_CONFIG_H
  56 #define RRD_CONFIG_H
  57
  58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  59 #undef MUST_DISABLE_FPMASK
  60
  61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  62 #undef MUST_DISABLE_SIGFPE
  63
  64 /* realloc does not support NULL as argument */
  65 #undef NO_NULL_REALLOC
  66
  67 /* lets enable madvise defines in NetBSD */
  68 #if defined(__NetBSD__)
  69 # if !defined(_NETBSD_SOURCE)
  70 #  define _NETBSD_SOURCE
  71 # endif
  72 #endif
  73
  74 ])
  75
  76 AH_BOTTOM([
  77
  78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  79 #  include <malloc/malloc.h>
  80 #endif
  81
  82 #include <rrd_config_bottom.h>
  83
  84 #endif
  85 ])
  86
  87 dnl Process Special Options
  88 dnl -----------------------------------
  89
  90 dnl How the vertical axis label is printed
  91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  92  [Vertical label angle: -90.0 (default) or 90.0])
  93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  94  [Vertical label angle: -90.0 (default) or 90.0])
  95
  96 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
  97 [],[enable_rrdcgi=yes])
  98
  99 dnl Check if we run on a system that has fonts
 100 AC_ARG_WITH(rrd-default-font,
 101 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 102 [RRD_DEFAULT_FONT=$withval],[
 103   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 104         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 105   else
 106         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 107   fi
 108 ])
 109
 110 dnl Use mmap in rrd_update instead of seek+write
 111 AC_ARG_ENABLE([mmap],
 112 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 113 [],
 114 [enable_mmap=yes])
 115
 116 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 117 [],[enable_pthread=yes])
 118
 119 AC_ARG_ENABLE(static-programs,
 120      [  --enable-static-programs  Build static programs],
 121      [case "${enableval}" in
 122        yes) staticprogs=yes ;;
 123        no)  staticprogs=no ;;
 124        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 125      esac],[staticprogs=no])
 126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 127
 128
 129 CONFIGURE_PART(Audit Compilation Environment)
 130
 131
 132 dnl Check for the compiler and static/shared library creation.
 133 AC_PROG_CC
 134 AC_PROG_CPP
 135 AC_PROG_LIBTOOL
 136
 137 dnl Try to detect/use GNU features
 138 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 139
 140 dnl which flags does the compiler support?
 141 if test "x$GCC" = "xyes"; then
 142   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 143     oCFLAGS="$CFLAGS"
 144     CFLAGS="$CFLAGS $flag"
 145     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 146     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 147        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 148     if eval test \$$cachename = no; then
 149          CFLAGS="$oCFLAGS"
 150     fi
 151   done
 152 fi
 153
 154
 155
 156 AC_SUBST(RRD_DEFAULT_FONT)
 157
 158 CONFIGURE_PART(Checking for Header Files)
 159
 160 dnl Checks for header files.
 161 AC_HEADER_STDC
 162 AC_HEADER_DIRENT
 163 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 164
 165 dnl Checks for typedefs, structures, and compiler characteristics.
 166 AC_C_CONST
 167 AC_HEADER_TIME
 168 AC_STRUCT_TM
 169
 170 CONFIGURE_PART(Test Library Functions)
 171
 172 dnl Checks for libraries.
 173 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 174
 175
 176 dnl add pic flag in any case this makes sure all our code is relocatable
 177 eval `./libtool --config | grep pic_flag`
 178 CFLAGS="$CFLAGS $pic_flag"
 179
 180
 181 dnl Checks for library functions.
 182 AC_FUNC_STRFTIME
 183 AC_FUNC_VPRINTF
 184
 185 AC_C_BIGENDIAN
 186
 187 dnl for each function found we get a definition in config.h
 188 dnl of the form HAVE_FUNCTION
 189
 190 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 191
 192 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 193
 194 dnl Could use these to know if we need to provide a prototype
 195 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 196
 197 dnl check for fdatasync. Solaris has fdatasync in the librt
 198
 199 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 200 dnl if there is no fdatasync we may get lucky with fsync
 201 AC_CHECK_FUNCS(fsync)
 202
 203
 204 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 205 if test "x$enable_mmap" = "xyes"; then
 206   case "$host" in
 207   *cygwin*)
 208     # the normal mmap test does not work in cygwin
 209     AC_CHECK_FUNCS(mmap)
 210     if test "x$ac_cv_func_mmap" = "xyes"; then
 211       ac_cv_func_mmap_fixed_mapped=yes
 212     fi
 213   ;;
 214   *)
 215     AC_CHECK_HEADERS(sys/mman.h)
 216     AC_FUNC_MMAP
 217     AC_CHECK_FUNCS(mmap munmap msync)
 218     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 219                                      # include <sys/mman.h>
 220                                      #endif])
 221     if test "x$ac_cv_have_decl_madvise" = "xyes";
 222     then
 223       AC_CHECK_FUNCS(madvise)
 224     else
 225       AC_CHECK_FUNCS(posix_madvise)
 226       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 227         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 228       fi
 229     fi
 230   ;;
 231   esac
 232   if test "x$ac_cv_func_mmap" != "xyes";
 233   then
 234     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 235 dnl enable_mmap="no"
 236   fi
 237 fi
 238
 239 dnl can we use posix_fadvise
 240 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 241 #include <fcntl.h>])
 242 AC_CHECK_FUNCS(posix_fadvise)
 243
 244 CONFIGURE_PART(Libintl Processing)
 245
 246
 247 dnl gettext
 248 GETTEXT_PACKAGE=rrdtool
 249 AC_SUBST(GETTEXT_PACKAGE)
 250 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 251
 252 AM_GLIB_GNU_GETTEXT()
 253
 254 AC_ARG_ENABLE(libintl,[  --disable-libintl        i18n support (libintl)],
 255 [],[enable_libintl=yes])
 256
 257 if test x$enable_libintl = xyes; then
 258   IT_PROG_INTLTOOL([0.35.0],[no-xml])
 259 fi
 260
 261 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
 262   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
 263   enable_libintl=no
 264 fi
 265
 266 if test x$enable_libintl = xyes; then
 267   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
 268 fi
 269
 270 if test x$enable_libintl = xyes ; then
 271   dnl it seems bsd synstems need to link against libintl
 272   dnl when compiling rrdupdate. lets check
 273   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
 274 fi
 275
 276 dnl use for linking rrdupdate
 277 AC_SUBST(LIB_LIBINTL)
 278
 279 dnl do not touch the po stuff if we are not going to build intl
 280 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
 281
 282 if test x$enable_libintl = xyes; then
 283    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
 284 fi
 285
 286 CONFIGURE_PART(IEEE Math Checks)
 287
 288
 289 dnl actual code to check if this works
 290 AC_CHECK_FUNCS(fpclassify, ,
 291   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 292     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 293 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 294       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 295
 296 AC_CHECK_FUNCS(isinf, ,
 297   [AC_MSG_CHECKING(for isinf with <math.h>)
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 299 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 300       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 301
 302 dnl finite is BSD, isfinite is C99, so prefer the latter
 303 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 304 AC_TRY_RUN([
 305 #ifdef HAVE_MATH_H
 306 #include <math.h>
 307 #endif
 308 #ifdef HAVE_FLOAT_H
 309 #include <float.h>
 310 #endif
 311 int main ()
 312 {
 313 #ifdef isfinite
 314 #ifdef LDBL_MAX
 315   if (!isfinite(LDBL_MAX)) return 1;
 316 #endif
 317 #ifdef DBL_MAX
 318   if (!isfinite(DBL_MAX)) return 1;
 319 #endif
 320 #endif
 321 return 0;
 322 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 323 case "${target}" in
 324   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 325   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 326   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 327   *) ac_cv_have_broken_isfinite=no ;;
 328 esac])
 329 ])
 330
 331 dnl the test does not seem to work on solaris 2.8/9
 332 dnl so lets fix this by hand
 333 case "${target}" in
 334   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 335   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 336 esac
 337
 338 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 339   AC_DEFINE(HAVE_ISFINITE)
 340 else
 341   AC_CHECK_FUNCS(finite,[],
 342       [AC_CHECK_FUNCS(isfinite,[],
 343          [AC_MSG_CHECKING(for isfinite with <math.h>)
 344           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 345 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 346                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 347 fi
 348
 349 AC_FULL_IEEE
 350
 351 CONFIGURE_PART(Resolve Portability Issues)
 352
 353 CHECK_FOR_WORKING_MS_ASYNC
 354
 355 dnl Do we need getopt_long
 356
 357 build_getopt=no
 358 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 359 AC_CHECK_FUNC(getopt_long,[],[
 360 RRD_GETOPT_LONG="getopt_long"
 361 build_getopt=yes
 362 ])
 363 AC_SUBST(RRD_GETOPT_LONG)
 364 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 365
 366 dnl what does realloc do if it gets called with a NULL pointer
 367
 368 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 369 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 370               int main(void){
 371               char *x = NULL;
 372               x = realloc (x,10);
 373               if (x==NULL) return 1;
 374               return 0;
 375              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 376
 377 if test x"$rd_cv_null_realloc" = xnope; then
 378 AC_DEFINE(NO_NULL_REALLOC)
 379 fi
 380
 381 AC_LANG_PUSH(C)
 382 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 383 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 384 AC_LINK_IFELSE(
 385     AC_LANG_PROGRAM(
 386            [[#include <time.h>]],
 387            [[ctime_r(NULL,NULL,0)]]
 388                    ),
 389     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 390       AC_LINK_IFELSE(
 391           AC_LANG_PROGRAM(
 392                 [[#include <time.h>]],
 393                 [[ctime_r(NULL,NULL)]]
 394                          ),
 395           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 396           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 397       )
 398     ],
 399     [ AC_LINK_IFELSE(
 400           AC_LANG_PROGRAM(
 401                 [[#include <time.h>]],
 402                 [[ctime_r(NULL,NULL)]]
 403                          ),
 404           [AC_MSG_RESULT(no)],
 405           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 406       )
 407     ]
 408 )
 409 AC_LANG_POP(C)
 410
 411 dnl Check for pthreads
 412 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 413
 414 AC_SUBST(MULTITHREAD_CFLAGS)
 415 AC_SUBST(MULTITHREAD_LDFLAGS)
 416
 417 if test $enable_pthread != no; then
 418  ACX_PTHREAD([
 419     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 420     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 421              ],
 422              [])
 423 fi
 424
 425 dnl since we use lots of *_r functions all over the code we better
 426 dnl make sure they are known
 427
 428 if test  "x$x_rflag" != "xno"; then
 429    CPPFLAGS="$CPPFLAGS $x_rflag"
 430 fi
 431
 432 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 433
 434 AC_LANG_PUSH(C)
 435 dnl see if we have to include malloc/malloc.h
 436 AC_MSG_CHECKING([do we need malloc/malloc.h])
 437 AC_LINK_IFELSE(
 438     AC_LANG_PROGRAM(
 439            [[#include <stdlib.h>]],
 440            [[malloc(1)]]
 441                    ),
 442     [ AC_MSG_RESULT([nope, works out of the box]) ],
 443     [ AC_LINK_IFELSE(
 444           AC_LANG_PROGRAM(
 445                 [[#include <stdlib.h>
 446                   #include <malloc/malloc.h>]],
 447                 [[malloc(1)]]
 448                          ),[
 449            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 450            AC_MSG_RESULT([yes we do])],
 451           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 452       )
 453     ]
 454 )
 455 AC_LANG_POP(C)
 456
 457 CONFIGURE_PART(Find 3rd-Party Libraries)
 458
 459
 460 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 461
 462
 463 CORE_LIBS="$LIBS"
 464
 465 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 466 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 467 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 468 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 469 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 470 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 471 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 472 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 473 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 474 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 475 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 476
 477 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 478   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 479 fi
 480
 481 ALL_LIBS="$LIBS"
 482 LIBS=
 483
 484 AC_SUBST(CORE_LIBS)
 485 AC_SUBST(ALL_LIBS)
 486
 487 CONFIGURE_PART(Prep for Building Language Bindings)
 488
 489 dnl Check for Perl and friends
 490 PATH=$PATH:/usr/perl5/bin
 491 export PATH
 492 AC_PATH_PROG(PERL, perl, no)
 493 AC_PATH_PROG(POD2MAN, pod2man, no)
 494 AC_PATH_PROG(POD2HTML, pod2html, no)
 495
 496
 497 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 498 [],[enable_perl=yes])
 499
 500
 501 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 502 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 503 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 504 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 505
 506 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 507         COMP_PERL=
 508 else
 509         COMP_PERL="perl_piped perl_shared"
 510         AC_MSG_CHECKING(for the perl version you are running)
 511         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 512         AC_MSG_RESULT($PERL_VERSION)
 513         if test -z "$PERLCC"; then
 514             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 515             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 516             AC_MSG_RESULT($perlcc)
 517             if test ! -x "$perlcc"; then
 518                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 519                 if test "$PERL_CC" = "no"; then
 520                     AC_MSG_WARN([
 521 I would not find the Compiler ($perlcc) that was originally used to compile
 522 your perl binary. You should either make sure that this compiler is
 523 available on your system, pick an other compiler and set PERLCC
 524 appropriately, or use a different perl setup that was compiled locally.
 525
 526 I will disable the compilation of the RRDs perl module for now.
 527 ])
 528                     COMP_PERL="perl_piped"
 529                 fi
 530             fi
 531         fi
 532 fi
 533
 534 AC_MSG_CHECKING(Perl Modules to build)
 535 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 536
 537 # Options to pass when configuring perl module
 538 ppref=$prefix
 539 test "$ppref" = 'NONE' && ppref=$ac_default_prefix
 540
 541 PERL_MAKE_OPTIONS="PREFIX="'$(DESTDIR)'"$ppref LIB="'$(DESTDIR)'"$ppref/lib/perl/$PERL_VERSION"
 542
 543 dnl pass additional perl options when generating Makefile from Makefile.PL
 544 AC_ARG_ENABLE(perl-site-install,
 545 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 546                           together with rrdtool in $prefix/lib/perl. You have to
 547                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 548                           when you want to use them. When you set this option
 549                           the perl modules will get installed wherever
 550                           your perl setup thinks it is best.],
 551 [PERL_MAKE_OPTIONS=],[])
 552
 553 if test ! -z "$PERLCC"; then
 554    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 555
 556    if test ! -z "$PERLCCFLAGS"; then
 557        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 558    fi
 559
 560    if test -z "$PERLLD"; then
 561        PERLLD=$PERLCC
 562    fi
 563    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 564
 565    if test ! -z "$PERLLDFLAGS"; then
 566        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 567    fi
 568 fi
 569
 570 AC_ARG_WITH(perl-options,
 571 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 572                           generating Makefile from Makefile.PL. If you set this
 573                           option, interesting things may happen unless you know
 574                           what you are doing!],
 575 [PERL_MAKE_OPTIONS=$withval])
 576
 577 AC_SUBST(PERL_MAKE_OPTIONS)
 578 AC_SUBST(PERL)
 579 AC_SUBST(COMP_PERL)
 580 AC_SUBST(PERL_VERSION)
 581
 582 dnl Check for Ruby.
 583 AC_PATH_PROG(RUBY, ruby, no)
 584
 585 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 586 [],[enable_ruby=yes])
 587
 588 AC_MSG_CHECKING(if ruby modules can be built)
 589
 590 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 591         COMP_RUBY=
 592         AC_MSG_RESULT(No .. Ruby not found or disabled)
 593 else
 594         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 595                 COMP_RUBY="ruby"
 596                 AC_MSG_RESULT(YES)
 597         else
 598                 COMP_RUBY=
 599                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 600         fi
 601 fi
 602
 603 rpref=$prefix
 604 test "$rpref" = 'NONE' && rpref=$ac_default_prefix
 605
 606 dnl pass additional ruby options when generating Makefile from Makefile.PL
 607 AC_ARG_ENABLE(ruby-site-install,
 608 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 609                           together with rrdtool in $prefix/lib/ruby. You have to
 610                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 611                           for ruby to find the RRD.so file.],
 612 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$rpref/lib/ruby"])
 613
 614
 615 AC_ARG_WITH(ruby-options,
 616 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 617                           generating Makefile from extconf.rb. If you set this
 618                           option, interesting things may happen unless you know
 619                           what you are doing!],
 620 [RUBY_MAKE_OPTIONS=$withval])
 621
 622 AC_SUBST(RUBY_MAKE_OPTIONS)
 623 AC_SUBST(RUBY)
 624 AC_SUBST(COMP_RUBY)
 625
 626
 627 enable_tcl_site=no
 628
 629 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 630 [],[enable_tcl=yes])
 631
 632 if test  "$enable_tcl" = "yes"; then
 633   dnl Check for Tcl.
 634   withval=""
 635   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 636   enable_tcl=no
 637   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 638     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 639     if test -f "$dir/tclConfig.sh" ; then
 640         tcl_config=$dir/tclConfig.sh
 641         enable_tcl=yes
 642         AC_MSG_RESULT(yes)
 643         break
 644     else
 645         AC_MSG_RESULT(no)
 646     fi
 647   done
 648
 649   if test "$enable_tcl" = "no"; then
 650         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 651   else
 652         . $tcl_config
 653         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 654         if test -n "$TCL_INC_DIR"; then
 655           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 656         fi
 657   fi
 658   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 659   [],[enable_tcl_site=yes])
 660
 661 fi
 662
 663 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 664 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 665
 666
 667 AC_SUBST(TCL_PREFIX)
 668 AC_SUBST(TCL_SHLIB_CFLAGS)
 669 AC_SUBST(TCL_SHLIB_LD)
 670 AC_SUBST(TCL_SHLIB_SUFFIX)
 671 AC_SUBST(TCL_PACKAGE_PATH)
 672 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 673 AC_SUBST(TCL_STUB_LIB_SPEC)
 674 AC_SUBST(TCL_VERSION)
 675 AC_SUBST(TCL_PACKAGE_DIR)
 676 AC_SUBST(TCL_INCLUDE_SPEC)
 677
 678 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 679 [],[enable_python=yes])
 680
 681 if test  "$enable_python" = "yes"; then
 682 dnl Check for python
 683 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 684 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 685 fi
 686
 687 if test  x$enable_python = xno; then
 688         COMP_PYTHON=
 689 else
 690         COMP_PYTHON="python"
 691 fi
 692
 693 AC_SUBST(COMP_PYTHON)
 694
 695 dnl Check for nroff
 696 AC_PATH_PROGS(NROFF, gnroff nroff)
 697 AC_PATH_PROGS(TROFF, groff troff)
 698
 699 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 700 if test -z "$RRDDOCDIR"; then
 701    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 702
 703
 704 CONFIGURE_PART(Apply Configuration Information)
 705
 706 AC_CONFIG_FILES([examples/shared-demo.pl])
 707 AC_CONFIG_FILES([examples/piped-demo.pl])
 708 AC_CONFIG_FILES([examples/stripes.pl])
 709 AC_CONFIG_FILES([examples/bigtops.pl])
 710 AC_CONFIG_FILES([examples/minmax.pl])
 711 AC_CONFIG_FILES([examples/4charts.pl])
 712 AC_CONFIG_FILES([examples/perftest.pl])
 713 AC_CONFIG_FILES([examples/Makefile])
 714 AC_CONFIG_FILES([doc/Makefile])
 715 AC_CONFIG_FILES([po/Makefile.in])
 716 AC_CONFIG_FILES([src/Makefile])
 717 AC_CONFIG_FILES([src/librrd.sym.in])
 718 AC_CONFIG_FILES([src/librrd.pc])
 719 AC_CONFIG_FILES([bindings/Makefile])
 720 AC_CONFIG_FILES([bindings/tcl/Makefile])
 721 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 722 AC_CONFIG_FILES([Makefile])
 723
 724 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 725 AC_OUTPUT
 726
 727 AC_MSG_CHECKING(in)
 728 AC_MSG_RESULT(and out again)
 729
 730 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 731 sleep 1
 732 echo $ECHO_N ".$ECHO_C" 1>&6
 733 sleep 1
 734 echo $ECHO_N ".$ECHO_C" 1>&6
 735 sleep 1
 736 echo $ECHO_N ".$ECHO_C" 1>&6
 737 sleep 1
 738 echo $ECHO_N ".$ECHO_C" 1>&6
 739 sleep 1
 740 AC_MSG_RESULT([ just kidding ;-)])
 741 echo
 742 echo "----------------------------------------------------------------"
 743 echo "Config is DONE!"
 744 echo
 745 echo "          With MMAP IO: $enable_mmap"
 746 echo "      Build rrd_getopt: $build_getopt"
 747 echo "       Static programs: $staticprogs"
 748 echo "          Perl Modules: $COMP_PERL"
 749 echo "           Perl Binary: $PERL"
 750 echo "          Perl Version: $PERL_VERSION"
 751 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 752 echo "          Ruby Modules: $COMP_RUBY"
 753 echo "           Ruby Binary: $RUBY"
 754 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 755 echo "    Build Tcl Bindings: $enable_tcl"
 756 echo " Build Python Bindings: $enable_python"
 757 echo "          Build rrdcgi: $enable_rrdcgi"
 758 echo "       Build librrd MT: $enable_pthread"
 759 echo "     Link with libintl: $enable_libintl"
 760 echo
 761 echo "             Libraries: $ALL_LIBS"
 762 echo
 763 echo "Type 'make' to compile the software and use 'make install' to "
 764 echo "install everything to: $prefix."
 765 echo
 766 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 767 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 768 echo "place an order."
 769 echo
 770 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 771 echo "----------------------------------------------------------------"