plugins-scripts/check_ntp.pl

   1 #!/usr/bin/perl -w
   2
   3 # (c)1999 Ian Cass, Knowledge Matters Ltd.
   4 # Read the GNU copyright stuff for all the legalese
   5 #
   6 # Check NTP time servers plugin. This plugin requires the ntpdate utility to
   7 # be installed on the system, however since it's part of the ntp suite, you
   8 # should already have it installed.
   9 #
  10 # $Id$
  11 #
  12 # Nothing clever done in this program - its a very simple bare basics hack to
  13 # get the job done.
  14 #
  15 # Things to do...
  16 # check @words[9] for time differences greater than +/- x secs & return a
  17 # warning.
  18 #
  19 # (c) 1999 Mark Jewiss, Knowledge Matters Limited
  20 # 22-9-1999, 12:45
  21 #
  22 # Modified script to accept 2 parameters or set defaults.
  23 # Now issues warning or critical alert is time difference is greater than the
  24 # time passed.
  25 #
  26 # These changes have not been tested completely due to the unavailability of a
  27 # server with the incorrect time.
  28 #
  29 # (c) 1999 Bo Kersey, VirCIO - Managed Server Solutions <bo@vircio.com>
  30 # 22-10-99, 12:17
  31 #
  32 # Modified the script to give useage if no parameters are input.
  33 #
  34 # Modified the script to check for negative as well as positive
  35 # time differences.
  36 #
  37 # Modified the script to work with ntpdate 3-5.93e Wed Apr 14 20:23:03 EDT 1999
  38 #
  39 # Modified the script to work with ntpdate's that return adjust or offset...
  40 #
  41 #
  42 # Script modified 2000 June 01 by William Pietri <william@bianca.com>
  43 #
  44 # Modified script to handle weird cases:
  45 #     o NTP server doesn't respond (e.g., has died)
  46 #     o Server has correct time but isn't suitable synchronization
  47 #           source. This happens while starting up and if contact
  48 #           with master has been lost.
  49 #
  50 # Modifed to run under Embedded Perl  (sghosh@users.sf.net)
  51 #   - combined logic some blocks together..
  52 #
  53 # Added ntpdate check for stratum 16 desynch peer (James Fidell) Feb 03, 2003
  54 #
  55 # ntpdate - offset is in seconds
  56 # changed ntpdc to ntpq - jitter/dispersion is in milliseconds
  57 #
  58 # Patch for for regex for stratum1 refid.
  59
  60 require 5.004;
  61 use POSIX;
  62 use strict;
  63 use Getopt::Long;
  64 use vars qw($opt_V $opt_h $opt_H $opt_t $opt_w $opt_c $opt_j $opt_k $verbose $PROGNAME $def_jitter $ipv4 $ipv6);
  65 use lib utils.pm;
  66 use utils qw($TIMEOUT %ERRORS &print_revision &support);
  67
  68 $PROGNAME="check_ntp";
  69
  70 sub print_help ();
  71 sub print_usage ();
  72
  73 $ENV{'PATH'}='';
  74 $ENV{'BASH_ENV'}='';
  75 $ENV{'ENV'}='';
  76
  77 # defaults in sec
  78 my $DEFAULT_OFFSET_WARN =  60;  # 1 minute
  79 my $DEFAULT_OFFSET_CRIT = 120;  # 2 minutes
  80 # default in millisec
  81 my $DEFAULT_JITTER_WARN =   5000; # 5 sec
  82 my $DEFAULT_JITTER_CRIT =  10000; # 10 sec
  83
  84 Getopt::Long::Configure('bundling');
  85 GetOptions
  86         ("V"   => \$opt_V, "version"    => \$opt_V,
  87          "h"   => \$opt_h, "help"       => \$opt_h,
  88          "v"   => \$verbose, "verbose"  => \$verbose,
  89          "4"   => \$ipv4, "use-ipv4"    => \$ipv4,
  90          "6"   => \$ipv6, "use-ipv6"    => \$ipv6,
  91          "w=f" => \$opt_w, "warning=f"  => \$opt_w,   # offset|adjust warning if above this number
  92          "c=f" => \$opt_c, "critical=f" => \$opt_c,   # offset|adjust critical if above this number
  93          "j=s" => \$opt_j, "jwarn=i"    => \$opt_j,   # jitter warning if above this number
  94          "k=s" => \$opt_k, "jcrit=i"    => \$opt_k,   # jitter critical if above this number
  95          "t=s" => \$opt_t, "timeout=i"  => \$opt_t,
  96          "H=s" => \$opt_H, "hostname=s" => \$opt_H);
  97
  98 if ($opt_V) {
  99         print_revision($PROGNAME,'$Revision$ ');
 100         exit $ERRORS{'OK'};
 101 }
 102
 103 if ($opt_h) {
 104         print_help();
 105         exit $ERRORS{'OK'};
 106 }
 107
 108 # jitter test params specified
 109 if (defined $opt_j || defined $opt_k ) {
 110         $def_jitter = 1;
 111 }
 112
 113 $opt_H = shift unless ($opt_H);
 114 my $host = $1 if ($opt_H && $opt_H =~ m/^([0-9]+\.[0-9]+\.[0-9]+\.[0-9]+|[a-zA-Z][-a-zA-Z0-9]+(\.[a-zA-Z][-a-zA-Z0-9]+)*)$/);
 115 unless ($host) {
 116         print "No target host specified\n";
 117         print_usage();
 118         exit $ERRORS{'UNKNOWN'};
 119 }
 120
 121 my ($timeout, $owarn, $ocrit, $jwarn, $jcrit);
 122
 123 $timeout = $TIMEOUT;
 124 ($opt_t) && ($opt_t =~ /^([0-9]+)$/) && ($timeout = $1);
 125
 126 $owarn = $DEFAULT_OFFSET_WARN;
 127 ($opt_w) && ($opt_w =~ /^([0-9.]+)$/) && ($owarn = $1);
 128
 129 $ocrit = $DEFAULT_OFFSET_CRIT;
 130 ($opt_c) && ($opt_c =~ /^([0-9.]+)$/) && ($ocrit = $1);
 131
 132 $jwarn = $DEFAULT_JITTER_WARN;
 133 ($opt_j) && ($opt_j =~ /^([0-9]+)$/) && ($jwarn = $1);
 134
 135 $jcrit = $DEFAULT_JITTER_CRIT;
 136 ($opt_k) && ($opt_k =~ /^([0-9]+)$/) && ($jcrit = $1);
 137
 138 if ($ocrit < $owarn ) {
 139         print "Critical offset should be larger than warning offset\n";
 140         print_usage();
 141         exit $ERRORS{"UNKNOWN"};
 142 }
 143
 144 if ($def_jitter) {
 145         if ($opt_k < $opt_j) {
 146                 print "Critical jitter should be larger than warning jitter\n";
 147                 print_usage();
 148                 exit $ERRORS{'UNKNOWN'};
 149         }
 150 }
 151
 152
 153 my $stratum = -1;
 154 my $ignoreret = 0;
 155 my $answer = undef;
 156 my $offset = undef;
 157 my $jitter = undef;
 158 my $syspeer = undef;
 159 my $candidate = 0;
 160 my @candidates;
 161 my $msg; # first line of output to print if format is invalid
 162
 163 my $state = $ERRORS{'UNKNOWN'};
 164 my $ntpdate_error = $ERRORS{'UNKNOWN'};
 165 my $jitter_error = $ERRORS{'UNKNOWN'};
 166
 167 # some systems don't have a proper ntpq  (migrated from ntpdc)
 168 my $have_ntpq = undef;
 169 if ($utils::PATH_TO_NTPQ && -x $utils::PATH_TO_NTPQ ) {
 170         $have_ntpq = 1;
 171 }else{
 172         $have_ntpq = 0;
 173 }
 174
 175 # Just in case of problems, let's not hang Nagios
 176 $SIG{'ALRM'} = sub {
 177         print ("ERROR: No response from ntp server (alarm)\n");
 178         exit $ERRORS{"UNKNOWN"};
 179 };
 180 alarm($timeout);
 181
 182 # Determine protocol to be used for ntpdate and ntpq
 183 my $ntpdate = $utils::PATH_TO_NTPDATE;
 184 my $ntpq    = $utils::PATH_TO_NTPQ;
 185 if ($ipv4) {
 186         $ntpdate .= " -4";
 187         $ntpq .= " -4";
 188 }
 189 elsif ($ipv6) {
 190         $ntpdate .= " -6";
 191         $ntpq .= " -6";
 192 }
 193 # else don't use any flags
 194
 195 ###
 196 ###
 197 ### First, check ntpdate
 198 ###
 199 ###
 200
 201 if (!open (NTPDATE, $ntpdate . " -q $host 2>&1 |")) {
 202         print "Could not open ntpdate\n";
 203         exit $ERRORS{"UNKNOWN"};
 204 }
 205
 206 while (<NTPDATE>) {
 207         #print if ($verbose);  # noop
 208         $msg = $_ unless ($msg);
 209
 210         if (/stratum\s(\d+)/) {
 211                 $stratum = $1;
 212         }
 213
 214         if (/(offset|adjust)\s+([-.\d]+)/i) {
 215                 $offset = $2;
 216
 217                 # An offset of 0.000000 with an error is probably bogus. Actually,
 218                 # it's probably always bogus, but let's be paranoid here.
 219                 # Has been reported that 0.0000 happens in a production environment
 220                 # on Solaris 8 so this check should be taken out - SF tracker 1150777
 221                 #if ($offset == 0) { undef $offset;}
 222
 223                 $ntpdate_error = defined ($offset) ? $ERRORS{"OK"} : $ERRORS{"CRITICAL"};
 224                 print "ntperr = $ntpdate_error \n" if $verbose;
 225
 226         }
 227
 228         if (/no server suitable for synchronization found/) {
 229                 if ($stratum == 16) {
 230                         $ntpdate_error = $ERRORS{"WARNING"};
 231                         $msg = "Desynchronized peer server found";
 232                         $ignoreret=1;
 233                 }
 234                 else {
 235                         $ntpdate_error = $ERRORS{"CRITICAL"};
 236                         $msg = "No suitable peer server found - ";
 237                 }
 238         }
 239
 240 }
 241
 242 close (NTPDATE);
 243 # declare an error if we also get a non-zero return code from ntpdate
 244 # unless already set to critical
 245 if ( $? && !$ignoreret ) {
 246         print "stderr = $? : $! \n" if $verbose;
 247         $ntpdate_error = $ntpdate_error == $ERRORS{"CRITICAL"} ? $ERRORS{"CRITICAL"} : $ERRORS{"UNKNOWN"}  ;
 248         print "ntperr = $ntpdate_error : $!\n" if $verbose;
 249 }
 250
 251 ###
 252 ###
 253 ### Then scan xntpq/ntpq if it exists
 254 ### and look in the 11th column for jitter
 255 ###
 256 # Field 1: Tally Code ( Space, 'x','.','-','+','#','*','o')
 257 #           Only match for '*' which implies sys.peer
 258 #           or 'o' which implies pps.peer
 259 #           If both exist, the last one is picked.
 260 # Field 2: address of the remote peer
 261 # Field 3: Refid of the clock (0.0.0.0 if unknown, WWWV/PPS/GPS/ACTS/USNO/PCS/... if Stratum1)
 262 # Field 4: stratum (0-15)
 263 # Field 5: Type of the peer: local (l), unicast (u), multicast (m)
 264 #          broadcast (b); not sure about multicast/broadcast
 265 # Field 6: last packet receive (in seconds)
 266 # Field 7: polling interval
 267 # Field 8: reachability resgister (octal)
 268 # Field 9: delay
 269 # Field 10: offset
 270 # Field 11: dispersion/jitter
 271 #
 272 # According to bug 773588 Some solaris xntpd implementations seemto match on
 273 # "#" even though the docs say it exceeds maximum distance. Providing patch
 274 # here which will generate a warining.
 275
 276 if ($have_ntpq) {
 277
 278         if ( open(NTPQ, $ntpq . " -np $host 2>&1 |") ) {
 279                 while (<NTPQ>) {
 280                         print $_ if ($verbose);
 281                         if ( /timed out/ ){
 282                                 $have_ntpq = 0 ;
 283                                 last ;
 284                         }
 285                         # number of candidates on <host> for sys.peer
 286                         if (/^(\*|\+|\#|o])/) {
 287                                 ++$candidate;
 288                                 push (@candidates, $_);
 289                                 print "Candiate count= $candidate\n" if ($verbose);
 290                         }
 291
 292                         # match sys.peer or pps.peer
 293                         if (/^(\*|o)([-0-9.\s]+)\s+([-0-9A-Za-z.]+)\s+([-0-9.]+)\s+([lumb-]+)\s+([-0-9hm.]+)\s+([-0-9.mh]+)\s+([-0-9.]+)\s+([-0-9.]+)\s+([-0-9.]+)\s+([-0-9.]+)/) {
 294                                 $syspeer = $2;
 295                                 $stratum = $4;
 296                                 $jitter = $11;
 297                                 print "match $_ \n" if $verbose;
 298                                 if ($jitter > $jcrit) {
 299                                         print "Jitter_crit = $11 :$jcrit\n" if ($verbose);
 300                                         $jitter_error = $ERRORS{'CRITICAL'};
 301                                 } elsif ($jitter > $jwarn ) {
 302                                         print "Jitter_warn = $11 :$jwarn \n" if ($verbose);
 303                                         $jitter_error = $ERRORS{'WARNING'};
 304                                 } else {
 305                                         $jitter_error = $ERRORS{'OK'};
 306                                 }
 307                         }
 308
 309                 }
 310                 close NTPQ;
 311
 312                 # if we did not match sys.peer or pps.peer but matched # candidates only
 313                 # generate a warning
 314                 # based on bug id 773588
 315                 unless (defined $syspeer) {
 316                         if ($#candidates >=0) {
 317                                 foreach my $c (@candidates) {
 318                                         $c =~ /^(#)([-0-9.\s]+)\s+([-0-9A-Za-z.]+)\s+([-0-9.]+)\s+([lumb-]+)\s+([-0-9m.]+)\s+([-0-9.]+)\s+([-0-9.]+)\s+([-0-9.]+)\s+([-0-9.]+)\s+([-0-9.]+)/;
 319                                         $syspeer = $2;
 320                                         $stratum = $4;
 321                                         $jitter = $11;
 322                                         print "candidate match $c \n" if $verbose;
 323                                         if ($jitter > $jcrit) {
 324                                                 print "Candidate match - Jitter_crit = $11 :$jcrit\n" if ($verbose);
 325                                                 $jitter_error = $ERRORS{'CRITICAL'};
 326                                         }elsif ($jitter > $jwarn ) {
 327                                                 print "Candidate match - Jitter_warn = $11 :$jwarn \n" if ($verbose);
 328                                                 $jitter_error = $ERRORS{'WARNING'};
 329                                         } else {
 330                                                 $jitter_error = $ERRORS{'WARNING'};
 331                                         }
 332                                 }
 333
 334                         }
 335                 }
 336         }
 337 }
 338
 339
 340 if ($ntpdate_error != $ERRORS{'OK'}) {
 341         $state = $ntpdate_error;
 342         if ($ntpdate_error == $ERRORS{'WARNING'} ) {
 343                 $answer = $msg . "\n";
 344         }
 345         else {
 346                 $answer = $msg . "Server for ntp probably down\n";
 347         }
 348
 349         if (defined($offset) && abs($offset) > $ocrit) {
 350                 $state = $ERRORS{'CRITICAL'};
 351                 $answer = "Server Error and offset $offset sec > +/- $ocrit sec\n";
 352         } elsif (defined($offset) && abs($offset) > $owarn) {
 353                 $answer = "Server error and offset $offset sec > +/- $owarn sec\n";
 354         } elsif (defined($jitter) && abs($jitter) > $jcrit) {
 355                 $answer = "Server error and jitter $jitter msec > +/- $jcrit msec\n";
 356         } elsif (defined($jitter) && abs($jitter) > $jwarn) {
 357                 $answer = "Server error and jitter $jitter msec > +/- $jwarn msec\n";
 358         }
 359
 360 } elsif ($have_ntpq && $jitter_error != $ERRORS{'OK'}) {
 361         $state = $jitter_error;
 362         $answer = "Jitter $jitter too high\n";
 363         if (defined($offset) && abs($offset) > $ocrit) {
 364                 $state = $ERRORS{'CRITICAL'};
 365                 $answer = "Jitter error and offset $offset sec > +/- $ocrit sec\n";
 366         } elsif (defined($offset) && abs($offset) > $owarn) {
 367                 $answer = "Jitter error and offset $offset sec > +/- $owarn sec\n";
 368         } elsif (defined($jitter) && abs($jitter) > $jcrit) {
 369                 $answer = "Jitter error and jitter $jitter msec > +/- $jcrit msec\n";
 370         } elsif (defined($jitter) && abs($jitter) > $jwarn) {
 371                 $answer = "Jitter error and jitter $jitter msec > +/- $jwarn msec\n";
 372         }
 373
 374 } elsif( !$have_ntpq ) { # no errors from ntpdate and no ntpq or ntpq timed out
 375         if (abs($offset) > $ocrit) {
 376                 $state = $ERRORS{'CRITICAL'};
 377                 $answer = "Offset $offset sec > +/- $ocrit sec\n";
 378         } elsif (abs($offset) > $owarn) {
 379                 $state = $ERRORS{'WARNING'};
 380                 $answer = "Offset $offset sec > +/- $owarn sec\n";
 381         } elsif (( abs($offset) > $owarn) && $def_jitter ) {
 382                 $state = $ERRORS{'WARNING'};
 383                 $answer = "Offset $offset sec > +/- $owarn sec, ntpq timed out\n";
 384         } elsif ( $def_jitter ) {
 385                 $state = $ERRORS{'WARNING'};
 386                 $answer = "Offset $offset secs, ntpq timed out\n";
 387         } else{
 388                 $state = $ERRORS{'OK'};
 389                 $answer = "Offset $offset secs \n";
 390         }
 391
 392
 393
 394 } else { # no errors from ntpdate or ntpq
 395         if (abs($offset) > $ocrit) {
 396                 $state = $ERRORS{'CRITICAL'};
 397                 $answer = "Offset $offset sec > +/- $ocrit sec, jitter $jitter msec\n";
 398         } elsif (abs($jitter) > $jcrit ) {
 399                 $state = $ERRORS{'CRITICAL'};
 400                 $answer = "Jitter $jitter msec> +/- $jcrit msec, offset $offset sec \n";
 401         } elsif (abs($offset) > $owarn) {
 402                 $state = $ERRORS{'WARNING'};
 403                 $answer = "Offset $offset sec > +/- $owarn sec, jitter $jitter msec\n";
 404         } elsif (abs($jitter) > $jwarn ) {
 405                 $state = $ERRORS{'WARNING'};
 406                 $answer = "Jitter $jitter msec> +/- $jwarn msec, offset $offset sec \n";
 407
 408         } else {
 409                 $state = $ERRORS{'OK'};
 410                 $answer = "Offset $offset secs, jitter $jitter msec, peer is stratum $stratum\n";
 411         }
 412
 413 }
 414
 415 foreach my $key (keys %ERRORS) {
 416         if ($state==$ERRORS{$key}) {
 417                 print ("NTP $key: $answer");
 418                 last;
 419         }
 420 }
 421 exit $state;
 422
 423
 424 ####
 425 #### subs
 426
 427 sub print_usage () {
 428         print "Usage: $PROGNAME -H <host> [-46] [-w <warn>] [-c <crit>] [-j <warn>] [-k <crit>] [-v verbose]\n";
 429 }
 430
 431 sub print_help () {
 432         print_revision($PROGNAME,'$Revision$');
 433         print "Copyright (c) 2003 Bo Kersey/Karl DeBisschop\n";
 434         print "\n";
 435         print_usage();
 436         print "
 437 Checks the local timestamp offset versus <host> with ntpdate
 438 Checks the jitter/dispersion of clock signal between <host> and its sys.peer with ntpq\n
 439 -w ( --warning)
 440      Clock offset in seconds at which a warning message will be generated.\n    Defaults to $DEFAULT_OFFSET_WARN.
 441 -c (--critical)
 442      Clock offset in seconds at which a critical message will be generated.\n   Defaults to $DEFAULT_OFFSET_CRIT.
 443 -j (--jwarn)
 444      Clock jitter in milliseconds at which a warning message will be generated.\n       Defaults to $DEFAULT_JITTER_WARN.
 445 -k (--jcrit)
 446     Clock jitter in milliseconds at which a critical message will be generated.\n       Defaults to $DEFAULT_JITTER_CRIT.
 447
 448     If jitter/dispersion is specified with -j or -k and ntpq times out, then a
 449     warning is returned.\n
 450 -4 (--use-ipv4)
 451     Use IPv4 connection
 452 -6 (--use-ipv6)
 453     Use IPv6 connection
 454 \n";
 455 support();
 456 }