m4/np_curl.m4

   1 dnl These are for the libs and macros from curl
   2 dnl Currently utilising v7.12.3
   3
   4 dnl We use jm_ for non Autoconf macros.
   5 dnl m4_pattern_forbid([^np_[ABCDEFGHIJKLMNOPQRSTUVXYZ]])dnl
   6 dnl m4_pattern_forbid([^jm_[ABCDEFGHIJKLMNOPQRSTUVXYZ]])dnl
   7 dnl m4_pattern_forbid([^gl_[ABCDEFGHIJKLMNOPQRSTUVXYZ]])dnl
   8
   9 dnl These are all m4 things that need to be called
  10 dnl Usually in coreutils' prereq.m4, but this is a subset that we need
  11 AC_DEFUN([np_CURL],
  12 [
  13   AC_REQUIRE([TYPE_SOCKLEN_T])
  14 ])
  15
  16 dnl Check for socklen_t: historically on BSD it is an int, and in
  17 dnl POSIX 1g it is a type of its own, but some platforms use different
  18 dnl types for the argument to getsockopt, getpeername, etc.  So we
  19 dnl have to test to find something that will work.
  20 AC_DEFUN([TYPE_SOCKLEN_T],
  21 [
  22    AC_CHECK_TYPE([socklen_t], ,[
  23       AC_MSG_CHECKING([for socklen_t equivalent])
  24       AC_CACHE_VAL([curl_cv_socklen_t_equiv],
  25       [
  26          # Systems have either "struct sockaddr *" or
  27          # "void *" as the second argument to getpeername
  28          curl_cv_socklen_t_equiv=
  29          for arg2 in "struct sockaddr" void; do
  30             for t in int size_t unsigned long "unsigned long"; do
  31                AC_TRY_COMPILE([
  32                   #ifdef HAVE_SYS_TYPES_H
  33                   #include <sys/types.h>
  34                   #endif
  35                   #ifdef HAVE_SYS_SOCKET_H
  36                   #include <sys/socket.h>
  37                   #endif
  38
  39                   int getpeername (int, $arg2 *, $t *);
  40                ],[
  41                   $t len;
  42                   getpeername(0,0,&len);
  43                ],[
  44                   curl_cv_socklen_t_equiv="$t"
  45                   break
  46                ])
  47             done
  48          done
  49
  50          if test "x$curl_cv_socklen_t_equiv" = x; then
  51             AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
  52          fi
  53       ])
  54       AC_MSG_RESULT($curl_cv_socklen_t_equiv)
  55       AC_DEFINE_UNQUOTED(socklen_t, $curl_cv_socklen_t_equiv,
  56                         [type to use in place of socklen_t if not defined])],
  57       [#include <sys/types.h>
  58 #include <sys/socket.h>])
  59 ])
  60