gl/m4/strstr.m4

   1 # strstr.m4 serial 7
   2 dnl Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check that strstr works.
   8 AC_DEFUN([gl_FUNC_STRSTR_SIMPLE],
   9 [
  10   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_MEMCHR])
  12   if test "$gl_cv_func_memchr_works" != yes; then
  13     REPLACE_STRSTR=1
  14     AC_LIBOBJ([strstr])
  15   fi
  16 ]) # gl_FUNC_STRSTR_SIMPLE
  17
  18 dnl Additionally, check that strstr is efficient.
  19 AC_DEFUN([gl_FUNC_STRSTR],
  20 [
  21   AC_REQUIRE([gl_FUNC_STRSTR_SIMPLE])
  22   if test $REPLACE_STRSTR = 0; then
  23     AC_CACHE_CHECK([whether strstr works in linear time],
  24       [gl_cv_func_strstr_linear],
  25       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  26 #include <signal.h> /* for signal */
  27 #include <string.h> /* for memmem */
  28 #include <stdlib.h> /* for malloc */
  29 #include <unistd.h> /* for alarm */
  30 ]], [[size_t m = 1000000;
  31     char *haystack = (char *) malloc (2 * m + 2);
  32     char *needle = (char *) malloc (m + 2);
  33     void *result = 0;
  34     /* Failure to compile this test due to missing alarm is okay,
  35        since all such platforms (mingw) also have quadratic strstr.  */
  36     signal (SIGALRM, SIG_DFL);
  37     alarm (5);
  38     /* Check for quadratic performance.  */
  39     if (haystack && needle)
  40       {
  41         memset (haystack, 'A', 2 * m);
  42         haystack[2 * m] = 'B';
  43         haystack[2 * m + 1] = 0;
  44         memset (needle, 'A', m);
  45         needle[m] = 'B';
  46         needle[m + 1] = 0;
  47         result = strstr (haystack, needle);
  48       }
  49     return !result;]])],
  50         [gl_cv_func_strstr_linear=yes], [gl_cv_func_strstr_linear=no],
  51         [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
  52          dnl strstr that works in linear time.
  53          AC_EGREP_CPP([Lucky user],
  54            [
  55 #include <features.h>
  56 #ifdef __GNU_LIBRARY__
  57  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
  58   Lucky user
  59  #endif
  60 #endif
  61 #ifdef __CYGWIN__
  62  #include <cygwin/version.h>
  63  #if CYGWIN_VERSION_DLL_MAJOR >= 1007
  64   Lucky user
  65  #endif
  66 #endif
  67            ],
  68            [gl_cv_func_strstr_linear=yes],
  69            [gl_cv_func_strstr_linear="guessing no"])
  70         ])
  71       ])
  72     if test "$gl_cv_func_strstr_linear" != yes; then
  73       REPLACE_STRSTR=1
  74     fi
  75   fi
  76   if test $REPLACE_STRSTR = 1; then
  77     AC_LIBOBJ([strstr])
  78   fi
  79 ]) # gl_FUNC_STRSTR