gl/m4/setenv.m4

   1 # setenv.m4 serial 16
   2 dnl Copyright (C) 2001-2004, 2006-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SETENV],
   8 [
   9   AC_REQUIRE([gl_FUNC_SETENV_SEPARATE])
  10   if test $HAVE_SETENV$REPLACE_SETENV != 10; then
  11     AC_LIBOBJ([setenv])
  12   fi
  13 ])
  14
  15 # Like gl_FUNC_SETENV, except prepare for separate compilation (no AC_LIBOBJ).
  16 AC_DEFUN([gl_FUNC_SETENV_SEPARATE],
  17 [
  18   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  19   AC_CHECK_FUNCS_ONCE([setenv])
  20   if test $ac_cv_func_setenv = no; then
  21     HAVE_SETENV=0
  22   else
  23     AC_CACHE_CHECK([whether setenv validates arguments],
  24       [gl_cv_func_setenv_works],
  25       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  26        #include <stdlib.h>
  27        #include <errno.h>
  28        #include <string.h>
  29       ]], [[
  30        if (setenv ("", "", 0) != -1) return 1;
  31        if (errno != EINVAL) return 2;
  32        if (setenv ("a", "=", 1) != 0) return 3;
  33        if (strcmp (getenv ("a"), "=") != 0) return 4;
  34       ]])],
  35       [gl_cv_func_setenv_works=yes], [gl_cv_func_setenv_works=no],
  36       [gl_cv_func_setenv_works="guessing no"])])
  37     if test "$gl_cv_func_setenv_works" != yes; then
  38       REPLACE_SETENV=1
  39       AC_LIBOBJ([setenv])
  40     fi
  41   fi
  42   gl_PREREQ_SETENV
  43 ])
  44
  45 AC_DEFUN([gl_FUNC_UNSETENV],
  46 [
  47   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  48   AC_CHECK_FUNCS([unsetenv])
  49   if test $ac_cv_func_unsetenv = no; then
  50     HAVE_UNSETENV=0
  51     AC_LIBOBJ([unsetenv])
  52     gl_PREREQ_UNSETENV
  53   else
  54     dnl Some BSDs return void, failing to do error checking.
  55     AC_CACHE_CHECK([for unsetenv() return type], [gt_cv_func_unsetenv_ret],
  56       [AC_TRY_COMPILE([#include <stdlib.h>
  57 extern
  58 #ifdef __cplusplus
  59 "C"
  60 #endif
  61 #if defined(__STDC__) || defined(__cplusplus)
  62 int unsetenv (const char *name);
  63 #else
  64 int unsetenv();
  65 #endif
  66 ], , gt_cv_func_unsetenv_ret='int', gt_cv_func_unsetenv_ret='void')])
  67     if test $gt_cv_func_unsetenv_ret = 'void'; then
  68       AC_DEFINE([VOID_UNSETENV], [1], [Define to 1 if unsetenv returns void
  69        instead of int.])
  70       REPLACE_UNSETENV=1
  71       AC_LIBOBJ([unsetenv])
  72     fi
  73
  74     dnl Solaris 10 unsetenv does not remove all copies of a name.
  75     AC_CACHE_CHECK([whether unsetenv works on duplicates],
  76       [gl_cv_func_unsetenv_works],
  77       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  78        #include <stdlib.h>
  79       ]], [[
  80        char entry[] = "b=2";
  81        if (putenv ((char *) "a=1")) return 1;
  82        if (putenv (entry)) return 2;
  83        entry[0] = 'a';
  84        unsetenv ("a");
  85        if (getenv ("a")) return 3;
  86       ]])],
  87       [gl_cv_func_unsetenv_works=yes], [gl_cv_func_unsetenv_works=no],
  88       [gl_cv_func_unsetenv_works="guessing no"])])
  89     if test "$gl_cv_func_unsetenv_works" != yes; then
  90       REPLACE_UNSETENV=1
  91       AC_LIBOBJ([unsetenv])
  92     fi
  93   fi
  94 ])
  95
  96 # Prerequisites of lib/setenv.c.
  97 AC_DEFUN([gl_PREREQ_SETENV],
  98 [
  99   AC_REQUIRE([AC_FUNC_ALLOCA])
 100   AC_REQUIRE([gl_ENVIRON])
 101   AC_CHECK_HEADERS_ONCE([unistd.h])
 102   AC_CHECK_HEADERS([search.h])
 103   AC_CHECK_FUNCS([tsearch])
 104 ])
 105
 106 # Prerequisites of lib/unsetenv.c.
 107 AC_DEFUN([gl_PREREQ_UNSETENV],
 108 [
 109   AC_REQUIRE([gl_ENVIRON])
 110   AC_CHECK_HEADERS_ONCE([unistd.h])
 111 ])