gl/m4/gnulib-common.m4

   1 # gnulib-common.m4 serial 18
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_COMMON
   8 # is expanded unconditionally through gnulib-tool magic.
   9 AC_DEFUN([gl_COMMON], [
  10   dnl Use AC_REQUIRE here, so that the code is expanded once only.
  11   AC_REQUIRE([gl_00GNULIB])
  12   AC_REQUIRE([gl_COMMON_BODY])
  13 ])
  14 AC_DEFUN([gl_COMMON_BODY], [
  15   AH_VERBATIM([isoc99_inline],
  16 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
  17    the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
  18    earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
  19    __APPLE__ && __MACH__ test for MacOS X.
  20    __APPLE_CC__ tests for the Apple compiler and its version.
  21    __STDC_VERSION__ tests for the C99 mode.  */
  22 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
  23 # define __GNUC_STDC_INLINE__ 1
  24 #endif])
  25   AH_VERBATIM([unused_parameter],
  26 [/* Define as a marker that can be attached to declarations that might not
  27     be used.  This helps to reduce warnings, such as from
  28     GCC -Wunused-parameter.  */
  29 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
  30 # define _GL_UNUSED __attribute__ ((__unused__))
  31 #else
  32 # define _GL_UNUSED
  33 #endif
  34 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
  35    is a misnomer outside of parameter lists.  */
  36 #define _UNUSED_PARAMETER_ _GL_UNUSED
  37 ])
  38 ])
  39
  40 # gl_MODULE_INDICATOR_CONDITION
  41 # expands to a C preprocessor expression that evaluates to 1 or 0, depending
  42 # whether a gnulib module that has been requested shall be considered present
  43 # or not.
  44 AC_DEFUN([gl_MODULE_INDICATOR_CONDITION], [1])
  45
  46 # gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
  47 # sets the shell variable that indicates the presence of the given module to
  48 # a C preprocessor expression that will evaluate to 1.
  49 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
  50 [
  51   GNULIB_[]m4_translit([[$1]],
  52     [abcdefghijklmnopqrstuvwxyz./-],
  53     [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=gl_MODULE_INDICATOR_CONDITION
  54 ])
  55
  56 # gl_MODULE_INDICATOR([modulename])
  57 # defines a C macro indicating the presence of the given module
  58 # in a location where it can be used.
  59 #                                             |  Value  |   Value   |
  60 #                                             | in lib/ | in tests/ |
  61 # --------------------------------------------+---------+-----------+
  62 # Module present among main modules:          |    1    |     1     |
  63 # --------------------------------------------+---------+-----------+
  64 # Module present among tests-related modules: |    0    |     1     |
  65 # --------------------------------------------+---------+-----------+
  66 # Module not present at all:                  |    0    |     0     |
  67 # --------------------------------------------+---------+-----------+
  68 AC_DEFUN([gl_MODULE_INDICATOR],
  69 [
  70   AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
  71       [abcdefghijklmnopqrstuvwxyz./-],
  72       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
  73     [gl_MODULE_INDICATOR_CONDITION],
  74     [Define to a C preprocessor expression that evaluates to 1 or 0,
  75      depending whether the gnulib module $1 shall be considered present.])
  76 ])
  77
  78 # gl_MODULE_INDICATOR_FOR_TESTS([modulename])
  79 # defines a C macro indicating the presence of the given module
  80 # in lib or tests. This is useful to determine whether the module
  81 # should be tested.
  82 #                                             |  Value  |   Value   |
  83 #                                             | in lib/ | in tests/ |
  84 # --------------------------------------------+---------+-----------+
  85 # Module present among main modules:          |    1    |     1     |
  86 # --------------------------------------------+---------+-----------+
  87 # Module present among tests-related modules: |    1    |     1     |
  88 # --------------------------------------------+---------+-----------+
  89 # Module not present at all:                  |    0    |     0     |
  90 # --------------------------------------------+---------+-----------+
  91 AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
  92 [
  93   AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
  94       [abcdefghijklmnopqrstuvwxyz./-],
  95       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
  96     [Define to 1 when the gnulib module $1 should be tested.])
  97 ])
  98
  99 # m4_foreach_w
 100 # is a backport of autoconf-2.59c's m4_foreach_w.
 101 # Remove this macro when we can assume autoconf >= 2.60.
 102 m4_ifndef([m4_foreach_w],
 103   [m4_define([m4_foreach_w],
 104     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
 105
 106 # AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
 107 # ----------------------------------------------------
 108 # Backport of autoconf-2.63b's macro.
 109 # Remove this macro when we can assume autoconf >= 2.64.
 110 m4_ifndef([AS_VAR_IF],
 111 [m4_define([AS_VAR_IF],
 112 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
 113
 114 # AC_PROG_MKDIR_P
 115 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
 116 # for interoperability with automake-1.9.6 from autoconf-2.62.
 117 # Remove this macro when we can assume autoconf >= 2.62 or
 118 # autoconf >= 2.60 && automake >= 1.10.
 119 m4_ifdef([AC_PROG_MKDIR_P], [
 120   dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
 121   m4_define([AC_PROG_MKDIR_P],
 122     m4_defn([AC_PROG_MKDIR_P])[
 123     AC_SUBST([MKDIR_P])])], [
 124   dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
 125   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
 126     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 127      MKDIR_P='$(mkdir_p)'
 128      AC_SUBST([MKDIR_P])])])
 129
 130 # AC_C_RESTRICT
 131 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
 132 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
 133 # works.
 134 # This definition can be removed once autoconf >= 2.62 can be assumed.
 135 AC_DEFUN([AC_C_RESTRICT],
 136 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
 137   [ac_cv_c_restrict=no
 138    # The order here caters to the fact that C++ does not require restrict.
 139    for ac_kw in __restrict __restrict__ _Restrict restrict; do
 140      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 141       [[typedef int * int_ptr;
 142         int foo (int_ptr $ac_kw ip) {
 143         return ip[0];
 144        }]],
 145       [[int s[1];
 146         int * $ac_kw t = s;
 147         t[0] = 0;
 148         return foo(t)]])],
 149       [ac_cv_c_restrict=$ac_kw])
 150      test "$ac_cv_c_restrict" != no && break
 151    done
 152   ])
 153  AH_VERBATIM([restrict],
 154 [/* Define to the equivalent of the C99 'restrict' keyword, or to
 155    nothing if this is not supported.  Do not define if restrict is
 156    supported directly.  */
 157 #undef restrict
 158 /* Work around a bug in Sun C++: it does not support _Restrict, even
 159    though the corresponding Sun C compiler does, which causes
 160    "#define restrict _Restrict" in the previous line.  Perhaps some future
 161    version of Sun C++ will work with _Restrict; if so, it'll probably
 162    define __RESTRICT, just as Sun C does.  */
 163 #if defined __SUNPRO_CC && !defined __RESTRICT
 164 # define _Restrict
 165 #endif])
 166  case $ac_cv_c_restrict in
 167    restrict) ;;
 168    no) AC_DEFINE([restrict], []) ;;
 169    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 170  esac
 171 ])
 172
 173 # gl_BIGENDIAN
 174 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
 175 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
 176 # macros invoke AC_C_BIGENDIAN with arguments.
 177 AC_DEFUN([gl_BIGENDIAN],
 178 [
 179   AC_C_BIGENDIAN
 180 ])
 181
 182 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
 183 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
 184 # output a spurious "(cached)" mark in the midst of other configure output.
 185 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded
 186 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
 187 AC_DEFUN([gl_CACHE_VAL_SILENT],
 188 [
 189   saved_as_echo_n="$as_echo_n"
 190   as_echo_n=':'
 191   AC_CACHE_VAL([$1], [$2])
 192   as_echo_n="$saved_as_echo_n"
 193 ])