1 # Check for getloadavg.
3 # Copyright (C) 1992-1996, 1999-2000, 2002-2003, 2006, 2008-2010 Free Software
4 # Foundation, Inc.
6 # This file is free software; the Free Software Foundation
7 # gives unlimited permission to copy and/or distribute it,
8 # with or without modifications, as long as this notice is preserved.
10 # Autoconf defines AC_FUNC_GETLOADAVG, but that is obsolescent.
11 # New applications should use gl_GETLOADAVG instead.
13 # gl_GETLOADAVG(LIBOBJDIR)
14 # ------------------------
15 AC_DEFUN([gl_GETLOADAVG],
16 [AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
18 # Persuade glibc <stdlib.h> to declare getloadavg().
19 AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
21 gl_have_func=no # yes means we've found a way to get the load average.
23 # Make sure getloadavg.c is where it belongs, at configure-time.
24 test -f "$srcdir/$1/getloadavg.c" ||
25 AC_MSG_ERROR([$srcdir/$1/getloadavg.c is missing])
27 gl_save_LIBS=$LIBS
29 # Check for getloadavg, but be sure not to touch the cache variable.
30 (AC_CHECK_FUNC([getloadavg], [exit 0], [exit 1])) && gl_have_func=yes
32 # On HPUX9, an unprivileged user can get load averages through this function.
33 AC_CHECK_FUNCS([pstat_getdynamic])
35 # Solaris has libkstat which does not require root.
36 AC_CHECK_LIB([kstat], [kstat_open])
37 test $ac_cv_lib_kstat_kstat_open = yes && gl_have_func=yes
39 # AIX has libperfstat which does not require root
40 AC_CHECK_LIB([perfstat], [perfstat_cpu_total])
41 test $ac_cv_lib_perfstat_perfstat_cpu_total = yes && gl_have_func=yes
43 # Some systems with -lutil have (and need) -lkvm as well, some do not.
44 # On Solaris, -lkvm requires nlist from -lelf, so check that first
45 # to get the right answer into the cache.
46 # For kstat on solaris, we need libelf to force the definition of SVR4 below.
47 if test $gl_have_func = no; then
48 AC_CHECK_LIB([elf], [elf_begin], [LIBS="-lelf $LIBS"])
49 fi
50 if test $gl_have_func = no; then
51 AC_CHECK_LIB([kvm], [kvm_open], [LIBS="-lkvm $LIBS"])
52 # Check for the 4.4BSD definition of getloadavg.
53 AC_CHECK_LIB([util], [getloadavg],
54 [LIBS="-lutil $LIBS" gl_have_func=yes gl_cv_func_getloadavg_setgid=yes])
55 fi
57 if test $gl_have_func = no; then
58 # There is a commonly available library for RS/6000 AIX.
59 # Since it is not a standard part of AIX, it might be installed locally.
60 gl_getloadavg_LIBS=$LIBS
61 LIBS="-L/usr/local/lib $LIBS"
62 AC_CHECK_LIB([getloadavg], [getloadavg],
63 [LIBS="-lgetloadavg $LIBS"], [LIBS=$gl_getloadavg_LIBS])
64 fi
66 # Make sure it is really in the library, if we think we found it,
67 # otherwise set up the replacement function.
68 AC_CHECK_FUNCS([getloadavg], [],
69 [gl_PREREQ_GETLOADAVG])
71 # Some definitions of getloadavg require that the program be installed setgid.
72 AC_CACHE_CHECK([whether getloadavg requires setgid],
73 gl_cv_func_getloadavg_setgid,
74 [AC_EGREP_CPP([Yowza Am I SETGID yet],
75 [#define CONFIGURING_GETLOADAVG
76 #include "$srcdir/$1/getloadavg.c"
77 #ifdef LDAV_PRIVILEGED
78 Yowza Am I SETGID yet
79 #endif
80 ],
81 gl_cv_func_getloadavg_setgid=yes,
82 gl_cv_func_getloadavg_setgid=no)])
83 if test $gl_cv_func_getloadavg_setgid = yes; then
84 NEED_SETGID=true
85 AC_DEFINE([GETLOADAVG_PRIVILEGED], [1],
86 [Define to 1 if the `getloadavg' function needs to be run setuid
87 or setgid.])
88 else
89 NEED_SETGID=false
90 fi
91 AC_SUBST([NEED_SETGID])dnl
93 if test $gl_cv_func_getloadavg_setgid = yes; then
94 AC_CACHE_CHECK([group of /dev/kmem], [gl_cv_group_kmem],
95 [ # On Solaris, /dev/kmem is a symlink. Get info on the real file.
96 ac_ls_output=`ls -lgL /dev/kmem 2>/dev/null`
97 # If we got an error (system does not support symlinks), try without -L.
98 test -z "$ac_ls_output" && ac_ls_output=`ls -lg /dev/kmem`
99 gl_cv_group_kmem=`echo $ac_ls_output \
100 | sed -ne ['s/[ ][ ]*/ /g
101 s/^.[sSrwx-]* *[0-9]* *\([^0-9]*\) *.*/\1/
102 / /s/.* //;p']`
103 ])
104 AC_SUBST([KMEM_GROUP], [$gl_cv_group_kmem])dnl
105 fi
106 if test "x$gl_save_LIBS" = x; then
107 GETLOADAVG_LIBS=$LIBS
108 else
109 GETLOADAVG_LIBS=`echo "$LIBS" | sed "s!$gl_save_LIBS!!"`
110 fi
111 LIBS=$gl_save_LIBS
113 AC_SUBST([GETLOADAVG_LIBS])dnl
115 # Test whether the system declares getloadavg. Solaris has the function
116 # but declares it in <sys/loadavg.h>, not <stdlib.h>.
117 AC_CHECK_HEADERS([sys/loadavg.h])
118 if test $ac_cv_header_sys_loadavg_h = yes; then
119 HAVE_SYS_LOADAVG_H=1
120 else
121 HAVE_SYS_LOADAVG_H=0
122 fi
123 AC_CHECK_DECL([getloadavg], [], [HAVE_DECL_GETLOADAVG=0],
124 [#if HAVE_SYS_LOADAVG_H
125 # include <sys/loadavg.h>
126 #endif
127 #include <stdlib.h>])
128 ])# gl_GETLOADAVG
131 # gl_PREREQ_GETLOADAVG
132 # --------------------
133 # Set up the AC_LIBOBJ replacement of `getloadavg'.
134 AC_DEFUN([gl_PREREQ_GETLOADAVG],
135 [AC_LIBOBJ([getloadavg])
136 AC_DEFINE([C_GETLOADAVG], [1], [Define to 1 if using `getloadavg.c'.])
137 # Figure out what our getloadavg.c needs.
138 gl_have_func=no
139 AC_CHECK_HEADER([sys/dg_sys_info.h],
140 [gl_have_func=yes
141 AC_DEFINE([DGUX], [1], [Define to 1 for DGUX with <sys/dg_sys_info.h>.])
142 AC_CHECK_LIB([dgc], [dg_sys_info])])
144 # We cannot check for <dwarf.h>, because Solaris 2 does not use dwarf (it
145 # uses stabs), but it is still SVR4. We cannot check for <elf.h> because
146 # Irix 4.0.5F has the header but not the library.
147 if test $gl_have_func = no && test "$ac_cv_lib_elf_elf_begin" = yes; then
148 gl_have_func=yes
149 AC_DEFINE([SVR4], [1], [Define to 1 on System V Release 4.])
150 fi
152 if test $gl_have_func = no; then
153 AC_CHECK_HEADER([inq_stats/cpustats.h],
154 [gl_have_func=yes
155 AC_DEFINE([UMAX], [1], [Define to 1 for Encore UMAX.])
156 AC_DEFINE([UMAX4_3], [1],
157 [Define to 1 for Encore UMAX 4.3 that has <inq_status/cpustats.h>
158 instead of <sys/cpustats.h>.])])
159 fi
161 if test $gl_have_func = no; then
162 AC_CHECK_HEADER([sys/cpustats.h],
163 [gl_have_func=yes; AC_DEFINE([UMAX])])
164 fi
166 if test $gl_have_func = no; then
167 AC_CHECK_HEADERS([mach/mach.h])
168 fi
170 AC_CHECK_HEADERS([nlist.h],
171 [AC_CHECK_MEMBERS([struct nlist.n_un.n_name],
172 [AC_DEFINE([NLIST_NAME_UNION], [1],
173 [Define to 1 if your `struct nlist' has an
174 `n_un' member. Obsolete, depend on
175 `HAVE_STRUCT_NLIST_N_UN_N_NAME])], [],
176 [@%:@include <nlist.h>])
177 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <nlist.h>]],
178 [[struct nlist x;
179 #ifdef HAVE_STRUCT_NLIST_N_UN_N_NAME
180 x.n_un.n_name = "";
181 #else
182 x.n_name = "";
183 #endif]])],
184 [AC_DEFINE([N_NAME_POINTER], [1],
185 [Define to 1 if the nlist n_name member is a pointer])])
186 ])dnl
187 ])# gl_PREREQ_GETLOADAVG