configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.50)
   4 AC_INIT(inkscape, 0.45+devel)
   5 dnl N.B. After 0.40, please change to `0.40+cvs' instead of `0.41cvs'.
   6 dnl Rationale: (i) placate simple version comparison software such as
   7 dnl `dpkg --compare-versions'.  (ii) We don't always know what the next
   8 dnl version is going to be called until about the time we release it
   9 dnl (whereas we always know what the previous version was called).
  10 AC_CANONICAL_HOST
  11 AC_CONFIG_SRCDIR(src/main.cpp)
  12 AM_INIT_AUTOMAKE([dist-zip dist-bzip2 tar-pax])
  13
  14 AC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [
  15   prefix=/opt/inkscape
  16   PATH="/opt/lsb/bin:$PATH"
  17   CC=lsbcc
  18   CXX=lsbc++
  19   export CC CXX
  20 ])
  21
  22 AM_CONFIG_HEADER(config.h)
  23
  24 AC_PROG_INTLTOOL(0.22)
  25
  26 AC_LANG(C++)
  27 AC_ISC_POSIX
  28 AC_PROG_CXX
  29 AM_PROG_CC_STDC
  30 AM_PROG_AS
  31 AC_HEADER_STDC
  32
  33 dnl These next few lines are needed only while libcroco is in our source tree.
  34 AC_PROG_CC
  35 AM_PROG_CC_C_O
  36 AC_MSG_NOTICE([Testing -Wno-pointer-sign])
  37 if test "$GCC" = "yes"; then
  38   # Enable some warnings from gcc.
  39
  40   AC_LANG_PUSH(C)
  41   # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted
  42   # by gcc 2.95.
  43   ink_svd_CFLAGS="$CFLAGS"
  44   CFLAGS="-Wno-pointer-sign $CFLAGS"
  45   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), AC_MSG_NOTICE([ compiler supports -Wno-pointer-sign]), CFLAGS="$ink_svd_CFLAGS")
  46   CFLAGS="-Wall -Wformat-security -W -D_FORTIFY_SOURCE=2 $CFLAGS"
  47   AC_LANG_POP
  48 fi
  49
  50 dnl Honor aclocal flags
  51 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  52
  53 AC_PROG_RANLIB
  54
  55 dnl Verify our GCC version
  56 if test "x$GXX" = "xyes"; then
  57         AC_MSG_CHECKING([GNU compiler version])
  58
  59         # Don't pass CXXFLAGS to the following CXX command as some
  60         # of them can't be specified along with '-v'.
  61         cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\
  62                 sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]
  63
  64         AC_MSG_RESULT([$cc_version])
  65
  66         # Some version numbers
  67         cc_vers_major=`echo $cc_version | cut -f1 -d.`
  68         cc_vers_minor=`echo $cc_version | cut -f2 -d.`
  69         cc_vers_patch=`echo $cc_version | cut -f3 -d.`
  70         test -n "$cc_vers_major" || cc_vers_major=0
  71         test -n "$cc_vers_minor" || cc_vers_minor=0
  72         test -n "$cc_vers_patch" || cc_vers_patch=0
  73         cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`
  74
  75         if test $cc_vers_major -lt 3; then
  76                 AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])
  77         fi
  78 fi
  79
  80 dnl ******************************
  81 dnl Gettext stuff
  82 dnl ******************************
  83 GETTEXT_PACKAGE="AC_PACKAGE_NAME"
  84 AC_SUBST(GETTEXT_PACKAGE)
  85 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])
  86 dnl Add the languages which your application supports here.
  87 ALL_LINGUAS="am ar az be bg bn br ca ca@valencia cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fi fr ga gl he hr hu id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@latin sr sv th tr uk vi zh_CN zh_TW"
  88 AM_GLIB_GNU_GETTEXT
  89
  90 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  91 if test "x$PKG_CONFIG" = "xno"; then
  92         AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)
  93 fi
  94
  95 dnl Find msgfmt.  Without this, po/Makefile fails to set MSGFMT on some platforms.
  96 AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)
  97 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
  98
  99 dnl ******************************
 100 dnl Check for libpng
 101 dnl ******************************
 102 AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=no)], png_ok=no, -lz -lm)
 103 if test "x$png_ok" != "xyes"; then
 104         AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])
 105 fi
 106
 107 dnl Handle possible dlopen requirement for libgc
 108 dnl Isn't this internal to something in autoconf?  Couldn't find it...
 109 AC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],
 110           [lt_cv_dlopen="dlopen"],
 111       [AC_CHECK_LIB([dl], [dlopen],
 112             [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
 113         [AC_CHECK_LIB([svld], [dlopen],
 114               [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
 115           [AC_CHECK_LIB([dld], [dld_link],
 116                 [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
 117           ])
 118         ])
 119       ])
 120     ])
 121
 122 AC_CHECK_HEADERS([gc.h gc/gc.h],
 123                  [
 124                     # To test for the different required libs, I have to
 125                     # overcome autoconf's caching system, so I change the
 126                     # desired function name.  They're all in libgc.
 127                     # The "break" will exit from the top level
 128                     # AC_CHECK_HEADERS.
 129                     gc_libs=""
 130                     AC_CHECK_LIB(gc, GC_init,
 131                                  [gc_ok=yes;
 132                                   LIBS="-lgc $gc_libs $LIBS";
 133                                   break], [gc_ok=no], [$gc_libs])
 134                     gc_libs="-lpthread"
 135                     AC_CHECK_LIB(gc, GC_malloc,
 136                                  [gc_ok=yes;
 137                                   LIBS="-lgc $gc_libs $LIBS";
 138                                   break], [gc_ok=no], [$gc_libs])
 139                     gc_libs="$lt_cv_dlopen_libs"
 140                     AC_CHECK_LIB(gc, GC_realloc,
 141                                  [gc_ok=yes;
 142                                   LIBS="-lgc $gc_libs $LIBS";
 143                                   break], [gc_ok=no], [$gc_libs])
 144                     gc_libs="-lpthread $lt_cv_dlopen_libs"
 145                     AC_CHECK_LIB(gc, GC_free,
 146                                  [gc_ok=yes;
 147                                   LIBS="-lgc $gc_libs $LIBS";
 148                                   break], [gc_ok=no], [$gc_libs])
 149                     break],
 150                  [gc_ok=no])
 151 if test "x$gc_ok" = "xyes"; then
 152         AC_MSG_CHECKING([libgc version 6.4+])
 153         AC_RUN_IFELSE(
 154                 [AC_LANG_SOURCE([[
 155                         #ifdef HAVE_GC_GC_H
 156                         # include <gc/gc.h>
 157                         #else
 158                         # include <gc.h>
 159                         #endif
 160                         #include <stdio.h>
 161                         extern unsigned GC_version;
 162                         int main(void){
 163                                 unsigned min = ((6 << 16) | (4 << 8) | 0);
 164                                 printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);
 165                                 if (GC_version>=min) return 0;
 166                                 return 1;
 167                         }]])],
 168                 [gc_ok=yes],
 169                 [gc_ok=no]
 170         )
 171         AC_MSG_RESULT([$gc_ok])
 172 fi
 173 if test "x$gc_ok" != "xyes"; then
 174         AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])
 175 fi
 176
 177 dnl This check is to get a FIONREAD definition on Solaris 8
 178 AC_CHECK_HEADERS([sys/filio.h])
 179
 180
 181 AC_CHECK_HEADERS([malloc.h])
 182 AC_CHECK_FUNCS([mallinfo], [
 183         AC_CHECK_MEMBERS([struct mallinfo.usmblks,
 184                           struct mallinfo.fsmblks,
 185                           struct mallinfo.uordblks,
 186                           struct mallinfo.fordblks,
 187                           struct mallinfo.hblkhd],,,
 188                          [#include <malloc.h>])
 189 ])
 190
 191 AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 192 if test "x$FREETYPE_CONFIG" = "xno"; then
 193         AC_MSG_ERROR([Cannot find freetype-config])
 194 fi
 195 FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
 196 FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
 197 AC_SUBST(FREETYPE_CFLAGS)
 198 AC_SUBST(FREETYPE_LIBS)
 199
 200 dnl ******************************
 201 dnl Win32
 202 dnl ******************************
 203 AC_MSG_CHECKING([for Win32 platform])
 204 case "$host" in
 205   *-*-mingw*)
 206     platform_win32=yes
 207     INKSCAPE_CFLAGS="$INKSCAPE_CFLAGS -mms-bitfields -DLIBXML_STATIC"
 208     ;;
 209   *)
 210     platform_win32=no
 211     ;;
 212 esac
 213 AC_MSG_RESULT([$platform_win32])
 214 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 215
 216 AC_MSG_CHECKING([for Solaris 2.8 platform])
 217 case "$host" in
 218   *-solaris2.8)
 219     platform_solaris_2_8=yes
 220     CFLAGS="$CFLAGS -DSOLARIS_2_8"
 221     CXXFLAGS="$CXXFLAGS -DSOLARIS_2_8"
 222     ;;
 223   *)
 224     platform_solaris_2_8=no
 225     ;;
 226 esac
 227 AC_MSG_RESULT([$platform_solaris_2_8])
 228 AM_CONDITIONAL(PLATFORM_SOLARIS_2_8, test "$platform_solaris_2_8" = "yes")
 229
 230 dnl ******************************
 231 dnl Xft checking
 232 dnl ******************************
 233
 234 AC_ARG_WITH(xft,
 235             AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),
 236             [with_xft=$withval], [with_xft=auto])
 237
 238 if test "x$with_xft" != "xno" ; then
 239         dnl Test fontconfig package
 240         PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)
 241         if test "x$xft_ok" != "xyes"; then
 242                 dnl test xft package
 243                 PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)
 244                 if test "x$xft_ok" != "xyes"; then
 245                         dnl Have to test xft presence
 246                         AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)
 247                         if test "x$xft_ok" != "xyes"; then
 248                                 dnl No xft found
 249                                 if test "x$with_xft" = "xyes"; then
 250                                         dnl Xft was explicitly asked, so stop
 251                                         AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])
 252                                 fi
 253                         else
 254                                 dnl Working Xft1
 255                                 XFT_LIBS="-L/usr/X11R6/lib -lXft "
 256                         fi
 257                 fi
 258         fi
 259 else
 260         dnl Asked to ignore xft
 261         xft_ok=no
 262 fi
 263
 264 AC_SUBST(XFT_CFLAGS)
 265 AC_SUBST(XFT_LIBS)
 266
 267 AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")
 268 if test "x$xft_ok" = "xyes"; then
 269         AC_DEFINE(WITH_XFT, 1, [Use Xft font database])
 270 fi
 271
 272 dnl ******************************
 273 dnl pangoft2 for xft
 274 dnl ******************************
 275
 276 if test "x$xft_ok" = "xyes"; then
 277         PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)
 278         if test "x$pango_ok" = "xyes"; then
 279                 XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"
 280         fi
 281 fi
 282
 283
 284 dnl ******************************
 285 dnl gnome vfs checking
 286 dnl ******************************
 287
 288 AC_ARG_WITH(gnome-vfs,
 289         AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),
 290         [with_gnome_vfs=$withval], [with_gnome_vfs=auto])
 291
 292 if test "x$with_gnome_vfs" = "xno"; then
 293         dnl Asked to ignore gnome-vfs
 294         gnome_vfs=no
 295 else
 296         dnl Have to test gnome-vfs presence
 297         PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)
 298         if test "x$gnome_vfs" != "xyes"; then
 299                 dnl No gnome-vfs found
 300                 if test "x$with_gnome_vfs" = "xyes"; then
 301                         dnl Gnome-VFS was explicitly asked for, so stop
 302                         AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])
 303                 else
 304                         # gnome-vfs is no, tell us for the log file
 305                         AC_MSG_RESULT($gnome_vfs)
 306                 fi
 307         fi
 308 fi
 309
 310 AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")
 311 if test "x$gnome_vfs" = "xyes"; then
 312         AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])
 313 fi
 314
 315 AC_SUBST(GNOME_VFS_CFLAGS)
 316 AC_SUBST(GNOME_VFS_LIBS)
 317
 318 dnl ******************************
 319 dnl libinkjar checking
 320 dnl ******************************
 321
 322 AC_ARG_WITH(inkjar,
 323         AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])
 324
 325 if test "x$with_ij" = "xyes"; then
 326         AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])
 327         AC_C_BIGENDIAN
 328         AC_CHECK_HEADERS(zlib.h)
 329         ij=yes
 330 else
 331         ij=no
 332 fi
 333 AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")
 334
 335 ink_spell_pkg=
 336 if pkg-config --exists gtkspell-2.0; then
 337         ink_spell_pkg=gtkspell-2.0
 338         AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])
 339 fi
 340
 341 dnl ******************************
 342 dnl PERL checking
 343 dnl ******************************
 344
 345 AC_MSG_CHECKING(for Perl development environment)
 346 AC_ARG_WITH(perl,
 347             AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),
 348             [with_perl=$withval], [with_perl=skipped])
 349
 350 if test "x$with_perl" = "xyes"; then
 351     checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`
 352     if test "$?" -gt "0"; then
 353         with_perl="no"
 354     else
 355         checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`
 356         if test "$?" -gt "0"; then
 357             with_perl="no"
 358         else
 359             with_perl="yes"
 360         fi
 361     fi
 362 fi
 363 AC_MSG_RESULT([$with_perl])
 364 if test "x$with_perl" = "xyes"; then
 365     # Test that we actually have the perl libraries installed
 366     oldCFLAGS="$CFLAGS"
 367     oldLIBS="$LIBS"
 368     CFLAGS="$CFLAGS $checkPERL_CFLAGS"
 369     LIBS="$LIBS $checkPERL_LIBS"
 370     AC_CHECK_FUNC([perl_parse],[
 371         PERL_CFLAGS="$checkPERL_CFLAGS"
 372         PERL_LIBS="$checkPERL_LIBS"
 373         AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])
 374         ],[
 375         with_perl="no"
 376         ])
 377     CFLAGS="$oldCFLAGS"
 378     LIBS="$oldLIBS"
 379 fi
 380 AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")
 381 AC_SUBST(PERL_CFLAGS)
 382 AC_SUBST(PERL_LIBS)
 383
 384 dnl ******************************
 385 dnl Python checking
 386 dnl ******************************
 387
 388 AC_MSG_CHECKING(for Python development environment)
 389 AC_ARG_WITH(python,
 390             AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),
 391             [with_python=$withval], [with_python=skipped])
 392
 393 if test "x$with_python" = "xyes"; then
 394     checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`
 395     if test "$?" -gt "0"; then
 396         with_python="no"
 397     else
 398         checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`
 399         if test "$?" -gt "0"; then
 400             with_python="no"
 401         else
 402             with_python="yes"
 403         fi
 404     fi
 405 fi
 406 AC_MSG_RESULT([$with_python])
 407 if test "x$with_python" = "xyes"; then
 408     # Test that we actually have the python libraries installed
 409     oldCFLAGS="$CFLAGS"
 410     oldLIBS="$LIBS"
 411     CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"
 412     LIBS="$LIBS $checkPYTHON_LIBS"
 413     AC_CHECK_FUNC([Py_Initialize],[
 414         PYTHON_CFLAGS="$checkPYTHON_CFLAGS"
 415         PYTHON_LIBS="$checkPYTHON_LIBS"
 416         AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])
 417         ],[
 418         with_python="no"
 419         ])
 420     CFLAGS="$oldCFLAGS"
 421     LIBS="$oldLIBS"
 422 fi
 423 AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")
 424 AC_SUBST(PYTHON_CFLAGS)
 425 AC_SUBST(PYTHON_LIBS)
 426
 427 dnl ******************************
 428 dnl LittleCms checking
 429 dnl ******************************
 430
 431 AC_ARG_ENABLE(lcms,
 432         AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),
 433         [enable_lcms=$enableval], [enable_lcms=yes])
 434
 435 if test "x$enable_lcms" = "xno"; then
 436         dnl Asked to ignore LittleCms
 437         lcms=no
 438 else
 439         dnl Have to test LittleCms presence
 440         PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)
 441         if test "x$lcms" != "xyes"; then
 442                 dnl No lcms found
 443                 if test "x$enable_lcms" = "xyes"; then
 444                         dnl LittleCms was explicitly asked for, so stop
 445                         AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])
 446                 else
 447                         # lcms is no, tell us for the log file
 448                         AC_MSG_RESULT($lcms)
 449                 fi
 450         else
 451                 dnl Working lcms
 452                 LIBS="$LIBS $LCMS_LIBS"
 453                 AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])
 454         fi
 455 fi
 456
 457 AC_SUBST(LCMS_CFLAGS)
 458 AC_SUBST(LCMS_LIBS)
 459
 460 dnl ******************************
 461 dnl Libpoppler checking
 462 dnl ******************************
 463
 464 AC_ARG_ENABLE(poppler-cairo,
 465         AC_HELP_STRING([--enable-poppler-cairo], [Enable libpoppler-cairo for rendering PDF preview]),
 466         [enable_poppler_cairo=$enableval], [enable_poppler_cairo=yes])
 467
 468 POPPLER_CFLAGS=""
 469 PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.9, poppler=yes, poppler=no)
 470
 471 if test "x$poppler" = "xyes"; then
 472         dnl Working libpoppler
 473         POPPLER_LIBS="-lpoppler "
 474         dnl Have to test libpoppler-glib presence
 475         PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.9, poppler_glib=yes, poppler_glib=no)
 476         if test "x$poppler_glib" = "xyes"; then
 477                 dnl Working libpoppler-glib found
 478                 dnl Check whether the Cairo SVG backend is available
 479                 PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)
 480                 if test "x$cairo_svg" = "xyes"; then
 481                         POPPLER_LIBS="$POPPLER_LIBS -lpoppler-glib "
 482                 fi
 483         fi
 484         if test "x$enable_poppler_cairo" = "xyes"; then
 485                 dnl Have to test libpoppler-cairo presence for PDF preview
 486                 dnl AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)
 487                 PKG_CHECK_MODULES(POPPLER_CAIRO, poppler-cairo >= 0.5.9, poppler_cairo=yes, poppler_cairo=no)
 488                 if test "x$poppler_glib" = "xyes" -a "x$poppler_cairo" = "xyes" -a \
 489                         "x$cairo_svg" = "xno"
 490                 then
 491                         POPPLER_LIBS="$POPPLER_LIBS -lpoppler-glib "
 492                 fi
 493         fi
 494 fi
 495
 496 if test "x$poppler" = "xyes"; then
 497         LIBS="$LIBS $POPPLER_LIBS"
 498         AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])
 499 fi
 500 if test "x$poppler_cairo" = "xyes" -a "x$poppler_glib" = "xyes"; then
 501         AC_DEFINE(HAVE_POPPLER_CAIRO, 1, [Use libpoppler-cairo for rendering PDF preview])
 502 fi
 503 if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then
 504         AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])
 505 fi
 506 AC_SUBST(POPPLER_CFLAGS)
 507 AC_SUBST(POPPLER_LIBS)
 508
 509 dnl ******************************
 510 dnl Inkboard dependency checking
 511 dnl ******************************
 512
 513 with_inkboard="no"
 514 with_inkboard_ssl="no"
 515
 516 INKBOARD_CFLAGS=""
 517
 518 AC_ARG_ENABLE(inkboard,
 519                 AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),
 520        with_inkboard=$enableval,with_inkboard=no)
 521
 522 if test "x$with_inkboard" = "xyes"; then
 523                 with_inkboard="yes"
 524                 AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])
 525
 526                 dnl Test for OpenSSL
 527                 PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)
 528                 if test "x$with_inkboard_ssl" = "xyes"; then
 529                         dnl OpenSSL found; enable SSL support in Pedro
 530                         INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"
 531                         RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
 532                         RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
 533                         AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])
 534                 fi
 535 else
 536         with_inkboard="no"
 537 fi
 538
 539 AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")
 540 AC_SUBST(INKBOARD_LIBS)
 541 AC_SUBST(INKBOARD_CFLAGS)
 542
 543 dnl ******************************
 544 dnl Check for libwpg for extension
 545 dnl ******************************
 546
 547 PKG_CHECK_MODULES(LIBWPG, libwpg-0.1 libwpg-stream-0.1, with_libwpg=yes, with_libwpg=no)
 548 if test "x$with_libwpg" = "xyes"; then
 549         AC_DEFINE(WITH_LIBWPG,1,[Build in libwpg])
 550 fi
 551 AM_CONDITIONAL(WITH_LIBWPG, test "x$with_libwpg" = "xyes")
 552
 553 AC_SUBST(LIBWPG_LIBS)
 554 AC_SUBST(LIBWPG_CFLAGS)
 555
 556 dnl ******************************
 557 dnl Check for ImageMagick Magick++
 558 dnl ******************************
 559
 560 AC_CHECK_LIB(Magick++, InitializeMagick, [AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)], magick_ok=no, -llcms -lfreetype -ljpeg -lfontconfig -lXext -lSM -lICE -lX11 -lz -lpthread -lm -lpthread)
 561
 562 if test "x$magick_ok" = "xyes"; then
 563         AC_CHECK_PROG(MAGICKPP_CONFIG, Magick++-config, yes, no)
 564         if test "x$MAGICKPP_CONFIG" = "xyes"; then
 565                 IMAGEMAGICK_LIBS=`Magick++-config --libs`
 566                 AC_SUBST(IMAGEMAGICK_LIBS)
 567                 AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])
 568         fi
 569 fi
 570
 571 AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")
 572
 573 dnl ******************************
 574 dnl   Unconditional dependencies
 575 dnl ******************************
 576
 577 dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10
 578 if test $cc_vers_major -gt 3; then
 579   min_sigc_version=2.0.12
 580 else
 581   min_sigc_version=2.0.11
 582 fi
 583 PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4  glibmm-2.4  gtkmm-2.4 >= 2.10.0  gtk+-2.0  libxml-2.0 >= 2.6.11  libxslt >= 1.0.15  cairo  sigc++-2.0 >= $min_sigc_version  $ink_spell_pkg  gthread-2.0 >= 2.0 libpng >= 1.2)
 584
 585 # Check for Apple Mac OS X Carbon framework
 586 carbon_ok=no
 587 AC_MSG_CHECKING([for Mac OS X Carbon support])
 588 AC_TRY_CPP([
 589 #include <Carbon/Carbon.h>
 590 #include <CoreServices/CoreServices.h>
 591 ], carbon_ok=yes)
 592 AC_MSG_RESULT($carbon_ok)
 593 if test "x$carbon_ok" = "xyes"; then
 594   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 595   CARBON_LDFLAGS="-framework Carbon"
 596   AC_SUBST(CARBON_LDFLAGS)
 597 fi
 598 AM_CONDITIONAL(HAVE_CARBON, test "x$carbon_ok" = "xyes")
 599
 600 # Check for some boost header files
 601 AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))
 602
 603 PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)
 604 if test "x$cairo_pdf" = "xyes"; then
 605   AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])
 606 fi
 607
 608 dnl Shouldn't we test for libpng and libz?
 609 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz"
 610
 611 AC_CHECK_HEADER(popt.h,
 612                 [INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],
 613                 AC_MSG_ERROR([libpopt is required]))
 614
 615 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 616 sp_save_LIBS=$LIBS
 617 LIBS="$LIBS $INKSCAPE_LIBS"
 618 AC_CHECK_FUNCS(bind_textdomain_codeset)
 619 dnl Check for gtk_window_fullscreen in gtk (>= 2.2)
 620 AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)
 621 AC_CHECK_FUNCS(gtk_window_fullscreen)
 622 LIBS=$sp_save_LIBS
 623
 624
 625 dnl Check for binary relocation support
 626 dnl Hongli Lai <h.lai@chello.nl>
 627
 628 AC_ARG_ENABLE(binreloc,
 629        [  --enable-binreloc       compile with binary relocation support],
 630        enable_binreloc=$enableval,enable_binreloc=no)
 631
 632 AC_MSG_CHECKING(whether binary relocation support should be enabled)
 633 if test "$enable_binreloc" = "yes"; then
 634        AC_MSG_RESULT(yes)
 635        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
 636        if test -e /proc/self/maps; then
 637                AC_MSG_RESULT(yes)
 638        else
 639                AC_MSG_RESULT(no)
 640                AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
 641                enable_binreloc="no"
 642        fi
 643
 644 elif test "$enable_binreloc" = "auto"; then
 645        AC_MSG_RESULT(yes when available)
 646        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
 647        if test -e /proc/self/maps; then
 648                AC_MSG_RESULT(yes)
 649                enable_binreloc=yes
 650
 651                AC_MSG_CHECKING(whether everything is installed to the same prefix)
 652                if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
 653                        "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
 654                        "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
 655                then
 656                        AC_MSG_RESULT(yes)
 657                else
 658                        AC_MSG_RESULT(no)
 659                        AC_MSG_NOTICE(Binary relocation support will be disabled.)
 660                        enable_binreloc=no
 661                fi
 662
 663        else
 664                AC_MSG_RESULT(no)
 665                enable_binreloc=no
 666        fi
 667
 668 elif test "$enable_binreloc" = "no"; then
 669        AC_MSG_RESULT(no)
 670 else
 671        AC_MSG_RESULT(no (unknown value "$enable_binreloc"))
 672        enable_binreloc=no
 673 fi
 674 AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])
 675 if test "$enable_binreloc" = "yes"; then
 676    AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
 677 fi
 678
 679 AC_ARG_ENABLE(osxapp,
 680        [  --enable-osxapp         compile with OSX .app data dir paths],
 681        enable_osxapp=$enableval,enable_osxapp=no)
 682 if test "$enable_osxapp" = "yes"; then
 683    AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])
 684 fi
 685
 686 dnl ******************************
 687 dnl   Reported by autoscan
 688 dnl ******************************
 689 AC_CHECK_FUNCS(pow)
 690 # if we did not find pow(), see if it's in libm.
 691 if test x"$ac_cv_func_pow" = x"no" ; then
 692         AC_CHECK_LIB(m,pow)
 693 fi
 694 AC_CHECK_FUNCS(sqrt)
 695 AC_CHECK_FUNCS(floor)
 696 AC_CHECK_FUNCS(gettimeofday)
 697 AC_CHECK_FUNCS(memmove)
 698 AC_CHECK_FUNCS(memset)
 699 AC_CHECK_FUNCS(mkdir)
 700 AC_CHECK_FUNCS(strncasecmp)
 701 AC_CHECK_FUNCS(strpbrk)
 702 AC_CHECK_FUNCS(strrchr)
 703 AC_CHECK_FUNCS(strspn)
 704 AC_CHECK_FUNCS(strstr)
 705 AC_CHECK_FUNCS(strtoul)
 706 AC_CHECK_FUNCS(fpsetmask)
 707 AC_CHECK_FUNCS(ecvt)
 708 AC_CHECK_HEADERS(ieeefp.h)
 709 AC_CHECK_HEADERS(fcntl.h)
 710 AC_CHECK_HEADERS(libintl.h)
 711 AC_CHECK_HEADERS(stddef.h)
 712 AC_CHECK_HEADERS(sys/time.h)
 713 AC_FUNC_STAT
 714 AC_FUNC_STRFTIME
 715 AC_FUNC_STRTOD
 716 AC_HEADER_STAT
 717 AC_HEADER_TIME
 718 AC_STRUCT_TM
 719 AC_TYPE_MODE_T
 720 AC_TYPE_SIGNAL
 721
 722 dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't
 723 dnl set correctly because the gettext function isn't noticed.
 724 if test "$ac_cv_header_libintl_h" = "yes" &&
 725    test "$ac_cv_func_bind_textdomain_codeset" = "yes"  &&
 726    test "$gt_cv_func_have_gettext" != "yes"; then
 727     AC_DEFINE(ENABLE_NLS)
 728 fi
 729
 730 dnl ******************************
 731 dnl   Compilation warnings
 732 dnl ******************************
 733 if test "$GXX" = "yes"; then
 734   # Enable some warnings from g++.
 735
 736   # Rationale: a number of bugs in inkscape have been fixed by enabling g++
 737   # warnings and addressing the produced warnings.  Usually the committing
 738   # developer is the best person to address the warnings.
 739
 740   ink_svd_CXXFLAGS="$CXXFLAGS"
 741   CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"
 742   # -Wno-unused-parameter isn't accepted by gcc 2.95.
 743   AC_COMPILE_IFELSE([int dummy;
 744 ], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)
 745   # Note: At least one bug has been caught from unused parameter warnings,
 746   # so it might be worth trying not to disable it.
 747   # One way of selectively disabling the warnings (i.e. only where the
 748   # programmer deliberately isn't using the parameter, e.g. for a callback)
 749   # is to remove the parameter name (leaving just its type), as is done
 750   # in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the
 751   # programmer deliberately has an unused parameter (e.g. because it's used
 752   # as a callback or similar function pointer use).
 753
 754   CXXFLAGS="-Wall -Wformat-security -W -Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch -D_FORTIFY_SOURCE=2 $CXXFLAGS"
 755
 756   dnl Test for arch-specific situations.
 757   case "$host_cpu" in
 758     mips|mipsel)
 759       dnl Symbol tables can get too large: this uses alternate tables
 760       dnl See http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=283476
 761       CXXFLAGS="$CXXFLAGS -Wa,-xgot"
 762       CFLAGS="$CFLAGS -Wa,-xgot"
 763       ;;
 764   esac
 765 fi
 766
 767 AC_DEFINE(WITH_MODULES, 1, [Use experimental module support])
 768
 769 dnl ******************************
 770 dnl   libinkscape
 771 dnl ******************************
 772 dnl
 773 dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])
 774 dnl
 775 dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")
 776 dnl
 777
 778 AC_SUBST(INKSCAPE_CFLAGS)
 779 AC_SUBST(INKSCAPE_LIBS)
 780
 781 #
 782 # Checks to see if we should compile in MMX support (there will be
 783 # a runtime test when the code is actually run to see if it should
 784 # be used - this just checks if we can compile it.)
 785 #
 786 # This code is partially taken from Mesa
 787 #
 788 dnl Let people disable the MMX optimization
 789 AC_ARG_ENABLE(mmx, [  --disable-mmx     Don't use MMX optimization [default=auto]], enable_mmx="$enableval", enable_mmx=auto)
 790
 791 AC_MSG_CHECKING(for x86 platform)
 792 case $host_cpu in
 793   i386|i486|i586|i686|i786|k6|k7)
 794     use_x86_asm=yes
 795     ;;
 796   *)
 797     use_x86_asm=no
 798 esac
 799 AC_MSG_RESULT($use_x86_asm)
 800
 801 dnl Are we going to use MMX extensions
 802 use_mmx_asm=no
 803
 804 AC_MSG_CHECKING(compiler support for MMX)
 805
 806 if test x$enable_mmx = xauto ; then
 807   if test $use_x86_asm = yes; then
 808     save_ac_ext=$ac_ext
 809     ac_ext=S
 810
 811     cp $srcdir/src/libnr/nr_mmx_R8G8B8A8_P_R8G8B8A8_P_A8_RGBAP.S conftest.S
 812     if AC_TRY_EVAL(ac_compile); then
 813         use_mmx_asm=yes
 814     fi
 815     dnl rm -f conftest.[oS]
 816
 817     ac_ext=$save_ac_ext
 818   fi
 819
 820 dnl Enforce usage of MMX extensions
 821 elif test x$enable_mmx = xyes ; then
 822     use_mmx_asm=yes
 823 else
 824     use_mmx_asm=no
 825 fi
 826
 827 if test $use_mmx_asm = yes; then
 828         AC_DEFINE(WITH_MMX, 1, [Use MMX optimizations, if CPU supports it])
 829         AC_MSG_RESULT(yes)
 830 else
 831         AC_MSG_RESULT(no)
 832 fi
 833
 834 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 835
 836 dnl Figure out where the datadir actually is
 837 dnl http://autoconf-archive.cryp.to/ac_define_dir.html
 838 prefix_NONE=
 839 exec_prefix_NONE=
 840 test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
 841 test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
 842 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
 843 dnl refers to ${prefix}.  Thus we have to use `eval' twice.
 844 eval runtime_datadir="${datadir}"
 845 eval runtime_datadir="${runtime_datadir}"
 846 test "$prefix_NONE" && prefix=NONE
 847 test "$exec_prefix_NONE" && exec_prefix=NONE
 848
 849 inkscape_sharedir="${runtime_datadir}/${PACKAGE_NAME}"
 850
 851 dnl Define our data paths for config.h
 852 AC_SUBST(INKSCAPE_DATADIR)
 853 AC_DEFINE_UNQUOTED([INKSCAPE_DATADIR], "${runtime_datadir}",
 854                                         [Base data directory -- only path-prefix.h should use it!])
 855 AC_SUBST(PACKAGE_LOCALE_DIR)
 856 AC_DEFINE_UNQUOTED([PACKAGE_LOCALE_DIR], "${runtime_datadir}/locale",
 857                                         [Localization directory])
 858 AC_SUBST(INKSCAPE_LIBDIR)
 859 AC_DEFINE_UNQUOTED([INKSCAPE_LIBDIR], "${prefix}/lib",
 860                                         [Base library directory -- only path-prefix.h should use it!])
 861
 862 dnl Have to add module makefiles (lauris)
 863
 864 AC_CONFIG_FILES([
 865 Makefile
 866 src/Makefile
 867 src/check-header-compile
 868 src/algorithms/makefile
 869 src/application/makefile
 870 src/bind/makefile
 871 src/debug/makefile
 872 src/dialogs/makefile
 873 src/display/makefile
 874 src/dom/makefile
 875 src/extension/implementation/makefile
 876 src/extension/internal/makefile
 877 src/extension/makefile
 878 src/extension/script/makefile
 879 src/helper/makefile
 880 src/inkjar/makefile
 881 src/io/makefile
 882 src/libcroco/makefile
 883 src/libgdl/makefile
 884 src/libnr/makefile
 885 src/libnrtype/makefile
 886 src/libavoid/makefile
 887 src/livarot/makefile
 888 src/live_effects/makefile
 889 src/live_effects/parameter/makefile
 890 src/pedro/makefile
 891 src/jabber_whiteboard/makefile
 892 src/removeoverlap/makefile
 893 src/svg/makefile
 894 src/trace/makefile
 895 src/traits/makefile
 896 src/ui/cache/makefile
 897 src/ui/dialog/makefile
 898 src/ui/makefile
 899 src/ui/view/makefile
 900 src/ui/widget/makefile
 901 src/utest/makefile
 902 src/util/makefile
 903 src/widgets/makefile
 904 src/xml/makefile
 905 src/2geom/makefile
 906 doc/Makefile
 907 po/Makefile.in
 908 share/Makefile
 909 share/clipart/Makefile
 910 share/examples/Makefile
 911 share/extensions/Makefile
 912 share/extensions/Barcode/Makefile
 913 share/extensions/xaml2svg/Makefile
 914 share/fonts/Makefile
 915 share/gradients/Makefile
 916 share/icons/Makefile
 917 share/keys/Makefile
 918 share/markers/Makefile
 919 share/palettes/Makefile
 920 share/patterns/Makefile
 921 share/screens/Makefile
 922 share/templates/Makefile
 923 share/tutorials/Makefile
 924 share/ui/Makefile
 925 packaging/autopackage/default.apspec
 926 inkscape.spec
 927 Info.plist
 928 inkview.1
 929 ])
 930
 931 AH_BOTTOM([
 932
 933
 934 ])
 935
 936 AC_OUTPUT
 937
 938 echo "
 939 Configuration:
 940
 941         Source code location:     ${srcdir}
 942         Destination path prefix:  ${prefix}
 943         Compiler:                 ${CXX}
 944         CPPFLAGS:                 ${CPPFLAGS}
 945         CXXFLAGS:                 ${CXXFLAGS}
 946         CFLAGS:                   ${CFLAGS}
 947         LDFLAGS:                  ${LDFLAGS}
 948
 949         Use Xft font database:    ${xft_ok}
 950         Use gnome-vfs:            ${gnome_vfs}
 951         Use openoffice files:     ${ij}
 952         Use MMX optimizations:    ${use_mmx_asm}
 953         Use relocation support:   ${enable_binreloc}
 954         Internal Python:          ${with_python}
 955         Internal Perl:            ${with_perl}
 956         Enable LittleCms:         ${enable_lcms}
 957         Enable Inkboard:          ${with_inkboard}
 958         Enable SSL in Inkboard:   ${with_inkboard_ssl}
 959         Enable Poppler-Cairo:     ${enable_poppler_cairo}
 960         ImageMagick Magick++:     ${magick_ok}
 961         Libwpg:                   ${with_libwpg}
 962 "