1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
10 dnl the official version number is
11 dnl a.b.c
12 AC_INIT([rrdtool],[1.3.2])
14 dnl for testing a numberical version number comes handy
15 dnl the released version are
16 dnl a.bccc
17 dnl the devel versions will be something like
18 dnl a.b999yymmddhh
19 NUMVERS=1.3002
20 AC_SUBST(NUMVERS)
22 dnl for the linker to understand which versions the library are compatible with
23 dnl each other we must keep a separate library version cout of the format c:r:a.
24 dnl - if only implementation changed but all interfaces are kept, do r++
25 dnl - if only functionality was added do c++,r=0,a++
26 dnl - if any functionality was removed do c++,r=0,a=0.
27 dnl
28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
29 dnl
30 LIBVERS=4:1:0
31 AC_SUBST(LIBVERS)
33 AC_CANONICAL_TARGET
34 AM_INIT_AUTOMAKE
35 AM_MAINTAINER_MODE
37 AC_CONFIG_HEADERS([rrd_config.h])
39 dnl all our local stuff like install scripts and include files
40 dnl is in there
43 dnl determine the type of system we are running on
45 AC_SUBST(VERSION)
47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
49 dnl Minimum Autoconf version required.
50 AC_PREREQ(2.59)
52 dnl At the TOP of the HEADER
54 AH_TOP([
55 #ifndef RRD_CONFIG_H
56 #define RRD_CONFIG_H
58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
59 #undef MUST_DISABLE_FPMASK
61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
62 #undef MUST_DISABLE_SIGFPE
64 /* realloc does not support NULL as argument */
65 #undef NO_NULL_REALLOC
67 /* lets enable madvise defines in NetBSD */
68 #if defined(__NetBSD__)
69 # if !defined(_NETBSD_SOURCE)
70 # define _NETBSD_SOURCE
71 # endif
72 #endif
74 ])
76 AH_BOTTOM([
78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
79 # include <malloc/malloc.h>
80 #endif
82 #include <rrd_config_bottom.h>
84 #endif
85 ])
87 dnl Process Special Options
88 dnl -----------------------------------
90 dnl How the vertical axis label is printed
91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
92 [Vertical label angle: -90.0 (default) or 90.0])
93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
94 [Vertical label angle: -90.0 (default) or 90.0])
96 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
97 [],[enable_rrdcgi=yes])
99 dnl Check if we run on a system that has fonts
100 AC_ARG_WITH(rrd-default-font,
101 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
102 [RRD_DEFAULT_FONT=$withval],[
103 if test -d ${WINDIR:-nodir}/cour.ttf ; then
104 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
105 else
106 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
107 fi
108 ])
110 dnl Use mmap in rrd_update instead of seek+write
111 AC_ARG_ENABLE([mmap],
112 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
113 [],
114 [enable_mmap=yes])
116 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
117 [],[enable_pthread=yes])
119 AC_ARG_ENABLE(static-programs,
120 [ --enable-static-programs Build static programs],
121 [case "${enableval}" in
122 yes) staticprogs=yes ;;
123 no) staticprogs=no ;;
124 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
125 esac],[staticprogs=no])
126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
129 CONFIGURE_PART(Audit Compilation Environment)
132 dnl Check for the compiler and static/shared library creation.
133 AC_PROG_CPP
134 AC_PROG_CC
135 AM_PROG_CC_C_O
136 AC_PROG_LIBTOOL
138 dnl Try to detect/use GNU features
139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
141 dnl which flags does the compiler support?
142 if test "x$GCC" = "xyes"; then
143 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
144 oCFLAGS="$CFLAGS"
145 CFLAGS="$CFLAGS $flag"
146 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
147 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
148 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
149 if eval test \$$cachename = no; then
150 CFLAGS="$oCFLAGS"
151 fi
152 done
153 fi
157 AC_SUBST(RRD_DEFAULT_FONT)
159 CONFIGURE_PART(Checking for Header Files)
161 dnl Checks for header files.
162 AC_HEADER_STDC
163 AC_HEADER_DIRENT
164 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
166 dnl Checks for typedefs, structures, and compiler characteristics.
167 AC_C_CONST
168 AC_HEADER_TIME
169 AC_STRUCT_TM
171 CONFIGURE_PART(Test Library Functions)
173 dnl Checks for libraries.
174 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
177 dnl add pic flag in any case this makes sure all our code is relocatable
178 eval `./libtool --config | grep pic_flag`
179 CFLAGS="$CFLAGS $pic_flag"
182 dnl Checks for library functions.
183 AC_FUNC_STRFTIME
184 AC_FUNC_VPRINTF
186 AC_C_BIGENDIAN
188 dnl for each function found we get a definition in config.h
189 dnl of the form HAVE_FUNCTION
191 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
193 CONFIGURE_PART(Map/Fadvis/Madvise checking)
195 dnl Could use these to know if we need to provide a prototype
196 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
198 dnl check for fdatasync. Solaris has fdatasync in the librt
200 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
201 dnl if there is no fdatasync we may get lucky with fsync
202 AC_CHECK_FUNCS(fsync)
205 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
206 if test "x$enable_mmap" = "xyes"; then
207 case "$host" in
208 *cygwin*)
209 # the normal mmap test does not work in cygwin
210 AC_CHECK_FUNCS(mmap)
211 if test "x$ac_cv_func_mmap" = "xyes"; then
212 ac_cv_func_mmap_fixed_mapped=yes
213 fi
214 ;;
215 *)
216 AC_CHECK_HEADERS(sys/mman.h)
217 AC_FUNC_MMAP
218 AC_CHECK_FUNCS(mmap munmap msync)
219 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
220 # include <sys/mman.h>
221 #endif])
222 if test "x$ac_cv_have_decl_madvise" = "xyes";
223 then
224 AC_CHECK_FUNCS(madvise)
225 else
226 AC_CHECK_FUNCS(posix_madvise)
227 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
228 AC_MSG_WARN([madvise() nor posix_madvise() found.])
229 fi
230 fi
231 ;;
232 esac
233 if test "x$ac_cv_func_mmap" != "xyes";
234 then
235 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
236 dnl enable_mmap="no"
237 fi
238 fi
240 dnl can we use posix_fadvise
241 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
242 #include <fcntl.h>])
243 AC_CHECK_FUNCS(posix_fadvise)
245 CONFIGURE_PART(Libintl Processing)
248 dnl gettext
249 GETTEXT_PACKAGE=rrdtool
250 AC_SUBST(GETTEXT_PACKAGE)
251 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
253 AM_GLIB_GNU_GETTEXT()
255 AC_ARG_ENABLE(libintl,[ --disable-libintl i18n support (libintl)],
256 [],[enable_libintl=yes])
258 if test x$enable_libintl = xyes; then
259 IT_PROG_INTLTOOL([0.35.0],[no-xml])
260 fi
262 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
263 AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
264 enable_libintl=no
265 fi
267 if test x$enable_libintl = xyes; then
268 AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
269 fi
271 if test x$enable_libintl = xyes ; then
272 dnl it seems bsd synstems need to link against libintl
273 dnl when compiling rrdupdate. lets check
274 AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
275 fi
277 dnl use for linking rrdupdate
278 AC_SUBST(LIB_LIBINTL)
280 dnl do not touch the po stuff if we are not going to build intl
281 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
283 if test x$enable_libintl = xyes; then
284 AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
285 fi
287 CONFIGURE_PART(IEEE Math Checks)
290 dnl actual code to check if this works
291 AC_CHECK_FUNCS(fpclassify, ,
292 [AC_MSG_CHECKING(for fpclassify with <math.h>)
293 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
294 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
295 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
297 AC_CHECK_FUNCS(isinf, ,
298 [AC_MSG_CHECKING(for isinf with <math.h>)
299 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
300 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
301 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
303 dnl finite is BSD, isfinite is C99, so prefer the latter
304 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
305 AC_TRY_RUN([
306 #ifdef HAVE_MATH_H
307 #include <math.h>
308 #endif
309 #ifdef HAVE_FLOAT_H
310 #include <float.h>
311 #endif
312 int main ()
313 {
314 #ifdef isfinite
315 #ifdef LDBL_MAX
316 if (!isfinite(LDBL_MAX)) return 1;
317 #endif
318 #ifdef DBL_MAX
319 if (!isfinite(DBL_MAX)) return 1;
320 #endif
321 #endif
322 return 0;
323 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
324 case "${target}" in
325 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
326 *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
327 *) ac_cv_have_broken_isfinite=no ;;
328 esac])
329 ])
331 dnl the test does not seem to work on solaris 2.8
332 dnl so lets fix this by hand
333 case "${target}" in
334 *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
335 esac
337 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
338 AC_DEFINE(HAVE_ISFINITE)
339 else
340 AC_CHECK_FUNCS(finite,[],
341 [AC_CHECK_FUNCS(isfinite,[],
342 [AC_MSG_CHECKING(for isfinite with <math.h>)
343 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
344 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
345 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
346 fi
348 AC_FULL_IEEE
350 CONFIGURE_PART(Resolve Portability Issues)
352 dnl Do we need getopt_long
354 build_getopt=no
355 RRD_GETOPT_LONG="#"
356 AC_CHECK_FUNC(getopt_long,[],[
357 RRD_GETOPT_LONG="getopt_long"
358 build_getopt=yes
359 ])
360 AC_SUBST(RRD_GETOPT_LONG)
361 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
363 dnl what does realloc do if it gets called with a NULL pointer
365 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
366 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
367 int main(void){
368 char *x = NULL;
369 x = realloc (x,10);
370 if (x==NULL) return 1;
371 return 0;
372 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
374 if test x"$rd_cv_null_realloc" = xnope; then
375 AC_DEFINE(NO_NULL_REALLOC)
376 fi
378 AC_LANG_PUSH(C)
379 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
380 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
381 AC_LINK_IFELSE(
382 AC_LANG_PROGRAM(
383 [[#include <time.h>]],
384 [[ctime_r(NULL,NULL,0)]]
385 ),
386 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
387 AC_LINK_IFELSE(
388 AC_LANG_PROGRAM(
389 [[#include <time.h>]],
390 [[ctime_r(NULL,NULL)]]
391 ),
392 [AC_MSG_RESULT([yes, this seems to be solaris style])],
393 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
394 )
395 ],
396 [ AC_LINK_IFELSE(
397 AC_LANG_PROGRAM(
398 [[#include <time.h>]],
399 [[ctime_r(NULL,NULL)]]
400 ),
401 [AC_MSG_RESULT(no)],
402 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
403 )
404 ]
405 )
406 AC_LANG_POP(C)
408 dnl Check for pthreads
409 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
411 AC_SUBST(MULTITHREAD_CFLAGS)
412 AC_SUBST(MULTITHREAD_LDFLAGS)
414 if test $enable_pthread != no; then
415 ACX_PTHREAD([
416 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
417 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
418 ],
419 [])
420 fi
422 dnl since we use lots of *_r functions all over the code we better
423 dnl make sure they are known
425 if test "x$x_rflag" != "xno"; then
426 CPPFLAGS="$CPPFLAGS $x_rflag"
427 fi
429 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
431 AC_LANG_PUSH(C)
432 dnl see if we have to include malloc/malloc.h
433 AC_MSG_CHECKING([do we need malloc/malloc.h])
434 AC_LINK_IFELSE(
435 AC_LANG_PROGRAM(
436 [[#include <stdlib.h>]],
437 [[malloc(1)]]
438 ),
439 [ AC_MSG_RESULT([nope, works out of the box]) ],
440 [ AC_LINK_IFELSE(
441 AC_LANG_PROGRAM(
442 [[#include <stdlib.h>
443 #include <malloc/malloc.h>]],
444 [[malloc(1)]]
445 ),[
446 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
447 AC_MSG_RESULT([yes we do])],
448 [AC_MSG_ERROR([Can not figure how to compile malloc])]
449 )
450 ]
451 )
452 AC_LANG_POP(C)
454 CONFIGURE_PART(Find 3rd-Party Libraries)
457 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
460 CORE_LIBS="$LIBS"
462 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
463 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
464 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
465 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
466 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
467 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
468 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
469 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
470 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
471 EX_CHECK_ALL(pango-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
472 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
474 if test "$EX_CHECK_ALL_ERR" = "YES"; then
475 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
476 fi
478 ALL_LIBS="$LIBS"
479 LIBS=
481 AC_SUBST(CORE_LIBS)
482 AC_SUBST(ALL_LIBS)
484 CONFIGURE_PART(Prep for Building Language Bindings)
486 dnl Check for Perl and friends
487 PATH=$PATH:/usr/perl5/bin
488 export PATH
489 AC_PATH_PROG(PERL, perl, no)
490 AC_PATH_PROG(POD2MAN, pod2man, no)
491 AC_PATH_PROG(POD2HTML, pod2html, no)
494 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
495 [],[enable_perl=yes])
498 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
499 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
500 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
501 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
503 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
504 COMP_PERL=
505 else
506 COMP_PERL="perl_piped perl_shared"
507 AC_MSG_CHECKING(for the perl version you are running)
508 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
509 AC_MSG_RESULT($PERL_VERSION)
510 if test -z "$PERLCC"; then
511 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
512 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
513 AC_MSG_RESULT($perlcc)
514 if test ! -x "$perlcc"; then
515 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
516 if test "$PERL_CC" = "no"; then
517 AC_MSG_WARN([
518 I would not find the Compiler ($perlcc) that was originally used to compile
519 your perl binary. You should either make sure that this compiler is
520 available on your system, pick an other compiler and set PERLCC
521 appropriately, or use a different perl setup that was compiled locally.
523 I will disable the compilation of the RRDs perl module for now.
524 ])
525 COMP_PERL="perl_piped"
526 fi
527 fi
528 fi
529 fi
531 AC_MSG_CHECKING(Perl Modules to build)
532 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
534 # Options to pass when configuring perl module
535 ppref=$prefix
536 test "$ppref" = "NONE" && ppref=$ac_default_prefix
538 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
540 dnl pass additional perl options when generating Makefile from Makefile.PL
541 AC_ARG_ENABLE(perl-site-install,
542 [ --enable-perl-site-install by default the rrdtool perl modules are installed
543 together with rrdtool in $prefix/lib/perl. You have to
544 put a 'use lib qw($prefix/lib/perl)' into your scripts
545 when you want to use them. When you set this option
546 the perl modules will get installed wherever
547 your perl setup thinks it is best.],
548 [PERL_MAKE_OPTIONS=],[])
550 if test ! -z "$PERLCC"; then
551 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
553 if test ! -z "$PERLCCFLAGS"; then
554 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
555 fi
557 if test -z "$PERLLD"; then
558 PERLLD=$PERLCC
559 fi
560 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
562 if test ! -z "$PERLLDFLAGS"; then
563 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
564 fi
565 fi
567 AC_ARG_WITH(perl-options,
568 [ --with-perl-options=[OPTIONS] options to pass on command-line when
569 generating Makefile from Makefile.PL. If you set this
570 option, interesting things may happen unless you know
571 what you are doing!],
572 [PERL_MAKE_OPTIONS=$withval])
574 AC_SUBST(PERL_MAKE_OPTIONS)
575 AC_SUBST(PERL)
576 AC_SUBST(COMP_PERL)
577 AC_SUBST(PERL_VERSION)
579 dnl Check for Ruby.
580 AC_PATH_PROG(RUBY, ruby, no)
582 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
583 [],[enable_ruby=yes])
585 AC_MSG_CHECKING(if ruby modules can be built)
587 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
588 COMP_RUBY=
589 AC_MSG_RESULT(No .. Ruby not found or disabled)
590 else
591 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
592 COMP_RUBY="ruby"
593 AC_MSG_RESULT(YES)
594 else
595 COMP_RUBY=
596 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
597 fi
598 fi
601 dnl pass additional ruby options when generating Makefile from Makefile.PL
602 AC_ARG_ENABLE(ruby-site-install,
603 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
604 together with rrdtool in $prefix/lib/ruby. You have to
605 add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
606 for ruby to find the RRD.so file.],
607 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$prefix/lib/ruby"])
610 AC_ARG_WITH(ruby-options,
611 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
612 generating Makefile from extconf.rb. If you set this
613 option, interesting things may happen unless you know
614 what you are doing!],
615 [RUBY_MAKE_OPTIONS=$withval])
617 AC_SUBST(RUBY_MAKE_OPTIONS)
618 AC_SUBST(RUBY)
619 AC_SUBST(COMP_RUBY)
622 enable_tcl_site=no
624 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
625 [],[enable_tcl=yes])
627 if test "$enable_tcl" = "yes"; then
628 dnl Check for Tcl.
629 withval=""
630 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
631 enable_tcl=no
632 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
633 AC_MSG_CHECKING(for tclConfig.sh in $dir)
634 if test -f "$dir/tclConfig.sh" ; then
635 tcl_config=$dir/tclConfig.sh
636 enable_tcl=yes
637 AC_MSG_RESULT(yes)
638 break
639 else
640 AC_MSG_RESULT(no)
641 fi
642 done
644 if test "$enable_tcl" = "no"; then
645 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
646 else
647 . $tcl_config
648 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
649 if test -n "$TCL_INC_DIR"; then
650 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
651 fi
652 fi
653 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
654 [],[enable_tcl_site=yes])
656 fi
658 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
659 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
662 AC_SUBST(TCL_PREFIX)
663 AC_SUBST(TCL_SHLIB_CFLAGS)
664 AC_SUBST(TCL_SHLIB_LD)
665 AC_SUBST(TCL_SHLIB_SUFFIX)
666 AC_SUBST(TCL_PACKAGE_PATH)
667 AC_SUBST(TCL_LD_SEARCH_FLAGS)
668 AC_SUBST(TCL_STUB_LIB_SPEC)
669 AC_SUBST(TCL_VERSION)
670 AC_SUBST(TCL_PACKAGE_DIR)
671 AC_SUBST(TCL_INCLUDE_SPEC)
673 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
674 [],[enable_python=yes])
676 if test "$enable_python" = "yes"; then
677 dnl Check for python
678 AM_PATH_PYTHON(2.3,[],[enable_python=no])
679 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
680 fi
682 if test x$enable_python = xno; then
683 COMP_PYTHON=
684 else
685 COMP_PYTHON="python"
686 fi
688 AC_SUBST(COMP_PYTHON)
690 dnl Check for nroff
691 AC_PATH_PROGS(NROFF, gnroff nroff)
692 AC_PATH_PROGS(TROFF, groff troff)
694 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
695 if test -z "$RRDDOCDIR"; then
696 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
699 CONFIGURE_PART(Apply Configuration Information)
701 AC_CONFIG_FILES([examples/shared-demo.pl])
702 AC_CONFIG_FILES([examples/piped-demo.pl])
703 AC_CONFIG_FILES([examples/stripes.pl])
704 AC_CONFIG_FILES([examples/bigtops.pl])
705 AC_CONFIG_FILES([examples/minmax.pl])
706 AC_CONFIG_FILES([examples/4charts.pl])
707 AC_CONFIG_FILES([examples/perftest.pl])
708 AC_CONFIG_FILES([examples/Makefile])
709 AC_CONFIG_FILES([doc/Makefile])
710 AC_CONFIG_FILES([po/Makefile.in])
711 AC_CONFIG_FILES([src/Makefile])
712 AC_CONFIG_FILES([src/librrd.sym])
713 AC_CONFIG_FILES([bindings/Makefile])
714 AC_CONFIG_FILES([bindings/tcl/Makefile])
715 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
716 AC_CONFIG_FILES([Makefile])
718 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
719 AC_OUTPUT
721 AC_MSG_CHECKING(in)
722 AC_MSG_RESULT(and out again)
724 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
725 sleep 1
726 echo $ECHO_N ".$ECHO_C" 1>&6
727 sleep 1
728 echo $ECHO_N ".$ECHO_C" 1>&6
729 sleep 1
730 echo $ECHO_N ".$ECHO_C" 1>&6
731 sleep 1
732 echo $ECHO_N ".$ECHO_C" 1>&6
733 sleep 1
734 AC_MSG_RESULT([ just kidding ;-)])
735 echo
736 echo "----------------------------------------------------------------"
737 echo "Config is DONE!"
738 echo
739 echo " With MMAP IO: $enable_mmap"
740 echo " Build rrd_getopt: $build_getopt"
741 echo " Static programs: $staticprogs"
742 echo " Perl Modules: $COMP_PERL"
743 echo " Perl Binary: $PERL"
744 echo " Perl Version: $PERL_VERSION"
745 echo " Perl Options: $PERL_MAKE_OPTIONS"
746 echo " Ruby Modules: $COMP_RUBY"
747 echo " Ruby Binary: $RUBY"
748 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
749 echo " Build Tcl Bindings: $enable_tcl"
750 echo " Build Python Bindings: $enable_python"
751 echo " Build rrdcgi: $enable_rrdcgi"
752 echo " Build librrd MT: $enable_pthread"
753 echo " Link with libintl: $enable_libintl"
754 echo
755 echo " Libraries: $ALL_LIBS"
756 echo
757 echo "Type 'make' to compile the software and use 'make install' to "
758 echo "install everything to: $prefix."
759 echo
760 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
761 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
762 echo "place an order."
763 echo
764 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
765 echo "----------------------------------------------------------------"