configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.6])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4006
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:4:2
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 106
 107 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 108 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 109
 110 if test $enable_rrd_graph != no; then
 111  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 112 fi
 113
 114 dnl Check if we run on a system that has fonts
 115 AC_ARG_WITH(rrd-default-font,
 116 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 117 [RRD_DEFAULT_FONT=$withval],[
 118   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 119         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 120   else
 121         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 122   fi
 123 ])
 124
 125 dnl Use mmap in rrd_update instead of seek+write
 126 AC_ARG_ENABLE([mmap],
 127 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 128 [],
 129 [enable_mmap=yes])
 130
 131 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 132 [],[enable_pthread=yes])
 133
 134 AC_ARG_ENABLE(static-programs,
 135      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 136      [case "${enableval}" in
 137        yes) staticprogs=yes ;;
 138        no)  staticprogs=no ;;
 139        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 140      esac],[staticprogs=no])
 141 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 142
 143
 144 CONFIGURE_PART(Audit Compilation Environment)
 145
 146
 147 dnl Check for the compiler and static/shared library creation.
 148 AC_PROG_CPP
 149 AC_PROG_CC
 150 AM_PROG_CC_C_O
 151 AC_PROG_LIBTOOL
 152
 153 dnl Try to detect/use GNU features
 154 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 155
 156 dnl check for -Werror separatly
 157 dnl (quite a few autotool checks do not work with -Werror; also, the
 158 dnl check for -Werror fails after checking and adding the other flags)
 159 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 160   [AC_COMPILE_IFELSE(
 161     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 162     [rd_cv_gcc_flag__Werror="yes"],
 163     [rd_cv_gcc_flag__Werror="no"])])
 164 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 165   WERROR="-Werror"
 166 else
 167   WERROR=""
 168 fi
 169 AC_SUBST(WERROR)
 170
 171 dnl which flags does the compiler support?
 172 if test "x$GCC" = "xyes"; then
 173   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 174     oCFLAGS="$CFLAGS"
 175     CFLAGS="$CFLAGS $flag"
 176     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 177     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 178        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 179     if eval test \$$cachename = no; then
 180          CFLAGS="$oCFLAGS"
 181     fi
 182   done
 183 fi
 184
 185
 186
 187 AC_SUBST(RRD_DEFAULT_FONT)
 188
 189 CONFIGURE_PART(Checking for Header Files)
 190
 191 dnl Checks for header files.
 192 AC_HEADER_STDC
 193 AC_HEADER_DIRENT
 194 AC_CHECK_HEADERS(tcpd.h dbi/dbi.h langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 195
 196 dnl Checks for typedefs, structures, and compiler characteristics.
 197 AC_C_CONST
 198 AC_HEADER_TIME
 199 AC_STRUCT_TM
 200
 201 CONFIGURE_PART(Test Library Functions)
 202
 203 dnl Checks for libraries.
 204 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 205
 206
 207 dnl add pic flag in any case this makes sure all our code is relocatable
 208 eval `./libtool --config | grep pic_flag`
 209 CFLAGS="$CFLAGS $pic_flag"
 210
 211
 212 dnl Checks for library functions.
 213 AC_FUNC_STRFTIME
 214 AC_FUNC_VPRINTF
 215
 216 AC_C_BIGENDIAN
 217
 218 dnl for each function found we get a definition in config.h
 219 dnl of the form HAVE_FUNCTION
 220
 221 AC_CHECK_FUNCS(nl_langinfo tzset round rint fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 222
 223 AC_FUNC_STRERROR_R
 224
 225 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 226
 227 dnl Could use these to know if we need to provide a prototype
 228 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 229
 230 dnl check for fdatasync. Solaris has fdatasync in the librt
 231
 232 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 233 dnl if there is no fdatasync we may get lucky with fsync
 234 AC_CHECK_FUNCS(fsync)
 235
 236 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 237
 238 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 239 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 240
 241
 242
 243 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 244 if test "x$enable_mmap" = "xyes"; then
 245   case "$host" in
 246   *cygwin*)
 247     # the normal mmap test does not work in cygwin
 248     AC_CHECK_FUNCS(mmap)
 249     if test "x$ac_cv_func_mmap" = "xyes"; then
 250       ac_cv_func_mmap_fixed_mapped=yes
 251     fi
 252   ;;
 253   *)
 254     AC_CHECK_HEADERS(sys/mman.h)
 255     AC_FUNC_MMAP
 256     AC_CHECK_FUNCS(mmap munmap msync)
 257     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 258                                      # include <sys/mman.h>
 259                                      #endif])
 260     if test "x$ac_cv_have_decl_madvise" = "xyes";
 261     then
 262       AC_CHECK_FUNCS(madvise)
 263     else
 264       AC_CHECK_FUNCS(posix_madvise)
 265       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 266         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 267       fi
 268     fi
 269   ;;
 270   esac
 271   if test "x$ac_cv_func_mmap" != "xyes";
 272   then
 273     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 274 dnl enable_mmap="no"
 275   fi
 276 fi
 277
 278 dnl can we use posix_fadvise
 279 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 280 #include <fcntl.h>])
 281 AC_CHECK_FUNCS(posix_fadvise)
 282
 283 CONFIGURE_PART(Libintl Processing)
 284
 285 AM_GNU_GETTEXT_VERSION(0.17)
 286 AM_GNU_GETTEXT(external)
 287
 288 CONFIGURE_PART(IEEE Math Checks)
 289
 290
 291 dnl actual code to check if this works
 292 AC_CHECK_FUNCS(fpclassify, ,
 293   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 294     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 295 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 296       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 297
 298 AC_CHECK_FUNCS(isinf, ,
 299   [AC_MSG_CHECKING(for isinf with <math.h>)
 300     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 301 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 302       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 303
 304 dnl finite is BSD, isfinite is C99, so prefer the latter
 305 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 306 AC_TRY_RUN([
 307 #ifdef HAVE_MATH_H
 308 #include <math.h>
 309 #endif
 310 #ifdef HAVE_FLOAT_H
 311 #include <float.h>
 312 #endif
 313 int main ()
 314 {
 315 #ifdef isfinite
 316 #ifdef LDBL_MAX
 317   if (!isfinite(LDBL_MAX)) return 1;
 318 #endif
 319 #ifdef DBL_MAX
 320   if (!isfinite(DBL_MAX)) return 1;
 321 #endif
 322 #endif
 323 return 0;
 324 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 325 case "${target}" in
 326   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 327   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 328   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 329   *) ac_cv_have_broken_isfinite=no ;;
 330 esac])
 331 ])
 332
 333 dnl the test does not seem to work on solaris 2.8
 334 dnl so lets fix this by hand
 335 case "${target}" in
 336   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 337   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 338 esac
 339
 340 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 341   AC_DEFINE(HAVE_ISFINITE)
 342 else
 343   AC_CHECK_FUNCS(finite,[],
 344       [AC_CHECK_FUNCS(isfinite,[],
 345          [AC_MSG_CHECKING(for isfinite with <math.h>)
 346           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 347 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 348                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 349 fi
 350
 351 AC_FULL_IEEE
 352
 353 CONFIGURE_PART(Resolve Portability Issues)
 354
 355 CHECK_FOR_WORKING_MS_ASYNC
 356
 357 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 358 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 359   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 360     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 361       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 362
 363 dnl Do we need getopt_long
 364
 365 dnl even when including our own getopt implementation
 366 dnl we may want to make sure we use the external
 367 dnl defined by libc to not run into linker resolve trouble
 368
 369 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 370 [AC_TRY_LINK([#include <unistd.h>],
 371   [extern int opterr; opterr = 1;],
 372   [rd_cv_var_int_opterr=yes],
 373   [rd_cv_var_int_opterr=no])])
 374 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 375   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 376 fi
 377
 378 build_getopt=no
 379 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 380 AC_CHECK_FUNC(getopt_long,[],[
 381 RRD_GETOPT_LONG="getopt_long"
 382 build_getopt=yes
 383 ])
 384 AC_SUBST(RRD_GETOPT_LONG)
 385 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 386
 387 dnl what does realloc do if it gets called with a NULL pointer
 388
 389 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 390 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 391               int main(void){
 392               char *x = NULL;
 393               x = realloc (x,10);
 394               if (x==NULL) return 1;
 395               return 0;
 396              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 397
 398 if test x"$rd_cv_null_realloc" = xnope; then
 399 AC_DEFINE(NO_NULL_REALLOC)
 400 fi
 401
 402 AC_LANG_PUSH(C)
 403 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 404 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 405 AC_LINK_IFELSE(
 406     AC_LANG_PROGRAM(
 407            [[#include <time.h>]],
 408            [[ctime_r(NULL,NULL,0)]]
 409                    ),
 410     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 411       AC_LINK_IFELSE(
 412           AC_LANG_PROGRAM(
 413                 [[#include <time.h>]],
 414                 [[ctime_r(NULL,NULL)]]
 415                          ),
 416           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 417           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 418       )
 419     ],
 420     [ AC_LINK_IFELSE(
 421           AC_LANG_PROGRAM(
 422                 [[#include <time.h>]],
 423                 [[ctime_r(NULL,NULL)]]
 424                          ),
 425           [AC_MSG_RESULT(no)],
 426           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 427       )
 428     ]
 429 )
 430 AC_LANG_POP(C)
 431
 432 dnl Check for pthreads
 433 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 434
 435 AC_SUBST(MULTITHREAD_CFLAGS)
 436 AC_SUBST(MULTITHREAD_LDFLAGS)
 437
 438 if test $enable_pthread != no; then
 439  ACX_PTHREAD([
 440     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 441     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 442              ],
 443              [])
 444 fi
 445
 446 dnl since we use lots of *_r functions all over the code we better
 447 dnl make sure they are known
 448
 449 if test  "x$x_rflag" != "xno"; then
 450    CPPFLAGS="$CPPFLAGS $x_rflag"
 451 fi
 452
 453 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 454
 455 AC_LANG_PUSH(C)
 456 dnl see if we have to include malloc/malloc.h
 457 AC_MSG_CHECKING([do we need malloc/malloc.h])
 458 AC_LINK_IFELSE(
 459     AC_LANG_PROGRAM(
 460            [[#include <stdlib.h>]],
 461            [[malloc(1)]]
 462                    ),
 463     [ AC_MSG_RESULT([nope, works out of the box]) ],
 464     [ AC_LINK_IFELSE(
 465           AC_LANG_PROGRAM(
 466                 [[#include <stdlib.h>
 467                   #include <malloc/malloc.h>]],
 468                 [[malloc(1)]]
 469                          ),[
 470            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 471            AC_MSG_RESULT([yes we do])],
 472           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 473       )
 474     ]
 475 )
 476
 477 dnl is time_t 32 of 64 bit ?
 478 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 479 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 480 AC_MSG_CHECKING([the type of time_t])
 481 AC_CHECK_SIZEOF([time_t])
 482 if test "x$ac_cv_sizeof_time_t" = "x4"; then
 483   AC_MSG_RESULT([time_t is 32 bit])
 484   AC_DEFINE([TIME_T_IS_32BIT])
 485 elif test "x$ac_cv_sizeof_time_t" = "x8"; then
 486   AC_MSG_RESULT([time_t is 64 bit])
 487   AC_DEFINE([TIME_T_IS_64BIT])
 488 else
 489   AC_MSG_ERROR([can not figure type of time_t])
 490 fi
 491
 492 AC_LANG_POP(C)
 493
 494 CONFIGURE_PART(Find 3rd-Party Libraries)
 495
 496 have_libdbi=no
 497
 498 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[],[
 499     AC_CHECK_LIB(dbi, dbi_initialize, [
 500         LIBS="${LIBS} -ldbi -ldl"
 501         AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 502         have_libdbi=yes
 503     ],[],[-ldl])
 504 ])
 505
 506 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 507
 508 have_libwrap=no
 509 AC_ARG_ENABLE(libwrap,
 510   AS_HELP_STRING([--disable-libwrap],
 511     [do not build in support for libwrap (tcp wrapper)]
 512   ),
 513   [],
 514   [
 515       AC_CHECK_FUNCS(hosts_access, [],
 516           AC_CHECK_LIB(wrap, hosts_access, [
 517               LIBS="${LIBS} -lwrap"
 518               AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 519               have_libwrap=yes
 520           ],[])
 521       )
 522   ]
 523 )
 524
 525 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 526
 527 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 528
 529 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 530
 531
 532 CORE_LIBS="$LIBS"
 533
 534 if test $enable_rrd_graph != no; then
 535 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.5,  http://zlib.net/, "")
 536 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.4.8,  ftp://ftp.simplesystems.org/pub/libpng/png/src/, "")
 537 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.4.6,  http://download.savannah.gnu.org/releases/freetype/, /usr/include/freetype2)
 538 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.8.0,  http://www.freedesktop.org/software/fontconfig/release/, /usr/include)
 539 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.10.2,  http://cairographics.org/releases/, "")
 540 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.10.2,  http://cairographics.org/releases/, "")
 541 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.10.2,  http://cairographics.org/releases/, "")
 542 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.10.2,  http://cairographics.org/releases/, "")
 543 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.28.4,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.28, "")
 544
 545 fi
 546 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.28.7, ftp://ftp.gtk.org/pub/glib/2.28/, "")
 547 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.7.8,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 548
 549 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 550   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 551 fi
 552
 553 ALL_LIBS="$LIBS"
 554 LIBS=
 555
 556 AC_SUBST(CORE_LIBS)
 557 AC_SUBST(ALL_LIBS)
 558
 559 CONFIGURE_PART(Prep for Building Language Bindings)
 560
 561 dnl Check for Perl and friends
 562 PATH=$PATH:/usr/perl5/bin
 563 export PATH
 564 AC_PATH_PROG(PERL, perl, no)
 565 AC_PATH_PROG(POD2MAN, pod2man, no)
 566 AC_PATH_PROG(POD2HTML, pod2html, no)
 567
 568
 569 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 570 [],[enable_perl=yes])
 571
 572
 573 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 574 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 575 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 576 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 577
 578 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 579         COMP_PERL=
 580 else
 581         COMP_PERL="perl_piped perl_shared"
 582         AC_MSG_CHECKING(for the perl version you are running)
 583         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 584         AC_MSG_RESULT($PERL_VERSION)
 585         if test -z "$PERLCC"; then
 586             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 587             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 588             AC_MSG_RESULT($perlcc)
 589             if test ! -x "$perlcc"; then
 590                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 591                 if test "$PERL_CC" = "no"; then
 592                     AC_MSG_WARN([
 593 I would not find the Compiler ($perlcc) that was originally used to compile
 594 your perl binary. You should either make sure that this compiler is
 595 available on your system, pick an other compiler and set PERLCC
 596 appropriately, or use a different perl setup that was compiled locally.
 597
 598 I will disable the compilation of the RRDs perl module for now.
 599 ])
 600                     COMP_PERL="perl_piped"
 601                 fi
 602             fi
 603         fi
 604 fi
 605
 606 AC_MSG_CHECKING(Perl Modules to build)
 607 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 608
 609 # Options to pass when configuring perl module
 610 langpref=$prefix
 611 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 612 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 613
 614 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 615
 616 dnl pass additional perl options when generating Makefile from Makefile.PL
 617 AC_ARG_ENABLE(perl-site-install,
 618 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 619 [PERL_MAKE_OPTIONS=],[])
 620
 621 if test ! -z "$PERLCC"; then
 622    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 623
 624    if test ! -z "$PERLCCFLAGS"; then
 625        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 626    fi
 627
 628    if test -z "$PERLLD"; then
 629        PERLLD=$PERLCC
 630    fi
 631    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 632
 633    if test ! -z "$PERLLDFLAGS"; then
 634        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 635    fi
 636 fi
 637
 638 AC_ARG_WITH(perl-options,
 639 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 640                           generating Makefile from Makefile.PL. If you set this
 641                           option, interesting things may happen unless you know
 642                           what you are doing!],
 643 [PERL_MAKE_OPTIONS=$withval])
 644
 645 AC_SUBST(PERL_MAKE_OPTIONS)
 646 AC_SUBST(PERL)
 647 AC_SUBST(COMP_PERL)
 648 AC_SUBST(PERL_VERSION)
 649
 650 dnl Check for Ruby.
 651 AC_PATH_PROG(RUBY, ruby, no)
 652
 653 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 654 [],[enable_ruby=yes])
 655
 656 AC_MSG_CHECKING(if ruby modules can be built)
 657
 658 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 659         COMP_RUBY=
 660         AC_MSG_RESULT(No .. Ruby not found or disabled)
 661 else
 662         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 663                 COMP_RUBY="ruby"
 664                 AC_MSG_RESULT(YES)
 665         else
 666                 COMP_RUBY=
 667                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 668         fi
 669 fi
 670
 671 dnl pass additional ruby options when generating Makefile from Makefile.PL
 672 AC_ARG_ENABLE(ruby-site-install,
 673 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 674 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 675
 676
 677 AC_ARG_WITH(ruby-options,
 678 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 679                           generating Makefile from extconf.rb. If you set this
 680                           option, interesting things may happen unless you know
 681                           what you are doing!],
 682 [RUBY_MAKE_OPTIONS=$withval])
 683
 684 AC_SUBST(RUBY_MAKE_OPTIONS)
 685 AC_SUBST(RUBY)
 686 AC_SUBST(COMP_RUBY)
 687
 688 dnl Check for Lua.
 689 AC_PATH_PROG(LUA, lua, no)
 690
 691 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 692 [],[enable_lua=yes])
 693
 694 COMP_LUA=
 695 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 696   enable_lua=no
 697 else
 698   AC_MSG_CHECKING(for lua >= 5.0)
 699   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 700     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 701 LUA_EOF
 702   if test 0$LUA_MAJOR -lt 5; then
 703     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 704   else
 705     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 706     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 707     lua_vndot=$LUA_MAJOR$LUA_MINOR
 708     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 709     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 710       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 711         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 712           [lua_headerdir=lua$lua_vndot],
 713           [])],
 714         [])],
 715       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 716         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 717           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 718             [lua_headerdir=lua$lua_vdot],
 719             [])],
 720           [])],
 721         [AC_CHECK_HEADERS(lua.h,
 722           [AC_CHECK_HEADERS(lualib.h,
 723             [AC_CHECK_HEADER(lauxlib.h,
 724               [lua_headerdir=""],
 725               [lua_headerdir="no"])],
 726             [])],
 727           [])])])
 728
 729     if test "$lua_headerdir" = "no"; then
 730       enable_lua=no
 731     else
 732       COMP_LUA=lua
 733     fi
 734
 735     if test "$COMP_LUA" != "lua"; then
 736       enable_lua=no
 737       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 738     else
 739       # OK, headers found, let's check the libraries (LIBS is not used)
 740       LIBS=
 741       lua_havelib=no
 742       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 743       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 744         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 745           [lua_havelib=LUA$lua_vndot],
 746           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 747             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 748              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 749             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 750               [lua_havelib=$lua_vndot],
 751               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 752         [COMP_LUA=], [-lm])
 753       lua_libs=$LIBS
 754       LIBS=
 755
 756       # Options to pass when configuring Lua module
 757       if test  "$lua_havelib" != "no"; then
 758         # OK, headers and libs found. Try to set lua flags
 759         # and modules installation dirs with pkg-config
 760         if test "$PKGCONFIG" != "no"; then
 761           if test "$lua_vndot" = "50"; then
 762             lua_pkg_prefix=lualib
 763           else
 764             lua_pkg_prefix=lua
 765           fi
 766           # try with dot, without dot and finally without version
 767           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 768             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 769             # same binaries?
 770             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 771                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 772                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 773                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 774                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 775                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 776                 break
 777             fi
 778           done
 779         fi
 780
 781         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 782         # if lua 5.0 can't find compat-5.1, force installation of
 783         # compat-5.1.lua together with RRDtool.
 784         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 785           lua_need_compat51=1
 786           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 787         fi
 788
 789         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 790         if test "$LUA_CFLAGS" = ""; then
 791           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 792           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 793           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 794           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 795         fi
 796
 797         dnl pass additional lua options
 798         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 799         dnl found and install together with RRDtool, under $langpref.
 800         AC_ARG_ENABLE(lua-site-install,
 801         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 802         [],
 803         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 804
 805         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 806         AC_SUBST(LUA)
 807         AC_SUBST(COMP_LUA)
 808         AC_SUBST(LUA_INSTALL_CMOD)
 809         AC_SUBST(LUA_INSTALL_LMOD)
 810         AC_SUBST(LUA_CFLAGS)
 811         AC_SUBST(LUA_LFLAGS)
 812         AC_SUBST(LUA_DEFINES)
 813       else
 814         enable_lua=no
 815         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 816       fi
 817     fi
 818   fi
 819 fi
 820 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 821 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 822 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 823       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 824 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 825 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 826 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 827 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 828
 829 enable_tcl_site=no
 830
 831 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 832 [],[enable_tcl=yes])
 833
 834 if test  "$enable_tcl" = "yes"; then
 835   dnl Check for Tcl.
 836   withval=""
 837   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 838   enable_tcl=no
 839   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 840     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 841     if test -f "$dir/tclConfig.sh" ; then
 842         tcl_config=$dir/tclConfig.sh
 843         enable_tcl=yes
 844         AC_MSG_RESULT(yes)
 845         break
 846     else
 847         AC_MSG_RESULT(no)
 848     fi
 849   done
 850
 851   if test "$enable_tcl" = "no"; then
 852         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 853   else
 854         . $tcl_config
 855         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 856         if test -n "$TCL_INC_DIR"; then
 857           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 858         fi
 859   fi
 860   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 861   [],[enable_tcl_site=yes])
 862
 863 fi
 864
 865 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 866 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 867
 868
 869 AC_SUBST(TCL_PREFIX)
 870 AC_SUBST(TCL_SHLIB_CFLAGS)
 871 AC_SUBST(TCL_SHLIB_LD)
 872 AC_SUBST(TCL_SHLIB_SUFFIX)
 873 AC_SUBST(TCL_PACKAGE_PATH)
 874 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 875 AC_SUBST(TCL_STUB_LIB_SPEC)
 876 AC_SUBST(TCL_VERSION)
 877 AC_SUBST(TCL_PACKAGE_DIR)
 878 AC_SUBST(TCL_INCLUDE_SPEC)
 879
 880 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 881 [],[enable_python=yes])
 882
 883 if test  "$enable_python" = "yes"; then
 884 dnl Check for python
 885 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 886 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 887 fi
 888
 889 if test  x$enable_python = xno; then
 890         COMP_PYTHON=
 891 else
 892         COMP_PYTHON="python"
 893 fi
 894
 895 AC_SUBST(COMP_PYTHON)
 896
 897 dnl Check for nroff
 898 AC_ARG_VAR(NROFF, [path to the local nroff version])
 899 AC_PATH_PROGS(NROFF, [gnroff nroff])
 900 if test x$NROFF = x; then
 901   AC_MSG_ERROR([I need a copy of *nroff to format the documentation])
 902 fi
 903 AC_ARG_VAR(TROFF, [path to the local troff version])
 904 AC_PATH_PROGS(TROFF, [groff troff])
 905 if test x$TROFF = x; then
 906   AC_MSG_ERROR([I need a copy of *troff to format the documentation])
 907 fi
 908
 909 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 910 if test -z "$RRDDOCDIR"; then
 911    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 912
 913
 914 CONFIGURE_PART(Apply Configuration Information)
 915
 916 AC_CONFIG_FILES([examples/shared-demo.pl])
 917 AC_CONFIG_FILES([examples/piped-demo.pl])
 918 AC_CONFIG_FILES([examples/stripes.pl])
 919 AC_CONFIG_FILES([examples/bigtops.pl])
 920 AC_CONFIG_FILES([examples/minmax.pl])
 921 AC_CONFIG_FILES([examples/4charts.pl])
 922 AC_CONFIG_FILES([examples/perftest.pl])
 923 AC_CONFIG_FILES([examples/Makefile])
 924 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 925 AC_CONFIG_FILES([doc/Makefile])
 926 AC_CONFIG_FILES([po/Makefile.in])
 927 AC_CONFIG_FILES([src/Makefile])
 928 AC_CONFIG_FILES([src/librrd.sym.in])
 929 AC_CONFIG_FILES([src/librrd.pc])
 930 AC_CONFIG_FILES([bindings/Makefile])
 931 AC_CONFIG_FILES([bindings/tcl/Makefile])
 932 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 933 AC_CONFIG_FILES([Makefile])
 934 AC_CONFIG_FILES([bindings/lua/Makefile])
 935
 936 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 937
 938 dnl intl requires our config to be called config.h. indulge it.
 939 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 940
 941 AC_OUTPUT
 942
 943 AC_MSG_CHECKING(in)
 944 AC_MSG_RESULT(and out again)
 945
 946 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 947 sleep 1
 948 echo $ECHO_N ".$ECHO_C" 1>&6
 949 sleep 1
 950 echo $ECHO_N ".$ECHO_C" 1>&6
 951 sleep 1
 952 echo $ECHO_N ".$ECHO_C" 1>&6
 953 sleep 1
 954 echo $ECHO_N ".$ECHO_C" 1>&6
 955 sleep 1
 956 AC_MSG_RESULT([ just kidding ;-)])
 957 echo
 958 echo "----------------------------------------------------------------"
 959 echo "Config is DONE!"
 960 echo
 961 echo "          With MMAP IO: $enable_mmap"
 962 echo "      Build rrd_getopt: $build_getopt"
 963 echo "       Build rrd_graph: $enable_rrd_graph"
 964 echo "       Static programs: $staticprogs"
 965 echo "          Perl Modules: $COMP_PERL"
 966 echo "           Perl Binary: $PERL"
 967 echo "          Perl Version: $PERL_VERSION"
 968 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 969 echo "          Ruby Modules: $COMP_RUBY"
 970 echo "           Ruby Binary: $RUBY"
 971 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 972 echo "    Build Lua Bindings: $enable_lua"
 973 if test "$enable_lua" = "yes"; then
 974 echo "            Lua Binary: $LUA"
 975 echo "           Lua Version: $lua_version"
 976 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 977 if test "$lua_need_compat51" = "1"; then
 978 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 979 fi
 980 fi
 981 echo "    Build Tcl Bindings: $enable_tcl"
 982 echo " Build Python Bindings: $enable_python"
 983 echo "          Build rrdcgi: $enable_rrdcgi"
 984 echo "       Build librrd MT: $enable_pthread"
 985 echo "           Use gettext: $USE_NLS"
 986 echo "           With libDBI: $have_libdbi"
 987 echo "          With libwrap: $have_libwrap"
 988 echo
 989 echo "             Libraries: $ALL_LIBS"
 990 echo
 991 echo "Type 'make' to compile the software and use 'make install' to "
 992 echo "install everything to: $prefix."
 993 echo
 994 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 995 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 996 echo "place an order."
 997 echo
 998 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 999 echo "----------------------------------------------------------------"