1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl $Id$
4 dnl
5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
6 dnl
7 dnl Inspiration from http://autoconf-archive.cryp.to
9 dnl tell automake the this script is for rrdtool
11 dnl Minimum Autoconf version required.
12 AC_PREREQ(2.59)
14 dnl the official version number is
15 dnl a.b.c
16 AC_INIT([rrdtool],[1.4.6])
18 dnl for testing a numberical version number comes handy
19 dnl the released version are
20 dnl a.bccc
21 dnl the devel versions will be something like
22 dnl a.b999yymmddhh
23 NUMVERS=1.4006
24 AC_SUBST(NUMVERS)
26 dnl for the linker to understand which versions the library are compatible with
27 dnl each other we must keep a separate library version cout of the format c:r:a.
28 dnl - if only implementation changed but all interfaces are kept, do r++
29 dnl - if only functionality was added do c++,r=0,a++
30 dnl - if any functionality was removed do c++,r=0,a=0.
31 dnl
32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
33 dnl
34 LIBVERS=5:4:2
35 AC_SUBST(LIBVERS)
37 AC_CANONICAL_TARGET
38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
39 AM_INIT_AUTOMAKE
40 AM_MAINTAINER_MODE
41 # Enable silent build rules by default, requires at least
42 # Automake-1.11. Disable by either passing --disable-silent-rules to
43 # configure or passing V=1 to make
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45 AC_CONFIG_HEADERS([rrd_config.h])
46 AC_CONFIG_MACRO_DIR([m4])
48 dnl all our local stuff like install scripts and include files
49 dnl is in there
52 dnl determine the type of system we are running on
54 AC_SUBST(VERSION)
56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
58 dnl At the TOP of the HEADER
60 AH_TOP([
61 #ifndef RRD_CONFIG_H
62 #define RRD_CONFIG_H
64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
65 #undef MUST_DISABLE_FPMASK
67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
68 #undef MUST_DISABLE_SIGFPE
70 /* realloc does not support NULL as argument */
71 #undef NO_NULL_REALLOC
73 /* lets enable madvise defines in NetBSD */
74 #if defined(__NetBSD__)
75 # if !defined(_NETBSD_SOURCE)
76 # define _NETBSD_SOURCE
77 # endif
78 #endif
80 ])
82 AH_BOTTOM([
84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
85 # include <malloc/malloc.h>
86 #endif
88 #include "src/rrd_config_bottom.h"
90 #endif
91 ])
93 dnl Process Special Options
94 dnl -----------------------------------
96 dnl How the vertical axis label is printed
97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
98 [Vertical label angle: -90.0 (default) or 90.0])
99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
100 [Vertical label angle: -90.0 (default) or 90.0])
102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
103 [],[enable_rrdcgi=yes])
105 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
107 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
108 [enable_rrdcgi=no],[enable_rrd_graph=yes])
110 if test $enable_rrd_graph != no; then
111 AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
112 fi
114 dnl Check if we run on a system that has fonts
115 AC_ARG_WITH(rrd-default-font,
116 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
117 [RRD_DEFAULT_FONT=$withval],[
118 if test -d ${WINDIR:-nodir}/cour.ttf ; then
119 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
120 else
121 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
122 fi
123 ])
125 dnl Use mmap in rrd_update instead of seek+write
126 AC_ARG_ENABLE([mmap],
127 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
128 [],
129 [enable_mmap=yes])
131 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
132 [],[enable_pthread=yes])
134 AC_ARG_ENABLE(static-programs,
135 AS_HELP_STRING([--enable-static-programs],[Build static programs]),
136 [case "${enableval}" in
137 yes) staticprogs=yes ;;
138 no) staticprogs=no ;;
139 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
140 esac],[staticprogs=no])
141 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
144 CONFIGURE_PART(Audit Compilation Environment)
147 dnl Check for the compiler and static/shared library creation.
148 AC_PROG_CPP
149 AC_PROG_CC
150 AM_PROG_CC_C_O
151 AC_PROG_LIBTOOL
153 dnl Try to detect/use GNU features
154 CFLAGS="$CFLAGS -D_GNU_SOURCE"
156 dnl check for -Werror separatly
157 dnl (quite a few autotool checks do not work with -Werror; also, the
158 dnl check for -Werror fails after checking and adding the other flags)
159 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
160 [AC_COMPILE_IFELSE(
161 [AC_LANG_PROGRAM([[]], [[return 0 ]])],
162 [rd_cv_gcc_flag__Werror="yes"],
163 [rd_cv_gcc_flag__Werror="no"])])
164 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
165 WERROR="-Werror"
166 else
167 WERROR=""
168 fi
169 AC_SUBST(WERROR)
171 dnl which flags does the compiler support?
172 if test "x$GCC" = "xyes"; then
173 for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
174 oCFLAGS="$CFLAGS"
175 CFLAGS="$CFLAGS $flag"
176 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
177 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
178 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
179 if eval test \$$cachename = no; then
180 CFLAGS="$oCFLAGS"
181 fi
182 done
183 fi
187 AC_SUBST(RRD_DEFAULT_FONT)
189 CONFIGURE_PART(Checking for Header Files)
191 dnl Checks for header files.
192 AC_HEADER_STDC
193 AC_HEADER_DIRENT
194 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
196 dnl Checks for typedefs, structures, and compiler characteristics.
197 AC_C_CONST
198 AC_HEADER_TIME
199 AC_STRUCT_TM
201 CONFIGURE_PART(Test Library Functions)
203 dnl Checks for libraries.
204 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
207 dnl add pic flag in any case this makes sure all our code is relocatable
208 eval `./libtool --config | grep pic_flag=`
209 CFLAGS="$CFLAGS $pic_flag"
212 dnl Checks for library functions.
213 AC_FUNC_STRFTIME
214 AC_FUNC_VPRINTF
216 AC_C_BIGENDIAN
218 dnl for each function found we get a definition in config.h
219 dnl of the form HAVE_FUNCTION
221 AC_CHECK_FUNCS(nl_langinfo tzset round rint fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
223 AC_FUNC_STRERROR_R
225 CONFIGURE_PART(Map/Fadvis/Madvise checking)
227 dnl Could use these to know if we need to provide a prototype
228 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
230 dnl check for fdatasync. Solaris has fdatasync in the librt
232 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
233 dnl if there is no fdatasync we may get lucky with fsync
234 AC_CHECK_FUNCS(fsync)
236 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
238 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
239 AC_CHECK_FUNCS(getaddrinfo, [], AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
243 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
244 if test "x$enable_mmap" = "xyes"; then
245 case "$host" in
246 *cygwin*)
247 # the normal mmap test does not work in cygwin
248 AC_CHECK_FUNCS(mmap)
249 if test "x$ac_cv_func_mmap" = "xyes"; then
250 ac_cv_func_mmap_fixed_mapped=yes
251 fi
252 ;;
253 *)
254 AC_CHECK_HEADERS(sys/mman.h)
255 AC_FUNC_MMAP
256 AC_CHECK_FUNCS(mmap munmap msync)
257 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
258 # include <sys/mman.h>
259 #endif])
260 if test "x$ac_cv_have_decl_madvise" = "xyes";
261 then
262 AC_CHECK_FUNCS(madvise)
263 else
264 AC_CHECK_FUNCS(posix_madvise)
265 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
266 AC_MSG_WARN([madvise() nor posix_madvise() found.])
267 fi
268 fi
269 ;;
270 esac
271 if test "x$ac_cv_func_mmap" != "xyes";
272 then
273 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
274 dnl enable_mmap="no"
275 fi
276 fi
278 dnl can we use posix_fadvise
279 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
280 #include <fcntl.h>])
281 AC_CHECK_FUNCS(posix_fadvise)
283 CONFIGURE_PART(Libintl Processing)
285 AM_GNU_GETTEXT_VERSION(0.17)
286 AM_GNU_GETTEXT(external)
288 CONFIGURE_PART(IEEE Math Checks)
291 dnl actual code to check if this works
292 AC_CHECK_FUNCS(fpclassify, ,
293 [AC_MSG_CHECKING(for fpclassify with <math.h>)
294 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
295 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
296 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
298 AC_CHECK_FUNCS(isinf, ,
299 [AC_MSG_CHECKING(for isinf with <math.h>)
300 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
301 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
302 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
304 dnl finite is BSD, isfinite is C99, so prefer the latter
305 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
306 AC_TRY_RUN([
307 #ifdef HAVE_MATH_H
308 #include <math.h>
309 #endif
310 #ifdef HAVE_FLOAT_H
311 #include <float.h>
312 #endif
313 int main ()
314 {
315 #ifdef isfinite
316 #ifdef LDBL_MAX
317 if (!isfinite(LDBL_MAX)) return 1;
318 #endif
319 #ifdef DBL_MAX
320 if (!isfinite(DBL_MAX)) return 1;
321 #endif
322 #endif
323 return 0;
324 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
325 case "${target}" in
326 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
327 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
328 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
329 *) ac_cv_have_broken_isfinite=no ;;
330 esac])
331 ])
333 dnl the test does not seem to work on solaris 2.8
334 dnl so lets fix this by hand
335 case "${target}" in
336 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
337 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
338 esac
340 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
341 AC_DEFINE(HAVE_ISFINITE)
342 else
343 AC_CHECK_FUNCS(finite,[],
344 [AC_CHECK_FUNCS(isfinite,[],
345 [AC_MSG_CHECKING(for isfinite with <math.h>)
346 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
347 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
348 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
349 fi
351 AC_FULL_IEEE
353 CONFIGURE_PART(Resolve Portability Issues)
355 CHECK_FOR_WORKING_MS_ASYNC
357 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
358 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
359 [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
360 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
361 AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
363 dnl Do we need getopt_long
365 dnl even when including our own getopt implementation
366 dnl we may want to make sure we use the external
367 dnl defined by libc to not run into linker resolve trouble
369 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
370 [AC_TRY_LINK([#include <unistd.h>],
371 [extern int opterr; opterr = 1;],
372 [rd_cv_var_int_opterr=yes],
373 [rd_cv_var_int_opterr=no])])
374 if test x"$rd_cv_var_int_opterr" = x"yes"; then
375 AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
376 fi
378 build_getopt=no
379 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
380 AC_CHECK_FUNC(getopt_long,[],[
381 RRD_GETOPT_LONG="getopt_long"
382 build_getopt=yes
383 ])
384 AC_SUBST(RRD_GETOPT_LONG)
385 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
387 dnl what does realloc do if it gets called with a NULL pointer
389 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
390 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
391 int main(void){
392 char *x = NULL;
393 x = realloc (x,10);
394 if (x==NULL) return 1;
395 return 0;
396 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
398 if test x"$rd_cv_null_realloc" = xnope; then
399 AC_DEFINE(NO_NULL_REALLOC)
400 fi
402 AC_LANG_PUSH(C)
403 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
404 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
405 AC_LINK_IFELSE(
406 AC_LANG_PROGRAM(
407 [[#include <time.h>]],
408 [[ctime_r(NULL,NULL,0)]]
409 ),
410 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
411 AC_LINK_IFELSE(
412 AC_LANG_PROGRAM(
413 [[#include <time.h>]],
414 [[ctime_r(NULL,NULL)]]
415 ),
416 [AC_MSG_RESULT([yes, this seems to be solaris style])],
417 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
418 )
419 ],
420 [ AC_LINK_IFELSE(
421 AC_LANG_PROGRAM(
422 [[#include <time.h>]],
423 [[ctime_r(NULL,NULL)]]
424 ),
425 [AC_MSG_RESULT(no)],
426 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
427 )
428 ]
429 )
430 AC_LANG_POP(C)
432 dnl Check for pthreads
433 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
435 AC_SUBST(MULTITHREAD_CFLAGS)
436 AC_SUBST(MULTITHREAD_LDFLAGS)
438 if test $enable_pthread != no; then
439 ACX_PTHREAD([
440 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
441 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
442 ],
443 [])
444 fi
446 dnl since we use lots of *_r functions all over the code we better
447 dnl make sure they are known
449 if test "x$x_rflag" != "xno"; then
450 CPPFLAGS="$CPPFLAGS $x_rflag"
451 fi
453 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
455 AC_LANG_PUSH(C)
456 dnl see if we have to include malloc/malloc.h
457 AC_MSG_CHECKING([do we need malloc/malloc.h])
458 AC_LINK_IFELSE(
459 AC_LANG_PROGRAM(
460 [[#include <stdlib.h>]],
461 [[malloc(1)]]
462 ),
463 [ AC_MSG_RESULT([nope, works out of the box]) ],
464 [ AC_LINK_IFELSE(
465 AC_LANG_PROGRAM(
466 [[#include <stdlib.h>
467 #include <malloc/malloc.h>]],
468 [[malloc(1)]]
469 ),[
470 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
471 AC_MSG_RESULT([yes we do])],
472 [AC_MSG_ERROR([Can not figure how to compile malloc])]
473 )
474 ]
475 )
477 dnl is time_t 32 of 64 bit ?
478 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
479 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
480 AC_MSG_CHECKING([the type of time_t])
481 AC_CHECK_SIZEOF([time_t])
482 if test "x$ac_cv_sizeof_time_t" = "x4"; then
483 AC_MSG_RESULT([time_t is 32 bit])
484 AC_DEFINE([TIME_T_IS_32BIT])
485 elif test "x$ac_cv_sizeof_time_t" = "x8"; then
486 AC_MSG_RESULT([time_t is 64 bit])
487 AC_DEFINE([TIME_T_IS_64BIT])
488 else
489 AC_MSG_ERROR([can not figure type of time_t])
490 fi
492 AC_LANG_POP(C)
494 CONFIGURE_PART(Find 3rd-Party Libraries)
496 have_libdbi=no
498 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[],[
499 AC_CHECK_HEADER(dbi/dbi.h, [
500 AC_CHECK_LIB(dbi, dbi_initialize, [
501 AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
502 LIBS="${LIBS} -ldbi -ldl"
503 have_libdbi=yes
504 ])
505 ])
506 ])
508 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
510 have_libwrap=no
512 AC_ARG_ENABLE(libwrap, AS_HELP_STRING([--disable-libwrap], [do not build in support for libwrap (tcp wrapper)]),[],[
513 AC_CHECK_HEADER(tcpd.h,[
514 AC_CHECK_FUNCS(hosts_access, [
515 AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
516 have_libwrap=yes
517 ],
518 [
519 AC_CHECK_LIB(wrap, hosts_access, [
520 AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
521 LIBS="${LIBS} -lwrap"
522 have_libwrap=yes
523 ])
524 ])
525 ])
526 ])
529 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
531 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
534 CORE_LIBS="$LIBS"
536 if test $enable_rrd_graph != no; then
537 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.5, http://zlib.net/, "")
538 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.4.8, ftp://ftp.simplesystems.org/pub/libpng/png/src/, "")
539 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.4.6, http://download.savannah.gnu.org/releases/freetype/, /usr/include/freetype2)
540 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.8.0, http://www.freedesktop.org/software/fontconfig/release/, /usr/include)
541 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.10.2, http://cairographics.org/releases/, "")
542 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.10.2, http://cairographics.org/releases/, "")
543 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.10.2, http://cairographics.org/releases/, "")
544 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.10.2, http://cairographics.org/releases/, "")
545 EX_CHECK_ALL(pangocairo-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.28.4, http://ftp.gnome.org/pub/GNOME/sources/pango/1.28, "")
547 fi
548 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.28.7, ftp://ftp.gtk.org/pub/glib/2.28/, "")
549 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.7.8, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
551 if test "$EX_CHECK_ALL_ERR" = "YES"; then
552 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
553 fi
555 ALL_LIBS="$LIBS"
556 LIBS=
558 AC_SUBST(CORE_LIBS)
559 AC_SUBST(ALL_LIBS)
561 CONFIGURE_PART(Prep for Building Language Bindings)
563 dnl Check for Perl and friends
564 PATH=$PATH:/usr/perl5/bin
565 export PATH
566 AC_PATH_PROG(PERL, perl, no)
567 AC_PATH_PROG(POD2MAN, pod2man, no)
568 AC_PATH_PROG(POD2HTML, pod2html, no)
571 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
572 [],[enable_perl=yes])
575 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
576 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
577 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
578 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
580 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
581 COMP_PERL=
582 else
583 COMP_PERL="perl_piped perl_shared"
584 AC_MSG_CHECKING(for the perl version you are running)
585 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
586 AC_MSG_RESULT($PERL_VERSION)
587 if test -z "$PERLCC"; then
588 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
589 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
590 AC_MSG_RESULT($perlcc)
591 if test ! -x "$perlcc"; then
592 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
593 if test "$PERL_CC" = "no"; then
594 AC_MSG_WARN([
595 I would not find the Compiler ($perlcc) that was originally used to compile
596 your perl binary. You should either make sure that this compiler is
597 available on your system, pick an other compiler and set PERLCC
598 appropriately, or use a different perl setup that was compiled locally.
600 I will disable the compilation of the RRDs perl module for now.
601 ])
602 COMP_PERL="perl_piped"
603 fi
604 fi
605 fi
606 fi
608 AC_MSG_CHECKING(Perl Modules to build)
609 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
611 # Options to pass when configuring perl module
612 langpref=$prefix
613 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
614 test "$langpref" = "NONE" && langpref=$ac_default_prefix
616 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
618 dnl pass additional perl options when generating Makefile from Makefile.PL
619 AC_ARG_ENABLE(perl-site-install,
620 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
621 [PERL_MAKE_OPTIONS=],[])
623 if test ! -z "$PERLCC"; then
624 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
626 if test ! -z "$PERLCCFLAGS"; then
627 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
628 fi
630 if test -z "$PERLLD"; then
631 PERLLD=$PERLCC
632 fi
633 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
635 if test ! -z "$PERLLDFLAGS"; then
636 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
637 fi
638 fi
640 AC_ARG_WITH(perl-options,
641 [ --with-perl-options=[OPTIONS] options to pass on command-line when
642 generating Makefile from Makefile.PL. If you set this
643 option, interesting things may happen unless you know
644 what you are doing!],
645 [PERL_MAKE_OPTIONS=$withval])
647 AC_SUBST(PERL_MAKE_OPTIONS)
648 AC_SUBST(PERL)
649 AC_SUBST(COMP_PERL)
650 AC_SUBST(PERL_VERSION)
652 dnl Check for Ruby.
653 AC_PATH_PROG(RUBY, ruby, no)
655 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
656 [],[enable_ruby=yes])
658 AC_MSG_CHECKING(if ruby modules can be built)
660 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
661 COMP_RUBY=
662 AC_MSG_RESULT(No .. Ruby not found or disabled)
663 else
664 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
665 COMP_RUBY="ruby"
666 AC_MSG_RESULT(YES)
667 else
668 COMP_RUBY=
669 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
670 fi
671 fi
673 dnl pass additional ruby options when generating Makefile from Makefile.PL
674 AC_ARG_ENABLE(ruby-site-install,
675 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
676 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
679 AC_ARG_WITH(ruby-options,
680 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
681 generating Makefile from extconf.rb. If you set this
682 option, interesting things may happen unless you know
683 what you are doing!],
684 [RUBY_MAKE_OPTIONS=$withval])
686 AC_SUBST(RUBY_MAKE_OPTIONS)
687 AC_SUBST(RUBY)
688 AC_SUBST(COMP_RUBY)
690 dnl Check for Lua.
691 AC_PATH_PROG(LUA, lua, no)
693 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
694 [],[enable_lua=yes])
696 COMP_LUA=
697 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
698 enable_lua=no
699 else
700 AC_MSG_CHECKING(for lua >= 5.0)
701 read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
702 $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
703 LUA_EOF
704 if test 0$LUA_MAJOR -lt 5; then
705 AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
706 else
707 AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
708 lua_vdot=$LUA_MAJOR.$LUA_MINOR
709 lua_vndot=$LUA_MAJOR$LUA_MINOR
710 lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
711 AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
712 [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
713 [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
714 [lua_headerdir=lua$lua_vndot],
715 [])],
716 [])],
717 [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
718 [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
719 [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
720 [lua_headerdir=lua$lua_vdot],
721 [])],
722 [])],
723 [AC_CHECK_HEADERS(lua.h,
724 [AC_CHECK_HEADERS(lualib.h,
725 [AC_CHECK_HEADER(lauxlib.h,
726 [lua_headerdir=""],
727 [lua_headerdir="no"])],
728 [])],
729 [])])])
731 if test "$lua_headerdir" = "no"; then
732 enable_lua=no
733 else
734 COMP_LUA=lua
735 fi
737 if test "$COMP_LUA" != "lua"; then
738 enable_lua=no
739 AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
740 else
741 # OK, headers found, let's check the libraries (LIBS is not used)
742 LIBS=
743 lua_havelib=no
744 LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
745 AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
746 [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
747 [lua_havelib=LUA$lua_vndot],
748 [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
749 [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
750 test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
751 [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
752 [lua_havelib=$lua_vndot],
753 [COMP_LUA=], [-lm])], [-lm])], [-lm])],
754 [COMP_LUA=], [-lm])
755 lua_libs=$LIBS
756 LIBS=
758 # Options to pass when configuring Lua module
759 if test "$lua_havelib" != "no"; then
760 # OK, headers and libs found. Try to set lua flags
761 # and modules installation dirs with pkg-config
762 if test "$PKGCONFIG" != "no"; then
763 if test "$lua_vndot" = "50"; then
764 lua_pkg_prefix=lualib
765 else
766 lua_pkg_prefix=lua
767 fi
768 # try with dot, without dot and finally without version
769 for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
770 lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
771 # same binaries?
772 if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
773 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
774 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
775 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
776 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
777 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
778 break
779 fi
780 done
781 fi
783 LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
784 # if lua 5.0 can't find compat-5.1, force installation of
785 # compat-5.1.lua together with RRDtool.
786 if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
787 lua_need_compat51=1
788 LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
789 fi
791 # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
792 if test "$LUA_CFLAGS" = ""; then
793 AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
794 LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
795 LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
796 LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
797 fi
799 dnl pass additional lua options
800 dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
801 dnl found and install together with RRDtool, under $langpref.
802 AC_ARG_ENABLE(lua-site-install,
803 AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
804 [],
805 [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
807 LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
808 AC_SUBST(LUA)
809 AC_SUBST(COMP_LUA)
810 AC_SUBST(LUA_INSTALL_CMOD)
811 AC_SUBST(LUA_INSTALL_LMOD)
812 AC_SUBST(LUA_CFLAGS)
813 AC_SUBST(LUA_LFLAGS)
814 AC_SUBST(LUA_DEFINES)
815 else
816 enable_lua=no
817 AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
818 fi
819 fi
820 fi
821 fi
822 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
823 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
824 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
825 [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
826 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
827 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
828 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
829 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
831 enable_tcl_site=no
833 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
834 [],[enable_tcl=yes])
836 if test "$enable_tcl" = "yes"; then
837 dnl Check for Tcl.
838 withval=""
839 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
840 enable_tcl=no
841 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
842 AC_MSG_CHECKING(for tclConfig.sh in $dir)
843 if test -f "$dir/tclConfig.sh" ; then
844 tcl_config=$dir/tclConfig.sh
845 enable_tcl=yes
846 AC_MSG_RESULT(yes)
847 break
848 else
849 AC_MSG_RESULT(no)
850 fi
851 done
853 if test "$enable_tcl" = "no"; then
854 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
855 else
856 . $tcl_config
857 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
858 if test -n "$TCL_INC_DIR"; then
859 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
860 fi
861 fi
862 AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
863 [],[enable_tcl_site=yes])
865 fi
867 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
868 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
871 AC_SUBST(TCL_PREFIX)
872 AC_SUBST(TCL_SHLIB_CFLAGS)
873 AC_SUBST(TCL_SHLIB_LD)
874 AC_SUBST(TCL_SHLIB_SUFFIX)
875 AC_SUBST(TCL_PACKAGE_PATH)
876 AC_SUBST(TCL_LD_SEARCH_FLAGS)
877 AC_SUBST(TCL_STUB_LIB_SPEC)
878 AC_SUBST(TCL_VERSION)
879 AC_SUBST(TCL_PACKAGE_DIR)
880 AC_SUBST(TCL_INCLUDE_SPEC)
882 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
883 [],[enable_python=yes])
885 if test "$enable_python" = "yes"; then
886 dnl Check for python
887 AM_PATH_PYTHON(2.3,[],[enable_python=no])
888 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
889 fi
891 if test x$enable_python = xno; then
892 COMP_PYTHON=
893 else
894 COMP_PYTHON="python"
895 fi
897 AC_SUBST(COMP_PYTHON)
899 dnl Check for nroff
900 AC_ARG_VAR(NROFF, [path to the local nroff version])
901 AC_PATH_PROGS(NROFF, [gnroff nroff])
902 if test x$NROFF = x; then
903 AC_MSG_ERROR([I need a copy of *nroff to format the documentation])
904 fi
905 AC_ARG_VAR(TROFF, [path to the local troff version])
906 AC_PATH_PROGS(TROFF, [groff troff])
907 if test x$TROFF = x; then
908 AC_MSG_ERROR([I need a copy of *troff to format the documentation])
909 fi
911 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
912 if test -z "$RRDDOCDIR"; then
913 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
916 CONFIGURE_PART(Apply Configuration Information)
918 AC_CONFIG_FILES([examples/shared-demo.pl])
919 AC_CONFIG_FILES([examples/piped-demo.pl])
920 AC_CONFIG_FILES([examples/stripes.pl])
921 AC_CONFIG_FILES([examples/bigtops.pl])
922 AC_CONFIG_FILES([examples/minmax.pl])
923 AC_CONFIG_FILES([examples/4charts.pl])
924 AC_CONFIG_FILES([examples/perftest.pl])
925 AC_CONFIG_FILES([examples/Makefile])
926 AC_CONFIG_FILES([examples/rrdcached/Makefile])
927 AC_CONFIG_FILES([doc/Makefile])
928 AC_CONFIG_FILES([po/Makefile.in])
929 AC_CONFIG_FILES([src/Makefile])
930 AC_CONFIG_FILES([src/librrd.sym.in])
931 AC_CONFIG_FILES([src/librrd.pc])
932 AC_CONFIG_FILES([bindings/Makefile])
933 AC_CONFIG_FILES([bindings/tcl/Makefile])
934 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
935 AC_CONFIG_FILES([Makefile])
936 AC_CONFIG_FILES([bindings/lua/Makefile])
938 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
940 dnl intl requires our config to be called config.h. indulge it.
941 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
943 AC_OUTPUT
945 AC_MSG_CHECKING(in)
946 AC_MSG_RESULT(and out again)
948 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
949 sleep 1
950 echo $ECHO_N ".$ECHO_C" 1>&6
951 sleep 1
952 echo $ECHO_N ".$ECHO_C" 1>&6
953 sleep 1
954 echo $ECHO_N ".$ECHO_C" 1>&6
955 sleep 1
956 echo $ECHO_N ".$ECHO_C" 1>&6
957 sleep 1
958 AC_MSG_RESULT([ just kidding ;-)])
959 echo
960 echo "----------------------------------------------------------------"
961 echo "Config is DONE!"
962 echo
963 echo " With MMAP IO: $enable_mmap"
964 echo " Build rrd_getopt: $build_getopt"
965 echo " Build rrd_graph: $enable_rrd_graph"
966 echo " Static programs: $staticprogs"
967 echo " Perl Modules: $COMP_PERL"
968 echo " Perl Binary: $PERL"
969 echo " Perl Version: $PERL_VERSION"
970 echo " Perl Options: $PERL_MAKE_OPTIONS"
971 echo " Ruby Modules: $COMP_RUBY"
972 echo " Ruby Binary: $RUBY"
973 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
974 echo " Build Lua Bindings: $enable_lua"
975 if test "$enable_lua" = "yes"; then
976 echo " Lua Binary: $LUA"
977 echo " Lua Version: $lua_version"
978 echo " Lua C-modules dir: $LUA_INSTALL_CMOD"
979 if test "$lua_need_compat51" = "1"; then
980 echo " Lua Lua-modules dir: $LUA_INSTALL_LMOD"
981 fi
982 fi
983 echo " Build Tcl Bindings: $enable_tcl"
984 echo " Build Python Bindings: $enable_python"
985 echo " Build rrdcgi: $enable_rrdcgi"
986 echo " Build librrd MT: $enable_pthread"
987 echo " Use gettext: $USE_NLS"
988 echo " With libDBI: $have_libdbi"
989 echo " With libwrap: $have_libwrap"
990 echo
991 echo " Libraries: $ALL_LIBS"
992 echo
993 echo "Type 'make' to compile the software and use 'make install' to "
994 echo "install everything to: $prefix."
995 echo
996 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
997 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
998 echo "place an order."
999 echo
1000 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
1001 echo "----------------------------------------------------------------"