configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.4])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4004
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:4:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 dnl Check if we run on a system that has fonts
 106 AC_ARG_WITH(rrd-default-font,
 107 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 108 [RRD_DEFAULT_FONT=$withval],[
 109   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 110         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 111   else
 112         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 113   fi
 114 ])
 115
 116 dnl Use mmap in rrd_update instead of seek+write
 117 AC_ARG_ENABLE([mmap],
 118 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 119 [],
 120 [enable_mmap=yes])
 121
 122 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 123 [],[enable_pthread=yes])
 124
 125 AC_ARG_ENABLE(static-programs,
 126      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 127      [case "${enableval}" in
 128        yes) staticprogs=yes ;;
 129        no)  staticprogs=no ;;
 130        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 131      esac],[staticprogs=no])
 132 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 133
 134
 135 CONFIGURE_PART(Audit Compilation Environment)
 136
 137
 138 dnl Check for the compiler and static/shared library creation.
 139 AC_PROG_CPP
 140 AC_PROG_CC
 141 AM_PROG_CC_C_O
 142 AC_PROG_LIBTOOL
 143
 144 dnl Try to detect/use GNU features
 145 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 146
 147 dnl check for -Werror separatly
 148 dnl (quite a few autotool checks do not work with -Werror; also, the
 149 dnl check for -Werror fails after checking and adding the other flags)
 150 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 151   [AC_COMPILE_IFELSE(
 152     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 153     [rd_cv_gcc_flag__Werror="yes"],
 154     [rd_cv_gcc_flag__Werror="no"])])
 155 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 156   WERROR="-Werror"
 157 else
 158   WERROR=""
 159 fi
 160 AC_SUBST(WERROR)
 161
 162 dnl which flags does the compiler support?
 163 if test "x$GCC" = "xyes"; then
 164   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 165     oCFLAGS="$CFLAGS"
 166     CFLAGS="$CFLAGS $flag"
 167     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 168     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 169        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 170     if eval test \$$cachename = no; then
 171          CFLAGS="$oCFLAGS"
 172     fi
 173   done
 174 fi
 175
 176
 177
 178 AC_SUBST(RRD_DEFAULT_FONT)
 179
 180 CONFIGURE_PART(Checking for Header Files)
 181
 182 dnl Checks for header files.
 183 AC_HEADER_STDC
 184 AC_HEADER_DIRENT
 185 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 186
 187 dnl Checks for typedefs, structures, and compiler characteristics.
 188 AC_C_CONST
 189 AC_HEADER_TIME
 190 AC_STRUCT_TM
 191
 192 CONFIGURE_PART(Test Library Functions)
 193
 194 dnl Checks for libraries.
 195 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 196
 197
 198 dnl add pic flag in any case this makes sure all our code is relocatable
 199 eval `./libtool --config | grep pic_flag`
 200 CFLAGS="$CFLAGS $pic_flag"
 201
 202
 203 dnl Checks for library functions.
 204 AC_FUNC_STRFTIME
 205 AC_FUNC_VPRINTF
 206
 207 AC_C_BIGENDIAN
 208
 209 dnl for each function found we get a definition in config.h
 210 dnl of the form HAVE_FUNCTION
 211
 212 AC_CHECK_FUNCS(nl_langinfo tzset round rint fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 213
 214 AC_FUNC_STRERROR_R
 215
 216 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 217
 218 dnl Could use these to know if we need to provide a prototype
 219 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 220
 221 dnl check for fdatasync. Solaris has fdatasync in the librt
 222
 223 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 224 dnl if there is no fdatasync we may get lucky with fsync
 225 AC_CHECK_FUNCS(fsync)
 226
 227 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 228
 229 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 230 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 231
 232
 233
 234 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 235 if test "x$enable_mmap" = "xyes"; then
 236   case "$host" in
 237   *cygwin*)
 238     # the normal mmap test does not work in cygwin
 239     AC_CHECK_FUNCS(mmap)
 240     if test "x$ac_cv_func_mmap" = "xyes"; then
 241       ac_cv_func_mmap_fixed_mapped=yes
 242     fi
 243   ;;
 244   *)
 245     AC_CHECK_HEADERS(sys/mman.h)
 246     AC_FUNC_MMAP
 247     AC_CHECK_FUNCS(mmap munmap msync)
 248     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 249                                      # include <sys/mman.h>
 250                                      #endif])
 251     if test "x$ac_cv_have_decl_madvise" = "xyes";
 252     then
 253       AC_CHECK_FUNCS(madvise)
 254     else
 255       AC_CHECK_FUNCS(posix_madvise)
 256       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 257         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 258       fi
 259     fi
 260   ;;
 261   esac
 262   if test "x$ac_cv_func_mmap" != "xyes";
 263   then
 264     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 265 dnl enable_mmap="no"
 266   fi
 267 fi
 268
 269 dnl can we use posix_fadvise
 270 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 271 #include <fcntl.h>])
 272 AC_CHECK_FUNCS(posix_fadvise)
 273
 274 CONFIGURE_PART(Libintl Processing)
 275
 276 AM_GNU_GETTEXT_VERSION(0.18)
 277 AM_GNU_GETTEXT(external)
 278
 279 CONFIGURE_PART(IEEE Math Checks)
 280
 281
 282 dnl actual code to check if this works
 283 AC_CHECK_FUNCS(fpclassify, ,
 284   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 285     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 286 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 287       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 288
 289 AC_CHECK_FUNCS(isinf, ,
 290   [AC_MSG_CHECKING(for isinf with <math.h>)
 291     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 292 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 293       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 294
 295 dnl finite is BSD, isfinite is C99, so prefer the latter
 296 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 297 AC_TRY_RUN([
 298 #ifdef HAVE_MATH_H
 299 #include <math.h>
 300 #endif
 301 #ifdef HAVE_FLOAT_H
 302 #include <float.h>
 303 #endif
 304 int main ()
 305 {
 306 #ifdef isfinite
 307 #ifdef LDBL_MAX
 308   if (!isfinite(LDBL_MAX)) return 1;
 309 #endif
 310 #ifdef DBL_MAX
 311   if (!isfinite(DBL_MAX)) return 1;
 312 #endif
 313 #endif
 314 return 0;
 315 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 316 case "${target}" in
 317   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 318   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 319   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 320   *) ac_cv_have_broken_isfinite=no ;;
 321 esac])
 322 ])
 323
 324 dnl the test does not seem to work on solaris 2.8
 325 dnl so lets fix this by hand
 326 case "${target}" in
 327   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 328   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 329 esac
 330
 331 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 332   AC_DEFINE(HAVE_ISFINITE)
 333 else
 334   AC_CHECK_FUNCS(finite,[],
 335       [AC_CHECK_FUNCS(isfinite,[],
 336          [AC_MSG_CHECKING(for isfinite with <math.h>)
 337           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 338 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 339                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 340 fi
 341
 342 AC_FULL_IEEE
 343
 344 CONFIGURE_PART(Resolve Portability Issues)
 345
 346 CHECK_FOR_WORKING_MS_ASYNC
 347
 348 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 349 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 350   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 352       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 353
 354 dnl Do we need getopt_long
 355
 356 dnl even when including our own getopt implementation
 357 dnl we may want to make sure we use the external
 358 dnl defined by libc to not run into linker resolve trouble
 359
 360 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 361 [AC_TRY_LINK([#include <unistd.h>],
 362   [extern int opterr; opterr = 1;],
 363   [rd_cv_var_int_opterr=yes],
 364   [rd_cv_var_int_opterr=no])])
 365 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 366   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 367 fi
 368
 369 build_getopt=no
 370 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 371 AC_CHECK_FUNC(getopt_long,[],[
 372 RRD_GETOPT_LONG="getopt_long"
 373 build_getopt=yes
 374 ])
 375 AC_SUBST(RRD_GETOPT_LONG)
 376 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 377
 378 dnl what does realloc do if it gets called with a NULL pointer
 379
 380 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 381 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 382               int main(void){
 383               char *x = NULL;
 384               x = realloc (x,10);
 385               if (x==NULL) return 1;
 386               return 0;
 387              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 388
 389 if test x"$rd_cv_null_realloc" = xnope; then
 390 AC_DEFINE(NO_NULL_REALLOC)
 391 fi
 392
 393 AC_LANG_PUSH(C)
 394 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 395 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 396 AC_LINK_IFELSE(
 397     AC_LANG_PROGRAM(
 398            [[#include <time.h>]],
 399            [[ctime_r(NULL,NULL,0)]]
 400                    ),
 401     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 402       AC_LINK_IFELSE(
 403           AC_LANG_PROGRAM(
 404                 [[#include <time.h>]],
 405                 [[ctime_r(NULL,NULL)]]
 406                          ),
 407           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 408           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 409       )
 410     ],
 411     [ AC_LINK_IFELSE(
 412           AC_LANG_PROGRAM(
 413                 [[#include <time.h>]],
 414                 [[ctime_r(NULL,NULL)]]
 415                          ),
 416           [AC_MSG_RESULT(no)],
 417           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 418       )
 419     ]
 420 )
 421 AC_LANG_POP(C)
 422
 423 dnl Check for pthreads
 424 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 425
 426 AC_SUBST(MULTITHREAD_CFLAGS)
 427 AC_SUBST(MULTITHREAD_LDFLAGS)
 428
 429 if test $enable_pthread != no; then
 430  ACX_PTHREAD([
 431     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 432     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 433              ],
 434              [])
 435 fi
 436
 437 dnl since we use lots of *_r functions all over the code we better
 438 dnl make sure they are known
 439
 440 if test  "x$x_rflag" != "xno"; then
 441    CPPFLAGS="$CPPFLAGS $x_rflag"
 442 fi
 443
 444 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 445
 446 AC_LANG_PUSH(C)
 447 dnl see if we have to include malloc/malloc.h
 448 AC_MSG_CHECKING([do we need malloc/malloc.h])
 449 AC_LINK_IFELSE(
 450     AC_LANG_PROGRAM(
 451            [[#include <stdlib.h>]],
 452            [[malloc(1)]]
 453                    ),
 454     [ AC_MSG_RESULT([nope, works out of the box]) ],
 455     [ AC_LINK_IFELSE(
 456           AC_LANG_PROGRAM(
 457                 [[#include <stdlib.h>
 458                   #include <malloc/malloc.h>]],
 459                 [[malloc(1)]]
 460                          ),[
 461            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 462            AC_MSG_RESULT([yes we do])],
 463           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 464       )
 465     ]
 466 )
 467
 468 dnl is time_t 32 of 64 bit ?
 469 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 470 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 471 AC_MSG_CHECKING([the type of time_t])
 472 AC_RUN_IFELSE(
 473     AC_LANG_PROGRAM(
 474         [[#include <time.h>]],
 475         [[if (sizeof(time_t) != 4) return 1; ]]
 476         ),
 477     [ AC_MSG_RESULT([time_t is 32 bit])
 478       AC_DEFINE([TIME_T_IS_32BIT])
 479     ],
 480     [ AC_RUN_IFELSE(
 481         AC_LANG_PROGRAM(
 482         [[#include <time.h>]],
 483         [[if (sizeof(time_t) != 8) return 1; ]]
 484         ),
 485         [
 486           AC_MSG_RESULT([time_t is 64 bit])
 487           AC_DEFINE([TIME_T_IS_64BIT])
 488         ],
 489         [AC_MSG_ERROR([can not figure type of time_t])]
 490       )
 491     ]
 492 )
 493
 494 AC_LANG_POP(C)
 495
 496 CONFIGURE_PART(Find 3rd-Party Libraries)
 497
 498 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 499   XXX=$LIBS
 500   LIBS="$LIBS -ldbi -ldl"
 501   AC_MSG_CHECKING(for libdbi)
 502   AC_LINK_IFELSE(
 503     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 504                      [[dbi_initialize(NULL)]]
 505                     )
 506     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 507        AC_MSG_RESULT([yes])
 508        have_libdbi=yes
 509     ],[LIBS=$XXX
 510        AC_MSG_RESULT([no])
 511        have_libdbi=no
 512     ]
 513   )
 514 ])
 515 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 516
 517 AC_ARG_ENABLE(libwrap,
 518   AS_HELP_STRING([--disable-libwrap],
 519   [do not build in support for libwrap (tcp wrapper)]),
 520   [have_libwrap=no],[
 521     XXX=$LIBS
 522     LIBS="$LIBS -lwrap"
 523     AC_MSG_CHECKING(for libwrap)
 524     AC_LINK_IFELSE(
 525       [AC_LANG_PROGRAM([[#include "tcpd.h"]], [[hosts_access(NULL)]])
 526     ],[AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 527        AC_MSG_RESULT([yes])
 528        have_libwrap=yes
 529     ],[LIBS=$XXX
 530        AC_MSG_RESULT([no])
 531        have_libwrap=no
 532     ]
 533   )
 534 ])
 535 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 536
 537 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 538
 539
 540 CORE_LIBS="$LIBS"
 541
 542 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 543 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 544 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 545 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 546 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 547 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 548 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 549 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 550 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 551 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 552 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 553
 554 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 555   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 556 fi
 557
 558 ALL_LIBS="$LIBS"
 559 LIBS=
 560
 561 AC_SUBST(CORE_LIBS)
 562 AC_SUBST(ALL_LIBS)
 563
 564 CONFIGURE_PART(Prep for Building Language Bindings)
 565
 566 dnl Check for Perl and friends
 567 PATH=$PATH:/usr/perl5/bin
 568 export PATH
 569 AC_PATH_PROG(PERL, perl, no)
 570 AC_PATH_PROG(POD2MAN, pod2man, no)
 571 AC_PATH_PROG(POD2HTML, pod2html, no)
 572
 573
 574 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 575 [],[enable_perl=yes])
 576
 577
 578 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 579 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 580 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 581 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 582
 583 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 584         COMP_PERL=
 585 else
 586         COMP_PERL="perl_piped perl_shared"
 587         AC_MSG_CHECKING(for the perl version you are running)
 588         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 589         AC_MSG_RESULT($PERL_VERSION)
 590         if test -z "$PERLCC"; then
 591             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 592             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 593             AC_MSG_RESULT($perlcc)
 594             if test ! -x "$perlcc"; then
 595                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 596                 if test "$PERL_CC" = "no"; then
 597                     AC_MSG_WARN([
 598 I would not find the Compiler ($perlcc) that was originally used to compile
 599 your perl binary. You should either make sure that this compiler is
 600 available on your system, pick an other compiler and set PERLCC
 601 appropriately, or use a different perl setup that was compiled locally.
 602
 603 I will disable the compilation of the RRDs perl module for now.
 604 ])
 605                     COMP_PERL="perl_piped"
 606                 fi
 607             fi
 608         fi
 609 fi
 610
 611 AC_MSG_CHECKING(Perl Modules to build)
 612 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 613
 614 # Options to pass when configuring perl module
 615 langpref=$prefix
 616 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 617 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 618
 619 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 620
 621 dnl pass additional perl options when generating Makefile from Makefile.PL
 622 AC_ARG_ENABLE(perl-site-install,
 623 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 624 [PERL_MAKE_OPTIONS=],[])
 625
 626 if test ! -z "$PERLCC"; then
 627    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 628
 629    if test ! -z "$PERLCCFLAGS"; then
 630        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 631    fi
 632
 633    if test -z "$PERLLD"; then
 634        PERLLD=$PERLCC
 635    fi
 636    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 637
 638    if test ! -z "$PERLLDFLAGS"; then
 639        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 640    fi
 641 fi
 642
 643 AC_ARG_WITH(perl-options,
 644 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 645                           generating Makefile from Makefile.PL. If you set this
 646                           option, interesting things may happen unless you know
 647                           what you are doing!],
 648 [PERL_MAKE_OPTIONS=$withval])
 649
 650 AC_SUBST(PERL_MAKE_OPTIONS)
 651 AC_SUBST(PERL)
 652 AC_SUBST(COMP_PERL)
 653 AC_SUBST(PERL_VERSION)
 654
 655 dnl Check for Ruby.
 656 AC_PATH_PROG(RUBY, ruby, no)
 657
 658 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 659 [],[enable_ruby=yes])
 660
 661 AC_MSG_CHECKING(if ruby modules can be built)
 662
 663 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 664         COMP_RUBY=
 665         AC_MSG_RESULT(No .. Ruby not found or disabled)
 666 else
 667         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 668                 COMP_RUBY="ruby"
 669                 AC_MSG_RESULT(YES)
 670         else
 671                 COMP_RUBY=
 672                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 673         fi
 674 fi
 675
 676 dnl pass additional ruby options when generating Makefile from Makefile.PL
 677 AC_ARG_ENABLE(ruby-site-install,
 678 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 679 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 680
 681
 682 AC_ARG_WITH(ruby-options,
 683 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 684                           generating Makefile from extconf.rb. If you set this
 685                           option, interesting things may happen unless you know
 686                           what you are doing!],
 687 [RUBY_MAKE_OPTIONS=$withval])
 688
 689 AC_SUBST(RUBY_MAKE_OPTIONS)
 690 AC_SUBST(RUBY)
 691 AC_SUBST(COMP_RUBY)
 692
 693 dnl Check for Lua.
 694 AC_PATH_PROG(LUA, lua, no)
 695
 696 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 697 [],[enable_lua=yes])
 698
 699 COMP_LUA=
 700 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 701   enable_lua=no
 702 else
 703   AC_MSG_CHECKING(for lua >= 5.0)
 704   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 705     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 706 LUA_EOF
 707   if test 0$LUA_MAJOR -lt 5; then
 708     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 709   else
 710     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 711     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 712     lua_vndot=$LUA_MAJOR$LUA_MINOR
 713     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 714     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 715       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 716         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 717           [lua_headerdir=lua$lua_vndot],
 718           [])],
 719         [])],
 720       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 721         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 722           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 723             [lua_headerdir=lua$lua_vdot],
 724             [])],
 725           [])],
 726         [AC_CHECK_HEADERS(lua.h,
 727           [AC_CHECK_HEADERS(lualib.h,
 728             [AC_CHECK_HEADER(lauxlib.h,
 729               [lua_headerdir=""],
 730               [lua_headerdir="no"])],
 731             [])],
 732           [])])])
 733
 734     if test "$lua_headerdir" = "no"; then
 735       enable_lua=no
 736     else
 737       COMP_LUA=lua
 738     fi
 739
 740     if test "$COMP_LUA" != "lua"; then
 741       enable_lua=no
 742       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 743     else
 744       # OK, headers found, let's check the libraries (LIBS is not used)
 745       LIBS=
 746       lua_havelib=no
 747       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 748       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 749         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 750           [lua_havelib=LUA$lua_vndot],
 751           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 752             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 753              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 754             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 755               [lua_havelib=$lua_vndot],
 756               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 757         [COMP_LUA=], [-lm])
 758       lua_libs=$LIBS
 759       LIBS=
 760
 761       # Options to pass when configuring Lua module
 762       if test  "$lua_havelib" != "no"; then
 763         # OK, headers and libs found. Try to set lua flags
 764         # and modules installation dirs with pkg-config
 765         if test "$PKGCONFIG" != "no"; then
 766           if test "$lua_vndot" = "50"; then
 767             lua_pkg_prefix=lualib
 768           else
 769             lua_pkg_prefix=lua
 770           fi
 771           # try with dot, without dot and finally without version
 772           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 773             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 774             # same binaries?
 775             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 776                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 777                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 778                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 779                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 780                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 781                 break
 782             fi
 783           done
 784         fi
 785
 786         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 787         # if lua 5.0 can't find compat-5.1, force installation of
 788         # compat-5.1.lua together with RRDtool.
 789         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 790           lua_need_compat51=1
 791           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 792         fi
 793
 794         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 795         if test "$LUA_CFLAGS" = ""; then
 796           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 797           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 798           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 799           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 800         fi
 801
 802         dnl pass additional lua options
 803         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 804         dnl found and install together with RRDtool, under $langpref.
 805         AC_ARG_ENABLE(lua-site-install,
 806         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 807         [],
 808         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 809
 810         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 811         AC_SUBST(LUA)
 812         AC_SUBST(COMP_LUA)
 813         AC_SUBST(LUA_INSTALL_CMOD)
 814         AC_SUBST(LUA_INSTALL_LMOD)
 815         AC_SUBST(LUA_CFLAGS)
 816         AC_SUBST(LUA_LFLAGS)
 817         AC_SUBST(LUA_DEFINES)
 818       else
 819         enable_lua=no
 820         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 821       fi
 822     fi
 823   fi
 824 fi
 825 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 826 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 827 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 828       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 829 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 830 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 831 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 832 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 833
 834 enable_tcl_site=no
 835
 836 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 837 [],[enable_tcl=yes])
 838
 839 if test  "$enable_tcl" = "yes"; then
 840   dnl Check for Tcl.
 841   withval=""
 842   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 843   enable_tcl=no
 844   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 845     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 846     if test -f "$dir/tclConfig.sh" ; then
 847         tcl_config=$dir/tclConfig.sh
 848         enable_tcl=yes
 849         AC_MSG_RESULT(yes)
 850         break
 851     else
 852         AC_MSG_RESULT(no)
 853     fi
 854   done
 855
 856   if test "$enable_tcl" = "no"; then
 857         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 858   else
 859         . $tcl_config
 860         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 861         if test -n "$TCL_INC_DIR"; then
 862           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 863         fi
 864   fi
 865   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 866   [],[enable_tcl_site=yes])
 867
 868 fi
 869
 870 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 871 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 872
 873
 874 AC_SUBST(TCL_PREFIX)
 875 AC_SUBST(TCL_SHLIB_CFLAGS)
 876 AC_SUBST(TCL_SHLIB_LD)
 877 AC_SUBST(TCL_SHLIB_SUFFIX)
 878 AC_SUBST(TCL_PACKAGE_PATH)
 879 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 880 AC_SUBST(TCL_STUB_LIB_SPEC)
 881 AC_SUBST(TCL_VERSION)
 882 AC_SUBST(TCL_PACKAGE_DIR)
 883 AC_SUBST(TCL_INCLUDE_SPEC)
 884
 885 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 886 [],[enable_python=yes])
 887
 888 if test  "$enable_python" = "yes"; then
 889 dnl Check for python
 890 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 891 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 892 fi
 893
 894 if test  x$enable_python = xno; then
 895         COMP_PYTHON=
 896 else
 897         COMP_PYTHON="python"
 898 fi
 899
 900 AC_SUBST(COMP_PYTHON)
 901
 902 dnl Check for nroff
 903 AC_PATH_PROGS(NROFF, gnroff nroff)
 904 AC_PATH_PROGS(TROFF, groff troff)
 905
 906 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 907 if test -z "$RRDDOCDIR"; then
 908    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 909
 910
 911 CONFIGURE_PART(Apply Configuration Information)
 912
 913 AC_CONFIG_FILES([examples/shared-demo.pl])
 914 AC_CONFIG_FILES([examples/piped-demo.pl])
 915 AC_CONFIG_FILES([examples/stripes.pl])
 916 AC_CONFIG_FILES([examples/bigtops.pl])
 917 AC_CONFIG_FILES([examples/minmax.pl])
 918 AC_CONFIG_FILES([examples/4charts.pl])
 919 AC_CONFIG_FILES([examples/perftest.pl])
 920 AC_CONFIG_FILES([examples/Makefile])
 921 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 922 AC_CONFIG_FILES([doc/Makefile])
 923 AC_CONFIG_FILES([po/Makefile.in])
 924 AC_CONFIG_FILES([src/Makefile])
 925 AC_CONFIG_FILES([src/librrd.sym.in])
 926 AC_CONFIG_FILES([src/librrd.pc])
 927 AC_CONFIG_FILES([bindings/Makefile])
 928 AC_CONFIG_FILES([bindings/tcl/Makefile])
 929 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 930 AC_CONFIG_FILES([Makefile])
 931 AC_CONFIG_FILES([bindings/lua/Makefile])
 932
 933 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 934
 935 dnl intl requires our config to be called config.h. indulge it.
 936 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 937
 938 AC_OUTPUT
 939
 940 AC_MSG_CHECKING(in)
 941 AC_MSG_RESULT(and out again)
 942
 943 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 944 sleep 1
 945 echo $ECHO_N ".$ECHO_C" 1>&6
 946 sleep 1
 947 echo $ECHO_N ".$ECHO_C" 1>&6
 948 sleep 1
 949 echo $ECHO_N ".$ECHO_C" 1>&6
 950 sleep 1
 951 echo $ECHO_N ".$ECHO_C" 1>&6
 952 sleep 1
 953 AC_MSG_RESULT([ just kidding ;-)])
 954 echo
 955 echo "----------------------------------------------------------------"
 956 echo "Config is DONE!"
 957 echo
 958 echo "          With MMAP IO: $enable_mmap"
 959 echo "      Build rrd_getopt: $build_getopt"
 960 echo "       Static programs: $staticprogs"
 961 echo "          Perl Modules: $COMP_PERL"
 962 echo "           Perl Binary: $PERL"
 963 echo "          Perl Version: $PERL_VERSION"
 964 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 965 echo "          Ruby Modules: $COMP_RUBY"
 966 echo "           Ruby Binary: $RUBY"
 967 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 968 echo "    Build Lua Bindings: $enable_lua"
 969 if test "$enable_lua" = "yes"; then
 970 echo "            Lua Binary: $LUA"
 971 echo "           Lua Version: $lua_version"
 972 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 973 if test "$lua_need_compat51" = "1"; then
 974 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 975 fi
 976 fi
 977 echo "    Build Tcl Bindings: $enable_tcl"
 978 echo " Build Python Bindings: $enable_python"
 979 echo "          Build rrdcgi: $enable_rrdcgi"
 980 echo "       Build librrd MT: $enable_pthread"
 981 echo "           Use gettext: $USE_NLS"
 982 echo "           With libDBI: $have_libdbi"
 983 echo "          With libwrap: $have_libwrap"
 984 echo
 985 echo "             Libraries: $ALL_LIBS"
 986 echo
 987 echo "Type 'make' to compile the software and use 'make install' to "
 988 echo "install everything to: $prefix."
 989 echo
 990 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 991 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 992 echo "place an order."
 993 echo
 994 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 995 echo "----------------------------------------------------------------"