configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.5])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4004
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:4:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 106 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 107
 108 if test $enable_rrd_graph != no; then
 109  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 110 fi
 111
 112 dnl Check if we run on a system that has fonts
 113 AC_ARG_WITH(rrd-default-font,
 114 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 115 [RRD_DEFAULT_FONT=$withval],[
 116   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 117         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 118   else
 119         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 120   fi
 121 ])
 122
 123 dnl Use mmap in rrd_update instead of seek+write
 124 AC_ARG_ENABLE([mmap],
 125 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 126 [],
 127 [enable_mmap=yes])
 128
 129 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 130 [],[enable_pthread=yes])
 131
 132 AC_ARG_ENABLE(static-programs,
 133      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 134      [case "${enableval}" in
 135        yes) staticprogs=yes ;;
 136        no)  staticprogs=no ;;
 137        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 138      esac],[staticprogs=no])
 139 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 140
 141
 142 CONFIGURE_PART(Audit Compilation Environment)
 143
 144
 145 dnl Check for the compiler and static/shared library creation.
 146 AC_PROG_CPP
 147 AC_PROG_CC
 148 AM_PROG_CC_C_O
 149 AC_PROG_LIBTOOL
 150
 151 dnl Try to detect/use GNU features
 152 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 153
 154 dnl check for -Werror separatly
 155 dnl (quite a few autotool checks do not work with -Werror; also, the
 156 dnl check for -Werror fails after checking and adding the other flags)
 157 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 158   [AC_COMPILE_IFELSE(
 159     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 160     [rd_cv_gcc_flag__Werror="yes"],
 161     [rd_cv_gcc_flag__Werror="no"])])
 162 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 163   WERROR="-Werror"
 164 else
 165   WERROR=""
 166 fi
 167 AC_SUBST(WERROR)
 168
 169 dnl which flags does the compiler support?
 170 if test "x$GCC" = "xyes"; then
 171   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 172     oCFLAGS="$CFLAGS"
 173     CFLAGS="$CFLAGS $flag"
 174     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 175     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 176        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 177     if eval test \$$cachename = no; then
 178          CFLAGS="$oCFLAGS"
 179     fi
 180   done
 181 fi
 182
 183
 184
 185 AC_SUBST(RRD_DEFAULT_FONT)
 186
 187 CONFIGURE_PART(Checking for Header Files)
 188
 189 dnl Checks for header files.
 190 AC_HEADER_STDC
 191 AC_HEADER_DIRENT
 192 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 193
 194 dnl Checks for typedefs, structures, and compiler characteristics.
 195 AC_C_CONST
 196 AC_HEADER_TIME
 197 AC_STRUCT_TM
 198
 199 CONFIGURE_PART(Test Library Functions)
 200
 201 dnl Checks for libraries.
 202 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 203
 204
 205 dnl add pic flag in any case this makes sure all our code is relocatable
 206 eval `./libtool --config | grep pic_flag`
 207 CFLAGS="$CFLAGS $pic_flag"
 208
 209
 210 dnl Checks for library functions.
 211 AC_FUNC_STRFTIME
 212 AC_FUNC_VPRINTF
 213
 214 AC_C_BIGENDIAN
 215
 216 dnl for each function found we get a definition in config.h
 217 dnl of the form HAVE_FUNCTION
 218
 219 AC_CHECK_FUNCS(nl_langinfo tzset round rint fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 220
 221 AC_FUNC_STRERROR_R
 222
 223 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 224
 225 dnl Could use these to know if we need to provide a prototype
 226 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 227
 228 dnl check for fdatasync. Solaris has fdatasync in the librt
 229
 230 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 231 dnl if there is no fdatasync we may get lucky with fsync
 232 AC_CHECK_FUNCS(fsync)
 233
 234 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 235
 236 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 237 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 238
 239
 240
 241 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 242 if test "x$enable_mmap" = "xyes"; then
 243   case "$host" in
 244   *cygwin*)
 245     # the normal mmap test does not work in cygwin
 246     AC_CHECK_FUNCS(mmap)
 247     if test "x$ac_cv_func_mmap" = "xyes"; then
 248       ac_cv_func_mmap_fixed_mapped=yes
 249     fi
 250   ;;
 251   *)
 252     AC_CHECK_HEADERS(sys/mman.h)
 253     AC_FUNC_MMAP
 254     AC_CHECK_FUNCS(mmap munmap msync)
 255     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 256                                      # include <sys/mman.h>
 257                                      #endif])
 258     if test "x$ac_cv_have_decl_madvise" = "xyes";
 259     then
 260       AC_CHECK_FUNCS(madvise)
 261     else
 262       AC_CHECK_FUNCS(posix_madvise)
 263       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 264         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 265       fi
 266     fi
 267   ;;
 268   esac
 269   if test "x$ac_cv_func_mmap" != "xyes";
 270   then
 271     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 272 dnl enable_mmap="no"
 273   fi
 274 fi
 275
 276 dnl can we use posix_fadvise
 277 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 278 #include <fcntl.h>])
 279 AC_CHECK_FUNCS(posix_fadvise)
 280
 281 CONFIGURE_PART(Libintl Processing)
 282
 283 AM_GNU_GETTEXT_VERSION(0.18)
 284 AM_GNU_GETTEXT(external)
 285
 286 CONFIGURE_PART(IEEE Math Checks)
 287
 288
 289 dnl actual code to check if this works
 290 AC_CHECK_FUNCS(fpclassify, ,
 291   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 292     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 293 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 294       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 295
 296 AC_CHECK_FUNCS(isinf, ,
 297   [AC_MSG_CHECKING(for isinf with <math.h>)
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 299 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 300       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 301
 302 dnl finite is BSD, isfinite is C99, so prefer the latter
 303 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 304 AC_TRY_RUN([
 305 #ifdef HAVE_MATH_H
 306 #include <math.h>
 307 #endif
 308 #ifdef HAVE_FLOAT_H
 309 #include <float.h>
 310 #endif
 311 int main ()
 312 {
 313 #ifdef isfinite
 314 #ifdef LDBL_MAX
 315   if (!isfinite(LDBL_MAX)) return 1;
 316 #endif
 317 #ifdef DBL_MAX
 318   if (!isfinite(DBL_MAX)) return 1;
 319 #endif
 320 #endif
 321 return 0;
 322 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 323 case "${target}" in
 324   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 325   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 326   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 327   *) ac_cv_have_broken_isfinite=no ;;
 328 esac])
 329 ])
 330
 331 dnl the test does not seem to work on solaris 2.8
 332 dnl so lets fix this by hand
 333 case "${target}" in
 334   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 335   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 336 esac
 337
 338 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 339   AC_DEFINE(HAVE_ISFINITE)
 340 else
 341   AC_CHECK_FUNCS(finite,[],
 342       [AC_CHECK_FUNCS(isfinite,[],
 343          [AC_MSG_CHECKING(for isfinite with <math.h>)
 344           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 345 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 346                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 347 fi
 348
 349 AC_FULL_IEEE
 350
 351 CONFIGURE_PART(Resolve Portability Issues)
 352
 353 CHECK_FOR_WORKING_MS_ASYNC
 354
 355 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 356 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 357   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 358     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 359       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 360
 361 dnl Do we need getopt_long
 362
 363 dnl even when including our own getopt implementation
 364 dnl we may want to make sure we use the external
 365 dnl defined by libc to not run into linker resolve trouble
 366
 367 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 368 [AC_TRY_LINK([#include <unistd.h>],
 369   [extern int opterr; opterr = 1;],
 370   [rd_cv_var_int_opterr=yes],
 371   [rd_cv_var_int_opterr=no])])
 372 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 373   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 374 fi
 375
 376 build_getopt=no
 377 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 378 AC_CHECK_FUNC(getopt_long,[],[
 379 RRD_GETOPT_LONG="getopt_long"
 380 build_getopt=yes
 381 ])
 382 AC_SUBST(RRD_GETOPT_LONG)
 383 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 384
 385 dnl what does realloc do if it gets called with a NULL pointer
 386
 387 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 388 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 389               int main(void){
 390               char *x = NULL;
 391               x = realloc (x,10);
 392               if (x==NULL) return 1;
 393               return 0;
 394              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 395
 396 if test x"$rd_cv_null_realloc" = xnope; then
 397 AC_DEFINE(NO_NULL_REALLOC)
 398 fi
 399
 400 AC_LANG_PUSH(C)
 401 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 402 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 403 AC_LINK_IFELSE(
 404     AC_LANG_PROGRAM(
 405            [[#include <time.h>]],
 406            [[ctime_r(NULL,NULL,0)]]
 407                    ),
 408     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 409       AC_LINK_IFELSE(
 410           AC_LANG_PROGRAM(
 411                 [[#include <time.h>]],
 412                 [[ctime_r(NULL,NULL)]]
 413                          ),
 414           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 415           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 416       )
 417     ],
 418     [ AC_LINK_IFELSE(
 419           AC_LANG_PROGRAM(
 420                 [[#include <time.h>]],
 421                 [[ctime_r(NULL,NULL)]]
 422                          ),
 423           [AC_MSG_RESULT(no)],
 424           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 425       )
 426     ]
 427 )
 428 AC_LANG_POP(C)
 429
 430 dnl Check for pthreads
 431 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 432
 433 AC_SUBST(MULTITHREAD_CFLAGS)
 434 AC_SUBST(MULTITHREAD_LDFLAGS)
 435
 436 if test $enable_pthread != no; then
 437  ACX_PTHREAD([
 438     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 439     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 440              ],
 441              [])
 442 fi
 443
 444 dnl since we use lots of *_r functions all over the code we better
 445 dnl make sure they are known
 446
 447 if test  "x$x_rflag" != "xno"; then
 448    CPPFLAGS="$CPPFLAGS $x_rflag"
 449 fi
 450
 451 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 452
 453 AC_LANG_PUSH(C)
 454 dnl see if we have to include malloc/malloc.h
 455 AC_MSG_CHECKING([do we need malloc/malloc.h])
 456 AC_LINK_IFELSE(
 457     AC_LANG_PROGRAM(
 458            [[#include <stdlib.h>]],
 459            [[malloc(1)]]
 460                    ),
 461     [ AC_MSG_RESULT([nope, works out of the box]) ],
 462     [ AC_LINK_IFELSE(
 463           AC_LANG_PROGRAM(
 464                 [[#include <stdlib.h>
 465                   #include <malloc/malloc.h>]],
 466                 [[malloc(1)]]
 467                          ),[
 468            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 469            AC_MSG_RESULT([yes we do])],
 470           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 471       )
 472     ]
 473 )
 474
 475 dnl is time_t 32 of 64 bit ?
 476 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 477 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 478 AC_MSG_CHECKING([the type of time_t])
 479 AC_CHECK_SIZEOF([time_t])
 480 if test "x$ac_cv_sizeof_time_t" = "x4"; then
 481   AC_MSG_RESULT([time_t is 32 bit])
 482   AC_DEFINE([TIME_T_IS_32BIT])
 483 elif test "x$ac_cv_sizeof_time_t" = "x8"; then
 484   AC_MSG_RESULT([time_t is 64 bit])
 485   AC_DEFINE([TIME_T_IS_64BIT])
 486 else
 487   AC_MSG_ERROR([can not figure type of time_t])
 488 fi
 489
 490 AC_LANG_POP(C)
 491
 492 CONFIGURE_PART(Find 3rd-Party Libraries)
 493
 494 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 495   XXX=$LIBS
 496   LIBS="$LIBS -ldbi -ldl"
 497   AC_MSG_CHECKING(for libdbi)
 498   AC_LINK_IFELSE(
 499     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 500                      [[dbi_initialize(NULL)]]
 501                     )
 502     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 503        AC_MSG_RESULT([yes])
 504        have_libdbi=yes
 505     ],[LIBS=$XXX
 506        AC_MSG_RESULT([no])
 507        have_libdbi=no
 508     ]
 509   )
 510 ])
 511 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 512
 513 AC_ARG_ENABLE(libwrap,
 514   AS_HELP_STRING([--disable-libwrap],
 515   [do not build in support for libwrap (tcp wrapper)]),
 516   [have_libwrap=no],[
 517     XXX=$LIBS
 518     LIBS="$LIBS -lwrap"
 519     AC_MSG_CHECKING(for libwrap)
 520     AC_LINK_IFELSE(
 521       [AC_LANG_PROGRAM([[#include "tcpd.h"]], [[hosts_access(NULL)]])
 522     ],[AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 523        AC_MSG_RESULT([yes])
 524        have_libwrap=yes
 525     ],[LIBS=$XXX
 526        AC_MSG_RESULT([no])
 527        have_libwrap=no
 528     ]
 529   )
 530 ])
 531 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 532
 533 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 534
 535 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 536
 537
 538 CORE_LIBS="$LIBS"
 539
 540 if test $enable_rrd_graph != no; then
 541 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 542 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 543 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 544 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 545 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 546 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 547 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 548 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 549 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 550 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 551
 552 fi
 553
 554 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 555
 556 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 557   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 558 fi
 559
 560 ALL_LIBS="$LIBS"
 561 LIBS=
 562
 563 AC_SUBST(CORE_LIBS)
 564 AC_SUBST(ALL_LIBS)
 565
 566 CONFIGURE_PART(Prep for Building Language Bindings)
 567
 568 dnl Check for Perl and friends
 569 PATH=$PATH:/usr/perl5/bin
 570 export PATH
 571 AC_PATH_PROG(PERL, perl, no)
 572 AC_PATH_PROG(POD2MAN, pod2man, no)
 573 AC_PATH_PROG(POD2HTML, pod2html, no)
 574
 575
 576 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 577 [],[enable_perl=yes])
 578
 579
 580 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 581 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 582 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 583 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 584
 585 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 586         COMP_PERL=
 587 else
 588         COMP_PERL="perl_piped perl_shared"
 589         AC_MSG_CHECKING(for the perl version you are running)
 590         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 591         AC_MSG_RESULT($PERL_VERSION)
 592         if test -z "$PERLCC"; then
 593             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 594             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 595             AC_MSG_RESULT($perlcc)
 596             if test ! -x "$perlcc"; then
 597                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 598                 if test "$PERL_CC" = "no"; then
 599                     AC_MSG_WARN([
 600 I would not find the Compiler ($perlcc) that was originally used to compile
 601 your perl binary. You should either make sure that this compiler is
 602 available on your system, pick an other compiler and set PERLCC
 603 appropriately, or use a different perl setup that was compiled locally.
 604
 605 I will disable the compilation of the RRDs perl module for now.
 606 ])
 607                     COMP_PERL="perl_piped"
 608                 fi
 609             fi
 610         fi
 611 fi
 612
 613 AC_MSG_CHECKING(Perl Modules to build)
 614 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 615
 616 # Options to pass when configuring perl module
 617 langpref=$prefix
 618 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 619 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 620
 621 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 622
 623 dnl pass additional perl options when generating Makefile from Makefile.PL
 624 AC_ARG_ENABLE(perl-site-install,
 625 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 626 [PERL_MAKE_OPTIONS=],[])
 627
 628 if test ! -z "$PERLCC"; then
 629    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 630
 631    if test ! -z "$PERLCCFLAGS"; then
 632        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 633    fi
 634
 635    if test -z "$PERLLD"; then
 636        PERLLD=$PERLCC
 637    fi
 638    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 639
 640    if test ! -z "$PERLLDFLAGS"; then
 641        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 642    fi
 643 fi
 644
 645 AC_ARG_WITH(perl-options,
 646 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 647                           generating Makefile from Makefile.PL. If you set this
 648                           option, interesting things may happen unless you know
 649                           what you are doing!],
 650 [PERL_MAKE_OPTIONS=$withval])
 651
 652 AC_SUBST(PERL_MAKE_OPTIONS)
 653 AC_SUBST(PERL)
 654 AC_SUBST(COMP_PERL)
 655 AC_SUBST(PERL_VERSION)
 656
 657 dnl Check for Ruby.
 658 AC_PATH_PROG(RUBY, ruby, no)
 659
 660 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 661 [],[enable_ruby=yes])
 662
 663 AC_MSG_CHECKING(if ruby modules can be built)
 664
 665 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 666         COMP_RUBY=
 667         AC_MSG_RESULT(No .. Ruby not found or disabled)
 668 else
 669         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 670                 COMP_RUBY="ruby"
 671                 AC_MSG_RESULT(YES)
 672         else
 673                 COMP_RUBY=
 674                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 675         fi
 676 fi
 677
 678 dnl pass additional ruby options when generating Makefile from Makefile.PL
 679 AC_ARG_ENABLE(ruby-site-install,
 680 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 681 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 682
 683
 684 AC_ARG_WITH(ruby-options,
 685 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 686                           generating Makefile from extconf.rb. If you set this
 687                           option, interesting things may happen unless you know
 688                           what you are doing!],
 689 [RUBY_MAKE_OPTIONS=$withval])
 690
 691 AC_SUBST(RUBY_MAKE_OPTIONS)
 692 AC_SUBST(RUBY)
 693 AC_SUBST(COMP_RUBY)
 694
 695 dnl Check for Lua.
 696 AC_PATH_PROG(LUA, lua, no)
 697
 698 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 699 [],[enable_lua=yes])
 700
 701 COMP_LUA=
 702 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 703   enable_lua=no
 704 else
 705   AC_MSG_CHECKING(for lua >= 5.0)
 706   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 707     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 708 LUA_EOF
 709   if test 0$LUA_MAJOR -lt 5; then
 710     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 711   else
 712     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 713     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 714     lua_vndot=$LUA_MAJOR$LUA_MINOR
 715     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 716     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 717       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 718         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 719           [lua_headerdir=lua$lua_vndot],
 720           [])],
 721         [])],
 722       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 723         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 724           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 725             [lua_headerdir=lua$lua_vdot],
 726             [])],
 727           [])],
 728         [AC_CHECK_HEADERS(lua.h,
 729           [AC_CHECK_HEADERS(lualib.h,
 730             [AC_CHECK_HEADER(lauxlib.h,
 731               [lua_headerdir=""],
 732               [lua_headerdir="no"])],
 733             [])],
 734           [])])])
 735
 736     if test "$lua_headerdir" = "no"; then
 737       enable_lua=no
 738     else
 739       COMP_LUA=lua
 740     fi
 741
 742     if test "$COMP_LUA" != "lua"; then
 743       enable_lua=no
 744       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 745     else
 746       # OK, headers found, let's check the libraries (LIBS is not used)
 747       LIBS=
 748       lua_havelib=no
 749       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 750       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 751         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 752           [lua_havelib=LUA$lua_vndot],
 753           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 754             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 755              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 756             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 757               [lua_havelib=$lua_vndot],
 758               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 759         [COMP_LUA=], [-lm])
 760       lua_libs=$LIBS
 761       LIBS=
 762
 763       # Options to pass when configuring Lua module
 764       if test  "$lua_havelib" != "no"; then
 765         # OK, headers and libs found. Try to set lua flags
 766         # and modules installation dirs with pkg-config
 767         if test "$PKGCONFIG" != "no"; then
 768           if test "$lua_vndot" = "50"; then
 769             lua_pkg_prefix=lualib
 770           else
 771             lua_pkg_prefix=lua
 772           fi
 773           # try with dot, without dot and finally without version
 774           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 775             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 776             # same binaries?
 777             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 778                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 779                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 780                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 781                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 782                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 783                 break
 784             fi
 785           done
 786         fi
 787
 788         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 789         # if lua 5.0 can't find compat-5.1, force installation of
 790         # compat-5.1.lua together with RRDtool.
 791         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 792           lua_need_compat51=1
 793           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 794         fi
 795
 796         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 797         if test "$LUA_CFLAGS" = ""; then
 798           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 799           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 800           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 801           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 802         fi
 803
 804         dnl pass additional lua options
 805         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 806         dnl found and install together with RRDtool, under $langpref.
 807         AC_ARG_ENABLE(lua-site-install,
 808         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 809         [],
 810         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 811
 812         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 813         AC_SUBST(LUA)
 814         AC_SUBST(COMP_LUA)
 815         AC_SUBST(LUA_INSTALL_CMOD)
 816         AC_SUBST(LUA_INSTALL_LMOD)
 817         AC_SUBST(LUA_CFLAGS)
 818         AC_SUBST(LUA_LFLAGS)
 819         AC_SUBST(LUA_DEFINES)
 820       else
 821         enable_lua=no
 822         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 823       fi
 824     fi
 825   fi
 826 fi
 827 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 828 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 829 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 830       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 831 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 832 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 833 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 834 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 835
 836 enable_tcl_site=no
 837
 838 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 839 [],[enable_tcl=yes])
 840
 841 if test  "$enable_tcl" = "yes"; then
 842   dnl Check for Tcl.
 843   withval=""
 844   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 845   enable_tcl=no
 846   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 847     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 848     if test -f "$dir/tclConfig.sh" ; then
 849         tcl_config=$dir/tclConfig.sh
 850         enable_tcl=yes
 851         AC_MSG_RESULT(yes)
 852         break
 853     else
 854         AC_MSG_RESULT(no)
 855     fi
 856   done
 857
 858   if test "$enable_tcl" = "no"; then
 859         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 860   else
 861         . $tcl_config
 862         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 863         if test -n "$TCL_INC_DIR"; then
 864           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 865         fi
 866   fi
 867   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 868   [],[enable_tcl_site=yes])
 869
 870 fi
 871
 872 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 873 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 874
 875
 876 AC_SUBST(TCL_PREFIX)
 877 AC_SUBST(TCL_SHLIB_CFLAGS)
 878 AC_SUBST(TCL_SHLIB_LD)
 879 AC_SUBST(TCL_SHLIB_SUFFIX)
 880 AC_SUBST(TCL_PACKAGE_PATH)
 881 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 882 AC_SUBST(TCL_STUB_LIB_SPEC)
 883 AC_SUBST(TCL_VERSION)
 884 AC_SUBST(TCL_PACKAGE_DIR)
 885 AC_SUBST(TCL_INCLUDE_SPEC)
 886
 887 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 888 [],[enable_python=yes])
 889
 890 if test  "$enable_python" = "yes"; then
 891 dnl Check for python
 892 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 893 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 894 fi
 895
 896 if test  x$enable_python = xno; then
 897         COMP_PYTHON=
 898 else
 899         COMP_PYTHON="python"
 900 fi
 901
 902 AC_SUBST(COMP_PYTHON)
 903
 904 dnl Check for nroff
 905 AC_PATH_PROGS(NROFF, gnroff nroff)
 906 AC_PATH_PROGS(TROFF, groff troff)
 907
 908 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 909 if test -z "$RRDDOCDIR"; then
 910    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 911
 912
 913 CONFIGURE_PART(Apply Configuration Information)
 914
 915 AC_CONFIG_FILES([examples/shared-demo.pl])
 916 AC_CONFIG_FILES([examples/piped-demo.pl])
 917 AC_CONFIG_FILES([examples/stripes.pl])
 918 AC_CONFIG_FILES([examples/bigtops.pl])
 919 AC_CONFIG_FILES([examples/minmax.pl])
 920 AC_CONFIG_FILES([examples/4charts.pl])
 921 AC_CONFIG_FILES([examples/perftest.pl])
 922 AC_CONFIG_FILES([examples/Makefile])
 923 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 924 AC_CONFIG_FILES([doc/Makefile])
 925 AC_CONFIG_FILES([po/Makefile.in])
 926 AC_CONFIG_FILES([src/Makefile])
 927 AC_CONFIG_FILES([src/librrd.sym.in])
 928 AC_CONFIG_FILES([src/librrd.pc])
 929 AC_CONFIG_FILES([bindings/Makefile])
 930 AC_CONFIG_FILES([bindings/tcl/Makefile])
 931 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 932 AC_CONFIG_FILES([Makefile])
 933 AC_CONFIG_FILES([bindings/lua/Makefile])
 934
 935 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 936
 937 dnl intl requires our config to be called config.h. indulge it.
 938 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 939
 940 AC_OUTPUT
 941
 942 AC_MSG_CHECKING(in)
 943 AC_MSG_RESULT(and out again)
 944
 945 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 946 sleep 1
 947 echo $ECHO_N ".$ECHO_C" 1>&6
 948 sleep 1
 949 echo $ECHO_N ".$ECHO_C" 1>&6
 950 sleep 1
 951 echo $ECHO_N ".$ECHO_C" 1>&6
 952 sleep 1
 953 echo $ECHO_N ".$ECHO_C" 1>&6
 954 sleep 1
 955 AC_MSG_RESULT([ just kidding ;-)])
 956 echo
 957 echo "----------------------------------------------------------------"
 958 echo "Config is DONE!"
 959 echo
 960 echo "          With MMAP IO: $enable_mmap"
 961 echo "      Build rrd_getopt: $build_getopt"
 962 echo "       Build rrd_graph: $enable_rrd_graph"
 963 echo "       Static programs: $staticprogs"
 964 echo "          Perl Modules: $COMP_PERL"
 965 echo "           Perl Binary: $PERL"
 966 echo "          Perl Version: $PERL_VERSION"
 967 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 968 echo "          Ruby Modules: $COMP_RUBY"
 969 echo "           Ruby Binary: $RUBY"
 970 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 971 echo "    Build Lua Bindings: $enable_lua"
 972 if test "$enable_lua" = "yes"; then
 973 echo "            Lua Binary: $LUA"
 974 echo "           Lua Version: $lua_version"
 975 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 976 if test "$lua_need_compat51" = "1"; then
 977 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 978 fi
 979 fi
 980 echo "    Build Tcl Bindings: $enable_tcl"
 981 echo " Build Python Bindings: $enable_python"
 982 echo "          Build rrdcgi: $enable_rrdcgi"
 983 echo "       Build librrd MT: $enable_pthread"
 984 echo "           Use gettext: $USE_NLS"
 985 echo "           With libDBI: $have_libdbi"
 986 echo "          With libwrap: $have_libwrap"
 987 echo
 988 echo "             Libraries: $ALL_LIBS"
 989 echo
 990 echo "Type 'make' to compile the software and use 'make install' to "
 991 echo "install everything to: $prefix."
 992 echo
 993 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 994 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 995 echo "place an order."
 996 echo
 997 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 998 echo "----------------------------------------------------------------"