meson.build

   1 project('ncmpc', 'c',
   2   version: '0.29',
   3   default_options: [
   4     'c_std=c99',
   5   ],
   6   license: 'GPLv2+',
   7 )
   8
   9 cc = meson.get_compiler('c')
  10
  11 conf = configuration_data()
  12 conf.set_quoted('PACKAGE', meson.project_name())
  13 conf.set_quoted('VERSION', meson.project_version())
  14 conf.set_quoted('SYSCONFDIR', join_paths(get_option('prefix'), get_option('sysconfdir')))
  15 conf.set_quoted('LOCALE_DIR', join_paths(get_option('prefix'), get_option('localedir')))
  16
  17 mini = get_option('mini')
  18 conf.set('NCMPC_MINI', mini)
  19
  20 enable_locale = get_option('locale')
  21 if enable_locale == 'false' or mini
  22   enable_locale = false
  23 elif cc.has_header('locale.h')
  24   enable_locale = true
  25 elif enable_locale == 'auto'
  26   enable_locale = false
  27 else
  28   error('locale.h not found')
  29 endif
  30 conf.set('ENABLE_LOCALE', enable_locale)
  31
  32 enable_nls = get_option('nls')
  33 if enable_nls == 'false' or mini
  34   enable_nls = false
  35 elif cc.has_header('libintl.h')
  36   enable_nls = true
  37 elif enable_nls == 'auto'
  38   enable_nls = false
  39 else
  40   error('libintl.h not found')
  41 endif
  42 conf.set('ENABLE_NLS', enable_nls)
  43 if enable_nls
  44   conf.set_quoted('GETTEXT_PACKAGE', meson.project_name())
  45   subdir('po')
  46 endif
  47
  48 if get_option('tcp')
  49   conf.set('ENABLE_TCP', true)
  50   conf.set('HAVE_GETADDRINFO', cc.has_function('getaddrinfo'))
  51 endif
  52
  53 async_connect = get_option('async_connect')
  54 conf.set('ENABLE_ASYNC_CONNECT', async_connect)
  55
  56 conf.set('ENABLE_MULTIBYTE', get_option('multibyte'))
  57
  58 curses = get_option('curses')
  59 if curses == 'ncursesw'
  60   curses_dep = dependency('ncursesw')
  61 elif curses == 'ncurses'
  62   curses_dep = dependency('ncurses')
  63 else
  64   curses_dep = dependency('ncursesw', required: false)
  65   if curses_dep.found()
  66     curses = 'ncursesw'
  67   else
  68     curses_dep = dependency('ncurses', required: false)
  69
  70     if curses_dep.found()
  71       curses = 'ncurses'
  72     else
  73       # TODO: find other curses implementation (pdcurses?)
  74     endif
  75   endif
  76 endif
  77
  78 if curses == 'ncursesw'
  79   conf.set('HAVE_NCURSESW', true)
  80   curses_enhanced = true
  81   curses_color = true
  82   if cc.has_header('ncursesw/curses.h', dependencies: curses_dep)
  83     conf.set('HAVE_NCURSESW_CURSES_H', true)
  84   elif cc.has_header('ncursesw.h', dependencies: curses_dep)
  85     conf.set('HAVE_NCURSESW_H', true)
  86   else
  87     error('No ncursesw header found')
  88   endif
  89 elif curses == 'ncurses'
  90   conf.set('HAVE_NCURSES', true)
  91   curses_enhanced = true
  92   curses_color = true
  93   if cc.has_header('ncurses/curses.h', dependencies: curses_dep)
  94     conf.set('HAVE_NCURSES_CURSES_H', true)
  95   elif cc.has_header('ncurses.h', dependencies: curses_dep)
  96     conf.set('HAVE_NCURSES_H', true)
  97   else
  98     error('No ncurses header found')
  99   endif
 100 else
 101   if cc.has_header('curses.h', dependencies: curses_dep)
 102     conf.set('HAVE_CURSES_H', true)
 103
 104     # TODO: test this with pdcurses
 105     curses_enhanced = cc.has_header_symbol('curses.h', '_XOPEN_CURSES', dependencies: curses_dep)
 106     curses_color = curses_enhanced or cc.has_header_symbol('curses.h', 'COLOR_PAIR', dependencies: curses_dep)
 107   else
 108     error('No curses header found')
 109   endif
 110 endif
 111 conf.set('HAVE_CURSES_ENHANCED', curses_enhanced)
 112
 113 enable_mouse = get_option('mouse')
 114 if enable_mouse == 'false'
 115   enable_mouse = false
 116 elif cc.has_function('getmouse', dependencies: curses_dep)
 117   enable_mouse = true
 118 elif enable_mouse == 'auto'
 119   enable_mouse = false
 120 else
 121   error('getmouse() not available')
 122 endif
 123 conf.set('HAVE_GETMOUSE', enable_mouse)
 124
 125 enable_lirc = get_option('lirc')
 126 if enable_lirc == 'false'
 127   enable_lirc = false
 128   lirc_dep = []
 129 else
 130   lirc_dep = dependency('lirc', required: false)
 131   if not lirc_dep.found()
 132     lirc_dep = dependency('liblircclient0', required: false)
 133   endif
 134
 135   if lirc_dep.found()
 136     enable_lirc = true
 137   elif enable_lirc == 'auto'
 138     enable_lirc = false
 139   else
 140     error('liblirc not found')
 141   endif
 142 endif
 143 conf.set('ENABLE_LIRC', enable_lirc)
 144
 145 conf.set('ENABLE_COLORS', curses_color)
 146
 147 common_cflags = [
 148   # for getaddrinfo() and sigaction() with glibc
 149   '-D_GNU_SOURCE',
 150 ]
 151
 152 test_cflags = [
 153   '-Wall',
 154   '-Wextra',
 155   '-Wno-deprecated-declarations',
 156   '-Wmissing-prototypes',
 157   '-Wshadow',
 158   '-Wpointer-arith',
 159   '-Wstrict-prototypes',
 160   '-Wcast-qual',
 161   '-Wwrite-strings',
 162   '-fvisibility=hidden',
 163 ]
 164
 165 test_ldflags = [
 166 ]
 167
 168 if get_option('buildtype') != 'debug'
 169   test_cflags += [
 170     '-ffunction-sections',
 171     '-fdata-sections',
 172   ]
 173   test_ldflags += [
 174     '-Wl,--gc-sections',
 175   ]
 176 endif
 177
 178 foreach f: test_cflags
 179   if cc.has_argument(f)
 180     common_cflags += [ f ]
 181   endif
 182 endforeach
 183
 184 add_global_arguments(common_cflags, language: 'c')
 185
 186 foreach f: test_ldflags
 187   if cc.has_argument(f)
 188     add_global_link_arguments(f, language: 'c')
 189   endif
 190 endforeach
 191
 192 glib_dep = dependency('glib-2.0', version: '>= 2.30')
 193 libmpdclient_dep = dependency('libmpdclient', version: '>= 2.9')
 194
 195 inc = include_directories(
 196   'src',
 197
 198   # for the generated config.h
 199   '.',
 200 )
 201
 202 sources = []
 203
 204 need_screen_text = false
 205 need_plugin_library = false
 206
 207 if host_machine.system() != 'windows'
 208   sources += [
 209     'src/signals.c',
 210   ]
 211 endif
 212
 213 if not mini
 214   sources += [
 215     'src/db_completion.c',
 216     'src/xterm_title.c',
 217     'src/hscroll.c',
 218     'src/match.c',
 219     'src/conf.c',
 220   ]
 221 endif
 222
 223 if async_connect
 224   sources += [
 225     'src/net/socket.c',
 226     'src/net/resolver.c',
 227     'src/net/async_connect.c',
 228     'src/net/async_rconnect.c',
 229     'src/aconnect.c',
 230   ]
 231 endif
 232
 233 if enable_lirc
 234   sources += [
 235     'src/lirc.c',
 236   ]
 237 endif
 238
 239 enable_help_screen = get_option('help_screen') and not mini
 240 conf.set('ENABLE_HELP_SCREEN', enable_help_screen)
 241 if enable_help_screen
 242   sources += ['src/screen_help.c']
 243 endif
 244
 245 enable_artist_screen = get_option('artist_screen') and not mini
 246 conf.set('ENABLE_ARTIST_SCREEN', enable_artist_screen)
 247 if enable_artist_screen
 248   sources += ['src/screen_artist.c']
 249 endif
 250
 251 enable_search_screen = get_option('search_screen') and not mini
 252 conf.set('ENABLE_SEARCH_SCREEN', enable_search_screen)
 253 if enable_search_screen
 254   sources += ['src/screen_search.c']
 255 endif
 256
 257 enable_song_screen = get_option('song_screen') and not mini
 258 conf.set('ENABLE_SONG_SCREEN', enable_song_screen)
 259 if enable_song_screen
 260   sources += ['src/screen_song.c']
 261 endif
 262
 263 enable_keydef_screen = get_option('key_screen') and not mini
 264 conf.set('ENABLE_KEYDEF_SCREEN', enable_keydef_screen)
 265 if enable_keydef_screen
 266   sources += ['src/screen_keydef.c']
 267 endif
 268
 269 enable_lyrics_screen = get_option('lyrics_screen') and not mini
 270 conf.set('ENABLE_LYRICS_SCREEN', enable_lyrics_screen)
 271 if enable_lyrics_screen
 272   sources += ['src/screen_lyrics.c', 'src/lyrics.c']
 273
 274   lyrics_plugin_dir = join_paths(get_option('prefix'), get_option('libdir'), meson.project_name(), 'lyrics')
 275   conf.set_quoted('LYRICS_PLUGIN_DIR', lyrics_plugin_dir)
 276   install_data(
 277     'lyrics/10-hd.sh',
 278     'lyrics/20-lyricwiki.rb',
 279     install_dir: lyrics_plugin_dir)
 280
 281   need_screen_text = true
 282   need_plugin_library = true
 283 endif
 284
 285 enable_outputs_screen = get_option('outputs_screen') and not mini
 286 conf.set('ENABLE_OUTPUTS_SCREEN', enable_outputs_screen)
 287 if enable_outputs_screen
 288   sources += ['src/screen_outputs.c']
 289 endif
 290
 291 enable_chat_screen = get_option('chat_screen') and not mini
 292 conf.set('ENABLE_CHAT_SCREEN', enable_chat_screen)
 293 if enable_chat_screen
 294   sources += ['src/screen_chat.c']
 295   need_screen_text = true
 296 endif
 297
 298 if need_screen_text
 299   sources += ['src/screen_text.c']
 300 endif
 301
 302 if need_plugin_library
 303   if host_machine.system() == 'windows'
 304     error('Plugins not yet compatible with Windows')
 305   endif
 306
 307   sources += ['src/plugin.c']
 308 endif
 309
 310 if host_machine.system() == 'windows'
 311   subdir('src/win')
 312 endif
 313
 314 ncmpc = executable('ncmpc',
 315   'src/main.c',
 316   'src/gidle.c',
 317   'src/mpdclient.c',
 318   'src/callbacks.c',
 319   'src/playlist.c',
 320   'src/filelist.c',
 321   'src/options.c',
 322   'src/command.c',
 323   'src/keyboard.c',
 324   'src/ncu.c',
 325   'src/player_command.c',
 326   'src/title_bar.c',
 327   'src/progress_bar.c',
 328   'src/status_bar.c',
 329   'src/screen.c',
 330   'src/screen_init.c',
 331   'src/screen_paint.c',
 332   'src/screen_utils.c',
 333   'src/screen_status.c',
 334   'src/screen_list.c',
 335   'src/screen_find.c',
 336   'src/screen_client.c',
 337   'src/screen_queue.c',
 338   'src/screen_browser.c',
 339   'src/screen_file.c',
 340   'src/list_window.c',
 341   'src/save_playlist.c',
 342   'src/song_paint.c',
 343   'src/colors.c',
 344   'src/charset.c',
 345   'src/wreadln.c',
 346   'src/strfsong.c',
 347   'src/time_format.c',
 348   'src/utils.c',
 349   sources,
 350   include_directories: inc,
 351   dependencies: [
 352     glib_dep,
 353     curses_dep,
 354     lirc_dep,
 355     libmpdclient_dep,
 356   ],
 357   install: true
 358 )
 359
 360 configure_file(output: 'config.h', configuration: conf)
 361
 362 install_man('doc/ncmpc.1')
 363
 364 docdir = join_paths(get_option('datadir'), 'doc', meson.project_name())
 365 install_data('AUTHORS', 'COPYING', 'NEWS', 'README.rst',
 366   'doc/config.sample',
 367   'doc/keys.sample',
 368   'doc/ncmpc.lirc',
 369   install_dir: docdir)
 370
 371 if not mini
 372   subdir('test')
 373 endif
 374
 375 if get_option('documentation')
 376   doxygen = find_program('doxygen', required: false)
 377   if doxygen.found()
 378     subdir('doc')
 379   endif
 380 endif