configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT(ncurses MPD client, 0.13~git, max@duempel.org, ncmpc)
   3 AC_CONFIG_SRCDIR([src/main.c])
   4 AM_INIT_AUTOMAKE([foreign 1.9 dist-bzip2])
   5 AM_CONFIG_HEADER([config.h])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 dnl Check for programs
   9 AC_PROG_CC_C99
  10 AC_PROG_INSTALL
  11
  12 dnl =======================================================
  13 dnl initialize variables
  14 dnl =======================================================
  15
  16 dnl i18n
  17 ALL_LINGUAS="es da de fr gl no ru sk sv hu"
  18
  19 set -- $CFLAGS
  20
  21 dnl
  22 dnl Check for headers
  23 dnl
  24
  25 AC_CHECK_HEADER([locale.h],
  26                 AC_DEFINE([HAVE_LOCALE_H], [1], [locale.h]),
  27                 ,)
  28
  29
  30 dnl
  31 dnl ncmpc-mini
  32 dnl
  33
  34 AC_ARG_ENABLE(mini,
  35     AS_HELP_STRING([--enable-mini],
  36                    [Build ncmpc-mini (default: disabled)]),
  37     [enable_mini=$enableval],
  38     [enable_mini=no])
  39
  40 AM_CONDITIONAL(NCMPC_MINI, test x$enable_mini = xyes)
  41 if test "x$enable_mini" = xyes; then
  42     AC_DEFINE([NCMPC_MINI], [1], [Build ncmpc-mini, which disables lots of features])
  43     auto=no
  44     disable_mini=no
  45     ncurses=ncurses
  46 else
  47     auto=auto
  48     disable_mini=yes
  49     ncurses=auto
  50 fi
  51
  52
  53 dnl
  54 dnl Check for libraries
  55 dnl
  56
  57 dnl Try to find the socket functions
  58 AC_CHECK_FUNC([socket],
  59               [],
  60               [AC_CHECK_LIB([socket],[socket],[LIBS="$LIBS -lsocket"],
  61                             [AC_MSG_ERROR(No UNIX socket API found)])
  62               ])
  63
  64 dnl Try to find the gethostbyname functions
  65 AC_CHECK_FUNC([gethostbyname],
  66               [],
  67               [AC_CHECK_LIB([nsl],[gethostbyname],[LIBS="$LIBS -lnsl"],
  68                             [AC_MSG_ERROR(No UNIX gethostbyname API found)])
  69               ])
  70
  71
  72 dnl wide character support
  73 AC_ARG_ENABLE([wide],
  74     AC_HELP_STRING([--enable-wide],
  75                    [Enable wide character support]),
  76                    [enable_wide=$enableval],
  77                    [enable_wide=auto])
  78
  79
  80 dnl ncurses
  81 AC_ARG_WITH([ncurses],
  82             AC_HELP_STRING([--with-ncurses], [compile/link with ncurses library] ),
  83             [ncurses=ncurses])
  84 AC_ARG_WITH(ncursesw,
  85             AC_HELP_STRING([--with-ncursesw], [compile/link with wide-char ncurses library @<:@default@:>@]),
  86             [ncurses=ncursesw])
  87
  88 if test "x$enable_wide" = "xno"; then
  89     if test "x$ncurses" = "xauto"; then
  90         dnl select narrow ncurses
  91         ncurses=ncurses
  92     fi
  93
  94     if test "x$ncurses" = "xncursesw"; then
  95         AC_MSG_WARN([Narrow ncmpc linking against wide libncurses])
  96     fi
  97 fi
  98
  99 if test "x$ncurses" = "xauto"; then
 100         AC_CHECK_LIB([ncursesw],
 101                      [initscr],
 102                      [ncurses=ncursesw],
 103                      [ncurses=ncurses])
 104 fi
 105
 106 AC_CHECK_LIB([$ncurses],
 107              [initscr],
 108              [LIBS="$LIBS -l$ncurses"],
 109              [AC_MSG_ERROR($ncurses library is required)])
 110
 111 if test "x$ncurses" = "xncursesw"; then
 112     AC_CHECK_HEADER([ncursesw/ncurses.h],
 113                     AC_DEFINE([HAVE_NCURSESW_NCURSES_H], [1], [ncursesw/ncurses.h]),
 114                     ,)
 115 fi
 116
 117
 118 dnl wide character support II
 119
 120 if test "x$enable_wide" = "xauto" ; then
 121     AC_CHECK_LIB([$ncurses],
 122                  [wget_wch],
 123                  [enable_wide=yes],
 124                  [enable_wide=no])
 125 fi
 126
 127 AC_MSG_CHECKING([wide character support])
 128 AC_MSG_RESULT([$enable_wide])
 129
 130 if test "x$enable_wide" = "xyes" ; then
 131     AC_DEFINE([ENABLE_WIDE], [1], [Enable wide character support])
 132 fi
 133
 134
 135 dnl Check for glib-2.4
 136 PKG_CHECK_MODULES([GLIB],
 137                   [glib-2.0 >= 2.4],
 138                   [glib24=yes],
 139                   [AC_MSG_WARN([glib-2.4 is required for NLS support!])])
 140 if test "x$glib24" != "xyes"; then
 141    PKG_CHECK_MODULES([GLIB],
 142                      [glib-2.0 >= 2.2],
 143                      [nls=no],
 144                      [AC_MSG_ERROR([glib-2.2 is required])])
 145 fi
 146
 147
 148 dnl i18n
 149
 150 AC_MSG_CHECKING([national language support])
 151 AC_ARG_ENABLE([nls],
 152         AS_HELP_STRING([--enable-nls], [Enable national language support]),
 153         [enable_nls=$enableval],
 154         [enable_nls=$disable_mini])
 155 AC_MSG_RESULT([$enable_nls])
 156
 157 if test "x$enable_nls" = xno; then
 158         glib24=no
 159         nls=no
 160 fi
 161
 162 AM_NLS
 163 if test "x$glib24" = "xyes"; then
 164   nls=$USE_NLS
 165 else
 166   USE_NLS=no
 167   AC_SUBST(USE_NLS)
 168 fi
 169
 170 if test "x$nls" = "xyes"; then
 171    AM_GLIB_GNU_GETTEXT
 172    GETTEXT_PACKAGE=$PACKAGE
 173    AC_SUBST(GETTEXT_PACKAGE)
 174    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 175                       ["${GETTEXT_PACKAGE}"],
 176                       [gettext domain])
 177   nls=$gt_cv_have_gettext
 178   if test "x$nls" != "xyes"; then
 179      AC_MSG_WARN([NLS support disabled!])
 180   fi
 181 else
 182   AM_PO_SUBDIRS
 183 fi
 184
 185 dnl enable colors
 186 AC_MSG_CHECKING([color support])
 187 AC_ARG_ENABLE([colors],
 188         AC_HELP_STRING([--enable-colors],
 189                        [Enable color support]),
 190                        [use_colors=$enableval],
 191         [use_colors=$disable_mini])
 192 AC_MSG_RESULT([$use_colors])
 193 if test "x$use_colors" = "xyes" ; then
 194     AC_DEFINE([ENABLE_COLORS], [1], [Enable color support])
 195 fi
 196
 197 dnl test for LIRC support
 198
 199 AC_ARG_ENABLE([lirc],
 200         AC_HELP_STRING([--enable-lirc],
 201                 [Enable LIRC support]),
 202         [enable_lirc=$enableval],
 203         [enable_lirc=no])
 204 if test x$enable_lirc = xyes; then
 205         PKG_CHECK_MODULES([LIBLIRCCLIENT], [liblircclient0],,
 206                 [AC_MSG_ERROR([liblircclient0 not found])])
 207         AC_DEFINE([ENABLE_LIRC], [1], [Enable LIRC support])
 208 fi
 209
 210 AM_CONDITIONAL(ENABLE_LIRC, test x$enable_lirc = xyes)
 211
 212 dnl Debugging
 213 AC_MSG_CHECKING([whether to build with debug support])
 214 AC_ARG_ENABLE([debug],
 215               AC_HELP_STRING([--enable-debug],
 216                              [Enable debugging @<:@default=no@:>@]),
 217               [enable_debug="$enableval"],
 218               [enable_debug=no])
 219 AC_MSG_RESULT([$enable_debug])
 220 if test "x$enable_debug" = "xyes" ; then
 221     CFLAGS="$CFLAGS -g"
 222 else
 223     CFLAGS="$CFLAGS -DNDEBUG"
 224 fi
 225
 226 dnl CFLAGS
 227
 228 AC_SUBST(AM_CFLAGS)
 229
 230 CHECK_CFLAG([-Wall])
 231 CHECK_CFLAG([-Wextra])
 232 CHECK_CFLAG([-Wno-deprecated-declarations])
 233 CHECK_CFLAG([-Wmissing-prototypes])
 234 CHECK_CFLAG([-Wdeclaration-after-statement])
 235 CHECK_CFLAG([-Wshadow])
 236 CHECK_CFLAG([-Wpointer-arith])
 237 CHECK_CFLAG([-Wstrict-prototypes])
 238 CHECK_CFLAG([-Wcast-qual])
 239 CHECK_CFLAG([-Wwrite-strings])
 240
 241 dnl Optional screen - help screen
 242 AC_MSG_CHECKING([whether to include the help screen])
 243 AC_ARG_ENABLE([help-screen],
 244         AS_HELP_STRING([--enable-help-screen],
 245                 [Enable the help screen @<:@default=yes@:>@]),
 246         [help_screen="$enableval"],
 247         [help_screen=$disable_mini])
 248 AC_MSG_RESULT([$help_screen])
 249 if test "x$help_screen" = "xyes" ; then
 250         AC_DEFINE(ENABLE_HELP_SCREEN, 1, [Enable the help screen])
 251 fi
 252
 253 AM_CONDITIONAL(ENABLE_HELP_SCREEN, test x$help_screen = xyes)
 254
 255 dnl Optional screen - browse screen
 256 #AC_MSG_CHECKING([whether to include the browse screen])r
 257 #AC_ARG_ENABLE([browse-screen],
 258 #              AC_HELP_STRING([--enable-browse-screen],
 259 #                            [Enable the browse screen @<:@default=yes@:>@]),
 260 #             [browse_screen="$enableval"],
 261 #             [browse_screen=yes])
 262 #AC_MSG_RESULT([$browse_screen])
 263 #if test "x$browse_screen" = "xyes" ; then
 264 #   AC_DEFINE(ENABLE_BROWSE_SCREEN, 1, [Enable the browse screen])
 265 #fi
 266
 267 dnl Optional - curses getmouse support
 268 AC_MSG_CHECKING([whether to include mouse support])
 269 AC_ARG_ENABLE([mouse],
 270               AC_HELP_STRING([--enable-mouse],
 271                              [Enable curses getmouse support @<:@default=yes@:>@]),
 272               [getmouse="$enableval"],
 273               [getmouse=$disable_mini])
 274 AC_MSG_RESULT([$getmouse])
 275 if test "x$getmouse" = "xyes" ; then
 276    AC_CHECK_LIB([$ncurses],
 277                 [getmouse],
 278                 [AC_DEFINE([HAVE_GETMOUSE], [1], [$ncurses - getmouse()])],
 279                 [])
 280 fi
 281
 282 dnl Optional screen - artist
 283 AC_MSG_CHECKING([whether to include the artist screen])
 284 AC_ARG_ENABLE([artist-screen],
 285               AC_HELP_STRING([--enable-artist-screen],
 286                              [Enable artist screen @<:@default=yes@:>@]),
 287               [artist_screen="$enableval"],
 288               [artist_screen=$disable_mini])
 289 AC_MSG_RESULT([$artist_screen])
 290 if test "x$artist_screen" = "xyes" ; then
 291     AC_DEFINE(ENABLE_ARTIST_SCREEN, 1, [Enable artist screen])
 292 fi
 293
 294 AM_CONDITIONAL(ENABLE_ARTIST_SCREEN, test x$artist_screen = xyes)
 295
 296 dnl Optional screen - search
 297 AC_MSG_CHECKING([whether to include the search screen])
 298 AC_ARG_ENABLE([search-screen],
 299               AC_HELP_STRING([--enable-search-screen],
 300                              [Enable search screen (EXPERIMENTAL) @<:@default=yes@:>@]),
 301               [search_screen="$enableval"],
 302               [search_screen=$disable_mini])
 303 AC_MSG_RESULT([$search_screen])
 304 if test "x$search_screen" = "xyes" ; then
 305     AC_DEFINE(ENABLE_SEARCH_SCREEN, 1, [Enable search screen])
 306 fi
 307
 308 AM_CONDITIONAL(ENABLE_SEARCH_SCREEN, test x$search_screen = xyes)
 309
 310 dnl Optional screen - song viewer
 311 AC_MSG_CHECKING([whether to include the song viewer screen])
 312 AC_ARG_ENABLE([song-screen],
 313         AC_HELP_STRING([--enable-song-screen],
 314                 [Enable song viewer screen @<:@default=yes@:>@]),
 315         [song_screen="$enableval"],
 316         [song_screen=$disable_mini])
 317 AC_MSG_RESULT([$song_screen])
 318 if test "x$song_screen" = "xyes" ; then
 319         AC_DEFINE(ENABLE_SONG_SCREEN, 1, [Enable song viewer screen])
 320 fi
 321
 322 AM_CONDITIONAL(ENABLE_SONG_SCREEN, test x$song_screen = xyes)
 323
 324 dnl Optional screen - key editor
 325 AC_MSG_CHECKING([whether to include the key editor screen])
 326 AC_ARG_ENABLE([key-screen],
 327               AC_HELP_STRING([--enable-key-screen],
 328                              [Enable key editor screen @<:@default=yes@:>@]),
 329               [keydef_screen="$enableval"],
 330               [keydef_screen=$disable_mini])
 331 AC_MSG_RESULT([$keydef_screen])
 332 if test "x$keydef_screen" = "xyes" ; then
 333     AC_DEFINE(ENABLE_KEYDEF_SCREEN, 1, [Enable key editor screen])
 334 fi
 335
 336 AM_CONDITIONAL(ENABLE_KEYDEF_SCREEN, test x$keydef_screen = xyes)
 337
 338 dnl Optional screen - lyrics
 339 AC_MSG_CHECKING([whether to include the lyrics screen])
 340 AC_ARG_ENABLE([lyrics-screen],
 341               AC_HELP_STRING([--enable-lyrics-screen],
 342                              [Enable lyrics screen @<:@default=no@:>@]),
 343               [lyrics_screen="$enableval"],
 344               [lyrics_screen=no])
 345 if test "x$lyrics_screen" = "xyes" ; then
 346     AC_DEFINE(ENABLE_LYRICS_SCREEN, 1, [Enable lyrics screen])
 347 fi
 348
 349 AM_CONDITIONAL(ENABLE_LYRICS_SCREEN, test x$lyrics_screen = xyes)
 350
 351 AC_MSG_RESULT([$lyrics_screen])
 352
 353 AC_ARG_WITH([lyrics-plugin-dir],
 354         AC_HELP_STRING([[--with-lyrics-plugin-dir[=DIRECTORY]]],
 355                        [Directory where lyrics plugins are stored @<:@default=PREFIX/lib/ncmpc/lyrics@:>@]),
 356        [lyrics_plugin_dir=$withval],
 357        [lyrics_plugin_dir=""])
 358 if test "x${lyrics_plugin_dir}" = "x"; then
 359     if test "x${prefix}" = "xNONE"; then
 360         lyrics_plugin_dir="${ac_default_prefix}/lib/ncmpc/lyrics"
 361     else
 362         lyrics_plugin_dir="${prefix}/lib/ncmpc/lyrics"
 363     fi
 364 fi
 365 AC_DEFINE_UNQUOTED([LYRICS_PLUGIN_DIR], ["$lyrics_plugin_dir"],
 366                   [Directory to search for lyrics plugins])
 367 AC_SUBST(lyrics_plugin_dir)
 368
 369 AM_CONDITIONAL(ENABLE_PLUGIN_LIBRARY, test x$lyrics_screen = xyes)
 370 AM_CONDITIONAL(ENABLE_SCREEN_TEXT, test x$lyrics_screen = xyes)
 371
 372 dnl Optional screen - outputs
 373 AC_MSG_CHECKING([whether to include the outputs screen])
 374 AC_ARG_ENABLE([outputs-screen],
 375         AC_HELP_STRING([--enable-outputs-screen],
 376                 [Enable outputs screen @<:@default=yes@:>@]),
 377         [outputs_screen=$enableval],
 378         [outputs_screen=$disable_mini])
 379 if test "x$outputs_screen" = "xyes" ; then
 380         AC_DEFINE(ENABLE_OUTPUTS_SCREEN, 1, [Enable outputs screen])
 381 fi
 382
 383 AM_CONDITIONAL(ENABLE_OUTPUTS_SCREEN, test x$outputs_screen = xyes)
 384
 385 dnl Default host
 386 AC_MSG_CHECKING([for default MPD host])
 387 AC_ARG_WITH([default-host],
 388             AC_HELP_STRING([--with-default-host=ARG],
 389                            [Default MPD host @<:@localhost@:>@]),
 390             [DEFAULT_HOST="$withval"],
 391             [DEFAULT_HOST="localhost"])
 392 AC_MSG_RESULT([$DEFAULT_HOST])
 393 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$DEFAULT_HOST"], [Default MPD host])
 394
 395 dnl Default port
 396 AC_MSG_CHECKING([for default MPD port])
 397 AC_ARG_WITH([default-port],
 398             AC_HELP_STRING([--with-default-port=ARG],
 399                            [Default port @<:@6600@:>@]),
 400             [DEFAULT_PORT="$withval"],
 401             [DEFAULT_PORT="6600"])
 402 AC_MSG_RESULT([$DEFAULT_PORT])
 403 AC_DEFINE_UNQUOTED([DEFAULT_PORT],     [$DEFAULT_PORT],   [Default MPD port])
 404 AC_DEFINE_UNQUOTED([DEFAULT_PORT_STR], ["$DEFAULT_PORT"], [Default MPD port])
 405
 406 dnl Default timedisplay type
 407 AC_MSG_CHECKING([for default timedisplay type])
 408 AC_ARG_WITH([default-timedisplay_type],
 409             AC_HELP_STRING([--with-default-timedisplay_type=ARG],
 410                            [default_timedisplay]),
 411             [DEFAULT_TIMEDISPLAY_TYPE="$withval"],
 412             [DEFAULT_TIMEDISPLAY_TYPE="elapsed"])
 413 AC_MSG_RESULT([$DEFAULT_TIMEDISPLAY_TYPE])
 414 AC_DEFINE_UNQUOTED([DEFAULT_TIMEDISPLAY_TYPE], ["$DEFAULT_TIMEDISPLAY_TYPE"], [Default way to display time, either 'elapsed' or 'remaining'])
 415 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile po/Makefile.in po/Makefile])
 416 AC_OUTPUT