configure.ac

   1 dnl
   2 dnl  $Id$
   3 dnl
   4
   5 AC_INIT(ncurses MPD client, 0.12~git, max@duempel.org, ncmpc)
   6 AC_CONFIG_SRCDIR([src/main.c])
   7 AM_INIT_AUTOMAKE([gnu 1.9 dist-bzip2])
   8 AM_CONFIG_HEADER([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 dnl Check for programs
  12 AC_PROG_CC_C99
  13 AC_PROG_INSTALL
  14
  15 dnl =======================================================
  16 dnl initialize variables
  17 dnl =======================================================
  18
  19 dnl i18n
  20 ALL_LINGUAS="es da de fr gl no ru sv"
  21
  22 set -- $CFLAGS
  23
  24 dnl
  25 dnl Check for headers
  26 dnl
  27
  28 AC_CHECK_HEADER([locale.h],
  29                 AC_DEFINE([HAVE_LOCALE_H], [1], [locale.h]),
  30                 ,)
  31
  32
  33 dnl
  34 dnl Check for functions
  35 dnl
  36 AC_CHECK_FUNCS([strcasestr])
  37
  38
  39 dnl
  40 dnl ncmpc-mini
  41 dnl
  42
  43 AC_ARG_ENABLE(mini,
  44     AS_HELP_STRING([--enable-mini],
  45                    [Build ncmpc-mini (default: disabled)]),
  46     [enable_mini=$enableval],
  47     [enable_mini=no])
  48
  49 AM_CONDITIONAL(NCMPC_MINI, test x$enable_mini = xyes)
  50 if test "x$enable_mini" = xyes; then
  51     AC_DEFINE([NCMPC_MINI], [1], [Build ncmpc-mini, which disables lots of features]),
  52     auto=no
  53     disable_mini=no
  54     ncurses=ncurses
  55 else
  56     auto=auto
  57     disable_mini=yes
  58     ncurses=auto
  59 fi
  60
  61
  62 dnl
  63 dnl Check for libraries
  64 dnl
  65
  66 dnl Try to find the socket functions
  67 AC_CHECK_FUNC([socket],
  68               [],
  69               [AC_CHECK_LIB([socket],[socket],[LIBS="$LIBS -lsocket"],
  70                             [AC_MSG_ERROR(No UNIX socket API found)])
  71               ])
  72
  73 dnl Try to find the gethostbyname functions
  74 AC_CHECK_FUNC([gethostbyname],
  75               [],
  76               [AC_CHECK_LIB([nsl],[gethostbyname],[LIBS="$LIBS -lnsl"],
  77                             [AC_MSG_ERROR(No UNIX gethostbyname API found)])
  78               ])
  79
  80
  81 dnl wide character support
  82 AC_ARG_ENABLE([wide],
  83     AC_HELP_STRING([--enable-wide],
  84                    [Enable wide character support]),
  85                    [enable_wide=$enableval],
  86                    [enable_wide=auto])
  87
  88
  89 dnl ncurses
  90 AC_ARG_WITH([ncurses],
  91             AC_HELP_STRING([--with-ncurses], [compile/link with ncurses library] ),
  92             [ncurses=ncurses])
  93 AC_ARG_WITH(ncursesw,
  94             AC_HELP_STRING([--with-ncursesw], [compile/link with wide-char ncurses library @<:@default@:>@]),
  95             [ncurses=ncursesw])
  96
  97 if test "x$enable_wide" = "xno"; then
  98     if test "x$ncurses" = "xauto"; then
  99         dnl select narrow ncurses
 100         ncurses=ncurses
 101     fi
 102
 103     if test "x$ncurses" = "xncursesw"; then
 104         AC_MSG_WARN([Narrow ncmpc linking against wide libncurses])
 105     fi
 106 fi
 107
 108 if test "x$ncurses" = "xauto"; then
 109         AC_CHECK_LIB([ncursesw],
 110                      [initscr],
 111                      [ncurses=ncursesw],
 112                      [ncurses=ncurses])
 113 fi
 114
 115 AC_CHECK_LIB([$ncurses],
 116              [initscr],
 117              [LIBS="$LIBS -l$ncurses"],
 118              [AC_MSG_ERROR($ncurses library is required)])
 119
 120 if test "x$ncurses" = "xncursesw"; then
 121     AC_CHECK_HEADER([ncursesw/ncurses.h],
 122                     AC_DEFINE([HAVE_NCURSESW_NCURSES_H], [1], [ncursesw/ncurses.h]),
 123                     ,)
 124 fi
 125
 126
 127 dnl wide character support II
 128
 129 if test "x$enable_wide" = "xauto" ; then
 130     AC_CHECK_LIB([$ncurses],
 131                  [wget_wch],
 132                  [enable_wide=yes],
 133                  [enable_wide=no])
 134 fi
 135
 136 AC_MSG_CHECKING([wide character support])
 137 AC_MSG_RESULT([$enable_wide])
 138
 139 if test "x$enable_wide" = "xyes" ; then
 140     AC_DEFINE([ENABLE_WIDE], [1], [Enable wide character support])
 141 fi
 142
 143
 144 dnl Check for glib-2.4
 145 PKG_CHECK_MODULES([GLIB],
 146                   [glib-2.0 >= 2.4],
 147                   [glib24=yes],
 148                   [AC_MSG_WARN([glib-2.4 is required for NLS support!])])
 149 if test "x$glib24" != "xyes"; then
 150    PKG_CHECK_MODULES([GLIB],
 151                      [glib-2.0 >= 2.2],
 152                      [nls=no],
 153                      [AC_MSG_ERROR([glib-2.2 is required])])
 154 fi
 155
 156
 157 dnl i18n
 158
 159 AC_MSG_CHECKING([national language support])
 160 AC_ARG_ENABLE([nls],
 161         AS_HELP_STRING([--enable-nls], [Enable national language support]),
 162         [enable_nls=$enableval],
 163         [enable_nls=$disable_mini])
 164 AC_MSG_RESULT([$enable_nls])
 165
 166 if test "x$enable_nls" = xno; then
 167         glib24=no
 168         nls=no
 169 fi
 170
 171 AM_NLS
 172 if test "x$glib24" = "xyes"; then
 173   nls=$USE_NLS
 174 else
 175   USE_NLS=no
 176   AC_SUBST(USE_NLS)
 177 fi
 178
 179 if test "x$nls" = "xyes"; then
 180    AM_GLIB_GNU_GETTEXT
 181    GETTEXT_PACKAGE=$PACKAGE
 182    AC_SUBST(GETTEXT_PACKAGE)
 183    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 184                       ["${GETTEXT_PACKAGE}"],
 185                       [gettext domain])
 186   nls=$gt_cv_have_gettext
 187   if test "x$nls" != "xyes"; then
 188      AC_MSG_WARN([NLS support disabled!])
 189   fi
 190 else
 191   AM_PO_SUBDIRS
 192 fi
 193
 194 dnl enable colors
 195 AC_MSG_CHECKING([color support])
 196 AC_ARG_ENABLE([colors],
 197         AC_HELP_STRING([--enable-colors],
 198                        [Enable color support]),
 199                        [use_colors=$enableval],
 200                        [use_colors=no])
 201 AC_MSG_RESULT([$use_colors])
 202 if test "x$use_colors" = "xyes" ; then
 203     AC_DEFINE([ENABLE_COLORS], [1], [Enable color support])
 204 fi
 205
 206 dnl test for LIRC support
 207
 208 AC_ARG_ENABLE([lirc],
 209         AC_HELP_STRING([--enable-lirc],
 210                 [Enable LIRC support]),
 211         [enable_lirc=$enableval],
 212         [enable_lirc=no])
 213 if test x$enable_lirc = xyes; then
 214         PKG_CHECK_MODULES([LIBLIRCCLIENT], [liblircclient0],,
 215                 [AC_MSG_ERROR([liblircclient0 not found])])
 216         AC_DEFINE([ENABLE_LIRC], [1], [Enable LIRC support])
 217 fi
 218
 219 AM_CONDITIONAL(ENABLE_LIRC, test x$enable_lirc = xyes)
 220
 221 dnl Debugging
 222 AC_MSG_CHECKING([whether to build with debug support])
 223 AC_ARG_ENABLE([debug],
 224               AC_HELP_STRING([--enable-debug],
 225                              [Enable debugging @<:@default=no@:>@]),
 226               [enable_debug="$enableval"],
 227               [enable_debug=no])
 228 AC_MSG_RESULT([$enable_debug])
 229 if test "x$enable_debug" = "xyes" ; then
 230     CFLAGS="$CFLAGS -g"
 231 else
 232     CFLAGS="$CFLAGS -DNDEBUG"
 233 fi
 234
 235 dnl CFLAGS
 236
 237 AC_SUBST(AM_CFLAGS)
 238
 239 CHECK_CFLAG([-Wall])
 240 CHECK_CFLAG([-Wextra])
 241 CHECK_CFLAG([-Wno-deprecated-declarations])
 242 CHECK_CFLAG([-Wmissing-prototypes])
 243 CHECK_CFLAG([-Wdeclaration-after-statement])
 244 CHECK_CFLAG([-Wshadow])
 245 CHECK_CFLAG([-Wpointer-arith])
 246 CHECK_CFLAG([-Wstrict-prototypes])
 247 CHECK_CFLAG([-Wcast-qual])
 248 CHECK_CFLAG([-Wwrite-strings])
 249
 250 dnl Optional screen - help screen
 251 AC_MSG_CHECKING([whether to include the help screen])
 252 AC_ARG_ENABLE([help-screen],
 253         AS_HELP_STRING([--enable-help-screen],
 254                 [Enable the help screen @<:@default=yes@:>@]),
 255         [help_screen="$enableval"],
 256         [help_screen=$disable_mini])
 257 AC_MSG_RESULT([$help_screen])
 258 if test "x$help_screen" = "xyes" ; then
 259         AC_DEFINE(ENABLE_HELP_SCREEN, 1, [Enable the help screen])
 260 fi
 261
 262 AM_CONDITIONAL(ENABLE_HELP_SCREEN, test x$help_screen = xyes)
 263
 264 dnl Optional screen - browse screen
 265 #AC_MSG_CHECKING([whether to include the browse screen])r
 266 #AC_ARG_ENABLE([browse-screen],
 267 #              AC_HELP_STRING([--enable-browse-screen],
 268 #                            [Enable the browse screen @<:@default=yes@:>@]),
 269 #             [browse_screen="$enableval"],
 270 #             [browse_screen=yes])
 271 #AC_MSG_RESULT([$browse_screen])
 272 #if test "x$browse_screen" = "xyes" ; then
 273 #   AC_DEFINE(ENABLE_BROWSE_SCREEN, 1, [Enable the browse screen])
 274 #fi
 275
 276 dnl Optional - curses getmouse support
 277 AC_MSG_CHECKING([whether to include mouse support])
 278 AC_ARG_ENABLE([mouse],
 279               AC_HELP_STRING([--enable-mouse],
 280                              [Enable curses getmouse support @<:@default=yes@:>@]),
 281               [getmouse="$enableval"],
 282               [getmouse=$disable_mini])
 283 AC_MSG_RESULT([$getmouse])
 284 if test "x$getmouse" = "xyes" ; then
 285    AC_CHECK_LIB([$ncurses],
 286                 [getmouse],
 287                 [AC_DEFINE([HAVE_GETMOUSE], [1], [$ncurses - getmouse()])],
 288                 [])
 289 fi
 290
 291 dnl Optional screen - artist
 292 AC_MSG_CHECKING([whether to include the artist screen])
 293 AC_ARG_ENABLE([artist-screen],
 294               AC_HELP_STRING([--enable-artist-screen],
 295                              [Enable artist screen (EXPERIMENTAL) @<:@default=no@:>@]),
 296               [artist_screen="$enableval"],
 297               [artist_screen=no])
 298 AC_MSG_RESULT([$artist_screen])
 299 if test "x$artist_screen" = "xyes" ; then
 300     AC_DEFINE(ENABLE_ARTIST_SCREEN, 1, [Enable artist screen])
 301 fi
 302
 303 AM_CONDITIONAL(ENABLE_ARTIST_SCREEN, test x$artist_screen = xyes)
 304
 305 dnl Optional screen - search
 306 AC_MSG_CHECKING([whether to include the search screen])
 307 AC_ARG_ENABLE([search-screen],
 308               AC_HELP_STRING([--enable-search-screen],
 309                              [Enable search screen (EXPERIMENTAL) @<:@default=yes@:>@]),
 310               [search_screen="$enableval"],
 311               [search_screen=$disable_mini])
 312 AC_MSG_RESULT([$search_screen])
 313 if test "x$search_screen" = "xyes" ; then
 314     AC_DEFINE(ENABLE_SEARCH_SCREEN, 1, [Enable search screen])
 315 fi
 316
 317 AM_CONDITIONAL(ENABLE_SEARCH_SCREEN, test x$search_screen = xyes)
 318
 319 dnl Optional screen - key editor
 320 AC_MSG_CHECKING([whether to include the key editor screen])
 321 AC_ARG_ENABLE([key-screen],
 322               AC_HELP_STRING([--enable-key-screen],
 323                              [Enable key editor screen @<:@default=yes@:>@]),
 324               [keydef_screen="$enableval"],
 325               [keydef_screen=$disable_mini])
 326 AC_MSG_RESULT([$keydef_screen])
 327 if test "x$keydef_screen" = "xyes" ; then
 328     AC_DEFINE(ENABLE_KEYDEF_SCREEN, 1, [Enable key editor screen])
 329 fi
 330
 331 AM_CONDITIONAL(ENABLE_KEYDEF_SCREEN, test x$keydef_screen = xyes)
 332
 333 dnl Optional screen - lyrics
 334 AC_MSG_CHECKING([whether to include the lyrics screen])
 335 AC_ARG_ENABLE([lyrics-screen],
 336               AC_HELP_STRING([--enable-lyrics-screen],
 337                              [Enable lyrics screen @<:@default=no@:>@]),
 338               [lyrics_screen="$enableval"],
 339               [lyrics_screen=no])
 340 if test "x$lyrics_screen" = "xyes" ; then
 341     AC_DEFINE(ENABLE_LYRICS_SCREEN, 1, [Enable lyrics screen])
 342 fi
 343
 344 AM_CONDITIONAL(ENABLE_LYRICS_SCREEN, test x$lyrics_screen = xyes)
 345
 346 AC_MSG_RESULT([$lyrics_screen])
 347
 348 AC_ARG_WITH([lyrics-plugin-dir],
 349         AC_HELP_STRING([[--with-lyrics-plugin-dir[=DIRECTORY]]],
 350                        [Directory where lyrics plugins are stored @<:@default=PREFIX/lib/ncmpc/lyrics@:>@]),
 351        [lyrics_plugin_dir=$withval],
 352        [lyrics_plugin_dir=""])
 353 if test "x${lyrics_plugin_dir}" = "x"; then
 354     if test "x${prefix}" = "xNONE"; then
 355         lyrics_plugin_dir="${ac_default_prefix}/lib/ncmpc/lyrics"
 356     else
 357         lyrics_plugin_dir="${prefix}/lib/ncmpc/lyrics"
 358     fi
 359 fi
 360 AC_DEFINE_UNQUOTED([LYRICS_PLUGIN_DIR], ["$lyrics_plugin_dir"],
 361                   [Directory to search for lyrics plugins])
 362 AC_SUBST(lyrics_plugin_dir)
 363
 364 dnl Default host
 365 AC_MSG_CHECKING([for default MPD host])
 366 AC_ARG_WITH([default-host],
 367             AC_HELP_STRING([--with-default-host=ARG],
 368                            [Default MPD host @<:@localhost@:>@]),
 369             [DEFAULT_HOST="$withval"],
 370             [DEFAULT_HOST="localhost"])
 371 AC_MSG_RESULT([$DEFAULT_HOST])
 372 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$DEFAULT_HOST"], [Default MPD host])
 373
 374 dnl Default port
 375 AC_MSG_CHECKING([for default MPD port])
 376 AC_ARG_WITH([default-port],
 377             AC_HELP_STRING([--with-default-port=ARG],
 378                            [Default port @<:@6600@:>@]),
 379             [DEFAULT_PORT="$withval"],
 380             [DEFAULT_PORT="6600"])
 381 AC_MSG_RESULT([$DEFAULT_PORT])
 382 AC_DEFINE_UNQUOTED([DEFAULT_PORT],     [$DEFAULT_PORT],   [Default MPD port])
 383 AC_DEFINE_UNQUOTED([DEFAULT_PORT_STR], ["$DEFAULT_PORT"], [Default MPD port])
 384
 385 dnl Default timedisplay type
 386 AC_MSG_CHECKING([for default timedisplay type])
 387 AC_ARG_WITH([default-timedisplay_type],
 388             AC_HELP_STRING([--with-default-timedisplay_type=ARG],
 389                            [default_timedisplay]),
 390             [DEFAULT_TIMEDISPLAY_TYPE="$withval"],
 391             [DEFAULT_TIMEDISPLAY_TYPE="elapsed"])
 392 AC_MSG_RESULT([$DEFAULT_TIMEDISPLAY_TYPE])
 393 AC_DEFINE_UNQUOTED([DEFAULT_TIMEDISPLAY_TYPE], ["$DEFAULT_TIMEDISPLAY_TYPE"], [Default way to display time, either 'elapsed' or 'remaining'])
 394 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile po/Makefile.in po/Makefile])
 395 AC_OUTPUT