configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT(ncurses MPD client, 0.13~git, max@duempel.org, ncmpc)
   3 AC_CONFIG_SRCDIR([src/main.c])
   4 AM_INIT_AUTOMAKE([foreign 1.9 dist-bzip2])
   5 AM_CONFIG_HEADER([config.h])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 dnl Check for programs
   9 AC_PROG_CC_C99
  10 AC_PROG_INSTALL
  11
  12 dnl =======================================================
  13 dnl initialize variables
  14 dnl =======================================================
  15
  16 dnl i18n
  17 ALL_LINGUAS="es da de fr gl no ru sk sv hu"
  18
  19 set -- $CFLAGS
  20
  21
  22 dnl
  23 dnl ncmpc-mini
  24 dnl
  25
  26 AC_ARG_ENABLE(mini,
  27     AS_HELP_STRING([--enable-mini],
  28                 [Build ncmpc-mini, i.e. without all optional features (default: disabled)]),
  29     [enable_mini=$enableval],
  30     [enable_mini=no])
  31
  32 AM_CONDITIONAL(NCMPC_MINI, test x$enable_mini = xyes)
  33 if test "x$enable_mini" = xyes; then
  34     AC_DEFINE([NCMPC_MINI], [1], [Build ncmpc-mini, which disables lots of features])
  35     auto=no
  36     disable_mini=no
  37     auto_mini=no
  38     ncurses=ncurses
  39 else
  40     auto=auto
  41     disable_mini=yes
  42     auto_mini=auto
  43     ncurses=auto
  44 fi
  45
  46
  47 dnl
  48 dnl Check for libraries
  49 dnl
  50
  51 dnl Try to find the socket functions
  52 AC_CHECK_FUNC([socket],
  53               [],
  54               [AC_CHECK_LIB([socket],[socket],[LIBS="$LIBS -lsocket"],
  55                             [AC_MSG_ERROR(No UNIX socket API found)])
  56               ])
  57
  58 dnl Try to find the gethostbyname functions
  59 AC_CHECK_FUNC([gethostbyname],
  60               [],
  61               [AC_CHECK_LIB([nsl],[gethostbyname],[LIBS="$LIBS -lnsl"],
  62                             [AC_MSG_ERROR(No UNIX gethostbyname API found)])
  63               ])
  64
  65
  66 dnl wide character support
  67 AC_ARG_ENABLE([wide],
  68     AC_HELP_STRING([--enable-wide],
  69                    [Enable wide character support]),
  70                    [enable_wide=$enableval],
  71                    [enable_wide=auto])
  72
  73
  74 dnl ncurses
  75 AC_ARG_WITH([ncurses],
  76             AC_HELP_STRING([--with-ncurses], [compile/link with ncurses library] ),
  77             [ncurses=ncurses])
  78 AC_ARG_WITH(ncursesw,
  79             AC_HELP_STRING([--with-ncursesw], [compile/link with wide-char ncurses library @<:@default@:>@]),
  80             [ncurses=ncursesw])
  81
  82 if test "x$enable_wide" = "xno"; then
  83     if test "x$ncurses" = "xauto"; then
  84         dnl select narrow ncurses
  85         ncurses=ncurses
  86     fi
  87
  88     if test "x$ncurses" = "xncursesw"; then
  89         AC_MSG_WARN([Narrow ncmpc linking against wide libncurses])
  90     fi
  91 fi
  92
  93 if test "x$ncurses" = "xauto"; then
  94         AC_CHECK_LIB([ncursesw],
  95                      [initscr],
  96                      [ncurses=ncursesw],
  97                      [ncurses=ncurses])
  98 fi
  99
 100 AC_CHECK_LIB([$ncurses],
 101              [initscr],
 102              [LIBS="$LIBS -l$ncurses"],
 103              [AC_MSG_ERROR($ncurses library is required)])
 104
 105 if test "x$ncurses" = "xncursesw"; then
 106     AC_CHECK_HEADER([ncursesw/ncurses.h],
 107                     AC_DEFINE([HAVE_NCURSESW_NCURSES_H], [1], [ncursesw/ncurses.h]),
 108                     ,)
 109 fi
 110
 111
 112 dnl wide character support II
 113
 114 if test "x$enable_wide" = "xauto" ; then
 115     AC_CHECK_LIB([$ncurses],
 116                  [wget_wch],
 117                  [enable_wide=yes],
 118                  [enable_wide=no])
 119 fi
 120
 121 AC_MSG_CHECKING([wide character support])
 122 AC_MSG_RESULT([$enable_wide])
 123
 124 if test "x$enable_wide" = "xyes" ; then
 125     AC_DEFINE([ENABLE_WIDE], [1], [Enable wide character support])
 126 fi
 127
 128
 129 dnl Check for glib-2.4
 130 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.4],,
 131         [AC_MSG_ERROR([glib-2.2 is required])])
 132
 133
 134 dnl i18n
 135
 136 AC_ARG_ENABLE([locale],
 137         AC_HELP_STRING([--disable-locale],
 138                 [Disable locale support (default: auto)]),
 139                 [enable_locale=$enableval],
 140                 [enable_locale=$auto_mini])
 141
 142 if test x$enable_locale = xyes; then
 143         AC_CHECK_HEADER([locale.h],,
 144                 [AC_MSG_ERROR(locale.h is unavailable)])
 145 fi
 146
 147 if test x$enable_locale = xauto; then
 148         AC_CHECK_HEADER([locale.h],
 149                 [enable_locale=yes],
 150                 [enable_locale=no])
 151 fi
 152
 153 if test x$enable_locale = xyes; then
 154         AC_DEFINE([ENABLE_LOCALE], [1], [Locale support is enabled])
 155 fi
 156
 157 if test x$enable_mini != xyes; then
 158         AM_NLS
 159 else
 160         USE_NLS=no
 161 fi
 162
 163 if test x$USE_NLS = xyes; then
 164    AM_GLIB_GNU_GETTEXT
 165    GETTEXT_PACKAGE=$PACKAGE
 166    AC_SUBST(GETTEXT_PACKAGE)
 167    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 168                       ["${GETTEXT_PACKAGE}"],
 169                       [gettext domain])
 170         USE_NLS=$gt_cv_have_gettext
 171         if test x$USE_NLS != xyes; then
 172      AC_MSG_WARN([NLS support disabled!])
 173   fi
 174 else
 175   AM_PO_SUBDIRS
 176 fi
 177
 178 dnl enable colors
 179 AC_MSG_CHECKING([color support])
 180 AC_ARG_ENABLE([colors],
 181         AC_HELP_STRING([--enable-colors],
 182                        [Enable color support]),
 183                        [use_colors=$enableval],
 184         [use_colors=$disable_mini])
 185 AC_MSG_RESULT([$use_colors])
 186 if test "x$use_colors" = "xyes" ; then
 187     AC_DEFINE([ENABLE_COLORS], [1], [Enable color support])
 188 fi
 189
 190 dnl test for LIRC support
 191
 192 AC_ARG_ENABLE([lirc],
 193         AC_HELP_STRING([--enable-lirc],
 194                 [Enable LIRC support]),
 195         [enable_lirc=$enableval],
 196         [enable_lirc=no])
 197 if test x$enable_lirc = xyes; then
 198         PKG_CHECK_MODULES([LIBLIRCCLIENT], [liblircclient0],,
 199                 [AC_MSG_ERROR([liblircclient0 not found])])
 200         AC_DEFINE([ENABLE_LIRC], [1], [Enable LIRC support])
 201 fi
 202
 203 AM_CONDITIONAL(ENABLE_LIRC, test x$enable_lirc = xyes)
 204
 205
 206 dnl Optional screen - help screen
 207 AC_MSG_CHECKING([whether to include the help screen])
 208 AC_ARG_ENABLE([help-screen],
 209         AS_HELP_STRING([--enable-help-screen],
 210                 [Enable the help screen @<:@default=yes@:>@]),
 211         [help_screen="$enableval"],
 212         [help_screen=$disable_mini])
 213 AC_MSG_RESULT([$help_screen])
 214 if test "x$help_screen" = "xyes" ; then
 215         AC_DEFINE(ENABLE_HELP_SCREEN, 1, [Enable the help screen])
 216 fi
 217
 218 AM_CONDITIONAL(ENABLE_HELP_SCREEN, test x$help_screen = xyes)
 219
 220 dnl Optional screen - browse screen
 221 #AC_MSG_CHECKING([whether to include the browse screen])r
 222 #AC_ARG_ENABLE([browse-screen],
 223 #              AC_HELP_STRING([--enable-browse-screen],
 224 #                            [Enable the browse screen @<:@default=yes@:>@]),
 225 #             [browse_screen="$enableval"],
 226 #             [browse_screen=yes])
 227 #AC_MSG_RESULT([$browse_screen])
 228 #if test "x$browse_screen" = "xyes" ; then
 229 #   AC_DEFINE(ENABLE_BROWSE_SCREEN, 1, [Enable the browse screen])
 230 #fi
 231
 232 dnl Optional - curses getmouse support
 233 AC_MSG_CHECKING([whether to include mouse support])
 234 AC_ARG_ENABLE([mouse],
 235               AC_HELP_STRING([--enable-mouse],
 236                              [Enable curses getmouse support @<:@default=yes@:>@]),
 237               [getmouse="$enableval"],
 238               [getmouse=$disable_mini])
 239 AC_MSG_RESULT([$getmouse])
 240 if test "x$getmouse" = "xyes" ; then
 241    AC_CHECK_LIB([$ncurses],
 242                 [getmouse],
 243                 [AC_DEFINE([HAVE_GETMOUSE], [1], [$ncurses - getmouse()])],
 244                 [])
 245 fi
 246
 247 dnl Optional screen - artist
 248 AC_MSG_CHECKING([whether to include the artist screen])
 249 AC_ARG_ENABLE([artist-screen],
 250               AC_HELP_STRING([--enable-artist-screen],
 251                              [Enable artist screen @<:@default=yes@:>@]),
 252               [artist_screen="$enableval"],
 253               [artist_screen=$disable_mini])
 254 AC_MSG_RESULT([$artist_screen])
 255 if test "x$artist_screen" = "xyes" ; then
 256     AC_DEFINE(ENABLE_ARTIST_SCREEN, 1, [Enable artist screen])
 257 fi
 258
 259 AM_CONDITIONAL(ENABLE_ARTIST_SCREEN, test x$artist_screen = xyes)
 260
 261 dnl Optional screen - search
 262 AC_MSG_CHECKING([whether to include the search screen])
 263 AC_ARG_ENABLE([search-screen],
 264               AC_HELP_STRING([--enable-search-screen],
 265                              [Enable search screen (EXPERIMENTAL) @<:@default=yes@:>@]),
 266               [search_screen="$enableval"],
 267               [search_screen=$disable_mini])
 268 AC_MSG_RESULT([$search_screen])
 269 if test "x$search_screen" = "xyes" ; then
 270     AC_DEFINE(ENABLE_SEARCH_SCREEN, 1, [Enable search screen])
 271 fi
 272
 273 AM_CONDITIONAL(ENABLE_SEARCH_SCREEN, test x$search_screen = xyes)
 274
 275 dnl Optional screen - song viewer
 276 AC_MSG_CHECKING([whether to include the song viewer screen])
 277 AC_ARG_ENABLE([song-screen],
 278         AC_HELP_STRING([--enable-song-screen],
 279                 [Enable song viewer screen @<:@default=yes@:>@]),
 280         [song_screen="$enableval"],
 281         [song_screen=$disable_mini])
 282 AC_MSG_RESULT([$song_screen])
 283 if test "x$song_screen" = "xyes" ; then
 284         AC_DEFINE(ENABLE_SONG_SCREEN, 1, [Enable song viewer screen])
 285 fi
 286
 287 AM_CONDITIONAL(ENABLE_SONG_SCREEN, test x$song_screen = xyes)
 288
 289 dnl Optional screen - key editor
 290 AC_MSG_CHECKING([whether to include the key editor screen])
 291 AC_ARG_ENABLE([key-screen],
 292               AC_HELP_STRING([--enable-key-screen],
 293                              [Enable key editor screen @<:@default=yes@:>@]),
 294               [keydef_screen="$enableval"],
 295               [keydef_screen=$disable_mini])
 296 AC_MSG_RESULT([$keydef_screen])
 297 if test "x$keydef_screen" = "xyes" ; then
 298     AC_DEFINE(ENABLE_KEYDEF_SCREEN, 1, [Enable key editor screen])
 299 fi
 300
 301 AM_CONDITIONAL(ENABLE_KEYDEF_SCREEN, test x$keydef_screen = xyes)
 302
 303 dnl Optional screen - lyrics
 304 AC_MSG_CHECKING([whether to include the lyrics screen])
 305 AC_ARG_ENABLE([lyrics-screen],
 306               AC_HELP_STRING([--enable-lyrics-screen],
 307                              [Enable lyrics screen @<:@default=no@:>@]),
 308               [lyrics_screen="$enableval"],
 309               [lyrics_screen=no])
 310 if test "x$lyrics_screen" = "xyes" ; then
 311     AC_DEFINE(ENABLE_LYRICS_SCREEN, 1, [Enable lyrics screen])
 312 fi
 313
 314 AM_CONDITIONAL(ENABLE_LYRICS_SCREEN, test x$lyrics_screen = xyes)
 315
 316 AC_MSG_RESULT([$lyrics_screen])
 317
 318 AC_ARG_WITH([lyrics-plugin-dir],
 319         AC_HELP_STRING([[--with-lyrics-plugin-dir[=DIRECTORY]]],
 320                        [Directory where lyrics plugins are stored @<:@default=PREFIX/lib/ncmpc/lyrics@:>@]),
 321        [lyrics_plugin_dir=$withval],
 322        [lyrics_plugin_dir=""])
 323 if test "x${lyrics_plugin_dir}" = "x"; then
 324     if test "x${prefix}" = "xNONE"; then
 325         lyrics_plugin_dir="${ac_default_prefix}/lib/ncmpc/lyrics"
 326     else
 327         lyrics_plugin_dir="${prefix}/lib/ncmpc/lyrics"
 328     fi
 329 fi
 330 AC_DEFINE_UNQUOTED([LYRICS_PLUGIN_DIR], ["$lyrics_plugin_dir"],
 331                   [Directory to search for lyrics plugins])
 332 AC_SUBST(lyrics_plugin_dir)
 333
 334 AM_CONDITIONAL(ENABLE_PLUGIN_LIBRARY, test x$lyrics_screen = xyes)
 335 AM_CONDITIONAL(ENABLE_SCREEN_TEXT, test x$lyrics_screen = xyes)
 336
 337 dnl Optional screen - outputs
 338 AC_MSG_CHECKING([whether to include the outputs screen])
 339 AC_ARG_ENABLE([outputs-screen],
 340         AC_HELP_STRING([--enable-outputs-screen],
 341                 [Enable outputs screen @<:@default=yes@:>@]),
 342         [outputs_screen=$enableval],
 343         [outputs_screen=$disable_mini])
 344 if test "x$outputs_screen" = "xyes" ; then
 345         AC_DEFINE(ENABLE_OUTPUTS_SCREEN, 1, [Enable outputs screen])
 346 fi
 347
 348 AM_CONDITIONAL(ENABLE_OUTPUTS_SCREEN, test x$outputs_screen = xyes)
 349
 350 dnl Default host
 351 AC_MSG_CHECKING([for default MPD host])
 352 AC_ARG_WITH([default-host],
 353             AC_HELP_STRING([--with-default-host=ARG],
 354                            [Default MPD host @<:@localhost@:>@]),
 355             [DEFAULT_HOST="$withval"],
 356             [DEFAULT_HOST="localhost"])
 357 AC_MSG_RESULT([$DEFAULT_HOST])
 358 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$DEFAULT_HOST"], [Default MPD host])
 359
 360 dnl Default port
 361 AC_MSG_CHECKING([for default MPD port])
 362 AC_ARG_WITH([default-port],
 363             AC_HELP_STRING([--with-default-port=ARG],
 364                            [Default port @<:@6600@:>@]),
 365             [DEFAULT_PORT="$withval"],
 366             [DEFAULT_PORT="6600"])
 367 AC_MSG_RESULT([$DEFAULT_PORT])
 368 AC_DEFINE_UNQUOTED([DEFAULT_PORT],     [$DEFAULT_PORT],   [Default MPD port])
 369 AC_DEFINE_UNQUOTED([DEFAULT_PORT_STR], ["$DEFAULT_PORT"], [Default MPD port])
 370
 371 dnl Default timedisplay type
 372 AC_MSG_CHECKING([for default timedisplay type])
 373 AC_ARG_WITH([default-timedisplay_type],
 374             AC_HELP_STRING([--with-default-timedisplay_type=ARG],
 375                            [default_timedisplay]),
 376             [DEFAULT_TIMEDISPLAY_TYPE="$withval"],
 377             [DEFAULT_TIMEDISPLAY_TYPE="elapsed"])
 378 AC_MSG_RESULT([$DEFAULT_TIMEDISPLAY_TYPE])
 379 AC_DEFINE_UNQUOTED([DEFAULT_TIMEDISPLAY_TYPE], ["$DEFAULT_TIMEDISPLAY_TYPE"], [Default way to display time, either 'elapsed' or 'remaining'])
 380
 381
 382 dnl
 383 dnl build options
 384 dnl
 385
 386 AC_ARG_ENABLE(werror,
 387         AS_HELP_STRING([--enable-werror],
 388                 [Treat warnings as errors (default: disabled)]),
 389         ENABLE_WERROR=$enableval,
 390         ENABLE_WERROR=no)
 391
 392 if test "x$ENABLE_WERROR" = xyes; then
 393         AM_CFLAGS="$AM_CFLAGS -Werror"
 394 fi
 395
 396 AC_ARG_ENABLE(debug,
 397         AS_HELP_STRING([--enable-debug],
 398                 [Enable debugging (default: disabled)]),
 399         ENABLE_DEBUG=$enableval,
 400         ENABLE_DEBUG=no)
 401
 402 if test "x$ENABLE_DEBUG" = xno; then
 403         AM_CFLAGS="$AM_CFLAGS -DNDEBUG"
 404 fi
 405
 406
 407 dnl
 408 dnl CFLAGS
 409 dnl
 410
 411 AC_SUBST(AM_CFLAGS)
 412
 413 CHECK_CFLAG([-Wall])
 414 CHECK_CFLAG([-Wextra])
 415 CHECK_CFLAG([-Wno-deprecated-declarations])
 416 CHECK_CFLAG([-Wmissing-prototypes])
 417 CHECK_CFLAG([-Wdeclaration-after-statement])
 418 CHECK_CFLAG([-Wshadow])
 419 CHECK_CFLAG([-Wpointer-arith])
 420 CHECK_CFLAG([-Wstrict-prototypes])
 421 CHECK_CFLAG([-Wcast-qual])
 422 CHECK_CFLAG([-Wwrite-strings])
 423
 424
 425 dnl
 426 dnl Generate output files
 427 dnl
 428
 429 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile po/Makefile.in po/Makefile])
 430 AC_OUTPUT