perl/Git.pm

   1 =head1 NAME
   2
   3 Git - Perl interface to the Git version control system
   4
   5 =cut
   6
   7
   8 package Git;
   9
  10 use 5.008;
  11 use strict;
  12
  13
  14 BEGIN {
  15
  16 our ($VERSION, @ISA, @EXPORT, @EXPORT_OK);
  17
  18 # Totally unstable API.
  19 $VERSION = '0.01';
  20
  21
  22 =head1 SYNOPSIS
  23
  24   use Git;
  25
  26   my $version = Git::command_oneline('version');
  27
  28   git_cmd_try { Git::command_noisy('update-server-info') }
  29               '%s failed w/ code %d';
  30
  31   my $repo = Git->repository (Directory => '/srv/git/cogito.git');
  32
  33
  34   my @revs = $repo->command('rev-list', '--since=last monday', '--all');
  35
  36   my ($fh, $c) = $repo->command_output_pipe('rev-list', '--since=last monday', '--all');
  37   my $lastrev = <$fh>; chomp $lastrev;
  38   $repo->command_close_pipe($fh, $c);
  39
  40   my $lastrev = $repo->command_oneline( [ 'rev-list', '--all' ],
  41                                         STDERR => 0 );
  42
  43   my $sha1 = $repo->hash_and_insert_object('file.txt');
  44   my $tempfile = tempfile();
  45   my $size = $repo->cat_blob($sha1, $tempfile);
  46
  47 =cut
  48
  49
  50 require Exporter;
  51
  52 @ISA = qw(Exporter);
  53
  54 @EXPORT = qw(git_cmd_try);
  55
  56 # Methods which can be called as standalone functions as well:
  57 @EXPORT_OK = qw(command command_oneline command_noisy
  58                 command_output_pipe command_input_pipe command_close_pipe
  59                 command_bidi_pipe command_close_bidi_pipe
  60                 version exec_path html_path hash_object git_cmd_try
  61                 remote_refs
  62                 temp_acquire temp_release temp_reset temp_path);
  63
  64
  65 =head1 DESCRIPTION
  66
  67 This module provides Perl scripts easy way to interface the Git version control
  68 system. The modules have an easy and well-tested way to call arbitrary Git
  69 commands; in the future, the interface will also provide specialized methods
  70 for doing easily operations which are not totally trivial to do over
  71 the generic command interface.
  72
  73 While some commands can be executed outside of any context (e.g. 'version'
  74 or 'init'), most operations require a repository context, which in practice
  75 means getting an instance of the Git object using the repository() constructor.
  76 (In the future, we will also get a new_repository() constructor.) All commands
  77 called as methods of the object are then executed in the context of the
  78 repository.
  79
  80 Part of the "repository state" is also information about path to the attached
  81 working copy (unless you work with a bare repository). You can also navigate
  82 inside of the working copy using the C<wc_chdir()> method. (Note that
  83 the repository object is self-contained and will not change working directory
  84 of your process.)
  85
  86 TODO: In the future, we might also do
  87
  88         my $remoterepo = $repo->remote_repository (Name => 'cogito', Branch => 'master');
  89         $remoterepo ||= Git->remote_repository ('http://git.or.cz/cogito.git/');
  90         my @refs = $remoterepo->refs();
  91
  92 Currently, the module merely wraps calls to external Git tools. In the future,
  93 it will provide a much faster way to interact with Git by linking directly
  94 to libgit. This should be completely opaque to the user, though (performance
  95 increase notwithstanding).
  96
  97 =cut
  98
  99
 100 use Carp qw(carp croak); # but croak is bad - throw instead
 101 use Error qw(:try);
 102 use Cwd qw(abs_path cwd);
 103 use IPC::Open2 qw(open2);
 104 use Fcntl qw(SEEK_SET SEEK_CUR);
 105 }
 106
 107
 108 =head1 CONSTRUCTORS
 109
 110 =over 4
 111
 112 =item repository ( OPTIONS )
 113
 114 =item repository ( DIRECTORY )
 115
 116 =item repository ()
 117
 118 Construct a new repository object.
 119 C<OPTIONS> are passed in a hash like fashion, using key and value pairs.
 120 Possible options are:
 121
 122 B<Repository> - Path to the Git repository.
 123
 124 B<WorkingCopy> - Path to the associated working copy; not strictly required
 125 as many commands will happily crunch on a bare repository.
 126
 127 B<WorkingSubdir> - Subdirectory in the working copy to work inside.
 128 Just left undefined if you do not want to limit the scope of operations.
 129
 130 B<Directory> - Path to the Git working directory in its usual setup.
 131 The C<.git> directory is searched in the directory and all the parent
 132 directories; if found, C<WorkingCopy> is set to the directory containing
 133 it and C<Repository> to the C<.git> directory itself. If no C<.git>
 134 directory was found, the C<Directory> is assumed to be a bare repository,
 135 C<Repository> is set to point at it and C<WorkingCopy> is left undefined.
 136 If the C<$GIT_DIR> environment variable is set, things behave as expected
 137 as well.
 138
 139 You should not use both C<Directory> and either of C<Repository> and
 140 C<WorkingCopy> - the results of that are undefined.
 141
 142 Alternatively, a directory path may be passed as a single scalar argument
 143 to the constructor; it is equivalent to setting only the C<Directory> option
 144 field.
 145
 146 Calling the constructor with no options whatsoever is equivalent to
 147 calling it with C<< Directory => '.' >>. In general, if you are building
 148 a standard porcelain command, simply doing C<< Git->repository() >> should
 149 do the right thing and setup the object to reflect exactly where the user
 150 is right now.
 151
 152 =cut
 153
 154 sub repository {
 155         my $class = shift;
 156         my @args = @_;
 157         my %opts = ();
 158         my $self;
 159
 160         if (defined $args[0]) {
 161                 if ($#args % 2 != 1) {
 162                         # Not a hash.
 163                         $#args == 0 or throw Error::Simple("bad usage");
 164                         %opts = ( Directory => $args[0] );
 165                 } else {
 166                         %opts = @args;
 167                 }
 168         }
 169
 170         if (not defined $opts{Repository} and not defined $opts{WorkingCopy}
 171                 and not defined $opts{Directory}) {
 172                 $opts{Directory} = '.';
 173         }
 174
 175         if (defined $opts{Directory}) {
 176                 -d $opts{Directory} or throw Error::Simple("Directory not found: $opts{Directory} $!");
 177
 178                 my $search = Git->repository(WorkingCopy => $opts{Directory});
 179                 my $dir;
 180                 try {
 181                         $dir = $search->command_oneline(['rev-parse', '--git-dir'],
 182                                                         STDERR => 0);
 183                 } catch Git::Error::Command with {
 184                         $dir = undef;
 185                 };
 186
 187                 if ($dir) {
 188                         $dir =~ m#^/# or $dir = $opts{Directory} . '/' . $dir;
 189                         $opts{Repository} = abs_path($dir);
 190
 191                         # If --git-dir went ok, this shouldn't die either.
 192                         my $prefix = $search->command_oneline('rev-parse', '--show-prefix');
 193                         $dir = abs_path($opts{Directory}) . '/';
 194                         if ($prefix) {
 195                                 if (substr($dir, -length($prefix)) ne $prefix) {
 196                                         throw Error::Simple("rev-parse confused me - $dir does not have trailing $prefix");
 197                                 }
 198                                 substr($dir, -length($prefix)) = '';
 199                         }
 200                         $opts{WorkingCopy} = $dir;
 201                         $opts{WorkingSubdir} = $prefix;
 202
 203                 } else {
 204                         # A bare repository? Let's see...
 205                         $dir = $opts{Directory};
 206
 207                         unless (-d "$dir/refs" and -d "$dir/objects" and -e "$dir/HEAD") {
 208                                 # Mimic git-rev-parse --git-dir error message:
 209                                 throw Error::Simple("fatal: Not a git repository: $dir");
 210                         }
 211                         my $search = Git->repository(Repository => $dir);
 212                         try {
 213                                 $search->command('symbolic-ref', 'HEAD');
 214                         } catch Git::Error::Command with {
 215                                 # Mimic git-rev-parse --git-dir error message:
 216                                 throw Error::Simple("fatal: Not a git repository: $dir");
 217                         }
 218
 219                         $opts{Repository} = abs_path($dir);
 220                 }
 221
 222                 delete $opts{Directory};
 223         }
 224
 225         $self = { opts => \%opts };
 226         bless $self, $class;
 227 }
 228
 229 =back
 230
 231 =head1 METHODS
 232
 233 =over 4
 234
 235 =item command ( COMMAND [, ARGUMENTS... ] )
 236
 237 =item command ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 238
 239 Execute the given Git C<COMMAND> (specify it without the 'git-'
 240 prefix), optionally with the specified extra C<ARGUMENTS>.
 241
 242 The second more elaborate form can be used if you want to further adjust
 243 the command execution. Currently, only one option is supported:
 244
 245 B<STDERR> - How to deal with the command's error output. By default (C<undef>)
 246 it is delivered to the caller's C<STDERR>. A false value (0 or '') will cause
 247 it to be thrown away. If you want to process it, you can get it in a filehandle
 248 you specify, but you must be extremely careful; if the error output is not
 249 very short and you want to read it in the same process as where you called
 250 C<command()>, you are set up for a nice deadlock!
 251
 252 The method can be called without any instance or on a specified Git repository
 253 (in that case the command will be run in the repository context).
 254
 255 In scalar context, it returns all the command output in a single string
 256 (verbatim).
 257
 258 In array context, it returns an array containing lines printed to the
 259 command's stdout (without trailing newlines).
 260
 261 In both cases, the command's stdin and stderr are the same as the caller's.
 262
 263 =cut
 264
 265 sub command {
 266         my ($fh, $ctx) = command_output_pipe(@_);
 267
 268         if (not defined wantarray) {
 269                 # Nothing to pepper the possible exception with.
 270                 _cmd_close($fh, $ctx);
 271
 272         } elsif (not wantarray) {
 273                 local $/;
 274                 my $text = <$fh>;
 275                 try {
 276                         _cmd_close($fh, $ctx);
 277                 } catch Git::Error::Command with {
 278                         # Pepper with the output:
 279                         my $E = shift;
 280                         $E->{'-outputref'} = \$text;
 281                         throw $E;
 282                 };
 283                 return $text;
 284
 285         } else {
 286                 my @lines = <$fh>;
 287                 defined and chomp for @lines;
 288                 try {
 289                         _cmd_close($fh, $ctx);
 290                 } catch Git::Error::Command with {
 291                         my $E = shift;
 292                         $E->{'-outputref'} = \@lines;
 293                         throw $E;
 294                 };
 295                 return @lines;
 296         }
 297 }
 298
 299
 300 =item command_oneline ( COMMAND [, ARGUMENTS... ] )
 301
 302 =item command_oneline ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 303
 304 Execute the given C<COMMAND> in the same way as command()
 305 does but always return a scalar string containing the first line
 306 of the command's standard output.
 307
 308 =cut
 309
 310 sub command_oneline {
 311         my ($fh, $ctx) = command_output_pipe(@_);
 312
 313         my $line = <$fh>;
 314         defined $line and chomp $line;
 315         try {
 316                 _cmd_close($fh, $ctx);
 317         } catch Git::Error::Command with {
 318                 # Pepper with the output:
 319                 my $E = shift;
 320                 $E->{'-outputref'} = \$line;
 321                 throw $E;
 322         };
 323         return $line;
 324 }
 325
 326
 327 =item command_output_pipe ( COMMAND [, ARGUMENTS... ] )
 328
 329 =item command_output_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 330
 331 Execute the given C<COMMAND> in the same way as command()
 332 does but return a pipe filehandle from which the command output can be
 333 read.
 334
 335 The function can return C<($pipe, $ctx)> in array context.
 336 See C<command_close_pipe()> for details.
 337
 338 =cut
 339
 340 sub command_output_pipe {
 341         _command_common_pipe('-|', @_);
 342 }
 343
 344
 345 =item command_input_pipe ( COMMAND [, ARGUMENTS... ] )
 346
 347 =item command_input_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 348
 349 Execute the given C<COMMAND> in the same way as command_output_pipe()
 350 does but return an input pipe filehandle instead; the command output
 351 is not captured.
 352
 353 The function can return C<($pipe, $ctx)> in array context.
 354 See C<command_close_pipe()> for details.
 355
 356 =cut
 357
 358 sub command_input_pipe {
 359         _command_common_pipe('|-', @_);
 360 }
 361
 362
 363 =item command_close_pipe ( PIPE [, CTX ] )
 364
 365 Close the C<PIPE> as returned from C<command_*_pipe()>, checking
 366 whether the command finished successfully. The optional C<CTX> argument
 367 is required if you want to see the command name in the error message,
 368 and it is the second value returned by C<command_*_pipe()> when
 369 called in array context. The call idiom is:
 370
 371         my ($fh, $ctx) = $r->command_output_pipe('status');
 372         while (<$fh>) { ... }
 373         $r->command_close_pipe($fh, $ctx);
 374
 375 Note that you should not rely on whatever actually is in C<CTX>;
 376 currently it is simply the command name but in future the context might
 377 have more complicated structure.
 378
 379 =cut
 380
 381 sub command_close_pipe {
 382         my ($self, $fh, $ctx) = _maybe_self(@_);
 383         $ctx ||= '<unknown>';
 384         _cmd_close($fh, $ctx);
 385 }
 386
 387 =item command_bidi_pipe ( COMMAND [, ARGUMENTS... ] )
 388
 389 Execute the given C<COMMAND> in the same way as command_output_pipe()
 390 does but return both an input pipe filehandle and an output pipe filehandle.
 391
 392 The function will return return C<($pid, $pipe_in, $pipe_out, $ctx)>.
 393 See C<command_close_bidi_pipe()> for details.
 394
 395 =cut
 396
 397 sub command_bidi_pipe {
 398         my ($pid, $in, $out);
 399         my ($self) = _maybe_self(@_);
 400         local %ENV = %ENV;
 401         my $cwd_save = undef;
 402         if ($self) {
 403                 shift;
 404                 $cwd_save = cwd();
 405                 _setup_git_cmd_env($self);
 406         }
 407         $pid = open2($in, $out, 'git', @_);
 408         chdir($cwd_save) if $cwd_save;
 409         return ($pid, $in, $out, join(' ', @_));
 410 }
 411
 412 =item command_close_bidi_pipe ( PID, PIPE_IN, PIPE_OUT [, CTX] )
 413
 414 Close the C<PIPE_IN> and C<PIPE_OUT> as returned from C<command_bidi_pipe()>,
 415 checking whether the command finished successfully. The optional C<CTX>
 416 argument is required if you want to see the command name in the error message,
 417 and it is the fourth value returned by C<command_bidi_pipe()>.  The call idiom
 418 is:
 419
 420         my ($pid, $in, $out, $ctx) = $r->command_bidi_pipe('cat-file --batch-check');
 421         print "000000000\n" $out;
 422         while (<$in>) { ... }
 423         $r->command_close_bidi_pipe($pid, $in, $out, $ctx);
 424
 425 Note that you should not rely on whatever actually is in C<CTX>;
 426 currently it is simply the command name but in future the context might
 427 have more complicated structure.
 428
 429 =cut
 430
 431 sub command_close_bidi_pipe {
 432         local $?;
 433         my ($pid, $in, $out, $ctx) = @_;
 434         foreach my $fh ($in, $out) {
 435                 unless (close $fh) {
 436                         if ($!) {
 437                                 carp "error closing pipe: $!";
 438                         } elsif ($? >> 8) {
 439                                 throw Git::Error::Command($ctx, $? >>8);
 440                         }
 441                 }
 442         }
 443
 444         waitpid $pid, 0;
 445
 446         if ($? >> 8) {
 447                 throw Git::Error::Command($ctx, $? >>8);
 448         }
 449 }
 450
 451
 452 =item command_noisy ( COMMAND [, ARGUMENTS... ] )
 453
 454 Execute the given C<COMMAND> in the same way as command() does but do not
 455 capture the command output - the standard output is not redirected and goes
 456 to the standard output of the caller application.
 457
 458 While the method is called command_noisy(), you might want to as well use
 459 it for the most silent Git commands which you know will never pollute your
 460 stdout but you want to avoid the overhead of the pipe setup when calling them.
 461
 462 The function returns only after the command has finished running.
 463
 464 =cut
 465
 466 sub command_noisy {
 467         my ($self, $cmd, @args) = _maybe_self(@_);
 468         _check_valid_cmd($cmd);
 469
 470         my $pid = fork;
 471         if (not defined $pid) {
 472                 throw Error::Simple("fork failed: $!");
 473         } elsif ($pid == 0) {
 474                 _cmd_exec($self, $cmd, @args);
 475         }
 476         if (waitpid($pid, 0) > 0 and $?>>8 != 0) {
 477                 throw Git::Error::Command(join(' ', $cmd, @args), $? >> 8);
 478         }
 479 }
 480
 481
 482 =item version ()
 483
 484 Return the Git version in use.
 485
 486 =cut
 487
 488 sub version {
 489         my $verstr = command_oneline('--version');
 490         $verstr =~ s/^git version //;
 491         $verstr;
 492 }
 493
 494
 495 =item exec_path ()
 496
 497 Return path to the Git sub-command executables (the same as
 498 C<git --exec-path>). Useful mostly only internally.
 499
 500 =cut
 501
 502 sub exec_path { command_oneline('--exec-path') }
 503
 504
 505 =item html_path ()
 506
 507 Return path to the Git html documentation (the same as
 508 C<git --html-path>). Useful mostly only internally.
 509
 510 =cut
 511
 512 sub html_path { command_oneline('--html-path') }
 513
 514
 515 =item repo_path ()
 516
 517 Return path to the git repository. Must be called on a repository instance.
 518
 519 =cut
 520
 521 sub repo_path { $_[0]->{opts}->{Repository} }
 522
 523
 524 =item wc_path ()
 525
 526 Return path to the working copy. Must be called on a repository instance.
 527
 528 =cut
 529
 530 sub wc_path { $_[0]->{opts}->{WorkingCopy} }
 531
 532
 533 =item wc_subdir ()
 534
 535 Return path to the subdirectory inside of a working copy. Must be called
 536 on a repository instance.
 537
 538 =cut
 539
 540 sub wc_subdir { $_[0]->{opts}->{WorkingSubdir} ||= '' }
 541
 542
 543 =item wc_chdir ( SUBDIR )
 544
 545 Change the working copy subdirectory to work within. The C<SUBDIR> is
 546 relative to the working copy root directory (not the current subdirectory).
 547 Must be called on a repository instance attached to a working copy
 548 and the directory must exist.
 549
 550 =cut
 551
 552 sub wc_chdir {
 553         my ($self, $subdir) = @_;
 554         $self->wc_path()
 555                 or throw Error::Simple("bare repository");
 556
 557         -d $self->wc_path().'/'.$subdir
 558                 or throw Error::Simple("subdir not found: $subdir $!");
 559         # Of course we will not "hold" the subdirectory so anyone
 560         # can delete it now and we will never know. But at least we tried.
 561
 562         $self->{opts}->{WorkingSubdir} = $subdir;
 563 }
 564
 565
 566 =item config ( VARIABLE )
 567
 568 Retrieve the configuration C<VARIABLE> in the same manner as C<config>
 569 does. In scalar context requires the variable to be set only one time
 570 (exception is thrown otherwise), in array context returns allows the
 571 variable to be set multiple times and returns all the values.
 572
 573 =cut
 574
 575 sub config {
 576         return _config_common({}, @_);
 577 }
 578
 579
 580 =item config_bool ( VARIABLE )
 581
 582 Retrieve the bool configuration C<VARIABLE>. The return value
 583 is usable as a boolean in perl (and C<undef> if it's not defined,
 584 of course).
 585
 586 =cut
 587
 588 sub config_bool {
 589         my $val = scalar _config_common({'kind' => '--bool'}, @_);
 590
 591         # Do not rewrite this as return (defined $val && $val eq 'true')
 592         # as some callers do care what kind of falsehood they receive.
 593         if (!defined $val) {
 594                 return undef;
 595         } else {
 596                 return $val eq 'true';
 597         }
 598 }
 599
 600
 601 =item config_path ( VARIABLE )
 602
 603 Retrieve the path configuration C<VARIABLE>. The return value
 604 is an expanded path or C<undef> if it's not defined.
 605
 606 =cut
 607
 608 sub config_path {
 609         return _config_common({'kind' => '--path'}, @_);
 610 }
 611
 612
 613 =item config_int ( VARIABLE )
 614
 615 Retrieve the integer configuration C<VARIABLE>. The return value
 616 is simple decimal number.  An optional value suffix of 'k', 'm',
 617 or 'g' in the config file will cause the value to be multiplied
 618 by 1024, 1048576 (1024^2), or 1073741824 (1024^3) prior to output.
 619 It would return C<undef> if configuration variable is not defined,
 620
 621 =cut
 622
 623 sub config_int {
 624         return scalar _config_common({'kind' => '--int'}, @_);
 625 }
 626
 627 # Common subroutine to implement bulk of what the config* family of methods
 628 # do. This curently wraps command('config') so it is not so fast.
 629 sub _config_common {
 630         my ($opts) = shift @_;
 631         my ($self, $var) = _maybe_self(@_);
 632
 633         try {
 634                 my @cmd = ('config', $opts->{'kind'} ? $opts->{'kind'} : ());
 635                 unshift @cmd, $self if $self;
 636                 if (wantarray) {
 637                         return command(@cmd, '--get-all', $var);
 638                 } else {
 639                         return command_oneline(@cmd, '--get', $var);
 640                 }
 641         } catch Git::Error::Command with {
 642                 my $E = shift;
 643                 if ($E->value() == 1) {
 644                         # Key not found.
 645                         return;
 646                 } else {
 647                         throw $E;
 648                 }
 649         };
 650 }
 651
 652 =item get_colorbool ( NAME )
 653
 654 Finds if color should be used for NAMEd operation from the configuration,
 655 and returns boolean (true for "use color", false for "do not use color").
 656
 657 =cut
 658
 659 sub get_colorbool {
 660         my ($self, $var) = @_;
 661         my $stdout_to_tty = (-t STDOUT) ? "true" : "false";
 662         my $use_color = $self->command_oneline('config', '--get-colorbool',
 663                                                $var, $stdout_to_tty);
 664         return ($use_color eq 'true');
 665 }
 666
 667 =item get_color ( SLOT, COLOR )
 668
 669 Finds color for SLOT from the configuration, while defaulting to COLOR,
 670 and returns the ANSI color escape sequence:
 671
 672         print $repo->get_color("color.interactive.prompt", "underline blue white");
 673         print "some text";
 674         print $repo->get_color("", "normal");
 675
 676 =cut
 677
 678 sub get_color {
 679         my ($self, $slot, $default) = @_;
 680         my $color = $self->command_oneline('config', '--get-color', $slot, $default);
 681         if (!defined $color) {
 682                 $color = "";
 683         }
 684         return $color;
 685 }
 686
 687 =item remote_refs ( REPOSITORY [, GROUPS [, REFGLOBS ] ] )
 688
 689 This function returns a hashref of refs stored in a given remote repository.
 690 The hash is in the format C<refname =\> hash>. For tags, the C<refname> entry
 691 contains the tag object while a C<refname^{}> entry gives the tagged objects.
 692
 693 C<REPOSITORY> has the same meaning as the appropriate C<git-ls-remote>
 694 argument; either a URL or a remote name (if called on a repository instance).
 695 C<GROUPS> is an optional arrayref that can contain 'tags' to return all the
 696 tags and/or 'heads' to return all the heads. C<REFGLOB> is an optional array
 697 of strings containing a shell-like glob to further limit the refs returned in
 698 the hash; the meaning is again the same as the appropriate C<git-ls-remote>
 699 argument.
 700
 701 This function may or may not be called on a repository instance. In the former
 702 case, remote names as defined in the repository are recognized as repository
 703 specifiers.
 704
 705 =cut
 706
 707 sub remote_refs {
 708         my ($self, $repo, $groups, $refglobs) = _maybe_self(@_);
 709         my @args;
 710         if (ref $groups eq 'ARRAY') {
 711                 foreach (@$groups) {
 712                         if ($_ eq 'heads') {
 713                                 push (@args, '--heads');
 714                         } elsif ($_ eq 'tags') {
 715                                 push (@args, '--tags');
 716                         } else {
 717                                 # Ignore unknown groups for future
 718                                 # compatibility
 719                         }
 720                 }
 721         }
 722         push (@args, $repo);
 723         if (ref $refglobs eq 'ARRAY') {
 724                 push (@args, @$refglobs);
 725         }
 726
 727         my @self = $self ? ($self) : (); # Ultra trickery
 728         my ($fh, $ctx) = Git::command_output_pipe(@self, 'ls-remote', @args);
 729         my %refs;
 730         while (<$fh>) {
 731                 chomp;
 732                 my ($hash, $ref) = split(/\t/, $_, 2);
 733                 $refs{$ref} = $hash;
 734         }
 735         Git::command_close_pipe(@self, $fh, $ctx);
 736         return \%refs;
 737 }
 738
 739
 740 =item ident ( TYPE | IDENTSTR )
 741
 742 =item ident_person ( TYPE | IDENTSTR | IDENTARRAY )
 743
 744 This suite of functions retrieves and parses ident information, as stored
 745 in the commit and tag objects or produced by C<var GIT_type_IDENT> (thus
 746 C<TYPE> can be either I<author> or I<committer>; case is insignificant).
 747
 748 The C<ident> method retrieves the ident information from C<git var>
 749 and either returns it as a scalar string or as an array with the fields parsed.
 750 Alternatively, it can take a prepared ident string (e.g. from the commit
 751 object) and just parse it.
 752
 753 C<ident_person> returns the person part of the ident - name and email;
 754 it can take the same arguments as C<ident> or the array returned by C<ident>.
 755
 756 The synopsis is like:
 757
 758         my ($name, $email, $time_tz) = ident('author');
 759         "$name <$email>" eq ident_person('author');
 760         "$name <$email>" eq ident_person($name);
 761         $time_tz =~ /^\d+ [+-]\d{4}$/;
 762
 763 =cut
 764
 765 sub ident {
 766         my ($self, $type) = _maybe_self(@_);
 767         my $identstr;
 768         if (lc $type eq lc 'committer' or lc $type eq lc 'author') {
 769                 my @cmd = ('var', 'GIT_'.uc($type).'_IDENT');
 770                 unshift @cmd, $self if $self;
 771                 $identstr = command_oneline(@cmd);
 772         } else {
 773                 $identstr = $type;
 774         }
 775         if (wantarray) {
 776                 return $identstr =~ /^(.*) <(.*)> (\d+ [+-]\d{4})$/;
 777         } else {
 778                 return $identstr;
 779         }
 780 }
 781
 782 sub ident_person {
 783         my ($self, @ident) = _maybe_self(@_);
 784         $#ident == 0 and @ident = $self ? $self->ident($ident[0]) : ident($ident[0]);
 785         return "$ident[0] <$ident[1]>";
 786 }
 787
 788
 789 =item hash_object ( TYPE, FILENAME )
 790
 791 Compute the SHA1 object id of the given C<FILENAME> considering it is
 792 of the C<TYPE> object type (C<blob>, C<commit>, C<tree>).
 793
 794 The method can be called without any instance or on a specified Git repository,
 795 it makes zero difference.
 796
 797 The function returns the SHA1 hash.
 798
 799 =cut
 800
 801 # TODO: Support for passing FILEHANDLE instead of FILENAME
 802 sub hash_object {
 803         my ($self, $type, $file) = _maybe_self(@_);
 804         command_oneline('hash-object', '-t', $type, $file);
 805 }
 806
 807
 808 =item hash_and_insert_object ( FILENAME )
 809
 810 Compute the SHA1 object id of the given C<FILENAME> and add the object to the
 811 object database.
 812
 813 The function returns the SHA1 hash.
 814
 815 =cut
 816
 817 # TODO: Support for passing FILEHANDLE instead of FILENAME
 818 sub hash_and_insert_object {
 819         my ($self, $filename) = @_;
 820
 821         carp "Bad filename \"$filename\"" if $filename =~ /[\r\n]/;
 822
 823         $self->_open_hash_and_insert_object_if_needed();
 824         my ($in, $out) = ($self->{hash_object_in}, $self->{hash_object_out});
 825
 826         unless (print $out $filename, "\n") {
 827                 $self->_close_hash_and_insert_object();
 828                 throw Error::Simple("out pipe went bad");
 829         }
 830
 831         chomp(my $hash = <$in>);
 832         unless (defined($hash)) {
 833                 $self->_close_hash_and_insert_object();
 834                 throw Error::Simple("in pipe went bad");
 835         }
 836
 837         return $hash;
 838 }
 839
 840 sub _open_hash_and_insert_object_if_needed {
 841         my ($self) = @_;
 842
 843         return if defined($self->{hash_object_pid});
 844
 845         ($self->{hash_object_pid}, $self->{hash_object_in},
 846          $self->{hash_object_out}, $self->{hash_object_ctx}) =
 847                 $self->command_bidi_pipe(qw(hash-object -w --stdin-paths --no-filters));
 848 }
 849
 850 sub _close_hash_and_insert_object {
 851         my ($self) = @_;
 852
 853         return unless defined($self->{hash_object_pid});
 854
 855         my @vars = map { 'hash_object_' . $_ } qw(pid in out ctx);
 856
 857         command_close_bidi_pipe(@$self{@vars});
 858         delete @$self{@vars};
 859 }
 860
 861 =item cat_blob ( SHA1, FILEHANDLE )
 862
 863 Prints the contents of the blob identified by C<SHA1> to C<FILEHANDLE> and
 864 returns the number of bytes printed.
 865
 866 =cut
 867
 868 sub cat_blob {
 869         my ($self, $sha1, $fh) = @_;
 870
 871         $self->_open_cat_blob_if_needed();
 872         my ($in, $out) = ($self->{cat_blob_in}, $self->{cat_blob_out});
 873
 874         unless (print $out $sha1, "\n") {
 875                 $self->_close_cat_blob();
 876                 throw Error::Simple("out pipe went bad");
 877         }
 878
 879         my $description = <$in>;
 880         if ($description =~ / missing$/) {
 881                 carp "$sha1 doesn't exist in the repository";
 882                 return -1;
 883         }
 884
 885         if ($description !~ /^[0-9a-fA-F]{40} \S+ (\d+)$/) {
 886                 carp "Unexpected result returned from git cat-file";
 887                 return -1;
 888         }
 889
 890         my $size = $1;
 891
 892         my $blob;
 893         my $bytesRead = 0;
 894
 895         while (1) {
 896                 my $bytesLeft = $size - $bytesRead;
 897                 last unless $bytesLeft;
 898
 899                 my $bytesToRead = $bytesLeft < 1024 ? $bytesLeft : 1024;
 900                 my $read = read($in, $blob, $bytesToRead, $bytesRead);
 901                 unless (defined($read)) {
 902                         $self->_close_cat_blob();
 903                         throw Error::Simple("in pipe went bad");
 904                 }
 905
 906                 $bytesRead += $read;
 907         }
 908
 909         # Skip past the trailing newline.
 910         my $newline;
 911         my $read = read($in, $newline, 1);
 912         unless (defined($read)) {
 913                 $self->_close_cat_blob();
 914                 throw Error::Simple("in pipe went bad");
 915         }
 916         unless ($read == 1 && $newline eq "\n") {
 917                 $self->_close_cat_blob();
 918                 throw Error::Simple("didn't find newline after blob");
 919         }
 920
 921         unless (print $fh $blob) {
 922                 $self->_close_cat_blob();
 923                 throw Error::Simple("couldn't write to passed in filehandle");
 924         }
 925
 926         return $size;
 927 }
 928
 929 sub _open_cat_blob_if_needed {
 930         my ($self) = @_;
 931
 932         return if defined($self->{cat_blob_pid});
 933
 934         ($self->{cat_blob_pid}, $self->{cat_blob_in},
 935          $self->{cat_blob_out}, $self->{cat_blob_ctx}) =
 936                 $self->command_bidi_pipe(qw(cat-file --batch));
 937 }
 938
 939 sub _close_cat_blob {
 940         my ($self) = @_;
 941
 942         return unless defined($self->{cat_blob_pid});
 943
 944         my @vars = map { 'cat_blob_' . $_ } qw(pid in out ctx);
 945
 946         command_close_bidi_pipe(@$self{@vars});
 947         delete @$self{@vars};
 948 }
 949
 950
 951 { # %TEMP_* Lexical Context
 952
 953 my (%TEMP_FILEMAP, %TEMP_FILES);
 954
 955 =item temp_acquire ( NAME )
 956
 957 Attempts to retreive the temporary file mapped to the string C<NAME>. If an
 958 associated temp file has not been created this session or was closed, it is
 959 created, cached, and set for autoflush and binmode.
 960
 961 Internally locks the file mapped to C<NAME>. This lock must be released with
 962 C<temp_release()> when the temp file is no longer needed. Subsequent attempts
 963 to retrieve temporary files mapped to the same C<NAME> while still locked will
 964 cause an error. This locking mechanism provides a weak guarantee and is not
 965 threadsafe. It does provide some error checking to help prevent temp file refs
 966 writing over one another.
 967
 968 In general, the L<File::Handle> returned should not be closed by consumers as
 969 it defeats the purpose of this caching mechanism. If you need to close the temp
 970 file handle, then you should use L<File::Temp> or another temp file faculty
 971 directly. If a handle is closed and then requested again, then a warning will
 972 issue.
 973
 974 =cut
 975
 976 sub temp_acquire {
 977         my $temp_fd = _temp_cache(@_);
 978
 979         $TEMP_FILES{$temp_fd}{locked} = 1;
 980         $temp_fd;
 981 }
 982
 983 =item temp_release ( NAME )
 984
 985 =item temp_release ( FILEHANDLE )
 986
 987 Releases a lock acquired through C<temp_acquire()>. Can be called either with
 988 the C<NAME> mapping used when acquiring the temp file or with the C<FILEHANDLE>
 989 referencing a locked temp file.
 990
 991 Warns if an attempt is made to release a file that is not locked.
 992
 993 The temp file will be truncated before being released. This can help to reduce
 994 disk I/O where the system is smart enough to detect the truncation while data
 995 is in the output buffers. Beware that after the temp file is released and
 996 truncated, any operations on that file may fail miserably until it is
 997 re-acquired. All contents are lost between each release and acquire mapped to
 998 the same string.
 999
1000 =cut
1001
1002 sub temp_release {
1003         my ($self, $temp_fd, $trunc) = _maybe_self(@_);
1004
1005         if (exists $TEMP_FILEMAP{$temp_fd}) {
1006                 $temp_fd = $TEMP_FILES{$temp_fd};
1007         }
1008         unless ($TEMP_FILES{$temp_fd}{locked}) {
1009                 carp "Attempt to release temp file '",
1010                         $temp_fd, "' that has not been locked";
1011         }
1012         temp_reset($temp_fd) if $trunc and $temp_fd->opened;
1013
1014         $TEMP_FILES{$temp_fd}{locked} = 0;
1015         undef;
1016 }
1017
1018 sub _temp_cache {
1019         my ($self, $name) = _maybe_self(@_);
1020
1021         _verify_require();
1022
1023         my $temp_fd = \$TEMP_FILEMAP{$name};
1024         if (defined $$temp_fd and $$temp_fd->opened) {
1025                 if ($TEMP_FILES{$$temp_fd}{locked}) {
1026                         throw Error::Simple("Temp file with moniker '" .
1027                                 $name . "' already in use");
1028                 }
1029         } else {
1030                 if (defined $$temp_fd) {
1031                         # then we're here because of a closed handle.
1032                         carp "Temp file '", $name,
1033                                 "' was closed. Opening replacement.";
1034                 }
1035                 my $fname;
1036
1037                 my $tmpdir;
1038                 if (defined $self) {
1039                         $tmpdir = $self->repo_path();
1040                 }
1041
1042                 ($$temp_fd, $fname) = File::Temp->tempfile(
1043                         'Git_XXXXXX', UNLINK => 1, DIR => $tmpdir,
1044                         ) or throw Error::Simple("couldn't open new temp file");
1045
1046                 $$temp_fd->autoflush;
1047                 binmode $$temp_fd;
1048                 $TEMP_FILES{$$temp_fd}{fname} = $fname;
1049         }
1050         $$temp_fd;
1051 }
1052
1053 sub _verify_require {
1054         eval { require File::Temp; require File::Spec; };
1055         $@ and throw Error::Simple($@);
1056 }
1057
1058 =item temp_reset ( FILEHANDLE )
1059
1060 Truncates and resets the position of the C<FILEHANDLE>.
1061
1062 =cut
1063
1064 sub temp_reset {
1065         my ($self, $temp_fd) = _maybe_self(@_);
1066
1067         truncate $temp_fd, 0
1068                 or throw Error::Simple("couldn't truncate file");
1069         sysseek($temp_fd, 0, SEEK_SET) and seek($temp_fd, 0, SEEK_SET)
1070                 or throw Error::Simple("couldn't seek to beginning of file");
1071         sysseek($temp_fd, 0, SEEK_CUR) == 0 and tell($temp_fd) == 0
1072                 or throw Error::Simple("expected file position to be reset");
1073 }
1074
1075 =item temp_path ( NAME )
1076
1077 =item temp_path ( FILEHANDLE )
1078
1079 Returns the filename associated with the given tempfile.
1080
1081 =cut
1082
1083 sub temp_path {
1084         my ($self, $temp_fd) = _maybe_self(@_);
1085
1086         if (exists $TEMP_FILEMAP{$temp_fd}) {
1087                 $temp_fd = $TEMP_FILEMAP{$temp_fd};
1088         }
1089         $TEMP_FILES{$temp_fd}{fname};
1090 }
1091
1092 sub END {
1093         unlink values %TEMP_FILEMAP if %TEMP_FILEMAP;
1094 }
1095
1096 } # %TEMP_* Lexical Context
1097
1098 =back
1099
1100 =head1 ERROR HANDLING
1101
1102 All functions are supposed to throw Perl exceptions in case of errors.
1103 See the L<Error> module on how to catch those. Most exceptions are mere
1104 L<Error::Simple> instances.
1105
1106 However, the C<command()>, C<command_oneline()> and C<command_noisy()>
1107 functions suite can throw C<Git::Error::Command> exceptions as well: those are
1108 thrown when the external command returns an error code and contain the error
1109 code as well as access to the captured command's output. The exception class
1110 provides the usual C<stringify> and C<value> (command's exit code) methods and
1111 in addition also a C<cmd_output> method that returns either an array or a
1112 string with the captured command output (depending on the original function
1113 call context; C<command_noisy()> returns C<undef>) and $<cmdline> which
1114 returns the command and its arguments (but without proper quoting).
1115
1116 Note that the C<command_*_pipe()> functions cannot throw this exception since
1117 it has no idea whether the command failed or not. You will only find out
1118 at the time you C<close> the pipe; if you want to have that automated,
1119 use C<command_close_pipe()>, which can throw the exception.
1120
1121 =cut
1122
1123 {
1124         package Git::Error::Command;
1125
1126         @Git::Error::Command::ISA = qw(Error);
1127
1128         sub new {
1129                 my $self = shift;
1130                 my $cmdline = '' . shift;
1131                 my $value = 0 + shift;
1132                 my $outputref = shift;
1133                 my(@args) = ();
1134
1135                 local $Error::Depth = $Error::Depth + 1;
1136
1137                 push(@args, '-cmdline', $cmdline);
1138                 push(@args, '-value', $value);
1139                 push(@args, '-outputref', $outputref);
1140
1141                 $self->SUPER::new(-text => 'command returned error', @args);
1142         }
1143
1144         sub stringify {
1145                 my $self = shift;
1146                 my $text = $self->SUPER::stringify;
1147                 $self->cmdline() . ': ' . $text . ': ' . $self->value() . "\n";
1148         }
1149
1150         sub cmdline {
1151                 my $self = shift;
1152                 $self->{'-cmdline'};
1153         }
1154
1155         sub cmd_output {
1156                 my $self = shift;
1157                 my $ref = $self->{'-outputref'};
1158                 defined $ref or undef;
1159                 if (ref $ref eq 'ARRAY') {
1160                         return @$ref;
1161                 } else { # SCALAR
1162                         return $$ref;
1163                 }
1164         }
1165 }
1166
1167 =over 4
1168
1169 =item git_cmd_try { CODE } ERRMSG
1170
1171 This magical statement will automatically catch any C<Git::Error::Command>
1172 exceptions thrown by C<CODE> and make your program die with C<ERRMSG>
1173 on its lips; the message will have %s substituted for the command line
1174 and %d for the exit status. This statement is useful mostly for producing
1175 more user-friendly error messages.
1176
1177 In case of no exception caught the statement returns C<CODE>'s return value.
1178
1179 Note that this is the only auto-exported function.
1180
1181 =cut
1182
1183 sub git_cmd_try(&$) {
1184         my ($code, $errmsg) = @_;
1185         my @result;
1186         my $err;
1187         my $array = wantarray;
1188         try {
1189                 if ($array) {
1190                         @result = &$code;
1191                 } else {
1192                         $result[0] = &$code;
1193                 }
1194         } catch Git::Error::Command with {
1195                 my $E = shift;
1196                 $err = $errmsg;
1197                 $err =~ s/\%s/$E->cmdline()/ge;
1198                 $err =~ s/\%d/$E->value()/ge;
1199                 # We can't croak here since Error.pm would mangle
1200                 # that to Error::Simple.
1201         };
1202         $err and croak $err;
1203         return $array ? @result : $result[0];
1204 }
1205
1206
1207 =back
1208
1209 =head1 COPYRIGHT
1210
1211 Copyright 2006 by Petr Baudis E<lt>pasky@suse.czE<gt>.
1212
1213 This module is free software; it may be used, copied, modified
1214 and distributed under the terms of the GNU General Public Licence,
1215 either version 2, or (at your option) any later version.
1216
1217 =cut
1218
1219
1220 # Take raw method argument list and return ($obj, @args) in case
1221 # the method was called upon an instance and (undef, @args) if
1222 # it was called directly.
1223 sub _maybe_self {
1224         UNIVERSAL::isa($_[0], 'Git') ? @_ : (undef, @_);
1225 }
1226
1227 # Check if the command id is something reasonable.
1228 sub _check_valid_cmd {
1229         my ($cmd) = @_;
1230         $cmd =~ /^[a-z0-9A-Z_-]+$/ or throw Error::Simple("bad command: $cmd");
1231 }
1232
1233 # Common backend for the pipe creators.
1234 sub _command_common_pipe {
1235         my $direction = shift;
1236         my ($self, @p) = _maybe_self(@_);
1237         my (%opts, $cmd, @args);
1238         if (ref $p[0]) {
1239                 ($cmd, @args) = @{shift @p};
1240                 %opts = ref $p[0] ? %{$p[0]} : @p;
1241         } else {
1242                 ($cmd, @args) = @p;
1243         }
1244         _check_valid_cmd($cmd);
1245
1246         my $fh;
1247         if ($^O eq 'MSWin32') {
1248                 # ActiveState Perl
1249                 #defined $opts{STDERR} and
1250                 #       warn 'ignoring STDERR option - running w/ ActiveState';
1251                 $direction eq '-|' or
1252                         die 'input pipe for ActiveState not implemented';
1253                 # the strange construction with *ACPIPE is just to
1254                 # explain the tie below that we want to bind to
1255                 # a handle class, not scalar. It is not known if
1256                 # it is something specific to ActiveState Perl or
1257                 # just a Perl quirk.
1258                 tie (*ACPIPE, 'Git::activestate_pipe', $cmd, @args);
1259                 $fh = *ACPIPE;
1260
1261         } else {
1262                 my $pid = open($fh, $direction);
1263                 if (not defined $pid) {
1264                         throw Error::Simple("open failed: $!");
1265                 } elsif ($pid == 0) {
1266                         if (defined $opts{STDERR}) {
1267                                 close STDERR;
1268                         }
1269                         if ($opts{STDERR}) {
1270                                 open (STDERR, '>&', $opts{STDERR})
1271                                         or die "dup failed: $!";
1272                         }
1273                         _cmd_exec($self, $cmd, @args);
1274                 }
1275         }
1276         return wantarray ? ($fh, join(' ', $cmd, @args)) : $fh;
1277 }
1278
1279 # When already in the subprocess, set up the appropriate state
1280 # for the given repository and execute the git command.
1281 sub _cmd_exec {
1282         my ($self, @args) = @_;
1283         _setup_git_cmd_env($self);
1284         _execv_git_cmd(@args);
1285         die qq[exec "@args" failed: $!];
1286 }
1287
1288 # set up the appropriate state for git command
1289 sub _setup_git_cmd_env {
1290         my $self = shift;
1291         if ($self) {
1292                 $self->repo_path() and $ENV{'GIT_DIR'} = $self->repo_path();
1293                 $self->repo_path() and $self->wc_path()
1294                         and $ENV{'GIT_WORK_TREE'} = $self->wc_path();
1295                 $self->wc_path() and chdir($self->wc_path());
1296                 $self->wc_subdir() and chdir($self->wc_subdir());
1297         }
1298 }
1299
1300 # Execute the given Git command ($_[0]) with arguments ($_[1..])
1301 # by searching for it at proper places.
1302 sub _execv_git_cmd { exec('git', @_); }
1303
1304 # Close pipe to a subprocess.
1305 sub _cmd_close {
1306         my ($fh, $ctx) = @_;
1307         if (not close $fh) {
1308                 if ($!) {
1309                         # It's just close, no point in fatalities
1310                         carp "error closing pipe: $!";
1311                 } elsif ($? >> 8) {
1312                         # The caller should pepper this.
1313                         throw Git::Error::Command($ctx, $? >> 8);
1314                 }
1315                 # else we might e.g. closed a live stream; the command
1316                 # dying of SIGPIPE would drive us here.
1317         }
1318 }
1319
1320
1321 sub DESTROY {
1322         my ($self) = @_;
1323         $self->_close_hash_and_insert_object();
1324         $self->_close_cat_blob();
1325 }
1326
1327
1328 # Pipe implementation for ActiveState Perl.
1329
1330 package Git::activestate_pipe;
1331 use strict;
1332
1333 sub TIEHANDLE {
1334         my ($class, @params) = @_;
1335         # FIXME: This is probably horrible idea and the thing will explode
1336         # at the moment you give it arguments that require some quoting,
1337         # but I have no ActiveState clue... --pasky
1338         # Let's just hope ActiveState Perl does at least the quoting
1339         # correctly.
1340         my @data = qx{git @params};
1341         bless { i => 0, data => \@data }, $class;
1342 }
1343
1344 sub READLINE {
1345         my $self = shift;
1346         if ($self->{i} >= scalar @{$self->{data}}) {
1347                 return undef;
1348         }
1349         my $i = $self->{i};
1350         if (wantarray) {
1351                 $self->{i} = $#{$self->{'data'}} + 1;
1352                 return splice(@{$self->{'data'}}, $i);
1353         }
1354         $self->{i} = $i + 1;
1355         return $self->{'data'}->[ $i ];
1356 }
1357
1358 sub CLOSE {
1359         my $self = shift;
1360         delete $self->{data};
1361         delete $self->{i};
1362 }
1363
1364 sub EOF {
1365         my $self = shift;
1366         return ($self->{i} >= scalar @{$self->{data}});
1367 }
1368
1369
1370 1; # Famous last words