perl/Git.pm

   1 =head1 NAME
   2
   3 Git - Perl interface to the Git version control system
   4
   5 =cut
   6
   7
   8 package Git;
   9
  10 use 5.008;
  11 use strict;
  12
  13
  14 BEGIN {
  15
  16 our ($VERSION, @ISA, @EXPORT, @EXPORT_OK);
  17
  18 # Totally unstable API.
  19 $VERSION = '0.01';
  20
  21
  22 =head1 SYNOPSIS
  23
  24   use Git;
  25
  26   my $version = Git::command_oneline('version');
  27
  28   git_cmd_try { Git::command_noisy('update-server-info') }
  29               '%s failed w/ code %d';
  30
  31   my $repo = Git->repository (Directory => '/srv/git/cogito.git');
  32
  33
  34   my @revs = $repo->command('rev-list', '--since=last monday', '--all');
  35
  36   my ($fh, $c) = $repo->command_output_pipe('rev-list', '--since=last monday', '--all');
  37   my $lastrev = <$fh>; chomp $lastrev;
  38   $repo->command_close_pipe($fh, $c);
  39
  40   my $lastrev = $repo->command_oneline( [ 'rev-list', '--all' ],
  41                                         STDERR => 0 );
  42
  43   my $sha1 = $repo->hash_and_insert_object('file.txt');
  44   my $tempfile = tempfile();
  45   my $size = $repo->cat_blob($sha1, $tempfile);
  46
  47 =cut
  48
  49
  50 require Exporter;
  51
  52 @ISA = qw(Exporter);
  53
  54 @EXPORT = qw(git_cmd_try);
  55
  56 # Methods which can be called as standalone functions as well:
  57 @EXPORT_OK = qw(command command_oneline command_noisy
  58                 command_output_pipe command_input_pipe command_close_pipe
  59                 command_bidi_pipe command_close_bidi_pipe
  60                 version exec_path html_path hash_object git_cmd_try
  61                 remote_refs
  62                 temp_acquire temp_release temp_reset temp_path);
  63
  64
  65 =head1 DESCRIPTION
  66
  67 This module provides Perl scripts easy way to interface the Git version control
  68 system. The modules have an easy and well-tested way to call arbitrary Git
  69 commands; in the future, the interface will also provide specialized methods
  70 for doing easily operations which are not totally trivial to do over
  71 the generic command interface.
  72
  73 While some commands can be executed outside of any context (e.g. 'version'
  74 or 'init'), most operations require a repository context, which in practice
  75 means getting an instance of the Git object using the repository() constructor.
  76 (In the future, we will also get a new_repository() constructor.) All commands
  77 called as methods of the object are then executed in the context of the
  78 repository.
  79
  80 Part of the "repository state" is also information about path to the attached
  81 working copy (unless you work with a bare repository). You can also navigate
  82 inside of the working copy using the C<wc_chdir()> method. (Note that
  83 the repository object is self-contained and will not change working directory
  84 of your process.)
  85
  86 TODO: In the future, we might also do
  87
  88         my $remoterepo = $repo->remote_repository (Name => 'cogito', Branch => 'master');
  89         $remoterepo ||= Git->remote_repository ('http://git.or.cz/cogito.git/');
  90         my @refs = $remoterepo->refs();
  91
  92 Currently, the module merely wraps calls to external Git tools. In the future,
  93 it will provide a much faster way to interact with Git by linking directly
  94 to libgit. This should be completely opaque to the user, though (performance
  95 increase notwithstanding).
  96
  97 =cut
  98
  99
 100 use Carp qw(carp croak); # but croak is bad - throw instead
 101 use Error qw(:try);
 102 use Cwd qw(abs_path);
 103 use IPC::Open2 qw(open2);
 104 use Fcntl qw(SEEK_SET SEEK_CUR);
 105 }
 106
 107
 108 =head1 CONSTRUCTORS
 109
 110 =over 4
 111
 112 =item repository ( OPTIONS )
 113
 114 =item repository ( DIRECTORY )
 115
 116 =item repository ()
 117
 118 Construct a new repository object.
 119 C<OPTIONS> are passed in a hash like fashion, using key and value pairs.
 120 Possible options are:
 121
 122 B<Repository> - Path to the Git repository.
 123
 124 B<WorkingCopy> - Path to the associated working copy; not strictly required
 125 as many commands will happily crunch on a bare repository.
 126
 127 B<WorkingSubdir> - Subdirectory in the working copy to work inside.
 128 Just left undefined if you do not want to limit the scope of operations.
 129
 130 B<Directory> - Path to the Git working directory in its usual setup.
 131 The C<.git> directory is searched in the directory and all the parent
 132 directories; if found, C<WorkingCopy> is set to the directory containing
 133 it and C<Repository> to the C<.git> directory itself. If no C<.git>
 134 directory was found, the C<Directory> is assumed to be a bare repository,
 135 C<Repository> is set to point at it and C<WorkingCopy> is left undefined.
 136 If the C<$GIT_DIR> environment variable is set, things behave as expected
 137 as well.
 138
 139 You should not use both C<Directory> and either of C<Repository> and
 140 C<WorkingCopy> - the results of that are undefined.
 141
 142 Alternatively, a directory path may be passed as a single scalar argument
 143 to the constructor; it is equivalent to setting only the C<Directory> option
 144 field.
 145
 146 Calling the constructor with no options whatsoever is equivalent to
 147 calling it with C<< Directory => '.' >>. In general, if you are building
 148 a standard porcelain command, simply doing C<< Git->repository() >> should
 149 do the right thing and setup the object to reflect exactly where the user
 150 is right now.
 151
 152 =cut
 153
 154 sub repository {
 155         my $class = shift;
 156         my @args = @_;
 157         my %opts = ();
 158         my $self;
 159
 160         if (defined $args[0]) {
 161                 if ($#args % 2 != 1) {
 162                         # Not a hash.
 163                         $#args == 0 or throw Error::Simple("bad usage");
 164                         %opts = ( Directory => $args[0] );
 165                 } else {
 166                         %opts = @args;
 167                 }
 168         }
 169
 170         if (not defined $opts{Repository} and not defined $opts{WorkingCopy}
 171                 and not defined $opts{Directory}) {
 172                 $opts{Directory} = '.';
 173         }
 174
 175         if (defined $opts{Directory}) {
 176                 -d $opts{Directory} or throw Error::Simple("Directory not found: $opts{Directory} $!");
 177
 178                 my $search = Git->repository(WorkingCopy => $opts{Directory});
 179                 my $dir;
 180                 try {
 181                         $dir = $search->command_oneline(['rev-parse', '--git-dir'],
 182                                                         STDERR => 0);
 183                 } catch Git::Error::Command with {
 184                         $dir = undef;
 185                 };
 186
 187                 if ($dir) {
 188                         $dir =~ m#^/# or $dir = $opts{Directory} . '/' . $dir;
 189                         $opts{Repository} = abs_path($dir);
 190
 191                         # If --git-dir went ok, this shouldn't die either.
 192                         my $prefix = $search->command_oneline('rev-parse', '--show-prefix');
 193                         $dir = abs_path($opts{Directory}) . '/';
 194                         if ($prefix) {
 195                                 if (substr($dir, -length($prefix)) ne $prefix) {
 196                                         throw Error::Simple("rev-parse confused me - $dir does not have trailing $prefix");
 197                                 }
 198                                 substr($dir, -length($prefix)) = '';
 199                         }
 200                         $opts{WorkingCopy} = $dir;
 201                         $opts{WorkingSubdir} = $prefix;
 202
 203                 } else {
 204                         # A bare repository? Let's see...
 205                         $dir = $opts{Directory};
 206
 207                         unless (-d "$dir/refs" and -d "$dir/objects" and -e "$dir/HEAD") {
 208                                 # Mimic git-rev-parse --git-dir error message:
 209                                 throw Error::Simple("fatal: Not a git repository: $dir");
 210                         }
 211                         my $search = Git->repository(Repository => $dir);
 212                         try {
 213                                 $search->command('symbolic-ref', 'HEAD');
 214                         } catch Git::Error::Command with {
 215                                 # Mimic git-rev-parse --git-dir error message:
 216                                 throw Error::Simple("fatal: Not a git repository: $dir");
 217                         }
 218
 219                         $opts{Repository} = abs_path($dir);
 220                 }
 221
 222                 delete $opts{Directory};
 223         }
 224
 225         $self = { opts => \%opts };
 226         bless $self, $class;
 227 }
 228
 229 =back
 230
 231 =head1 METHODS
 232
 233 =over 4
 234
 235 =item command ( COMMAND [, ARGUMENTS... ] )
 236
 237 =item command ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 238
 239 Execute the given Git C<COMMAND> (specify it without the 'git-'
 240 prefix), optionally with the specified extra C<ARGUMENTS>.
 241
 242 The second more elaborate form can be used if you want to further adjust
 243 the command execution. Currently, only one option is supported:
 244
 245 B<STDERR> - How to deal with the command's error output. By default (C<undef>)
 246 it is delivered to the caller's C<STDERR>. A false value (0 or '') will cause
 247 it to be thrown away. If you want to process it, you can get it in a filehandle
 248 you specify, but you must be extremely careful; if the error output is not
 249 very short and you want to read it in the same process as where you called
 250 C<command()>, you are set up for a nice deadlock!
 251
 252 The method can be called without any instance or on a specified Git repository
 253 (in that case the command will be run in the repository context).
 254
 255 In scalar context, it returns all the command output in a single string
 256 (verbatim).
 257
 258 In array context, it returns an array containing lines printed to the
 259 command's stdout (without trailing newlines).
 260
 261 In both cases, the command's stdin and stderr are the same as the caller's.
 262
 263 =cut
 264
 265 sub command {
 266         my ($fh, $ctx) = command_output_pipe(@_);
 267
 268         if (not defined wantarray) {
 269                 # Nothing to pepper the possible exception with.
 270                 _cmd_close($fh, $ctx);
 271
 272         } elsif (not wantarray) {
 273                 local $/;
 274                 my $text = <$fh>;
 275                 try {
 276                         _cmd_close($fh, $ctx);
 277                 } catch Git::Error::Command with {
 278                         # Pepper with the output:
 279                         my $E = shift;
 280                         $E->{'-outputref'} = \$text;
 281                         throw $E;
 282                 };
 283                 return $text;
 284
 285         } else {
 286                 my @lines = <$fh>;
 287                 defined and chomp for @lines;
 288                 try {
 289                         _cmd_close($fh, $ctx);
 290                 } catch Git::Error::Command with {
 291                         my $E = shift;
 292                         $E->{'-outputref'} = \@lines;
 293                         throw $E;
 294                 };
 295                 return @lines;
 296         }
 297 }
 298
 299
 300 =item command_oneline ( COMMAND [, ARGUMENTS... ] )
 301
 302 =item command_oneline ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 303
 304 Execute the given C<COMMAND> in the same way as command()
 305 does but always return a scalar string containing the first line
 306 of the command's standard output.
 307
 308 =cut
 309
 310 sub command_oneline {
 311         my ($fh, $ctx) = command_output_pipe(@_);
 312
 313         my $line = <$fh>;
 314         defined $line and chomp $line;
 315         try {
 316                 _cmd_close($fh, $ctx);
 317         } catch Git::Error::Command with {
 318                 # Pepper with the output:
 319                 my $E = shift;
 320                 $E->{'-outputref'} = \$line;
 321                 throw $E;
 322         };
 323         return $line;
 324 }
 325
 326
 327 =item command_output_pipe ( COMMAND [, ARGUMENTS... ] )
 328
 329 =item command_output_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 330
 331 Execute the given C<COMMAND> in the same way as command()
 332 does but return a pipe filehandle from which the command output can be
 333 read.
 334
 335 The function can return C<($pipe, $ctx)> in array context.
 336 See C<command_close_pipe()> for details.
 337
 338 =cut
 339
 340 sub command_output_pipe {
 341         _command_common_pipe('-|', @_);
 342 }
 343
 344
 345 =item command_input_pipe ( COMMAND [, ARGUMENTS... ] )
 346
 347 =item command_input_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 348
 349 Execute the given C<COMMAND> in the same way as command_output_pipe()
 350 does but return an input pipe filehandle instead; the command output
 351 is not captured.
 352
 353 The function can return C<($pipe, $ctx)> in array context.
 354 See C<command_close_pipe()> for details.
 355
 356 =cut
 357
 358 sub command_input_pipe {
 359         _command_common_pipe('|-', @_);
 360 }
 361
 362
 363 =item command_close_pipe ( PIPE [, CTX ] )
 364
 365 Close the C<PIPE> as returned from C<command_*_pipe()>, checking
 366 whether the command finished successfully. The optional C<CTX> argument
 367 is required if you want to see the command name in the error message,
 368 and it is the second value returned by C<command_*_pipe()> when
 369 called in array context. The call idiom is:
 370
 371         my ($fh, $ctx) = $r->command_output_pipe('status');
 372         while (<$fh>) { ... }
 373         $r->command_close_pipe($fh, $ctx);
 374
 375 Note that you should not rely on whatever actually is in C<CTX>;
 376 currently it is simply the command name but in future the context might
 377 have more complicated structure.
 378
 379 =cut
 380
 381 sub command_close_pipe {
 382         my ($self, $fh, $ctx) = _maybe_self(@_);
 383         $ctx ||= '<unknown>';
 384         _cmd_close($fh, $ctx);
 385 }
 386
 387 =item command_bidi_pipe ( COMMAND [, ARGUMENTS... ] )
 388
 389 Execute the given C<COMMAND> in the same way as command_output_pipe()
 390 does but return both an input pipe filehandle and an output pipe filehandle.
 391
 392 The function will return return C<($pid, $pipe_in, $pipe_out, $ctx)>.
 393 See C<command_close_bidi_pipe()> for details.
 394
 395 =cut
 396
 397 sub command_bidi_pipe {
 398         my ($pid, $in, $out);
 399         $pid = open2($in, $out, 'git', @_);
 400         return ($pid, $in, $out, join(' ', @_));
 401 }
 402
 403 =item command_close_bidi_pipe ( PID, PIPE_IN, PIPE_OUT [, CTX] )
 404
 405 Close the C<PIPE_IN> and C<PIPE_OUT> as returned from C<command_bidi_pipe()>,
 406 checking whether the command finished successfully. The optional C<CTX>
 407 argument is required if you want to see the command name in the error message,
 408 and it is the fourth value returned by C<command_bidi_pipe()>.  The call idiom
 409 is:
 410
 411         my ($pid, $in, $out, $ctx) = $r->command_bidi_pipe('cat-file --batch-check');
 412         print "000000000\n" $out;
 413         while (<$in>) { ... }
 414         $r->command_close_bidi_pipe($pid, $in, $out, $ctx);
 415
 416 Note that you should not rely on whatever actually is in C<CTX>;
 417 currently it is simply the command name but in future the context might
 418 have more complicated structure.
 419
 420 =cut
 421
 422 sub command_close_bidi_pipe {
 423         local $?;
 424         my ($pid, $in, $out, $ctx) = @_;
 425         foreach my $fh ($in, $out) {
 426                 unless (close $fh) {
 427                         if ($!) {
 428                                 carp "error closing pipe: $!";
 429                         } elsif ($? >> 8) {
 430                                 throw Git::Error::Command($ctx, $? >>8);
 431                         }
 432                 }
 433         }
 434
 435         waitpid $pid, 0;
 436
 437         if ($? >> 8) {
 438                 throw Git::Error::Command($ctx, $? >>8);
 439         }
 440 }
 441
 442
 443 =item command_noisy ( COMMAND [, ARGUMENTS... ] )
 444
 445 Execute the given C<COMMAND> in the same way as command() does but do not
 446 capture the command output - the standard output is not redirected and goes
 447 to the standard output of the caller application.
 448
 449 While the method is called command_noisy(), you might want to as well use
 450 it for the most silent Git commands which you know will never pollute your
 451 stdout but you want to avoid the overhead of the pipe setup when calling them.
 452
 453 The function returns only after the command has finished running.
 454
 455 =cut
 456
 457 sub command_noisy {
 458         my ($self, $cmd, @args) = _maybe_self(@_);
 459         _check_valid_cmd($cmd);
 460
 461         my $pid = fork;
 462         if (not defined $pid) {
 463                 throw Error::Simple("fork failed: $!");
 464         } elsif ($pid == 0) {
 465                 _cmd_exec($self, $cmd, @args);
 466         }
 467         if (waitpid($pid, 0) > 0 and $?>>8 != 0) {
 468                 throw Git::Error::Command(join(' ', $cmd, @args), $? >> 8);
 469         }
 470 }
 471
 472
 473 =item version ()
 474
 475 Return the Git version in use.
 476
 477 =cut
 478
 479 sub version {
 480         my $verstr = command_oneline('--version');
 481         $verstr =~ s/^git version //;
 482         $verstr;
 483 }
 484
 485
 486 =item exec_path ()
 487
 488 Return path to the Git sub-command executables (the same as
 489 C<git --exec-path>). Useful mostly only internally.
 490
 491 =cut
 492
 493 sub exec_path { command_oneline('--exec-path') }
 494
 495
 496 =item html_path ()
 497
 498 Return path to the Git html documentation (the same as
 499 C<git --html-path>). Useful mostly only internally.
 500
 501 =cut
 502
 503 sub html_path { command_oneline('--html-path') }
 504
 505
 506 =item repo_path ()
 507
 508 Return path to the git repository. Must be called on a repository instance.
 509
 510 =cut
 511
 512 sub repo_path { $_[0]->{opts}->{Repository} }
 513
 514
 515 =item wc_path ()
 516
 517 Return path to the working copy. Must be called on a repository instance.
 518
 519 =cut
 520
 521 sub wc_path { $_[0]->{opts}->{WorkingCopy} }
 522
 523
 524 =item wc_subdir ()
 525
 526 Return path to the subdirectory inside of a working copy. Must be called
 527 on a repository instance.
 528
 529 =cut
 530
 531 sub wc_subdir { $_[0]->{opts}->{WorkingSubdir} ||= '' }
 532
 533
 534 =item wc_chdir ( SUBDIR )
 535
 536 Change the working copy subdirectory to work within. The C<SUBDIR> is
 537 relative to the working copy root directory (not the current subdirectory).
 538 Must be called on a repository instance attached to a working copy
 539 and the directory must exist.
 540
 541 =cut
 542
 543 sub wc_chdir {
 544         my ($self, $subdir) = @_;
 545         $self->wc_path()
 546                 or throw Error::Simple("bare repository");
 547
 548         -d $self->wc_path().'/'.$subdir
 549                 or throw Error::Simple("subdir not found: $subdir $!");
 550         # Of course we will not "hold" the subdirectory so anyone
 551         # can delete it now and we will never know. But at least we tried.
 552
 553         $self->{opts}->{WorkingSubdir} = $subdir;
 554 }
 555
 556
 557 =item config ( VARIABLE )
 558
 559 Retrieve the configuration C<VARIABLE> in the same manner as C<config>
 560 does. In scalar context requires the variable to be set only one time
 561 (exception is thrown otherwise), in array context returns allows the
 562 variable to be set multiple times and returns all the values.
 563
 564 This currently wraps command('config') so it is not so fast.
 565
 566 =cut
 567
 568 sub config {
 569         my ($self, $var) = _maybe_self(@_);
 570
 571         try {
 572                 my @cmd = ('config');
 573                 unshift @cmd, $self if $self;
 574                 if (wantarray) {
 575                         return command(@cmd, '--get-all', $var);
 576                 } else {
 577                         return command_oneline(@cmd, '--get', $var);
 578                 }
 579         } catch Git::Error::Command with {
 580                 my $E = shift;
 581                 if ($E->value() == 1) {
 582                         # Key not found.
 583                         return;
 584                 } else {
 585                         throw $E;
 586                 }
 587         };
 588 }
 589
 590
 591 =item config_bool ( VARIABLE )
 592
 593 Retrieve the bool configuration C<VARIABLE>. The return value
 594 is usable as a boolean in perl (and C<undef> if it's not defined,
 595 of course).
 596
 597 This currently wraps command('config') so it is not so fast.
 598
 599 =cut
 600
 601 sub config_bool {
 602         my ($self, $var) = _maybe_self(@_);
 603
 604         try {
 605                 my @cmd = ('config', '--bool', '--get', $var);
 606                 unshift @cmd, $self if $self;
 607                 my $val = command_oneline(@cmd);
 608                 return undef unless defined $val;
 609                 return $val eq 'true';
 610         } catch Git::Error::Command with {
 611                 my $E = shift;
 612                 if ($E->value() == 1) {
 613                         # Key not found.
 614                         return undef;
 615                 } else {
 616                         throw $E;
 617                 }
 618         };
 619 }
 620
 621 =item config_int ( VARIABLE )
 622
 623 Retrieve the integer configuration C<VARIABLE>. The return value
 624 is simple decimal number.  An optional value suffix of 'k', 'm',
 625 or 'g' in the config file will cause the value to be multiplied
 626 by 1024, 1048576 (1024^2), or 1073741824 (1024^3) prior to output.
 627 It would return C<undef> if configuration variable is not defined,
 628
 629 This currently wraps command('config') so it is not so fast.
 630
 631 =cut
 632
 633 sub config_int {
 634         my ($self, $var) = _maybe_self(@_);
 635
 636         try {
 637                 my @cmd = ('config', '--int', '--get', $var);
 638                 unshift @cmd, $self if $self;
 639                 return command_oneline(@cmd);
 640         } catch Git::Error::Command with {
 641                 my $E = shift;
 642                 if ($E->value() == 1) {
 643                         # Key not found.
 644                         return undef;
 645                 } else {
 646                         throw $E;
 647                 }
 648         };
 649 }
 650
 651 =item get_colorbool ( NAME )
 652
 653 Finds if color should be used for NAMEd operation from the configuration,
 654 and returns boolean (true for "use color", false for "do not use color").
 655
 656 =cut
 657
 658 sub get_colorbool {
 659         my ($self, $var) = @_;
 660         my $stdout_to_tty = (-t STDOUT) ? "true" : "false";
 661         my $use_color = $self->command_oneline('config', '--get-colorbool',
 662                                                $var, $stdout_to_tty);
 663         return ($use_color eq 'true');
 664 }
 665
 666 =item get_color ( SLOT, COLOR )
 667
 668 Finds color for SLOT from the configuration, while defaulting to COLOR,
 669 and returns the ANSI color escape sequence:
 670
 671         print $repo->get_color("color.interactive.prompt", "underline blue white");
 672         print "some text";
 673         print $repo->get_color("", "normal");
 674
 675 =cut
 676
 677 sub get_color {
 678         my ($self, $slot, $default) = @_;
 679         my $color = $self->command_oneline('config', '--get-color', $slot, $default);
 680         if (!defined $color) {
 681                 $color = "";
 682         }
 683         return $color;
 684 }
 685
 686 =item remote_refs ( REPOSITORY [, GROUPS [, REFGLOBS ] ] )
 687
 688 This function returns a hashref of refs stored in a given remote repository.
 689 The hash is in the format C<refname =\> hash>. For tags, the C<refname> entry
 690 contains the tag object while a C<refname^{}> entry gives the tagged objects.
 691
 692 C<REPOSITORY> has the same meaning as the appropriate C<git-ls-remote>
 693 argument; either an URL or a remote name (if called on a repository instance).
 694 C<GROUPS> is an optional arrayref that can contain 'tags' to return all the
 695 tags and/or 'heads' to return all the heads. C<REFGLOB> is an optional array
 696 of strings containing a shell-like glob to further limit the refs returned in
 697 the hash; the meaning is again the same as the appropriate C<git-ls-remote>
 698 argument.
 699
 700 This function may or may not be called on a repository instance. In the former
 701 case, remote names as defined in the repository are recognized as repository
 702 specifiers.
 703
 704 =cut
 705
 706 sub remote_refs {
 707         my ($self, $repo, $groups, $refglobs) = _maybe_self(@_);
 708         my @args;
 709         if (ref $groups eq 'ARRAY') {
 710                 foreach (@$groups) {
 711                         if ($_ eq 'heads') {
 712                                 push (@args, '--heads');
 713                         } elsif ($_ eq 'tags') {
 714                                 push (@args, '--tags');
 715                         } else {
 716                                 # Ignore unknown groups for future
 717                                 # compatibility
 718                         }
 719                 }
 720         }
 721         push (@args, $repo);
 722         if (ref $refglobs eq 'ARRAY') {
 723                 push (@args, @$refglobs);
 724         }
 725
 726         my @self = $self ? ($self) : (); # Ultra trickery
 727         my ($fh, $ctx) = Git::command_output_pipe(@self, 'ls-remote', @args);
 728         my %refs;
 729         while (<$fh>) {
 730                 chomp;
 731                 my ($hash, $ref) = split(/\t/, $_, 2);
 732                 $refs{$ref} = $hash;
 733         }
 734         Git::command_close_pipe(@self, $fh, $ctx);
 735         return \%refs;
 736 }
 737
 738
 739 =item ident ( TYPE | IDENTSTR )
 740
 741 =item ident_person ( TYPE | IDENTSTR | IDENTARRAY )
 742
 743 This suite of functions retrieves and parses ident information, as stored
 744 in the commit and tag objects or produced by C<var GIT_type_IDENT> (thus
 745 C<TYPE> can be either I<author> or I<committer>; case is insignificant).
 746
 747 The C<ident> method retrieves the ident information from C<git var>
 748 and either returns it as a scalar string or as an array with the fields parsed.
 749 Alternatively, it can take a prepared ident string (e.g. from the commit
 750 object) and just parse it.
 751
 752 C<ident_person> returns the person part of the ident - name and email;
 753 it can take the same arguments as C<ident> or the array returned by C<ident>.
 754
 755 The synopsis is like:
 756
 757         my ($name, $email, $time_tz) = ident('author');
 758         "$name <$email>" eq ident_person('author');
 759         "$name <$email>" eq ident_person($name);
 760         $time_tz =~ /^\d+ [+-]\d{4}$/;
 761
 762 =cut
 763
 764 sub ident {
 765         my ($self, $type) = _maybe_self(@_);
 766         my $identstr;
 767         if (lc $type eq lc 'committer' or lc $type eq lc 'author') {
 768                 my @cmd = ('var', 'GIT_'.uc($type).'_IDENT');
 769                 unshift @cmd, $self if $self;
 770                 $identstr = command_oneline(@cmd);
 771         } else {
 772                 $identstr = $type;
 773         }
 774         if (wantarray) {
 775                 return $identstr =~ /^(.*) <(.*)> (\d+ [+-]\d{4})$/;
 776         } else {
 777                 return $identstr;
 778         }
 779 }
 780
 781 sub ident_person {
 782         my ($self, @ident) = _maybe_self(@_);
 783         $#ident == 0 and @ident = $self ? $self->ident($ident[0]) : ident($ident[0]);
 784         return "$ident[0] <$ident[1]>";
 785 }
 786
 787
 788 =item hash_object ( TYPE, FILENAME )
 789
 790 Compute the SHA1 object id of the given C<FILENAME> considering it is
 791 of the C<TYPE> object type (C<blob>, C<commit>, C<tree>).
 792
 793 The method can be called without any instance or on a specified Git repository,
 794 it makes zero difference.
 795
 796 The function returns the SHA1 hash.
 797
 798 =cut
 799
 800 # TODO: Support for passing FILEHANDLE instead of FILENAME
 801 sub hash_object {
 802         my ($self, $type, $file) = _maybe_self(@_);
 803         command_oneline('hash-object', '-t', $type, $file);
 804 }
 805
 806
 807 =item hash_and_insert_object ( FILENAME )
 808
 809 Compute the SHA1 object id of the given C<FILENAME> and add the object to the
 810 object database.
 811
 812 The function returns the SHA1 hash.
 813
 814 =cut
 815
 816 # TODO: Support for passing FILEHANDLE instead of FILENAME
 817 sub hash_and_insert_object {
 818         my ($self, $filename) = @_;
 819
 820         carp "Bad filename \"$filename\"" if $filename =~ /[\r\n]/;
 821
 822         $self->_open_hash_and_insert_object_if_needed();
 823         my ($in, $out) = ($self->{hash_object_in}, $self->{hash_object_out});
 824
 825         unless (print $out $filename, "\n") {
 826                 $self->_close_hash_and_insert_object();
 827                 throw Error::Simple("out pipe went bad");
 828         }
 829
 830         chomp(my $hash = <$in>);
 831         unless (defined($hash)) {
 832                 $self->_close_hash_and_insert_object();
 833                 throw Error::Simple("in pipe went bad");
 834         }
 835
 836         return $hash;
 837 }
 838
 839 sub _open_hash_and_insert_object_if_needed {
 840         my ($self) = @_;
 841
 842         return if defined($self->{hash_object_pid});
 843
 844         ($self->{hash_object_pid}, $self->{hash_object_in},
 845          $self->{hash_object_out}, $self->{hash_object_ctx}) =
 846                 command_bidi_pipe(qw(hash-object -w --stdin-paths --no-filters));
 847 }
 848
 849 sub _close_hash_and_insert_object {
 850         my ($self) = @_;
 851
 852         return unless defined($self->{hash_object_pid});
 853
 854         my @vars = map { 'hash_object_' . $_ } qw(pid in out ctx);
 855
 856         command_close_bidi_pipe(@$self{@vars});
 857         delete @$self{@vars};
 858 }
 859
 860 =item cat_blob ( SHA1, FILEHANDLE )
 861
 862 Prints the contents of the blob identified by C<SHA1> to C<FILEHANDLE> and
 863 returns the number of bytes printed.
 864
 865 =cut
 866
 867 sub cat_blob {
 868         my ($self, $sha1, $fh) = @_;
 869
 870         $self->_open_cat_blob_if_needed();
 871         my ($in, $out) = ($self->{cat_blob_in}, $self->{cat_blob_out});
 872
 873         unless (print $out $sha1, "\n") {
 874                 $self->_close_cat_blob();
 875                 throw Error::Simple("out pipe went bad");
 876         }
 877
 878         my $description = <$in>;
 879         if ($description =~ / missing$/) {
 880                 carp "$sha1 doesn't exist in the repository";
 881                 return -1;
 882         }
 883
 884         if ($description !~ /^[0-9a-fA-F]{40} \S+ (\d+)$/) {
 885                 carp "Unexpected result returned from git cat-file";
 886                 return -1;
 887         }
 888
 889         my $size = $1;
 890
 891         my $blob;
 892         my $bytesRead = 0;
 893
 894         while (1) {
 895                 my $bytesLeft = $size - $bytesRead;
 896                 last unless $bytesLeft;
 897
 898                 my $bytesToRead = $bytesLeft < 1024 ? $bytesLeft : 1024;
 899                 my $read = read($in, $blob, $bytesToRead, $bytesRead);
 900                 unless (defined($read)) {
 901                         $self->_close_cat_blob();
 902                         throw Error::Simple("in pipe went bad");
 903                 }
 904
 905                 $bytesRead += $read;
 906         }
 907
 908         # Skip past the trailing newline.
 909         my $newline;
 910         my $read = read($in, $newline, 1);
 911         unless (defined($read)) {
 912                 $self->_close_cat_blob();
 913                 throw Error::Simple("in pipe went bad");
 914         }
 915         unless ($read == 1 && $newline eq "\n") {
 916                 $self->_close_cat_blob();
 917                 throw Error::Simple("didn't find newline after blob");
 918         }
 919
 920         unless (print $fh $blob) {
 921                 $self->_close_cat_blob();
 922                 throw Error::Simple("couldn't write to passed in filehandle");
 923         }
 924
 925         return $size;
 926 }
 927
 928 sub _open_cat_blob_if_needed {
 929         my ($self) = @_;
 930
 931         return if defined($self->{cat_blob_pid});
 932
 933         ($self->{cat_blob_pid}, $self->{cat_blob_in},
 934          $self->{cat_blob_out}, $self->{cat_blob_ctx}) =
 935                 command_bidi_pipe(qw(cat-file --batch));
 936 }
 937
 938 sub _close_cat_blob {
 939         my ($self) = @_;
 940
 941         return unless defined($self->{cat_blob_pid});
 942
 943         my @vars = map { 'cat_blob_' . $_ } qw(pid in out ctx);
 944
 945         command_close_bidi_pipe(@$self{@vars});
 946         delete @$self{@vars};
 947 }
 948
 949
 950 { # %TEMP_* Lexical Context
 951
 952 my (%TEMP_FILEMAP, %TEMP_FILES);
 953
 954 =item temp_acquire ( NAME )
 955
 956 Attempts to retreive the temporary file mapped to the string C<NAME>. If an
 957 associated temp file has not been created this session or was closed, it is
 958 created, cached, and set for autoflush and binmode.
 959
 960 Internally locks the file mapped to C<NAME>. This lock must be released with
 961 C<temp_release()> when the temp file is no longer needed. Subsequent attempts
 962 to retrieve temporary files mapped to the same C<NAME> while still locked will
 963 cause an error. This locking mechanism provides a weak guarantee and is not
 964 threadsafe. It does provide some error checking to help prevent temp file refs
 965 writing over one another.
 966
 967 In general, the L<File::Handle> returned should not be closed by consumers as
 968 it defeats the purpose of this caching mechanism. If you need to close the temp
 969 file handle, then you should use L<File::Temp> or another temp file faculty
 970 directly. If a handle is closed and then requested again, then a warning will
 971 issue.
 972
 973 =cut
 974
 975 sub temp_acquire {
 976         my $temp_fd = _temp_cache(@_);
 977
 978         $TEMP_FILES{$temp_fd}{locked} = 1;
 979         $temp_fd;
 980 }
 981
 982 =item temp_release ( NAME )
 983
 984 =item temp_release ( FILEHANDLE )
 985
 986 Releases a lock acquired through C<temp_acquire()>. Can be called either with
 987 the C<NAME> mapping used when acquiring the temp file or with the C<FILEHANDLE>
 988 referencing a locked temp file.
 989
 990 Warns if an attempt is made to release a file that is not locked.
 991
 992 The temp file will be truncated before being released. This can help to reduce
 993 disk I/O where the system is smart enough to detect the truncation while data
 994 is in the output buffers. Beware that after the temp file is released and
 995 truncated, any operations on that file may fail miserably until it is
 996 re-acquired. All contents are lost between each release and acquire mapped to
 997 the same string.
 998
 999 =cut
1000
1001 sub temp_release {
1002         my ($self, $temp_fd, $trunc) = _maybe_self(@_);
1003
1004         if (exists $TEMP_FILEMAP{$temp_fd}) {
1005                 $temp_fd = $TEMP_FILES{$temp_fd};
1006         }
1007         unless ($TEMP_FILES{$temp_fd}{locked}) {
1008                 carp "Attempt to release temp file '",
1009                         $temp_fd, "' that has not been locked";
1010         }
1011         temp_reset($temp_fd) if $trunc and $temp_fd->opened;
1012
1013         $TEMP_FILES{$temp_fd}{locked} = 0;
1014         undef;
1015 }
1016
1017 sub _temp_cache {
1018         my ($self, $name) = _maybe_self(@_);
1019
1020         _verify_require();
1021
1022         my $temp_fd = \$TEMP_FILEMAP{$name};
1023         if (defined $$temp_fd and $$temp_fd->opened) {
1024                 if ($TEMP_FILES{$$temp_fd}{locked}) {
1025                         throw Error::Simple("Temp file with moniker '" .
1026                                 $name . "' already in use");
1027                 }
1028         } else {
1029                 if (defined $$temp_fd) {
1030                         # then we're here because of a closed handle.
1031                         carp "Temp file '", $name,
1032                                 "' was closed. Opening replacement.";
1033                 }
1034                 my $fname;
1035
1036                 my $tmpdir;
1037                 if (defined $self) {
1038                         $tmpdir = $self->repo_path();
1039                 }
1040
1041                 ($$temp_fd, $fname) = File::Temp->tempfile(
1042                         'Git_XXXXXX', UNLINK => 1, DIR => $tmpdir,
1043                         ) or throw Error::Simple("couldn't open new temp file");
1044
1045                 $$temp_fd->autoflush;
1046                 binmode $$temp_fd;
1047                 $TEMP_FILES{$$temp_fd}{fname} = $fname;
1048         }
1049         $$temp_fd;
1050 }
1051
1052 sub _verify_require {
1053         eval { require File::Temp; require File::Spec; };
1054         $@ and throw Error::Simple($@);
1055 }
1056
1057 =item temp_reset ( FILEHANDLE )
1058
1059 Truncates and resets the position of the C<FILEHANDLE>.
1060
1061 =cut
1062
1063 sub temp_reset {
1064         my ($self, $temp_fd) = _maybe_self(@_);
1065
1066         truncate $temp_fd, 0
1067                 or throw Error::Simple("couldn't truncate file");
1068         sysseek($temp_fd, 0, SEEK_SET) and seek($temp_fd, 0, SEEK_SET)
1069                 or throw Error::Simple("couldn't seek to beginning of file");
1070         sysseek($temp_fd, 0, SEEK_CUR) == 0 and tell($temp_fd) == 0
1071                 or throw Error::Simple("expected file position to be reset");
1072 }
1073
1074 =item temp_path ( NAME )
1075
1076 =item temp_path ( FILEHANDLE )
1077
1078 Returns the filename associated with the given tempfile.
1079
1080 =cut
1081
1082 sub temp_path {
1083         my ($self, $temp_fd) = _maybe_self(@_);
1084
1085         if (exists $TEMP_FILEMAP{$temp_fd}) {
1086                 $temp_fd = $TEMP_FILEMAP{$temp_fd};
1087         }
1088         $TEMP_FILES{$temp_fd}{fname};
1089 }
1090
1091 sub END {
1092         unlink values %TEMP_FILEMAP if %TEMP_FILEMAP;
1093 }
1094
1095 } # %TEMP_* Lexical Context
1096
1097 =back
1098
1099 =head1 ERROR HANDLING
1100
1101 All functions are supposed to throw Perl exceptions in case of errors.
1102 See the L<Error> module on how to catch those. Most exceptions are mere
1103 L<Error::Simple> instances.
1104
1105 However, the C<command()>, C<command_oneline()> and C<command_noisy()>
1106 functions suite can throw C<Git::Error::Command> exceptions as well: those are
1107 thrown when the external command returns an error code and contain the error
1108 code as well as access to the captured command's output. The exception class
1109 provides the usual C<stringify> and C<value> (command's exit code) methods and
1110 in addition also a C<cmd_output> method that returns either an array or a
1111 string with the captured command output (depending on the original function
1112 call context; C<command_noisy()> returns C<undef>) and $<cmdline> which
1113 returns the command and its arguments (but without proper quoting).
1114
1115 Note that the C<command_*_pipe()> functions cannot throw this exception since
1116 it has no idea whether the command failed or not. You will only find out
1117 at the time you C<close> the pipe; if you want to have that automated,
1118 use C<command_close_pipe()>, which can throw the exception.
1119
1120 =cut
1121
1122 {
1123         package Git::Error::Command;
1124
1125         @Git::Error::Command::ISA = qw(Error);
1126
1127         sub new {
1128                 my $self = shift;
1129                 my $cmdline = '' . shift;
1130                 my $value = 0 + shift;
1131                 my $outputref = shift;
1132                 my(@args) = ();
1133
1134                 local $Error::Depth = $Error::Depth + 1;
1135
1136                 push(@args, '-cmdline', $cmdline);
1137                 push(@args, '-value', $value);
1138                 push(@args, '-outputref', $outputref);
1139
1140                 $self->SUPER::new(-text => 'command returned error', @args);
1141         }
1142
1143         sub stringify {
1144                 my $self = shift;
1145                 my $text = $self->SUPER::stringify;
1146                 $self->cmdline() . ': ' . $text . ': ' . $self->value() . "\n";
1147         }
1148
1149         sub cmdline {
1150                 my $self = shift;
1151                 $self->{'-cmdline'};
1152         }
1153
1154         sub cmd_output {
1155                 my $self = shift;
1156                 my $ref = $self->{'-outputref'};
1157                 defined $ref or undef;
1158                 if (ref $ref eq 'ARRAY') {
1159                         return @$ref;
1160                 } else { # SCALAR
1161                         return $$ref;
1162                 }
1163         }
1164 }
1165
1166 =over 4
1167
1168 =item git_cmd_try { CODE } ERRMSG
1169
1170 This magical statement will automatically catch any C<Git::Error::Command>
1171 exceptions thrown by C<CODE> and make your program die with C<ERRMSG>
1172 on its lips; the message will have %s substituted for the command line
1173 and %d for the exit status. This statement is useful mostly for producing
1174 more user-friendly error messages.
1175
1176 In case of no exception caught the statement returns C<CODE>'s return value.
1177
1178 Note that this is the only auto-exported function.
1179
1180 =cut
1181
1182 sub git_cmd_try(&$) {
1183         my ($code, $errmsg) = @_;
1184         my @result;
1185         my $err;
1186         my $array = wantarray;
1187         try {
1188                 if ($array) {
1189                         @result = &$code;
1190                 } else {
1191                         $result[0] = &$code;
1192                 }
1193         } catch Git::Error::Command with {
1194                 my $E = shift;
1195                 $err = $errmsg;
1196                 $err =~ s/\%s/$E->cmdline()/ge;
1197                 $err =~ s/\%d/$E->value()/ge;
1198                 # We can't croak here since Error.pm would mangle
1199                 # that to Error::Simple.
1200         };
1201         $err and croak $err;
1202         return $array ? @result : $result[0];
1203 }
1204
1205
1206 =back
1207
1208 =head1 COPYRIGHT
1209
1210 Copyright 2006 by Petr Baudis E<lt>pasky@suse.czE<gt>.
1211
1212 This module is free software; it may be used, copied, modified
1213 and distributed under the terms of the GNU General Public Licence,
1214 either version 2, or (at your option) any later version.
1215
1216 =cut
1217
1218
1219 # Take raw method argument list and return ($obj, @args) in case
1220 # the method was called upon an instance and (undef, @args) if
1221 # it was called directly.
1222 sub _maybe_self {
1223         UNIVERSAL::isa($_[0], 'Git') ? @_ : (undef, @_);
1224 }
1225
1226 # Check if the command id is something reasonable.
1227 sub _check_valid_cmd {
1228         my ($cmd) = @_;
1229         $cmd =~ /^[a-z0-9A-Z_-]+$/ or throw Error::Simple("bad command: $cmd");
1230 }
1231
1232 # Common backend for the pipe creators.
1233 sub _command_common_pipe {
1234         my $direction = shift;
1235         my ($self, @p) = _maybe_self(@_);
1236         my (%opts, $cmd, @args);
1237         if (ref $p[0]) {
1238                 ($cmd, @args) = @{shift @p};
1239                 %opts = ref $p[0] ? %{$p[0]} : @p;
1240         } else {
1241                 ($cmd, @args) = @p;
1242         }
1243         _check_valid_cmd($cmd);
1244
1245         my $fh;
1246         if ($^O eq 'MSWin32') {
1247                 # ActiveState Perl
1248                 #defined $opts{STDERR} and
1249                 #       warn 'ignoring STDERR option - running w/ ActiveState';
1250                 $direction eq '-|' or
1251                         die 'input pipe for ActiveState not implemented';
1252                 # the strange construction with *ACPIPE is just to
1253                 # explain the tie below that we want to bind to
1254                 # a handle class, not scalar. It is not known if
1255                 # it is something specific to ActiveState Perl or
1256                 # just a Perl quirk.
1257                 tie (*ACPIPE, 'Git::activestate_pipe', $cmd, @args);
1258                 $fh = *ACPIPE;
1259
1260         } else {
1261                 my $pid = open($fh, $direction);
1262                 if (not defined $pid) {
1263                         throw Error::Simple("open failed: $!");
1264                 } elsif ($pid == 0) {
1265                         if (defined $opts{STDERR}) {
1266                                 close STDERR;
1267                         }
1268                         if ($opts{STDERR}) {
1269                                 open (STDERR, '>&', $opts{STDERR})
1270                                         or die "dup failed: $!";
1271                         }
1272                         _cmd_exec($self, $cmd, @args);
1273                 }
1274         }
1275         return wantarray ? ($fh, join(' ', $cmd, @args)) : $fh;
1276 }
1277
1278 # When already in the subprocess, set up the appropriate state
1279 # for the given repository and execute the git command.
1280 sub _cmd_exec {
1281         my ($self, @args) = @_;
1282         if ($self) {
1283                 $self->repo_path() and $ENV{'GIT_DIR'} = $self->repo_path();
1284                 $self->repo_path() and $self->wc_path()
1285                         and $ENV{'GIT_WORK_TREE'} = $self->wc_path();
1286                 $self->wc_path() and chdir($self->wc_path());
1287                 $self->wc_subdir() and chdir($self->wc_subdir());
1288         }
1289         _execv_git_cmd(@args);
1290         die qq[exec "@args" failed: $!];
1291 }
1292
1293 # Execute the given Git command ($_[0]) with arguments ($_[1..])
1294 # by searching for it at proper places.
1295 sub _execv_git_cmd { exec('git', @_); }
1296
1297 # Close pipe to a subprocess.
1298 sub _cmd_close {
1299         my ($fh, $ctx) = @_;
1300         if (not close $fh) {
1301                 if ($!) {
1302                         # It's just close, no point in fatalities
1303                         carp "error closing pipe: $!";
1304                 } elsif ($? >> 8) {
1305                         # The caller should pepper this.
1306                         throw Git::Error::Command($ctx, $? >> 8);
1307                 }
1308                 # else we might e.g. closed a live stream; the command
1309                 # dying of SIGPIPE would drive us here.
1310         }
1311 }
1312
1313
1314 sub DESTROY {
1315         my ($self) = @_;
1316         $self->_close_hash_and_insert_object();
1317         $self->_close_cat_blob();
1318 }
1319
1320
1321 # Pipe implementation for ActiveState Perl.
1322
1323 package Git::activestate_pipe;
1324 use strict;
1325
1326 sub TIEHANDLE {
1327         my ($class, @params) = @_;
1328         # FIXME: This is probably horrible idea and the thing will explode
1329         # at the moment you give it arguments that require some quoting,
1330         # but I have no ActiveState clue... --pasky
1331         # Let's just hope ActiveState Perl does at least the quoting
1332         # correctly.
1333         my @data = qx{git @params};
1334         bless { i => 0, data => \@data }, $class;
1335 }
1336
1337 sub READLINE {
1338         my $self = shift;
1339         if ($self->{i} >= scalar @{$self->{data}}) {
1340                 return undef;
1341         }
1342         my $i = $self->{i};
1343         if (wantarray) {
1344                 $self->{i} = $#{$self->{'data'}} + 1;
1345                 return splice(@{$self->{'data'}}, $i);
1346         }
1347         $self->{i} = $i + 1;
1348         return $self->{'data'}->[ $i ];
1349 }
1350
1351 sub CLOSE {
1352         my $self = shift;
1353         delete $self->{data};
1354         delete $self->{i};
1355 }
1356
1357 sub EOF {
1358         my $self = shift;
1359         return ($self->{i} >= scalar @{$self->{data}});
1360 }
1361
1362
1363 1; # Famous last words