gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101 # URI of GIT logo (72x27 size)
 102 our $logo = "++GITWEB_LOGO++";
 103 # URI of GIT favicon, assumed to be image/png type
 104 our $favicon = "++GITWEB_FAVICON++";
 105 # URI of gitweb.js (JavaScript code for gitweb)
 106 our $javascript = "++GITWEB_JS++";
 107
 108 # URI and label (title) of GIT logo link
 109 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110 #our $logo_label = "git documentation";
 111 our $logo_url = "http://git-scm.com/";
 112 our $logo_label = "git homepage";
 113
 114 # source of projects list
 115 our $projects_list = "++GITWEB_LIST++";
 116
 117 # the width (in characters) of the projects list "Description" column
 118 our $projects_list_description_width = 25;
 119
 120 # group projects by category on the projects list
 121 # (enabled if this variable evaluates to true)
 122 our $projects_list_group_categories = 0;
 123
 124 # default category if none specified
 125 # (leave the empty string for no category)
 126 our $project_list_default_category = "";
 127
 128 # default order of projects list
 129 # valid values are none, project, descr, owner, and age
 130 our $default_projects_order = "project";
 131
 132 # show repository only if this file exists
 133 # (only effective if this variable evaluates to true)
 134 our $export_ok = "++GITWEB_EXPORT_OK++";
 135
 136 # show repository only if this subroutine returns true
 137 # when given the path to the project, for example:
 138 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 139 our $export_auth_hook = undef;
 140
 141 # only allow viewing of repositories also shown on the overview page
 142 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 143
 144 # list of git base URLs used for URL to where fetch project from,
 145 # i.e. full URL is "$git_base_url/$project"
 146 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 147
 148 # default blob_plain mimetype and default charset for text/plain blob
 149 our $default_blob_plain_mimetype = 'text/plain';
 150 our $default_text_plain_charset  = undef;
 151
 152 # file to use for guessing MIME types before trying /etc/mime.types
 153 # (relative to the current git repository)
 154 our $mimetypes_file = undef;
 155
 156 # assume this charset if line contains non-UTF-8 characters;
 157 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 158 # for which encoding all byte sequences are valid, for example
 159 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 160 # could be even 'utf-8' for the old behavior)
 161 our $fallback_encoding = 'latin1';
 162
 163 # rename detection options for git-diff and git-diff-tree
 164 # - default is '-M', with the cost proportional to
 165 #   (number of removed files) * (number of new files).
 166 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 167 #   (number of changed files + number of removed files) * (number of new files)
 168 # - even more costly is '-C', '--find-copies-harder' with cost
 169 #   (number of files in the original tree) * (number of new files)
 170 # - one might want to include '-B' option, e.g. '-B', '-M'
 171 our @diff_opts = ('-M'); # taken from git_commit
 172
 173 # Disables features that would allow repository owners to inject script into
 174 # the gitweb domain.
 175 our $prevent_xss = 0;
 176
 177 # Path to the highlight executable to use (must be the one from
 178 # http://www.andre-simon.de due to assumptions about parameters and output).
 179 # Useful if highlight is not installed on your webserver's PATH.
 180 # [Default: highlight]
 181 our $highlight_bin = "++HIGHLIGHT_BIN++";
 182
 183 # information about snapshot formats that gitweb is capable of serving
 184 our %known_snapshot_formats = (
 185         # name => {
 186         #       'display' => display name,
 187         #       'type' => mime type,
 188         #       'suffix' => filename suffix,
 189         #       'format' => --format for git-archive,
 190         #       'compressor' => [compressor command and arguments]
 191         #                       (array reference, optional)
 192         #       'disabled' => boolean (optional)}
 193         #
 194         'tgz' => {
 195                 'display' => 'tar.gz',
 196                 'type' => 'application/x-gzip',
 197                 'suffix' => '.tar.gz',
 198                 'format' => 'tar',
 199                 'compressor' => ['gzip', '-n']},
 200
 201         'tbz2' => {
 202                 'display' => 'tar.bz2',
 203                 'type' => 'application/x-bzip2',
 204                 'suffix' => '.tar.bz2',
 205                 'format' => 'tar',
 206                 'compressor' => ['bzip2']},
 207
 208         'txz' => {
 209                 'display' => 'tar.xz',
 210                 'type' => 'application/x-xz',
 211                 'suffix' => '.tar.xz',
 212                 'format' => 'tar',
 213                 'compressor' => ['xz'],
 214                 'disabled' => 1},
 215
 216         'zip' => {
 217                 'display' => 'zip',
 218                 'type' => 'application/x-zip',
 219                 'suffix' => '.zip',
 220                 'format' => 'zip'},
 221 );
 222
 223 # Aliases so we understand old gitweb.snapshot values in repository
 224 # configuration.
 225 our %known_snapshot_format_aliases = (
 226         'gzip'  => 'tgz',
 227         'bzip2' => 'tbz2',
 228         'xz'    => 'txz',
 229
 230         # backward compatibility: legacy gitweb config support
 231         'x-gzip' => undef, 'gz' => undef,
 232         'x-bzip2' => undef, 'bz2' => undef,
 233         'x-zip' => undef, '' => undef,
 234 );
 235
 236 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 237 # are changed, it may be appropriate to change these values too via
 238 # $GITWEB_CONFIG.
 239 our %avatar_size = (
 240         'default' => 16,
 241         'double'  => 32
 242 );
 243
 244 # Used to set the maximum load that we will still respond to gitweb queries.
 245 # If server load exceed this value then return "503 server busy" error.
 246 # If gitweb cannot determined server load, it is taken to be 0.
 247 # Leave it undefined (or set to 'undef') to turn off load checking.
 248 our $maxload = 300;
 249
 250 # configuration for 'highlight' (http://www.andre-simon.de/)
 251 # match by basename
 252 our %highlight_basename = (
 253         #'Program' => 'py',
 254         #'Library' => 'py',
 255         'SConstruct' => 'py', # SCons equivalent of Makefile
 256         'Makefile' => 'make',
 257 );
 258 # match by extension
 259 our %highlight_ext = (
 260         # main extensions, defining name of syntax;
 261         # see files in /usr/share/highlight/langDefs/ directory
 262         map { $_ => $_ }
 263                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 264         # alternate extensions, see /etc/highlight/filetypes.conf
 265         'h' => 'c',
 266         map { $_ => 'sh'  } qw(bash zsh ksh),
 267         map { $_ => 'cpp' } qw(cxx c++ cc),
 268         map { $_ => 'php' } qw(php3 php4 php5 phps),
 269         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 270         map { $_ => 'make'} qw(mak mk),
 271         map { $_ => 'xml' } qw(xhtml html htm),
 272 );
 273
 274 # You define site-wide feature defaults here; override them with
 275 # $GITWEB_CONFIG as necessary.
 276 our %feature = (
 277         # feature => {
 278         #       'sub' => feature-sub (subroutine),
 279         #       'override' => allow-override (boolean),
 280         #       'default' => [ default options...] (array reference)}
 281         #
 282         # if feature is overridable (it means that allow-override has true value),
 283         # then feature-sub will be called with default options as parameters;
 284         # return value of feature-sub indicates if to enable specified feature
 285         #
 286         # if there is no 'sub' key (no feature-sub), then feature cannot be
 287         # overridden
 288         #
 289         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 290         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 291         # is enabled
 292
 293         # Enable the 'blame' blob view, showing the last commit that modified
 294         # each line in the file. This can be very CPU-intensive.
 295
 296         # To enable system wide have in $GITWEB_CONFIG
 297         # $feature{'blame'}{'default'} = [1];
 298         # To have project specific config enable override in $GITWEB_CONFIG
 299         # $feature{'blame'}{'override'} = 1;
 300         # and in project config gitweb.blame = 0|1;
 301         'blame' => {
 302                 'sub' => sub { feature_bool('blame', @_) },
 303                 'override' => 0,
 304                 'default' => [0]},
 305
 306         # Enable the 'snapshot' link, providing a compressed archive of any
 307         # tree. This can potentially generate high traffic if you have large
 308         # project.
 309
 310         # Value is a list of formats defined in %known_snapshot_formats that
 311         # you wish to offer.
 312         # To disable system wide have in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'default'} = [];
 314         # To have project specific config enable override in $GITWEB_CONFIG
 315         # $feature{'snapshot'}{'override'} = 1;
 316         # and in project config, a comma-separated list of formats or "none"
 317         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 318         'snapshot' => {
 319                 'sub' => \&feature_snapshot,
 320                 'override' => 0,
 321                 'default' => ['tgz']},
 322
 323         # Enable text search, which will list the commits which match author,
 324         # committer or commit text to a given string.  Enabled by default.
 325         # Project specific override is not supported.
 326         #
 327         # Note that this controls all search features, which means that if
 328         # it is disabled, then 'grep' and 'pickaxe' search would also be
 329         # disabled.
 330         'search' => {
 331                 'override' => 0,
 332                 'default' => [1]},
 333
 334         # Enable grep search, which will list the files in currently selected
 335         # tree containing the given string. Enabled by default. This can be
 336         # potentially CPU-intensive, of course.
 337         # Note that you need to have 'search' feature enabled too.
 338
 339         # To enable system wide have in $GITWEB_CONFIG
 340         # $feature{'grep'}{'default'} = [1];
 341         # To have project specific config enable override in $GITWEB_CONFIG
 342         # $feature{'grep'}{'override'} = 1;
 343         # and in project config gitweb.grep = 0|1;
 344         'grep' => {
 345                 'sub' => sub { feature_bool('grep', @_) },
 346                 'override' => 0,
 347                 'default' => [1]},
 348
 349         # Enable the pickaxe search, which will list the commits that modified
 350         # a given string in a file. This can be practical and quite faster
 351         # alternative to 'blame', but still potentially CPU-intensive.
 352         # Note that you need to have 'search' feature enabled too.
 353
 354         # To enable system wide have in $GITWEB_CONFIG
 355         # $feature{'pickaxe'}{'default'} = [1];
 356         # To have project specific config enable override in $GITWEB_CONFIG
 357         # $feature{'pickaxe'}{'override'} = 1;
 358         # and in project config gitweb.pickaxe = 0|1;
 359         'pickaxe' => {
 360                 'sub' => sub { feature_bool('pickaxe', @_) },
 361                 'override' => 0,
 362                 'default' => [1]},
 363
 364         # Enable showing size of blobs in a 'tree' view, in a separate
 365         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 366
 367         # To disable system wide have in $GITWEB_CONFIG
 368         # $feature{'show-sizes'}{'default'} = [0];
 369         # To have project specific config enable override in $GITWEB_CONFIG
 370         # $feature{'show-sizes'}{'override'} = 1;
 371         # and in project config gitweb.showsizes = 0|1;
 372         'show-sizes' => {
 373                 'sub' => sub { feature_bool('showsizes', @_) },
 374                 'override' => 0,
 375                 'default' => [1]},
 376
 377         # Make gitweb use an alternative format of the URLs which can be
 378         # more readable and natural-looking: project name is embedded
 379         # directly in the path and the query string contains other
 380         # auxiliary information. All gitweb installations recognize
 381         # URL in either format; this configures in which formats gitweb
 382         # generates links.
 383
 384         # To enable system wide have in $GITWEB_CONFIG
 385         # $feature{'pathinfo'}{'default'} = [1];
 386         # Project specific override is not supported.
 387
 388         # Note that you will need to change the default location of CSS,
 389         # favicon, logo and possibly other files to an absolute URL. Also,
 390         # if gitweb.cgi serves as your indexfile, you will need to force
 391         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 392         'pathinfo' => {
 393                 'override' => 0,
 394                 'default' => [0]},
 395
 396         # Make gitweb consider projects in project root subdirectories
 397         # to be forks of existing projects. Given project $projname.git,
 398         # projects matching $projname/*.git will not be shown in the main
 399         # projects list, instead a '+' mark will be added to $projname
 400         # there and a 'forks' view will be enabled for the project, listing
 401         # all the forks. If project list is taken from a file, forks have
 402         # to be listed after the main project.
 403
 404         # To enable system wide have in $GITWEB_CONFIG
 405         # $feature{'forks'}{'default'} = [1];
 406         # Project specific override is not supported.
 407         'forks' => {
 408                 'override' => 0,
 409                 'default' => [0]},
 410
 411         # Insert custom links to the action bar of all project pages.
 412         # This enables you mainly to link to third-party scripts integrating
 413         # into gitweb; e.g. git-browser for graphical history representation
 414         # or custom web-based repository administration interface.
 415
 416         # The 'default' value consists of a list of triplets in the form
 417         # (label, link, position) where position is the label after which
 418         # to insert the link and link is a format string where %n expands
 419         # to the project name, %f to the project path within the filesystem,
 420         # %h to the current hash (h gitweb parameter) and %b to the current
 421         # hash base (hb gitweb parameter); %% expands to %.
 422
 423         # To enable system wide have in $GITWEB_CONFIG e.g.
 424         # $feature{'actions'}{'default'} = [('graphiclog',
 425         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 426         # Project specific override is not supported.
 427         'actions' => {
 428                 'override' => 0,
 429                 'default' => []},
 430
 431         # Allow gitweb scan project content tags of project repository,
 432         # and display the popular Web 2.0-ish "tag cloud" near the projects
 433         # list.  Note that this is something COMPLETELY different from the
 434         # normal Git tags.
 435
 436         # gitweb by itself can show existing tags, but it does not handle
 437         # tagging itself; you need to do it externally, outside gitweb.
 438         # The format is described in git_get_project_ctags() subroutine.
 439         # You may want to install the HTML::TagCloud Perl module to get
 440         # a pretty tag cloud instead of just a list of tags.
 441
 442         # To enable system wide have in $GITWEB_CONFIG
 443         # $feature{'ctags'}{'default'} = [1];
 444         # Project specific override is not supported.
 445
 446         # In the future whether ctags editing is enabled might depend
 447         # on the value, but using 1 should always mean no editing of ctags.
 448         'ctags' => {
 449                 'override' => 0,
 450                 'default' => [0]},
 451
 452         # The maximum number of patches in a patchset generated in patch
 453         # view. Set this to 0 or undef to disable patch view, or to a
 454         # negative number to remove any limit.
 455
 456         # To disable system wide have in $GITWEB_CONFIG
 457         # $feature{'patches'}{'default'} = [0];
 458         # To have project specific config enable override in $GITWEB_CONFIG
 459         # $feature{'patches'}{'override'} = 1;
 460         # and in project config gitweb.patches = 0|n;
 461         # where n is the maximum number of patches allowed in a patchset.
 462         'patches' => {
 463                 'sub' => \&feature_patches,
 464                 'override' => 0,
 465                 'default' => [16]},
 466
 467         # Avatar support. When this feature is enabled, views such as
 468         # shortlog or commit will display an avatar associated with
 469         # the email of the committer(s) and/or author(s).
 470
 471         # Currently available providers are gravatar and picon.
 472         # If an unknown provider is specified, the feature is disabled.
 473
 474         # Gravatar depends on Digest::MD5.
 475         # Picon currently relies on the indiana.edu database.
 476
 477         # To enable system wide have in $GITWEB_CONFIG
 478         # $feature{'avatar'}{'default'} = ['<provider>'];
 479         # where <provider> is either gravatar or picon.
 480         # To have project specific config enable override in $GITWEB_CONFIG
 481         # $feature{'avatar'}{'override'} = 1;
 482         # and in project config gitweb.avatar = <provider>;
 483         'avatar' => {
 484                 'sub' => \&feature_avatar,
 485                 'override' => 0,
 486                 'default' => ['']},
 487
 488         # Enable displaying how much time and how many git commands
 489         # it took to generate and display page.  Disabled by default.
 490         # Project specific override is not supported.
 491         'timed' => {
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable turning some links into links to actions which require
 496         # JavaScript to run (like 'blame_incremental').  Not enabled by
 497         # default.  Project specific override is currently not supported.
 498         'javascript-actions' => {
 499                 'override' => 0,
 500                 'default' => [0]},
 501
 502         # Enable and configure ability to change common timezone for dates
 503         # in gitweb output via JavaScript.  Enabled by default.
 504         # Project specific override is not supported.
 505         'javascript-timezone' => {
 506                 'override' => 0,
 507                 'default' => [
 508                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 509                                      # or undef to turn off this feature
 510                         'gitweb_tz', # name of cookie where to store selected timezone
 511                         'datetime',  # CSS class used to mark up dates for manipulation
 512                 ]},
 513
 514         # Syntax highlighting support. This is based on Daniel Svensson's
 515         # and Sham Chukoury's work in gitweb-xmms2.git.
 516         # It requires the 'highlight' program present in $PATH,
 517         # and therefore is disabled by default.
 518
 519         # To enable system wide have in $GITWEB_CONFIG
 520         # $feature{'highlight'}{'default'} = [1];
 521
 522         'highlight' => {
 523                 'sub' => sub { feature_bool('highlight', @_) },
 524                 'override' => 0,
 525                 'default' => [0]},
 526
 527         # Enable displaying of remote heads in the heads list
 528
 529         # To enable system wide have in $GITWEB_CONFIG
 530         # $feature{'remote_heads'}{'default'} = [1];
 531         # To have project specific config enable override in $GITWEB_CONFIG
 532         # $feature{'remote_heads'}{'override'} = 1;
 533         # and in project config gitweb.remote_heads = 0|1;
 534         'remote_heads' => {
 535                 'sub' => sub { feature_bool('remote_heads', @_) },
 536                 'override' => 0,
 537                 'default' => [0]},
 538 );
 539
 540 sub gitweb_get_feature {
 541         my ($name) = @_;
 542         return unless exists $feature{$name};
 543         my ($sub, $override, @defaults) = (
 544                 $feature{$name}{'sub'},
 545                 $feature{$name}{'override'},
 546                 @{$feature{$name}{'default'}});
 547         # project specific override is possible only if we have project
 548         our $git_dir; # global variable, declared later
 549         if (!$override || !defined $git_dir) {
 550                 return @defaults;
 551         }
 552         if (!defined $sub) {
 553                 warn "feature $name is not overridable";
 554                 return @defaults;
 555         }
 556         return $sub->(@defaults);
 557 }
 558
 559 # A wrapper to check if a given feature is enabled.
 560 # With this, you can say
 561 #
 562 #   my $bool_feat = gitweb_check_feature('bool_feat');
 563 #   gitweb_check_feature('bool_feat') or somecode;
 564 #
 565 # instead of
 566 #
 567 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 568 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 569 #
 570 sub gitweb_check_feature {
 571         return (gitweb_get_feature(@_))[0];
 572 }
 573
 574
 575 sub feature_bool {
 576         my $key = shift;
 577         my ($val) = git_get_project_config($key, '--bool');
 578
 579         if (!defined $val) {
 580                 return ($_[0]);
 581         } elsif ($val eq 'true') {
 582                 return (1);
 583         } elsif ($val eq 'false') {
 584                 return (0);
 585         }
 586 }
 587
 588 sub feature_snapshot {
 589         my (@fmts) = @_;
 590
 591         my ($val) = git_get_project_config('snapshot');
 592
 593         if ($val) {
 594                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 595         }
 596
 597         return @fmts;
 598 }
 599
 600 sub feature_patches {
 601         my @val = (git_get_project_config('patches', '--int'));
 602
 603         if (@val) {
 604                 return @val;
 605         }
 606
 607         return ($_[0]);
 608 }
 609
 610 sub feature_avatar {
 611         my @val = (git_get_project_config('avatar'));
 612
 613         return @val ? @val : @_;
 614 }
 615
 616 # checking HEAD file with -e is fragile if the repository was
 617 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 618 # and then pruned.
 619 sub check_head_link {
 620         my ($dir) = @_;
 621         my $headfile = "$dir/HEAD";
 622         return ((-e $headfile) ||
 623                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 624 }
 625
 626 sub check_export_ok {
 627         my ($dir) = @_;
 628         return (check_head_link($dir) &&
 629                 (!$export_ok || -e "$dir/$export_ok") &&
 630                 (!$export_auth_hook || $export_auth_hook->($dir)));
 631 }
 632
 633 # process alternate names for backward compatibility
 634 # filter out unsupported (unknown) snapshot formats
 635 sub filter_snapshot_fmts {
 636         my @fmts = @_;
 637
 638         @fmts = map {
 639                 exists $known_snapshot_format_aliases{$_} ?
 640                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 641         @fmts = grep {
 642                 exists $known_snapshot_formats{$_} &&
 643                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 644 }
 645
 646 # If it is set to code reference, it is code that it is to be run once per
 647 # request, allowing updating configurations that change with each request,
 648 # while running other code in config file only once.
 649 #
 650 # Otherwise, if it is false then gitweb would process config file only once;
 651 # if it is true then gitweb config would be run for each request.
 652 our $per_request_config = 1;
 653
 654 # read and parse gitweb config file given by its parameter.
 655 # returns true on success, false on recoverable error, allowing
 656 # to chain this subroutine, using first file that exists.
 657 # dies on errors during parsing config file, as it is unrecoverable.
 658 sub read_config_file {
 659         my $filename = shift;
 660         return unless defined $filename;
 661         # die if there are errors parsing config file
 662         if (-e $filename) {
 663                 do $filename;
 664                 die $@ if $@;
 665                 return 1;
 666         }
 667         return;
 668 }
 669
 670 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 671 sub evaluate_gitweb_config {
 672         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 673         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 674         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 675
 676         # Protect agains duplications of file names, to not read config twice.
 677         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 678         # there possibility of duplication of filename there doesn't matter.
 679         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 680         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 681
 682         # Common system-wide settings for convenience.
 683         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 684         read_config_file($GITWEB_CONFIG_COMMON);
 685
 686         # Use first config file that exists.  This means use the per-instance
 687         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 688         read_config_file($GITWEB_CONFIG) and return;
 689         read_config_file($GITWEB_CONFIG_SYSTEM);
 690 }
 691
 692 # Get loadavg of system, to compare against $maxload.
 693 # Currently it requires '/proc/loadavg' present to get loadavg;
 694 # if it is not present it returns 0, which means no load checking.
 695 sub get_loadavg {
 696         if( -e '/proc/loadavg' ){
 697                 open my $fd, '<', '/proc/loadavg'
 698                         or return 0;
 699                 my @load = split(/\s+/, scalar <$fd>);
 700                 close $fd;
 701
 702                 # The first three columns measure CPU and IO utilization of the last one,
 703                 # five, and 10 minute periods.  The fourth column shows the number of
 704                 # currently running processes and the total number of processes in the m/n
 705                 # format.  The last column displays the last process ID used.
 706                 return $load[0] || 0;
 707         }
 708         # additional checks for load average should go here for things that don't export
 709         # /proc/loadavg
 710
 711         return 0;
 712 }
 713
 714 # version of the core git binary
 715 our $git_version;
 716 sub evaluate_git_version {
 717         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 718         $number_of_git_cmds++;
 719 }
 720
 721 sub check_loadavg {
 722         if (defined $maxload && get_loadavg() > $maxload) {
 723                 die_error(503, "The load average on the server is too high");
 724         }
 725 }
 726
 727 # ======================================================================
 728 # input validation and dispatch
 729
 730 # input parameters can be collected from a variety of sources (presently, CGI
 731 # and PATH_INFO), so we define an %input_params hash that collects them all
 732 # together during validation: this allows subsequent uses (e.g. href()) to be
 733 # agnostic of the parameter origin
 734
 735 our %input_params = ();
 736
 737 # input parameters are stored with the long parameter name as key. This will
 738 # also be used in the href subroutine to convert parameters to their CGI
 739 # equivalent, and since the href() usage is the most frequent one, we store
 740 # the name -> CGI key mapping here, instead of the reverse.
 741 #
 742 # XXX: Warning: If you touch this, check the search form for updating,
 743 # too.
 744
 745 our @cgi_param_mapping = (
 746         project => "p",
 747         action => "a",
 748         file_name => "f",
 749         file_parent => "fp",
 750         hash => "h",
 751         hash_parent => "hp",
 752         hash_base => "hb",
 753         hash_parent_base => "hpb",
 754         page => "pg",
 755         order => "o",
 756         searchtext => "s",
 757         searchtype => "st",
 758         snapshot_format => "sf",
 759         extra_options => "opt",
 760         search_use_regexp => "sr",
 761         ctag => "by_tag",
 762         # this must be last entry (for manipulation from JavaScript)
 763         javascript => "js"
 764 );
 765 our %cgi_param_mapping = @cgi_param_mapping;
 766
 767 # we will also need to know the possible actions, for validation
 768 our %actions = (
 769         "blame" => \&git_blame,
 770         "blame_incremental" => \&git_blame_incremental,
 771         "blame_data" => \&git_blame_data,
 772         "blobdiff" => \&git_blobdiff,
 773         "blobdiff_plain" => \&git_blobdiff_plain,
 774         "blob" => \&git_blob,
 775         "blob_plain" => \&git_blob_plain,
 776         "commitdiff" => \&git_commitdiff,
 777         "commitdiff_plain" => \&git_commitdiff_plain,
 778         "commit" => \&git_commit,
 779         "forks" => \&git_forks,
 780         "heads" => \&git_heads,
 781         "history" => \&git_history,
 782         "log" => \&git_log,
 783         "patch" => \&git_patch,
 784         "patches" => \&git_patches,
 785         "remotes" => \&git_remotes,
 786         "rss" => \&git_rss,
 787         "atom" => \&git_atom,
 788         "search" => \&git_search,
 789         "search_help" => \&git_search_help,
 790         "shortlog" => \&git_shortlog,
 791         "summary" => \&git_summary,
 792         "tag" => \&git_tag,
 793         "tags" => \&git_tags,
 794         "tree" => \&git_tree,
 795         "snapshot" => \&git_snapshot,
 796         "object" => \&git_object,
 797         # those below don't need $project
 798         "opml" => \&git_opml,
 799         "project_list" => \&git_project_list,
 800         "project_index" => \&git_project_index,
 801 );
 802
 803 # finally, we have the hash of allowed extra_options for the commands that
 804 # allow them
 805 our %allowed_options = (
 806         "--no-merges" => [ qw(rss atom log shortlog history) ],
 807 );
 808
 809 # fill %input_params with the CGI parameters. All values except for 'opt'
 810 # should be single values, but opt can be an array. We should probably
 811 # build an array of parameters that can be multi-valued, but since for the time
 812 # being it's only this one, we just single it out
 813 sub evaluate_query_params {
 814         our $cgi;
 815
 816         while (my ($name, $symbol) = each %cgi_param_mapping) {
 817                 if ($symbol eq 'opt') {
 818                         $input_params{$name} = [ $cgi->param($symbol) ];
 819                 } else {
 820                         $input_params{$name} = $cgi->param($symbol);
 821                 }
 822         }
 823 }
 824
 825 # now read PATH_INFO and update the parameter list for missing parameters
 826 sub evaluate_path_info {
 827         return if defined $input_params{'project'};
 828         return if !$path_info;
 829         $path_info =~ s,^/+,,;
 830         return if !$path_info;
 831
 832         # find which part of PATH_INFO is project
 833         my $project = $path_info;
 834         $project =~ s,/+$,,;
 835         while ($project && !check_head_link("$projectroot/$project")) {
 836                 $project =~ s,/*[^/]*$,,;
 837         }
 838         return unless $project;
 839         $input_params{'project'} = $project;
 840
 841         # do not change any parameters if an action is given using the query string
 842         return if $input_params{'action'};
 843         $path_info =~ s,^\Q$project\E/*,,;
 844
 845         # next, check if we have an action
 846         my $action = $path_info;
 847         $action =~ s,/.*$,,;
 848         if (exists $actions{$action}) {
 849                 $path_info =~ s,^$action/*,,;
 850                 $input_params{'action'} = $action;
 851         }
 852
 853         # list of actions that want hash_base instead of hash, but can have no
 854         # pathname (f) parameter
 855         my @wants_base = (
 856                 'tree',
 857                 'history',
 858         );
 859
 860         # we want to catch, among others
 861         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 862         my ($parentrefname, $parentpathname, $refname, $pathname) =
 863                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 864
 865         # first, analyze the 'current' part
 866         if (defined $pathname) {
 867                 # we got "branch:filename" or "branch:dir/"
 868                 # we could use git_get_type(branch:pathname), but:
 869                 # - it needs $git_dir
 870                 # - it does a git() call
 871                 # - the convention of terminating directories with a slash
 872                 #   makes it superfluous
 873                 # - embedding the action in the PATH_INFO would make it even
 874                 #   more superfluous
 875                 $pathname =~ s,^/+,,;
 876                 if (!$pathname || substr($pathname, -1) eq "/") {
 877                         $input_params{'action'} ||= "tree";
 878                         $pathname =~ s,/$,,;
 879                 } else {
 880                         # the default action depends on whether we had parent info
 881                         # or not
 882                         if ($parentrefname) {
 883                                 $input_params{'action'} ||= "blobdiff_plain";
 884                         } else {
 885                                 $input_params{'action'} ||= "blob_plain";
 886                         }
 887                 }
 888                 $input_params{'hash_base'} ||= $refname;
 889                 $input_params{'file_name'} ||= $pathname;
 890         } elsif (defined $refname) {
 891                 # we got "branch". In this case we have to choose if we have to
 892                 # set hash or hash_base.
 893                 #
 894                 # Most of the actions without a pathname only want hash to be
 895                 # set, except for the ones specified in @wants_base that want
 896                 # hash_base instead. It should also be noted that hand-crafted
 897                 # links having 'history' as an action and no pathname or hash
 898                 # set will fail, but that happens regardless of PATH_INFO.
 899                 if (defined $parentrefname) {
 900                         # if there is parent let the default be 'shortlog' action
 901                         # (for http://git.example.com/repo.git/A..B links); if there
 902                         # is no parent, dispatch will detect type of object and set
 903                         # action appropriately if required (if action is not set)
 904                         $input_params{'action'} ||= "shortlog";
 905                 }
 906                 if ($input_params{'action'} &&
 907                     grep { $_ eq $input_params{'action'} } @wants_base) {
 908                         $input_params{'hash_base'} ||= $refname;
 909                 } else {
 910                         $input_params{'hash'} ||= $refname;
 911                 }
 912         }
 913
 914         # next, handle the 'parent' part, if present
 915         if (defined $parentrefname) {
 916                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 917                 # someproject/blobdiff/oldrev..newrev:/filename
 918                 if ($parentpathname) {
 919                         $parentpathname =~ s,^/+,,;
 920                         $parentpathname =~ s,/$,,;
 921                         $input_params{'file_parent'} ||= $parentpathname;
 922                 } else {
 923                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 924                 }
 925                 # we assume that hash_parent_base is wanted if a path was specified,
 926                 # or if the action wants hash_base instead of hash
 927                 if (defined $input_params{'file_parent'} ||
 928                         grep { $_ eq $input_params{'action'} } @wants_base) {
 929                         $input_params{'hash_parent_base'} ||= $parentrefname;
 930                 } else {
 931                         $input_params{'hash_parent'} ||= $parentrefname;
 932                 }
 933         }
 934
 935         # for the snapshot action, we allow URLs in the form
 936         # $project/snapshot/$hash.ext
 937         # where .ext determines the snapshot and gets removed from the
 938         # passed $refname to provide the $hash.
 939         #
 940         # To be able to tell that $refname includes the format extension, we
 941         # require the following two conditions to be satisfied:
 942         # - the hash input parameter MUST have been set from the $refname part
 943         #   of the URL (i.e. they must be equal)
 944         # - the snapshot format MUST NOT have been defined already (e.g. from
 945         #   CGI parameter sf)
 946         # It's also useless to try any matching unless $refname has a dot,
 947         # so we check for that too
 948         if (defined $input_params{'action'} &&
 949                 $input_params{'action'} eq 'snapshot' &&
 950                 defined $refname && index($refname, '.') != -1 &&
 951                 $refname eq $input_params{'hash'} &&
 952                 !defined $input_params{'snapshot_format'}) {
 953                 # We loop over the known snapshot formats, checking for
 954                 # extensions. Allowed extensions are both the defined suffix
 955                 # (which includes the initial dot already) and the snapshot
 956                 # format key itself, with a prepended dot
 957                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 958                         my $hash = $refname;
 959                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 960                                 next;
 961                         }
 962                         my $sfx = $1;
 963                         # a valid suffix was found, so set the snapshot format
 964                         # and reset the hash parameter
 965                         $input_params{'snapshot_format'} = $fmt;
 966                         $input_params{'hash'} = $hash;
 967                         # we also set the format suffix to the one requested
 968                         # in the URL: this way a request for e.g. .tgz returns
 969                         # a .tgz instead of a .tar.gz
 970                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 971                         last;
 972                 }
 973         }
 974 }
 975
 976 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 977      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 978      $searchtext, $search_regexp);
 979 sub evaluate_and_validate_params {
 980         our $action = $input_params{'action'};
 981         if (defined $action) {
 982                 if (!validate_action($action)) {
 983                         die_error(400, "Invalid action parameter");
 984                 }
 985         }
 986
 987         # parameters which are pathnames
 988         our $project = $input_params{'project'};
 989         if (defined $project) {
 990                 if (!validate_project($project)) {
 991                         undef $project;
 992                         die_error(404, "No such project");
 993                 }
 994         }
 995
 996         our $file_name = $input_params{'file_name'};
 997         if (defined $file_name) {
 998                 if (!validate_pathname($file_name)) {
 999                         die_error(400, "Invalid file parameter");
1000                 }
1001         }
1002
1003         our $file_parent = $input_params{'file_parent'};
1004         if (defined $file_parent) {
1005                 if (!validate_pathname($file_parent)) {
1006                         die_error(400, "Invalid file parent parameter");
1007                 }
1008         }
1009
1010         # parameters which are refnames
1011         our $hash = $input_params{'hash'};
1012         if (defined $hash) {
1013                 if (!validate_refname($hash)) {
1014                         die_error(400, "Invalid hash parameter");
1015                 }
1016         }
1017
1018         our $hash_parent = $input_params{'hash_parent'};
1019         if (defined $hash_parent) {
1020                 if (!validate_refname($hash_parent)) {
1021                         die_error(400, "Invalid hash parent parameter");
1022                 }
1023         }
1024
1025         our $hash_base = $input_params{'hash_base'};
1026         if (defined $hash_base) {
1027                 if (!validate_refname($hash_base)) {
1028                         die_error(400, "Invalid hash base parameter");
1029                 }
1030         }
1031
1032         our @extra_options = @{$input_params{'extra_options'}};
1033         # @extra_options is always defined, since it can only be (currently) set from
1034         # CGI, and $cgi->param() returns the empty array in array context if the param
1035         # is not set
1036         foreach my $opt (@extra_options) {
1037                 if (not exists $allowed_options{$opt}) {
1038                         die_error(400, "Invalid option parameter");
1039                 }
1040                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1041                         die_error(400, "Invalid option parameter for this action");
1042                 }
1043         }
1044
1045         our $hash_parent_base = $input_params{'hash_parent_base'};
1046         if (defined $hash_parent_base) {
1047                 if (!validate_refname($hash_parent_base)) {
1048                         die_error(400, "Invalid hash parent base parameter");
1049                 }
1050         }
1051
1052         # other parameters
1053         our $page = $input_params{'page'};
1054         if (defined $page) {
1055                 if ($page =~ m/[^0-9]/) {
1056                         die_error(400, "Invalid page parameter");
1057                 }
1058         }
1059
1060         our $searchtype = $input_params{'searchtype'};
1061         if (defined $searchtype) {
1062                 if ($searchtype =~ m/[^a-z]/) {
1063                         die_error(400, "Invalid searchtype parameter");
1064                 }
1065         }
1066
1067         our $search_use_regexp = $input_params{'search_use_regexp'};
1068
1069         our $searchtext = $input_params{'searchtext'};
1070         our $search_regexp;
1071         if (defined $searchtext) {
1072                 if (length($searchtext) < 2) {
1073                         die_error(403, "At least two characters are required for search parameter");
1074                 }
1075                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1076         }
1077 }
1078
1079 # path to the current git repository
1080 our $git_dir;
1081 sub evaluate_git_dir {
1082         our $git_dir = "$projectroot/$project" if $project;
1083 }
1084
1085 our (@snapshot_fmts, $git_avatar);
1086 sub configure_gitweb_features {
1087         # list of supported snapshot formats
1088         our @snapshot_fmts = gitweb_get_feature('snapshot');
1089         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1090
1091         # check that the avatar feature is set to a known provider name,
1092         # and for each provider check if the dependencies are satisfied.
1093         # if the provider name is invalid or the dependencies are not met,
1094         # reset $git_avatar to the empty string.
1095         our ($git_avatar) = gitweb_get_feature('avatar');
1096         if ($git_avatar eq 'gravatar') {
1097                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1098         } elsif ($git_avatar eq 'picon') {
1099                 # no dependencies
1100         } else {
1101                 $git_avatar = '';
1102         }
1103 }
1104
1105 # custom error handler: 'die <message>' is Internal Server Error
1106 sub handle_errors_html {
1107         my $msg = shift; # it is already HTML escaped
1108
1109         # to avoid infinite loop where error occurs in die_error,
1110         # change handler to default handler, disabling handle_errors_html
1111         set_message("Error occured when inside die_error:\n$msg");
1112
1113         # you cannot jump out of die_error when called as error handler;
1114         # the subroutine set via CGI::Carp::set_message is called _after_
1115         # HTTP headers are already written, so it cannot write them itself
1116         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1117 }
1118 set_message(\&handle_errors_html);
1119
1120 # dispatch
1121 sub dispatch {
1122         if (!defined $action) {
1123                 if (defined $hash) {
1124                         $action = git_get_type($hash);
1125                 } elsif (defined $hash_base && defined $file_name) {
1126                         $action = git_get_type("$hash_base:$file_name");
1127                 } elsif (defined $project) {
1128                         $action = 'summary';
1129                 } else {
1130                         $action = 'project_list';
1131                 }
1132         }
1133         if (!defined($actions{$action})) {
1134                 die_error(400, "Unknown action");
1135         }
1136         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1137             !$project) {
1138                 die_error(400, "Project needed");
1139         }
1140         $actions{$action}->();
1141 }
1142
1143 sub reset_timer {
1144         our $t0 = [ gettimeofday() ]
1145                 if defined $t0;
1146         our $number_of_git_cmds = 0;
1147 }
1148
1149 our $first_request = 1;
1150 sub run_request {
1151         reset_timer();
1152
1153         evaluate_uri();
1154         if ($first_request) {
1155                 evaluate_gitweb_config();
1156                 evaluate_git_version();
1157         }
1158         if ($per_request_config) {
1159                 if (ref($per_request_config) eq 'CODE') {
1160                         $per_request_config->();
1161                 } elsif (!$first_request) {
1162                         evaluate_gitweb_config();
1163                 }
1164         }
1165         check_loadavg();
1166
1167         # $projectroot and $projects_list might be set in gitweb config file
1168         $projects_list ||= $projectroot;
1169
1170         evaluate_query_params();
1171         evaluate_path_info();
1172         evaluate_and_validate_params();
1173         evaluate_git_dir();
1174
1175         configure_gitweb_features();
1176
1177         dispatch();
1178 }
1179
1180 our $is_last_request = sub { 1 };
1181 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1182 our $CGI = 'CGI';
1183 our $cgi;
1184 sub configure_as_fcgi {
1185         require CGI::Fast;
1186         our $CGI = 'CGI::Fast';
1187
1188         my $request_number = 0;
1189         # let each child service 100 requests
1190         our $is_last_request = sub { ++$request_number > 100 };
1191 }
1192 sub evaluate_argv {
1193         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1194         configure_as_fcgi()
1195                 if $script_name =~ /\.fcgi$/;
1196
1197         return unless (@ARGV);
1198
1199         require Getopt::Long;
1200         Getopt::Long::GetOptions(
1201                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1202                 'nproc|n=i' => sub {
1203                         my ($arg, $val) = @_;
1204                         return unless eval { require FCGI::ProcManager; 1; };
1205                         my $proc_manager = FCGI::ProcManager->new({
1206                                 n_processes => $val,
1207                         });
1208                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1209                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1210                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1211                 },
1212         );
1213 }
1214
1215 sub run {
1216         evaluate_argv();
1217
1218         $first_request = 1;
1219         $pre_listen_hook->()
1220                 if $pre_listen_hook;
1221
1222  REQUEST:
1223         while ($cgi = $CGI->new()) {
1224                 $pre_dispatch_hook->()
1225                         if $pre_dispatch_hook;
1226
1227                 run_request();
1228
1229                 $post_dispatch_hook->()
1230                         if $post_dispatch_hook;
1231                 $first_request = 0;
1232
1233                 last REQUEST if ($is_last_request->());
1234         }
1235
1236  DONE_GITWEB:
1237         1;
1238 }
1239
1240 run();
1241
1242 if (defined caller) {
1243         # wrapped in a subroutine processing requests,
1244         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1245         return;
1246 } else {
1247         # pure CGI script, serving single request
1248         exit;
1249 }
1250
1251 ## ======================================================================
1252 ## action links
1253
1254 # possible values of extra options
1255 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1256 # -replay => 1      - start from a current view (replay with modifications)
1257 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1258 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1259 sub href {
1260         my %params = @_;
1261         # default is to use -absolute url() i.e. $my_uri
1262         my $href = $params{-full} ? $my_url : $my_uri;
1263
1264         # implicit -replay, must be first of implicit params
1265         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1266
1267         $params{'project'} = $project unless exists $params{'project'};
1268
1269         if ($params{-replay}) {
1270                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1271                         if (!exists $params{$name}) {
1272                                 $params{$name} = $input_params{$name};
1273                         }
1274                 }
1275         }
1276
1277         my $use_pathinfo = gitweb_check_feature('pathinfo');
1278         if (defined $params{'project'} &&
1279             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1280                 # try to put as many parameters as possible in PATH_INFO:
1281                 #   - project name
1282                 #   - action
1283                 #   - hash_parent or hash_parent_base:/file_parent
1284                 #   - hash or hash_base:/filename
1285                 #   - the snapshot_format as an appropriate suffix
1286
1287                 # When the script is the root DirectoryIndex for the domain,
1288                 # $href here would be something like http://gitweb.example.com/
1289                 # Thus, we strip any trailing / from $href, to spare us double
1290                 # slashes in the final URL
1291                 $href =~ s,/$,,;
1292
1293                 # Then add the project name, if present
1294                 $href .= "/".esc_path_info($params{'project'});
1295                 delete $params{'project'};
1296
1297                 # since we destructively absorb parameters, we keep this
1298                 # boolean that remembers if we're handling a snapshot
1299                 my $is_snapshot = $params{'action'} eq 'snapshot';
1300
1301                 # Summary just uses the project path URL, any other action is
1302                 # added to the URL
1303                 if (defined $params{'action'}) {
1304                         $href .= "/".esc_path_info($params{'action'})
1305                                 unless $params{'action'} eq 'summary';
1306                         delete $params{'action'};
1307                 }
1308
1309                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1310                 # stripping nonexistent or useless pieces
1311                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1312                         || $params{'hash_parent'} || $params{'hash'});
1313                 if (defined $params{'hash_base'}) {
1314                         if (defined $params{'hash_parent_base'}) {
1315                                 $href .= esc_path_info($params{'hash_parent_base'});
1316                                 # skip the file_parent if it's the same as the file_name
1317                                 if (defined $params{'file_parent'}) {
1318                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1319                                                 delete $params{'file_parent'};
1320                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1321                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1322                                                 delete $params{'file_parent'};
1323                                         }
1324                                 }
1325                                 $href .= "..";
1326                                 delete $params{'hash_parent'};
1327                                 delete $params{'hash_parent_base'};
1328                         } elsif (defined $params{'hash_parent'}) {
1329                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1330                                 delete $params{'hash_parent'};
1331                         }
1332
1333                         $href .= esc_path_info($params{'hash_base'});
1334                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1335                                 $href .= ":/".esc_path_info($params{'file_name'});
1336                                 delete $params{'file_name'};
1337                         }
1338                         delete $params{'hash'};
1339                         delete $params{'hash_base'};
1340                 } elsif (defined $params{'hash'}) {
1341                         $href .= esc_path_info($params{'hash'});
1342                         delete $params{'hash'};
1343                 }
1344
1345                 # If the action was a snapshot, we can absorb the
1346                 # snapshot_format parameter too
1347                 if ($is_snapshot) {
1348                         my $fmt = $params{'snapshot_format'};
1349                         # snapshot_format should always be defined when href()
1350                         # is called, but just in case some code forgets, we
1351                         # fall back to the default
1352                         $fmt ||= $snapshot_fmts[0];
1353                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1354                         delete $params{'snapshot_format'};
1355                 }
1356         }
1357
1358         # now encode the parameters explicitly
1359         my @result = ();
1360         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1361                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1362                 if (defined $params{$name}) {
1363                         if (ref($params{$name}) eq "ARRAY") {
1364                                 foreach my $par (@{$params{$name}}) {
1365                                         push @result, $symbol . "=" . esc_param($par);
1366                                 }
1367                         } else {
1368                                 push @result, $symbol . "=" . esc_param($params{$name});
1369                         }
1370                 }
1371         }
1372         $href .= "?" . join(';', @result) if scalar @result;
1373
1374         # final transformation: trailing spaces must be escaped (URI-encoded)
1375         $href =~ s/(\s+)$/CGI::escape($1)/e;
1376
1377         if ($params{-anchor}) {
1378                 $href .= "#".esc_param($params{-anchor});
1379         }
1380
1381         return $href;
1382 }
1383
1384
1385 ## ======================================================================
1386 ## validation, quoting/unquoting and escaping
1387
1388 sub validate_action {
1389         my $input = shift || return undef;
1390         return undef unless exists $actions{$input};
1391         return $input;
1392 }
1393
1394 sub validate_project {
1395         my $input = shift || return undef;
1396         if (!validate_pathname($input) ||
1397                 !(-d "$projectroot/$input") ||
1398                 !check_export_ok("$projectroot/$input") ||
1399                 ($strict_export && !project_in_list($input))) {
1400                 return undef;
1401         } else {
1402                 return $input;
1403         }
1404 }
1405
1406 sub validate_pathname {
1407         my $input = shift || return undef;
1408
1409         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1410         # at the beginning, at the end, and between slashes.
1411         # also this catches doubled slashes
1412         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1413                 return undef;
1414         }
1415         # no null characters
1416         if ($input =~ m!\0!) {
1417                 return undef;
1418         }
1419         return $input;
1420 }
1421
1422 sub validate_refname {
1423         my $input = shift || return undef;
1424
1425         # textual hashes are O.K.
1426         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1427                 return $input;
1428         }
1429         # it must be correct pathname
1430         $input = validate_pathname($input)
1431                 or return undef;
1432         # restrictions on ref name according to git-check-ref-format
1433         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1434                 return undef;
1435         }
1436         return $input;
1437 }
1438
1439 # decode sequences of octets in utf8 into Perl's internal form,
1440 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1441 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1442 sub to_utf8 {
1443         my $str = shift;
1444         return undef unless defined $str;
1445
1446         if (utf8::is_utf8($str) || utf8::decode($str)) {
1447                 return $str;
1448         } else {
1449                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1450         }
1451 }
1452
1453 # quote unsafe chars, but keep the slash, even when it's not
1454 # correct, but quoted slashes look too horrible in bookmarks
1455 sub esc_param {
1456         my $str = shift;
1457         return undef unless defined $str;
1458         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1459         $str =~ s/ /\+/g;
1460         return $str;
1461 }
1462
1463 # the quoting rules for path_info fragment are slightly different
1464 sub esc_path_info {
1465         my $str = shift;
1466         return undef unless defined $str;
1467
1468         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1469         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1470
1471         return $str;
1472 }
1473
1474 # quote unsafe chars in whole URL, so some characters cannot be quoted
1475 sub esc_url {
1476         my $str = shift;
1477         return undef unless defined $str;
1478         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1479         $str =~ s/ /\+/g;
1480         return $str;
1481 }
1482
1483 # quote unsafe characters in HTML attributes
1484 sub esc_attr {
1485
1486         # for XHTML conformance escaping '"' to '&quot;' is not enough
1487         return esc_html(@_);
1488 }
1489
1490 # replace invalid utf8 character with SUBSTITUTION sequence
1491 sub esc_html {
1492         my $str = shift;
1493         my %opts = @_;
1494
1495         return undef unless defined $str;
1496
1497         $str = to_utf8($str);
1498         $str = $cgi->escapeHTML($str);
1499         if ($opts{'-nbsp'}) {
1500                 $str =~ s/ /&nbsp;/g;
1501         }
1502         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1503         return $str;
1504 }
1505
1506 # quote control characters and escape filename to HTML
1507 sub esc_path {
1508         my $str = shift;
1509         my %opts = @_;
1510
1511         return undef unless defined $str;
1512
1513         $str = to_utf8($str);
1514         $str = $cgi->escapeHTML($str);
1515         if ($opts{'-nbsp'}) {
1516                 $str =~ s/ /&nbsp;/g;
1517         }
1518         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1519         return $str;
1520 }
1521
1522 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1523 sub sanitize {
1524         my $str = shift;
1525
1526         return undef unless defined $str;
1527
1528         $str = to_utf8($str);
1529         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1530         return $str;
1531 }
1532
1533 # Make control characters "printable", using character escape codes (CEC)
1534 sub quot_cec {
1535         my $cntrl = shift;
1536         my %opts = @_;
1537         my %es = ( # character escape codes, aka escape sequences
1538                 "\t" => '\t',   # tab            (HT)
1539                 "\n" => '\n',   # line feed      (LF)
1540                 "\r" => '\r',   # carrige return (CR)
1541                 "\f" => '\f',   # form feed      (FF)
1542                 "\b" => '\b',   # backspace      (BS)
1543                 "\a" => '\a',   # alarm (bell)   (BEL)
1544                 "\e" => '\e',   # escape         (ESC)
1545                 "\013" => '\v', # vertical tab   (VT)
1546                 "\000" => '\0', # nul character  (NUL)
1547         );
1548         my $chr = ( (exists $es{$cntrl})
1549                     ? $es{$cntrl}
1550                     : sprintf('\%2x', ord($cntrl)) );
1551         if ($opts{-nohtml}) {
1552                 return $chr;
1553         } else {
1554                 return "<span class=\"cntrl\">$chr</span>";
1555         }
1556 }
1557
1558 # Alternatively use unicode control pictures codepoints,
1559 # Unicode "printable representation" (PR)
1560 sub quot_upr {
1561         my $cntrl = shift;
1562         my %opts = @_;
1563
1564         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1565         if ($opts{-nohtml}) {
1566                 return $chr;
1567         } else {
1568                 return "<span class=\"cntrl\">$chr</span>";
1569         }
1570 }
1571
1572 # git may return quoted and escaped filenames
1573 sub unquote {
1574         my $str = shift;
1575
1576         sub unq {
1577                 my $seq = shift;
1578                 my %es = ( # character escape codes, aka escape sequences
1579                         't' => "\t",   # tab            (HT, TAB)
1580                         'n' => "\n",   # newline        (NL)
1581                         'r' => "\r",   # return         (CR)
1582                         'f' => "\f",   # form feed      (FF)
1583                         'b' => "\b",   # backspace      (BS)
1584                         'a' => "\a",   # alarm (bell)   (BEL)
1585                         'e' => "\e",   # escape         (ESC)
1586                         'v' => "\013", # vertical tab   (VT)
1587                 );
1588
1589                 if ($seq =~ m/^[0-7]{1,3}$/) {
1590                         # octal char sequence
1591                         return chr(oct($seq));
1592                 } elsif (exists $es{$seq}) {
1593                         # C escape sequence, aka character escape code
1594                         return $es{$seq};
1595                 }
1596                 # quoted ordinary character
1597                 return $seq;
1598         }
1599
1600         if ($str =~ m/^"(.*)"$/) {
1601                 # needs unquoting
1602                 $str = $1;
1603                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1604         }
1605         return $str;
1606 }
1607
1608 # escape tabs (convert tabs to spaces)
1609 sub untabify {
1610         my $line = shift;
1611
1612         while ((my $pos = index($line, "\t")) != -1) {
1613                 if (my $count = (8 - ($pos % 8))) {
1614                         my $spaces = ' ' x $count;
1615                         $line =~ s/\t/$spaces/;
1616                 }
1617         }
1618
1619         return $line;
1620 }
1621
1622 sub project_in_list {
1623         my $project = shift;
1624         my @list = git_get_projects_list();
1625         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1626 }
1627
1628 ## ----------------------------------------------------------------------
1629 ## HTML aware string manipulation
1630
1631 # Try to chop given string on a word boundary between position
1632 # $len and $len+$add_len. If there is no word boundary there,
1633 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1634 # (marking chopped part) would be longer than given string.
1635 sub chop_str {
1636         my $str = shift;
1637         my $len = shift;
1638         my $add_len = shift || 10;
1639         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1640
1641         # Make sure perl knows it is utf8 encoded so we don't
1642         # cut in the middle of a utf8 multibyte char.
1643         $str = to_utf8($str);
1644
1645         # allow only $len chars, but don't cut a word if it would fit in $add_len
1646         # if it doesn't fit, cut it if it's still longer than the dots we would add
1647         # remove chopped character entities entirely
1648
1649         # when chopping in the middle, distribute $len into left and right part
1650         # return early if chopping wouldn't make string shorter
1651         if ($where eq 'center') {
1652                 return $str if ($len + 5 >= length($str)); # filler is length 5
1653                 $len = int($len/2);
1654         } else {
1655                 return $str if ($len + 4 >= length($str)); # filler is length 4
1656         }
1657
1658         # regexps: ending and beginning with word part up to $add_len
1659         my $endre = qr/.{$len}\w{0,$add_len}/;
1660         my $begre = qr/\w{0,$add_len}.{$len}/;
1661
1662         if ($where eq 'left') {
1663                 $str =~ m/^(.*?)($begre)$/;
1664                 my ($lead, $body) = ($1, $2);
1665                 if (length($lead) > 4) {
1666                         $lead = " ...";
1667                 }
1668                 return "$lead$body";
1669
1670         } elsif ($where eq 'center') {
1671                 $str =~ m/^($endre)(.*)$/;
1672                 my ($left, $str)  = ($1, $2);
1673                 $str =~ m/^(.*?)($begre)$/;
1674                 my ($mid, $right) = ($1, $2);
1675                 if (length($mid) > 5) {
1676                         $mid = " ... ";
1677                 }
1678                 return "$left$mid$right";
1679
1680         } else {
1681                 $str =~ m/^($endre)(.*)$/;
1682                 my $body = $1;
1683                 my $tail = $2;
1684                 if (length($tail) > 4) {
1685                         $tail = "... ";
1686                 }
1687                 return "$body$tail";
1688         }
1689 }
1690
1691 # takes the same arguments as chop_str, but also wraps a <span> around the
1692 # result with a title attribute if it does get chopped. Additionally, the
1693 # string is HTML-escaped.
1694 sub chop_and_escape_str {
1695         my ($str) = @_;
1696
1697         my $chopped = chop_str(@_);
1698         $str = to_utf8($str);
1699         if ($chopped eq $str) {
1700                 return esc_html($chopped);
1701         } else {
1702                 $str =~ s/[[:cntrl:]]/?/g;
1703                 return $cgi->span({-title=>$str}, esc_html($chopped));
1704         }
1705 }
1706
1707 ## ----------------------------------------------------------------------
1708 ## functions returning short strings
1709
1710 # CSS class for given age value (in seconds)
1711 sub age_class {
1712         my $age = shift;
1713
1714         if (!defined $age) {
1715                 return "noage";
1716         } elsif ($age < 60*60*2) {
1717                 return "age0";
1718         } elsif ($age < 60*60*24*2) {
1719                 return "age1";
1720         } else {
1721                 return "age2";
1722         }
1723 }
1724
1725 # convert age in seconds to "nn units ago" string
1726 sub age_string {
1727         my $age = shift;
1728         my $age_str;
1729
1730         if ($age > 60*60*24*365*2) {
1731                 $age_str = (int $age/60/60/24/365);
1732                 $age_str .= " years ago";
1733         } elsif ($age > 60*60*24*(365/12)*2) {
1734                 $age_str = int $age/60/60/24/(365/12);
1735                 $age_str .= " months ago";
1736         } elsif ($age > 60*60*24*7*2) {
1737                 $age_str = int $age/60/60/24/7;
1738                 $age_str .= " weeks ago";
1739         } elsif ($age > 60*60*24*2) {
1740                 $age_str = int $age/60/60/24;
1741                 $age_str .= " days ago";
1742         } elsif ($age > 60*60*2) {
1743                 $age_str = int $age/60/60;
1744                 $age_str .= " hours ago";
1745         } elsif ($age > 60*2) {
1746                 $age_str = int $age/60;
1747                 $age_str .= " min ago";
1748         } elsif ($age > 2) {
1749                 $age_str = int $age;
1750                 $age_str .= " sec ago";
1751         } else {
1752                 $age_str .= " right now";
1753         }
1754         return $age_str;
1755 }
1756
1757 use constant {
1758         S_IFINVALID => 0030000,
1759         S_IFGITLINK => 0160000,
1760 };
1761
1762 # submodule/subproject, a commit object reference
1763 sub S_ISGITLINK {
1764         my $mode = shift;
1765
1766         return (($mode & S_IFMT) == S_IFGITLINK)
1767 }
1768
1769 # convert file mode in octal to symbolic file mode string
1770 sub mode_str {
1771         my $mode = oct shift;
1772
1773         if (S_ISGITLINK($mode)) {
1774                 return 'm---------';
1775         } elsif (S_ISDIR($mode & S_IFMT)) {
1776                 return 'drwxr-xr-x';
1777         } elsif (S_ISLNK($mode)) {
1778                 return 'lrwxrwxrwx';
1779         } elsif (S_ISREG($mode)) {
1780                 # git cares only about the executable bit
1781                 if ($mode & S_IXUSR) {
1782                         return '-rwxr-xr-x';
1783                 } else {
1784                         return '-rw-r--r--';
1785                 };
1786         } else {
1787                 return '----------';
1788         }
1789 }
1790
1791 # convert file mode in octal to file type string
1792 sub file_type {
1793         my $mode = shift;
1794
1795         if ($mode !~ m/^[0-7]+$/) {
1796                 return $mode;
1797         } else {
1798                 $mode = oct $mode;
1799         }
1800
1801         if (S_ISGITLINK($mode)) {
1802                 return "submodule";
1803         } elsif (S_ISDIR($mode & S_IFMT)) {
1804                 return "directory";
1805         } elsif (S_ISLNK($mode)) {
1806                 return "symlink";
1807         } elsif (S_ISREG($mode)) {
1808                 return "file";
1809         } else {
1810                 return "unknown";
1811         }
1812 }
1813
1814 # convert file mode in octal to file type description string
1815 sub file_type_long {
1816         my $mode = shift;
1817
1818         if ($mode !~ m/^[0-7]+$/) {
1819                 return $mode;
1820         } else {
1821                 $mode = oct $mode;
1822         }
1823
1824         if (S_ISGITLINK($mode)) {
1825                 return "submodule";
1826         } elsif (S_ISDIR($mode & S_IFMT)) {
1827                 return "directory";
1828         } elsif (S_ISLNK($mode)) {
1829                 return "symlink";
1830         } elsif (S_ISREG($mode)) {
1831                 if ($mode & S_IXUSR) {
1832                         return "executable";
1833                 } else {
1834                         return "file";
1835                 };
1836         } else {
1837                 return "unknown";
1838         }
1839 }
1840
1841
1842 ## ----------------------------------------------------------------------
1843 ## functions returning short HTML fragments, or transforming HTML fragments
1844 ## which don't belong to other sections
1845
1846 # format line of commit message.
1847 sub format_log_line_html {
1848         my $line = shift;
1849
1850         $line = esc_html($line, -nbsp=>1);
1851         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1852                 $cgi->a({-href => href(action=>"object", hash=>$1),
1853                                         -class => "text"}, $1);
1854         }eg;
1855
1856         return $line;
1857 }
1858
1859 # format marker of refs pointing to given object
1860
1861 # the destination action is chosen based on object type and current context:
1862 # - for annotated tags, we choose the tag view unless it's the current view
1863 #   already, in which case we go to shortlog view
1864 # - for other refs, we keep the current view if we're in history, shortlog or
1865 #   log view, and select shortlog otherwise
1866 sub format_ref_marker {
1867         my ($refs, $id) = @_;
1868         my $markers = '';
1869
1870         if (defined $refs->{$id}) {
1871                 foreach my $ref (@{$refs->{$id}}) {
1872                         # this code exploits the fact that non-lightweight tags are the
1873                         # only indirect objects, and that they are the only objects for which
1874                         # we want to use tag instead of shortlog as action
1875                         my ($type, $name) = qw();
1876                         my $indirect = ($ref =~ s/\^\{\}$//);
1877                         # e.g. tags/v2.6.11 or heads/next
1878                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1879                                 $type = $1;
1880                                 $name = $2;
1881                         } else {
1882                                 $type = "ref";
1883                                 $name = $ref;
1884                         }
1885
1886                         my $class = $type;
1887                         $class .= " indirect" if $indirect;
1888
1889                         my $dest_action = "shortlog";
1890
1891                         if ($indirect) {
1892                                 $dest_action = "tag" unless $action eq "tag";
1893                         } elsif ($action =~ /^(history|(short)?log)$/) {
1894                                 $dest_action = $action;
1895                         }
1896
1897                         my $dest = "";
1898                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1899                         $dest .= $ref;
1900
1901                         my $link = $cgi->a({
1902                                 -href => href(
1903                                         action=>$dest_action,
1904                                         hash=>$dest
1905                                 )}, $name);
1906
1907                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1908                                 $link . "</span>";
1909                 }
1910         }
1911
1912         if ($markers) {
1913                 return ' <span class="refs">'. $markers . '</span>';
1914         } else {
1915                 return "";
1916         }
1917 }
1918
1919 # format, perhaps shortened and with markers, title line
1920 sub format_subject_html {
1921         my ($long, $short, $href, $extra) = @_;
1922         $extra = '' unless defined($extra);
1923
1924         if (length($short) < length($long)) {
1925                 $long =~ s/[[:cntrl:]]/?/g;
1926                 return $cgi->a({-href => $href, -class => "list subject",
1927                                 -title => to_utf8($long)},
1928                        esc_html($short)) . $extra;
1929         } else {
1930                 return $cgi->a({-href => $href, -class => "list subject"},
1931                        esc_html($long)) . $extra;
1932         }
1933 }
1934
1935 # Rather than recomputing the url for an email multiple times, we cache it
1936 # after the first hit. This gives a visible benefit in views where the avatar
1937 # for the same email is used repeatedly (e.g. shortlog).
1938 # The cache is shared by all avatar engines (currently gravatar only), which
1939 # are free to use it as preferred. Since only one avatar engine is used for any
1940 # given page, there's no risk for cache conflicts.
1941 our %avatar_cache = ();
1942
1943 # Compute the picon url for a given email, by using the picon search service over at
1944 # http://www.cs.indiana.edu/picons/search.html
1945 sub picon_url {
1946         my $email = lc shift;
1947         if (!$avatar_cache{$email}) {
1948                 my ($user, $domain) = split('@', $email);
1949                 $avatar_cache{$email} =
1950                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1951                         "$domain/$user/" .
1952                         "users+domains+unknown/up/single";
1953         }
1954         return $avatar_cache{$email};
1955 }
1956
1957 # Compute the gravatar url for a given email, if it's not in the cache already.
1958 # Gravatar stores only the part of the URL before the size, since that's the
1959 # one computationally more expensive. This also allows reuse of the cache for
1960 # different sizes (for this particular engine).
1961 sub gravatar_url {
1962         my $email = lc shift;
1963         my $size = shift;
1964         $avatar_cache{$email} ||=
1965                 "http://www.gravatar.com/avatar/" .
1966                         Digest::MD5::md5_hex($email) . "?s=";
1967         return $avatar_cache{$email} . $size;
1968 }
1969
1970 # Insert an avatar for the given $email at the given $size if the feature
1971 # is enabled.
1972 sub git_get_avatar {
1973         my ($email, %opts) = @_;
1974         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1975         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1976         $opts{-size} ||= 'default';
1977         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1978         my $url = "";
1979         if ($git_avatar eq 'gravatar') {
1980                 $url = gravatar_url($email, $size);
1981         } elsif ($git_avatar eq 'picon') {
1982                 $url = picon_url($email);
1983         }
1984         # Other providers can be added by extending the if chain, defining $url
1985         # as needed. If no variant puts something in $url, we assume avatars
1986         # are completely disabled/unavailable.
1987         if ($url) {
1988                 return $pre_white .
1989                        "<img width=\"$size\" " .
1990                             "class=\"avatar\" " .
1991                             "src=\"".esc_url($url)."\" " .
1992                             "alt=\"\" " .
1993                        "/>" . $post_white;
1994         } else {
1995                 return "";
1996         }
1997 }
1998
1999 sub format_search_author {
2000         my ($author, $searchtype, $displaytext) = @_;
2001         my $have_search = gitweb_check_feature('search');
2002
2003         if ($have_search) {
2004                 my $performed = "";
2005                 if ($searchtype eq 'author') {
2006                         $performed = "authored";
2007                 } elsif ($searchtype eq 'committer') {
2008                         $performed = "committed";
2009                 }
2010
2011                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2012                                 searchtext=>$author,
2013                                 searchtype=>$searchtype), class=>"list",
2014                                 title=>"Search for commits $performed by $author"},
2015                                 $displaytext);
2016
2017         } else {
2018                 return $displaytext;
2019         }
2020 }
2021
2022 # format the author name of the given commit with the given tag
2023 # the author name is chopped and escaped according to the other
2024 # optional parameters (see chop_str).
2025 sub format_author_html {
2026         my $tag = shift;
2027         my $co = shift;
2028         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2029         return "<$tag class=\"author\">" .
2030                format_search_author($co->{'author_name'}, "author",
2031                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2032                        $author) .
2033                "</$tag>";
2034 }
2035
2036 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2037 sub format_git_diff_header_line {
2038         my $line = shift;
2039         my $diffinfo = shift;
2040         my ($from, $to) = @_;
2041
2042         if ($diffinfo->{'nparents'}) {
2043                 # combined diff
2044                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2045                 if ($to->{'href'}) {
2046                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2047                                          esc_path($to->{'file'}));
2048                 } else { # file was deleted (no href)
2049                         $line .= esc_path($to->{'file'});
2050                 }
2051         } else {
2052                 # "ordinary" diff
2053                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2054                 if ($from->{'href'}) {
2055                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2056                                          'a/' . esc_path($from->{'file'}));
2057                 } else { # file was added (no href)
2058                         $line .= 'a/' . esc_path($from->{'file'});
2059                 }
2060                 $line .= ' ';
2061                 if ($to->{'href'}) {
2062                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2063                                          'b/' . esc_path($to->{'file'}));
2064                 } else { # file was deleted
2065                         $line .= 'b/' . esc_path($to->{'file'});
2066                 }
2067         }
2068
2069         return "<div class=\"diff header\">$line</div>\n";
2070 }
2071
2072 # format extended diff header line, before patch itself
2073 sub format_extended_diff_header_line {
2074         my $line = shift;
2075         my $diffinfo = shift;
2076         my ($from, $to) = @_;
2077
2078         # match <path>
2079         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2080                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2081                                        esc_path($from->{'file'}));
2082         }
2083         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2084                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2085                                  esc_path($to->{'file'}));
2086         }
2087         # match single <mode>
2088         if ($line =~ m/\s(\d{6})$/) {
2089                 $line .= '<span class="info"> (' .
2090                          file_type_long($1) .
2091                          ')</span>';
2092         }
2093         # match <hash>
2094         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2095                 # can match only for combined diff
2096                 $line = 'index ';
2097                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2098                         if ($from->{'href'}[$i]) {
2099                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2100                                                   -class=>"hash"},
2101                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2102                         } else {
2103                                 $line .= '0' x 7;
2104                         }
2105                         # separator
2106                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2107                 }
2108                 $line .= '..';
2109                 if ($to->{'href'}) {
2110                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2111                                          substr($diffinfo->{'to_id'},0,7));
2112                 } else {
2113                         $line .= '0' x 7;
2114                 }
2115
2116         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2117                 # can match only for ordinary diff
2118                 my ($from_link, $to_link);
2119                 if ($from->{'href'}) {
2120                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2121                                              substr($diffinfo->{'from_id'},0,7));
2122                 } else {
2123                         $from_link = '0' x 7;
2124                 }
2125                 if ($to->{'href'}) {
2126                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2127                                            substr($diffinfo->{'to_id'},0,7));
2128                 } else {
2129                         $to_link = '0' x 7;
2130                 }
2131                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2132                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2133         }
2134
2135         return $line . "<br/>\n";
2136 }
2137
2138 # format from-file/to-file diff header
2139 sub format_diff_from_to_header {
2140         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2141         my $line;
2142         my $result = '';
2143
2144         $line = $from_line;
2145         #assert($line =~ m/^---/) if DEBUG;
2146         # no extra formatting for "^--- /dev/null"
2147         if (! $diffinfo->{'nparents'}) {
2148                 # ordinary (single parent) diff
2149                 if ($line =~ m!^--- "?a/!) {
2150                         if ($from->{'href'}) {
2151                                 $line = '--- a/' .
2152                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2153                                                 esc_path($from->{'file'}));
2154                         } else {
2155                                 $line = '--- a/' .
2156                                         esc_path($from->{'file'});
2157                         }
2158                 }
2159                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2160
2161         } else {
2162                 # combined diff (merge commit)
2163                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2164                         if ($from->{'href'}[$i]) {
2165                                 $line = '--- ' .
2166                                         $cgi->a({-href=>href(action=>"blobdiff",
2167                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2168                                                              hash_parent_base=>$parents[$i],
2169                                                              file_parent=>$from->{'file'}[$i],
2170                                                              hash=>$diffinfo->{'to_id'},
2171                                                              hash_base=>$hash,
2172                                                              file_name=>$to->{'file'}),
2173                                                  -class=>"path",
2174                                                  -title=>"diff" . ($i+1)},
2175                                                 $i+1) .
2176                                         '/' .
2177                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2178                                                 esc_path($from->{'file'}[$i]));
2179                         } else {
2180                                 $line = '--- /dev/null';
2181                         }
2182                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2183                 }
2184         }
2185
2186         $line = $to_line;
2187         #assert($line =~ m/^\+\+\+/) if DEBUG;
2188         # no extra formatting for "^+++ /dev/null"
2189         if ($line =~ m!^\+\+\+ "?b/!) {
2190                 if ($to->{'href'}) {
2191                         $line = '+++ b/' .
2192                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2193                                         esc_path($to->{'file'}));
2194                 } else {
2195                         $line = '+++ b/' .
2196                                 esc_path($to->{'file'});
2197                 }
2198         }
2199         $result .= qq!<div class="diff to_file">$line</div>\n!;
2200
2201         return $result;
2202 }
2203
2204 # create note for patch simplified by combined diff
2205 sub format_diff_cc_simplified {
2206         my ($diffinfo, @parents) = @_;
2207         my $result = '';
2208
2209         $result .= "<div class=\"diff header\">" .
2210                    "diff --cc ";
2211         if (!is_deleted($diffinfo)) {
2212                 $result .= $cgi->a({-href => href(action=>"blob",
2213                                                   hash_base=>$hash,
2214                                                   hash=>$diffinfo->{'to_id'},
2215                                                   file_name=>$diffinfo->{'to_file'}),
2216                                     -class => "path"},
2217                                    esc_path($diffinfo->{'to_file'}));
2218         } else {
2219                 $result .= esc_path($diffinfo->{'to_file'});
2220         }
2221         $result .= "</div>\n" . # class="diff header"
2222                    "<div class=\"diff nodifferences\">" .
2223                    "Simple merge" .
2224                    "</div>\n"; # class="diff nodifferences"
2225
2226         return $result;
2227 }
2228
2229 # format patch (diff) line (not to be used for diff headers)
2230 sub format_diff_line {
2231         my $line = shift;
2232         my ($from, $to) = @_;
2233         my $diff_class = "";
2234
2235         chomp $line;
2236
2237         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2238                 # combined diff
2239                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2240                 if ($line =~ m/^\@{3}/) {
2241                         $diff_class = " chunk_header";
2242                 } elsif ($line =~ m/^\\/) {
2243                         $diff_class = " incomplete";
2244                 } elsif ($prefix =~ tr/+/+/) {
2245                         $diff_class = " add";
2246                 } elsif ($prefix =~ tr/-/-/) {
2247                         $diff_class = " rem";
2248                 }
2249         } else {
2250                 # assume ordinary diff
2251                 my $char = substr($line, 0, 1);
2252                 if ($char eq '+') {
2253                         $diff_class = " add";
2254                 } elsif ($char eq '-') {
2255                         $diff_class = " rem";
2256                 } elsif ($char eq '@') {
2257                         $diff_class = " chunk_header";
2258                 } elsif ($char eq "\\") {
2259                         $diff_class = " incomplete";
2260                 }
2261         }
2262         $line = untabify($line);
2263         if ($from && $to && $line =~ m/^\@{2} /) {
2264                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2265                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2266
2267                 $from_lines = 0 unless defined $from_lines;
2268                 $to_lines   = 0 unless defined $to_lines;
2269
2270                 if ($from->{'href'}) {
2271                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2272                                              -class=>"list"}, $from_text);
2273                 }
2274                 if ($to->{'href'}) {
2275                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2276                                              -class=>"list"}, $to_text);
2277                 }
2278                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2279                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2280                 return "<div class=\"diff$diff_class\">$line</div>\n";
2281         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2282                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2283                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2284
2285                 @from_text = split(' ', $ranges);
2286                 for (my $i = 0; $i < @from_text; ++$i) {
2287                         ($from_start[$i], $from_nlines[$i]) =
2288                                 (split(',', substr($from_text[$i], 1)), 0);
2289                 }
2290
2291                 $to_text   = pop @from_text;
2292                 $to_start  = pop @from_start;
2293                 $to_nlines = pop @from_nlines;
2294
2295                 $line = "<span class=\"chunk_info\">$prefix ";
2296                 for (my $i = 0; $i < @from_text; ++$i) {
2297                         if ($from->{'href'}[$i]) {
2298                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2299                                                   -class=>"list"}, $from_text[$i]);
2300                         } else {
2301                                 $line .= $from_text[$i];
2302                         }
2303                         $line .= " ";
2304                 }
2305                 if ($to->{'href'}) {
2306                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2307                                           -class=>"list"}, $to_text);
2308                 } else {
2309                         $line .= $to_text;
2310                 }
2311                 $line .= " $prefix</span>" .
2312                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2313                 return "<div class=\"diff$diff_class\">$line</div>\n";
2314         }
2315         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2316 }
2317
2318 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2319 # linked.  Pass the hash of the tree/commit to snapshot.
2320 sub format_snapshot_links {
2321         my ($hash) = @_;
2322         my $num_fmts = @snapshot_fmts;
2323         if ($num_fmts > 1) {
2324                 # A parenthesized list of links bearing format names.
2325                 # e.g. "snapshot (_tar.gz_ _zip_)"
2326                 return "snapshot (" . join(' ', map
2327                         $cgi->a({
2328                                 -href => href(
2329                                         action=>"snapshot",
2330                                         hash=>$hash,
2331                                         snapshot_format=>$_
2332                                 )
2333                         }, $known_snapshot_formats{$_}{'display'})
2334                 , @snapshot_fmts) . ")";
2335         } elsif ($num_fmts == 1) {
2336                 # A single "snapshot" link whose tooltip bears the format name.
2337                 # i.e. "_snapshot_"
2338                 my ($fmt) = @snapshot_fmts;
2339                 return
2340                         $cgi->a({
2341                                 -href => href(
2342                                         action=>"snapshot",
2343                                         hash=>$hash,
2344                                         snapshot_format=>$fmt
2345                                 ),
2346                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2347                         }, "snapshot");
2348         } else { # $num_fmts == 0
2349                 return undef;
2350         }
2351 }
2352
2353 ## ......................................................................
2354 ## functions returning values to be passed, perhaps after some
2355 ## transformation, to other functions; e.g. returning arguments to href()
2356
2357 # returns hash to be passed to href to generate gitweb URL
2358 # in -title key it returns description of link
2359 sub get_feed_info {
2360         my $format = shift || 'Atom';
2361         my %res = (action => lc($format));
2362
2363         # feed links are possible only for project views
2364         return unless (defined $project);
2365         # some views should link to OPML, or to generic project feed,
2366         # or don't have specific feed yet (so they should use generic)
2367         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2368
2369         my $branch;
2370         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2371         # from tag links; this also makes possible to detect branch links
2372         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2373             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2374                 $branch = $1;
2375         }
2376         # find log type for feed description (title)
2377         my $type = 'log';
2378         if (defined $file_name) {
2379                 $type  = "history of $file_name";
2380                 $type .= "/" if ($action eq 'tree');
2381                 $type .= " on '$branch'" if (defined $branch);
2382         } else {
2383                 $type = "log of $branch" if (defined $branch);
2384         }
2385
2386         $res{-title} = $type;
2387         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2388         $res{'file_name'} = $file_name;
2389
2390         return %res;
2391 }
2392
2393 ## ----------------------------------------------------------------------
2394 ## git utility subroutines, invoking git commands
2395
2396 # returns path to the core git executable and the --git-dir parameter as list
2397 sub git_cmd {
2398         $number_of_git_cmds++;
2399         return $GIT, '--git-dir='.$git_dir;
2400 }
2401
2402 # quote the given arguments for passing them to the shell
2403 # quote_command("command", "arg 1", "arg with ' and ! characters")
2404 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2405 # Try to avoid using this function wherever possible.
2406 sub quote_command {
2407         return join(' ',
2408                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2409 }
2410
2411 # get HEAD ref of given project as hash
2412 sub git_get_head_hash {
2413         return git_get_full_hash(shift, 'HEAD');
2414 }
2415
2416 sub git_get_full_hash {
2417         return git_get_hash(@_);
2418 }
2419
2420 sub git_get_short_hash {
2421         return git_get_hash(@_, '--short=7');
2422 }
2423
2424 sub git_get_hash {
2425         my ($project, $hash, @options) = @_;
2426         my $o_git_dir = $git_dir;
2427         my $retval = undef;
2428         $git_dir = "$projectroot/$project";
2429         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2430             '--verify', '-q', @options, $hash) {
2431                 $retval = <$fd>;
2432                 chomp $retval if defined $retval;
2433                 close $fd;
2434         }
2435         if (defined $o_git_dir) {
2436                 $git_dir = $o_git_dir;
2437         }
2438         return $retval;
2439 }
2440
2441 # get type of given object
2442 sub git_get_type {
2443         my $hash = shift;
2444
2445         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2446         my $type = <$fd>;
2447         close $fd or return;
2448         chomp $type;
2449         return $type;
2450 }
2451
2452 # repository configuration
2453 our $config_file = '';
2454 our %config;
2455
2456 # store multiple values for single key as anonymous array reference
2457 # single values stored directly in the hash, not as [ <value> ]
2458 sub hash_set_multi {
2459         my ($hash, $key, $value) = @_;
2460
2461         if (!exists $hash->{$key}) {
2462                 $hash->{$key} = $value;
2463         } elsif (!ref $hash->{$key}) {
2464                 $hash->{$key} = [ $hash->{$key}, $value ];
2465         } else {
2466                 push @{$hash->{$key}}, $value;
2467         }
2468 }
2469
2470 # return hash of git project configuration
2471 # optionally limited to some section, e.g. 'gitweb'
2472 sub git_parse_project_config {
2473         my $section_regexp = shift;
2474         my %config;
2475
2476         local $/ = "\0";
2477
2478         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2479                 or return;
2480
2481         while (my $keyval = <$fh>) {
2482                 chomp $keyval;
2483                 my ($key, $value) = split(/\n/, $keyval, 2);
2484
2485                 hash_set_multi(\%config, $key, $value)
2486                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2487         }
2488         close $fh;
2489
2490         return %config;
2491 }
2492
2493 # convert config value to boolean: 'true' or 'false'
2494 # no value, number > 0, 'true' and 'yes' values are true
2495 # rest of values are treated as false (never as error)
2496 sub config_to_bool {
2497         my $val = shift;
2498
2499         return 1 if !defined $val;             # section.key
2500
2501         # strip leading and trailing whitespace
2502         $val =~ s/^\s+//;
2503         $val =~ s/\s+$//;
2504
2505         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2506                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2507 }
2508
2509 # convert config value to simple decimal number
2510 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2511 # to be multiplied by 1024, 1048576, or 1073741824
2512 sub config_to_int {
2513         my $val = shift;
2514
2515         # strip leading and trailing whitespace
2516         $val =~ s/^\s+//;
2517         $val =~ s/\s+$//;
2518
2519         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2520                 $unit = lc($unit);
2521                 # unknown unit is treated as 1
2522                 return $num * ($unit eq 'g' ? 1073741824 :
2523                                $unit eq 'm' ?    1048576 :
2524                                $unit eq 'k' ?       1024 : 1);
2525         }
2526         return $val;
2527 }
2528
2529 # convert config value to array reference, if needed
2530 sub config_to_multi {
2531         my $val = shift;
2532
2533         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2534 }
2535
2536 sub git_get_project_config {
2537         my ($key, $type) = @_;
2538
2539         return unless defined $git_dir;
2540
2541         # key sanity check
2542         return unless ($key);
2543         # only subsection, if exists, is case sensitive,
2544         # and not lowercased by 'git config -z -l'
2545         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2546                 $key = join(".", lc($hi), $mi, lc($lo));
2547         } else {
2548                 $key = lc($key);
2549         }
2550         $key =~ s/^gitweb\.//;
2551         return if ($key =~ m/\W/);
2552
2553         # type sanity check
2554         if (defined $type) {
2555                 $type =~ s/^--//;
2556                 $type = undef
2557                         unless ($type eq 'bool' || $type eq 'int');
2558         }
2559
2560         # get config
2561         if (!defined $config_file ||
2562             $config_file ne "$git_dir/config") {
2563                 %config = git_parse_project_config('gitweb');
2564                 $config_file = "$git_dir/config";
2565         }
2566
2567         # check if config variable (key) exists
2568         return unless exists $config{"gitweb.$key"};
2569
2570         # ensure given type
2571         if (!defined $type) {
2572                 return $config{"gitweb.$key"};
2573         } elsif ($type eq 'bool') {
2574                 # backward compatibility: 'git config --bool' returns true/false
2575                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2576         } elsif ($type eq 'int') {
2577                 return config_to_int($config{"gitweb.$key"});
2578         }
2579         return $config{"gitweb.$key"};
2580 }
2581
2582 # get hash of given path at given ref
2583 sub git_get_hash_by_path {
2584         my $base = shift;
2585         my $path = shift || return undef;
2586         my $type = shift;
2587
2588         $path =~ s,/+$,,;
2589
2590         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2591                 or die_error(500, "Open git-ls-tree failed");
2592         my $line = <$fd>;
2593         close $fd or return undef;
2594
2595         if (!defined $line) {
2596                 # there is no tree or hash given by $path at $base
2597                 return undef;
2598         }
2599
2600         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2601         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2602         if (defined $type && $type ne $2) {
2603                 # type doesn't match
2604                 return undef;
2605         }
2606         return $3;
2607 }
2608
2609 # get path of entry with given hash at given tree-ish (ref)
2610 # used to get 'from' filename for combined diff (merge commit) for renames
2611 sub git_get_path_by_hash {
2612         my $base = shift || return;
2613         my $hash = shift || return;
2614
2615         local $/ = "\0";
2616
2617         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2618                 or return undef;
2619         while (my $line = <$fd>) {
2620                 chomp $line;
2621
2622                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2623                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2624                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2625                         close $fd;
2626                         return $1;
2627                 }
2628         }
2629         close $fd;
2630         return undef;
2631 }
2632
2633 ## ......................................................................
2634 ## git utility functions, directly accessing git repository
2635
2636 # get the value of config variable either from file named as the variable
2637 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2638 # configuration variable in the repository config file.
2639 sub git_get_file_or_project_config {
2640         my ($path, $name) = @_;
2641
2642         $git_dir = "$projectroot/$path";
2643         open my $fd, '<', "$git_dir/$name"
2644                 or return git_get_project_config($name);
2645         my $conf = <$fd>;
2646         close $fd;
2647         if (defined $conf) {
2648                 chomp $conf;
2649         }
2650         return $conf;
2651 }
2652
2653 sub git_get_project_description {
2654         my $path = shift;
2655         return git_get_file_or_project_config($path, 'description');
2656 }
2657
2658 sub git_get_project_category {
2659         my $path = shift;
2660         return git_get_file_or_project_config($path, 'category');
2661 }
2662
2663
2664 # supported formats:
2665 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2666 #   - if its contents is a number, use it as tag weight,
2667 #   - otherwise add a tag with weight 1
2668 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2669 #   the same value multiple times increases tag weight
2670 # * `gitweb.ctag' multi-valued repo config variable
2671 sub git_get_project_ctags {
2672         my $project = shift;
2673         my $ctags = {};
2674
2675         $git_dir = "$projectroot/$project";
2676         if (opendir my $dh, "$git_dir/ctags") {
2677                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2678                 foreach my $tagfile (@files) {
2679                         open my $ct, '<', $tagfile
2680                                 or next;
2681                         my $val = <$ct>;
2682                         chomp $val if $val;
2683                         close $ct;
2684
2685                         (my $ctag = $tagfile) =~ s#.*/##;
2686                         if ($val =~ /^\d+$/) {
2687                                 $ctags->{$ctag} = $val;
2688                         } else {
2689                                 $ctags->{$ctag} = 1;
2690                         }
2691                 }
2692                 closedir $dh;
2693
2694         } elsif (open my $fh, '<', "$git_dir/ctags") {
2695                 while (my $line = <$fh>) {
2696                         chomp $line;
2697                         $ctags->{$line}++ if $line;
2698                 }
2699                 close $fh;
2700
2701         } else {
2702                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2703                 foreach my $tag (@$taglist) {
2704                         $ctags->{$tag}++;
2705                 }
2706         }
2707
2708         return $ctags;
2709 }
2710
2711 # return hash, where keys are content tags ('ctags'),
2712 # and values are sum of weights of given tag in every project
2713 sub git_gather_all_ctags {
2714         my $projects = shift;
2715         my $ctags = {};
2716
2717         foreach my $p (@$projects) {
2718                 foreach my $ct (keys %{$p->{'ctags'}}) {
2719                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2720                 }
2721         }
2722
2723         return $ctags;
2724 }
2725
2726 sub git_populate_project_tagcloud {
2727         my $ctags = shift;
2728
2729         # First, merge different-cased tags; tags vote on casing
2730         my %ctags_lc;
2731         foreach (keys %$ctags) {
2732                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2733                 if (not $ctags_lc{lc $_}->{topcount}
2734                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2735                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2736                         $ctags_lc{lc $_}->{topname} = $_;
2737                 }
2738         }
2739
2740         my $cloud;
2741         my $matched = $cgi->param('by_tag');
2742         if (eval { require HTML::TagCloud; 1; }) {
2743                 $cloud = HTML::TagCloud->new;
2744                 foreach my $ctag (sort keys %ctags_lc) {
2745                         # Pad the title with spaces so that the cloud looks
2746                         # less crammed.
2747                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2748                         $title =~ s/ /&nbsp;/g;
2749                         $title =~ s/^/&nbsp;/g;
2750                         $title =~ s/$/&nbsp;/g;
2751                         if (defined $matched && $matched eq $ctag) {
2752                                 $title = qq(<span class="match">$title</span>);
2753                         }
2754                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2755                                     $ctags_lc{$ctag}->{count});
2756                 }
2757         } else {
2758                 $cloud = {};
2759                 foreach my $ctag (keys %ctags_lc) {
2760                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2761                         if (defined $matched && $matched eq $ctag) {
2762                                 $title = qq(<span class="match">$title</span>);
2763                         }
2764                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2765                         $cloud->{$ctag}{ctag} =
2766                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2767                 }
2768         }
2769         return $cloud;
2770 }
2771
2772 sub git_show_project_tagcloud {
2773         my ($cloud, $count) = @_;
2774         if (ref $cloud eq 'HTML::TagCloud') {
2775                 return $cloud->html_and_css($count);
2776         } else {
2777                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2778                 return
2779                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2780                         join (', ', map {
2781                                 $cloud->{$_}->{'ctag'}
2782                         } splice(@tags, 0, $count)) .
2783                         '</div>';
2784         }
2785 }
2786
2787 sub git_get_project_url_list {
2788         my $path = shift;
2789
2790         $git_dir = "$projectroot/$path";
2791         open my $fd, '<', "$git_dir/cloneurl"
2792                 or return wantarray ?
2793                 @{ config_to_multi(git_get_project_config('url')) } :
2794                    config_to_multi(git_get_project_config('url'));
2795         my @git_project_url_list = map { chomp; $_ } <$fd>;
2796         close $fd;
2797
2798         return wantarray ? @git_project_url_list : \@git_project_url_list;
2799 }
2800
2801 sub git_get_projects_list {
2802         my $filter = shift || '';
2803         my @list;
2804
2805         $filter =~ s/\.git$//;
2806
2807         if (-d $projects_list) {
2808                 # search in directory
2809                 my $dir = $projects_list;
2810                 # remove the trailing "/"
2811                 $dir =~ s!/+$!!;
2812                 my $pfxlen = length("$projects_list");
2813                 my $pfxdepth = ($projects_list =~ tr!/!!);
2814                 # when filtering, search only given subdirectory
2815                 if ($filter) {
2816                         $dir .= "/$filter";
2817                         $dir =~ s!/+$!!;
2818                 }
2819
2820                 File::Find::find({
2821                         follow_fast => 1, # follow symbolic links
2822                         follow_skip => 2, # ignore duplicates
2823                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2824                         wanted => sub {
2825                                 # global variables
2826                                 our $project_maxdepth;
2827                                 our $projectroot;
2828                                 # skip project-list toplevel, if we get it.
2829                                 return if (m!^[/.]$!);
2830                                 # only directories can be git repositories
2831                                 return unless (-d $_);
2832                                 # don't traverse too deep (Find is super slow on os x)
2833                                 # $project_maxdepth excludes depth of $projectroot
2834                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2835                                         $File::Find::prune = 1;
2836                                         return;
2837                                 }
2838
2839                                 my $path = substr($File::Find::name, $pfxlen + 1);
2840                                 # we check related file in $projectroot
2841                                 if (check_export_ok("$projectroot/$path")) {
2842                                         push @list, { path => $path };
2843                                         $File::Find::prune = 1;
2844                                 }
2845                         },
2846                 }, "$dir");
2847
2848         } elsif (-f $projects_list) {
2849                 # read from file(url-encoded):
2850                 # 'git%2Fgit.git Linus+Torvalds'
2851                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2852                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2853                 open my $fd, '<', $projects_list or return;
2854         PROJECT:
2855                 while (my $line = <$fd>) {
2856                         chomp $line;
2857                         my ($path, $owner) = split ' ', $line;
2858                         $path = unescape($path);
2859                         $owner = unescape($owner);
2860                         if (!defined $path) {
2861                                 next;
2862                         }
2863                         # if $filter is rpovided, check if $path begins with $filter
2864                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2865                                 next;
2866                         }
2867                         if (check_export_ok("$projectroot/$path")) {
2868                                 my $pr = {
2869                                         path => $path,
2870                                         owner => to_utf8($owner),
2871                                 };
2872                                 push @list, $pr;
2873                         }
2874                 }
2875                 close $fd;
2876         }
2877         return @list;
2878 }
2879
2880 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2881 # as side effects it sets 'forks' field to list of forks for forked projects
2882 sub filter_forks_from_projects_list {
2883         my $projects = shift;
2884
2885         my %trie; # prefix tree of directories (path components)
2886         # generate trie out of those directories that might contain forks
2887         foreach my $pr (@$projects) {
2888                 my $path = $pr->{'path'};
2889                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2890                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2891                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2892                 next unless (-d "$projectroot/$path"); # containing directory exists
2893                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2894
2895                 # add to trie
2896                 my @dirs = split('/', $path);
2897                 # walk the trie, until either runs out of components or out of trie
2898                 my $ref = \%trie;
2899                 while (scalar @dirs &&
2900                        exists($ref->{$dirs[0]})) {
2901                         $ref = $ref->{shift @dirs};
2902                 }
2903                 # create rest of trie structure from rest of components
2904                 foreach my $dir (@dirs) {
2905                         $ref = $ref->{$dir} = {};
2906                 }
2907                 # create end marker, store $pr as a data
2908                 $ref->{''} = $pr if (!exists $ref->{''});
2909         }
2910
2911         # filter out forks, by finding shortest prefix match for paths
2912         my @filtered;
2913  PROJECT:
2914         foreach my $pr (@$projects) {
2915                 # trie lookup
2916                 my $ref = \%trie;
2917         DIR:
2918                 foreach my $dir (split('/', $pr->{'path'})) {
2919                         if (exists $ref->{''}) {
2920                                 # found [shortest] prefix, is a fork - skip it
2921                                 push @{$ref->{''}{'forks'}}, $pr;
2922                                 next PROJECT;
2923                         }
2924                         if (!exists $ref->{$dir}) {
2925                                 # not in trie, cannot have prefix, not a fork
2926                                 push @filtered, $pr;
2927                                 next PROJECT;
2928                         }
2929                         # If the dir is there, we just walk one step down the trie.
2930                         $ref = $ref->{$dir};
2931                 }
2932                 # we ran out of trie
2933                 # (shouldn't happen: it's either no match, or end marker)
2934                 push @filtered, $pr;
2935         }
2936
2937         return @filtered;
2938 }
2939
2940 # note: fill_project_list_info must be run first,
2941 # for 'descr_long' and 'ctags' to be filled
2942 sub search_projects_list {
2943         my ($projlist, %opts) = @_;
2944         my $tagfilter  = $opts{'tagfilter'};
2945         my $searchtext = $opts{'searchtext'};
2946
2947         return @$projlist
2948                 unless ($tagfilter || $searchtext);
2949
2950         my @projects;
2951  PROJECT:
2952         foreach my $pr (@$projlist) {
2953
2954                 if ($tagfilter) {
2955                         next unless ref($pr->{'ctags'}) eq 'HASH';
2956                         next unless
2957                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2958                 }
2959
2960                 if ($searchtext) {
2961                         next unless
2962                                 $pr->{'path'} =~ /$searchtext/ ||
2963                                 $pr->{'descr_long'} =~ /$searchtext/;
2964                 }
2965
2966                 push @projects, $pr;
2967         }
2968
2969         return @projects;
2970 }
2971
2972 our $gitweb_project_owner = undef;
2973 sub git_get_project_list_from_file {
2974
2975         return if (defined $gitweb_project_owner);
2976
2977         $gitweb_project_owner = {};
2978         # read from file (url-encoded):
2979         # 'git%2Fgit.git Linus+Torvalds'
2980         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2981         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2982         if (-f $projects_list) {
2983                 open(my $fd, '<', $projects_list);
2984                 while (my $line = <$fd>) {
2985                         chomp $line;
2986                         my ($pr, $ow) = split ' ', $line;
2987                         $pr = unescape($pr);
2988                         $ow = unescape($ow);
2989                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2990                 }
2991                 close $fd;
2992         }
2993 }
2994
2995 sub git_get_project_owner {
2996         my $project = shift;
2997         my $owner;
2998
2999         return undef unless $project;
3000         $git_dir = "$projectroot/$project";
3001
3002         if (!defined $gitweb_project_owner) {
3003                 git_get_project_list_from_file();
3004         }
3005
3006         if (exists $gitweb_project_owner->{$project}) {
3007                 $owner = $gitweb_project_owner->{$project};
3008         }
3009         if (!defined $owner){
3010                 $owner = git_get_project_config('owner');
3011         }
3012         if (!defined $owner) {
3013                 $owner = get_file_owner("$git_dir");
3014         }
3015
3016         return $owner;
3017 }
3018
3019 sub git_get_last_activity {
3020         my ($path) = @_;
3021         my $fd;
3022
3023         $git_dir = "$projectroot/$path";
3024         open($fd, "-|", git_cmd(), 'for-each-ref',
3025              '--format=%(committer)',
3026              '--sort=-committerdate',
3027              '--count=1',
3028              'refs/heads') or return;
3029         my $most_recent = <$fd>;
3030         close $fd or return;
3031         if (defined $most_recent &&
3032             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3033                 my $timestamp = $1;
3034                 my $age = time - $timestamp;
3035                 return ($age, age_string($age));
3036         }
3037         return (undef, undef);
3038 }
3039
3040 # Implementation note: when a single remote is wanted, we cannot use 'git
3041 # remote show -n' because that command always work (assuming it's a remote URL
3042 # if it's not defined), and we cannot use 'git remote show' because that would
3043 # try to make a network roundtrip. So the only way to find if that particular
3044 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3045 # and when we find what we want.
3046 sub git_get_remotes_list {
3047         my $wanted = shift;
3048         my %remotes = ();
3049
3050         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3051         return unless $fd;
3052         while (my $remote = <$fd>) {
3053                 chomp $remote;
3054                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3055                 next if $wanted and not $remote eq $wanted;
3056                 my ($url, $key) = ($1, $2);
3057
3058                 $remotes{$remote} ||= { 'heads' => () };
3059                 $remotes{$remote}{$key} = $url;
3060         }
3061         close $fd or return;
3062         return wantarray ? %remotes : \%remotes;
3063 }
3064
3065 # Takes a hash of remotes as first parameter and fills it by adding the
3066 # available remote heads for each of the indicated remotes.
3067 sub fill_remote_heads {
3068         my $remotes = shift;
3069         my @heads = map { "remotes/$_" } keys %$remotes;
3070         my @remoteheads = git_get_heads_list(undef, @heads);
3071         foreach my $remote (keys %$remotes) {
3072                 $remotes->{$remote}{'heads'} = [ grep {
3073                         $_->{'name'} =~ s!^$remote/!!
3074                         } @remoteheads ];
3075         }
3076 }
3077
3078 sub git_get_references {
3079         my $type = shift || "";
3080         my %refs;
3081         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3082         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3083         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3084                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3085                 or return;
3086
3087         while (my $line = <$fd>) {
3088                 chomp $line;
3089                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3090                         if (defined $refs{$1}) {
3091                                 push @{$refs{$1}}, $2;
3092                         } else {
3093                                 $refs{$1} = [ $2 ];
3094                         }
3095                 }
3096         }
3097         close $fd or return;
3098         return \%refs;
3099 }
3100
3101 sub git_get_rev_name_tags {
3102         my $hash = shift || return undef;
3103
3104         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3105                 or return;
3106         my $name_rev = <$fd>;
3107         close $fd;
3108
3109         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3110                 return $1;
3111         } else {
3112                 # catches also '$hash undefined' output
3113                 return undef;
3114         }
3115 }
3116
3117 ## ----------------------------------------------------------------------
3118 ## parse to hash functions
3119
3120 sub parse_date {
3121         my $epoch = shift;
3122         my $tz = shift || "-0000";
3123
3124         my %date;
3125         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3126         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3127         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3128         $date{'hour'} = $hour;
3129         $date{'minute'} = $min;
3130         $date{'mday'} = $mday;
3131         $date{'day'} = $days[$wday];
3132         $date{'month'} = $months[$mon];
3133         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3134                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3135         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3136                              $mday, $months[$mon], $hour ,$min;
3137         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3138                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3139
3140         my ($tz_sign, $tz_hour, $tz_min) =
3141                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3142         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3143         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3144         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3145         $date{'hour_local'} = $hour;
3146         $date{'minute_local'} = $min;
3147         $date{'tz_local'} = $tz;
3148         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3149                                   1900+$year, $mon+1, $mday,
3150                                   $hour, $min, $sec, $tz);
3151         return %date;
3152 }
3153
3154 sub parse_tag {
3155         my $tag_id = shift;
3156         my %tag;
3157         my @comment;
3158
3159         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3160         $tag{'id'} = $tag_id;
3161         while (my $line = <$fd>) {
3162                 chomp $line;
3163                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3164                         $tag{'object'} = $1;
3165                 } elsif ($line =~ m/^type (.+)$/) {
3166                         $tag{'type'} = $1;
3167                 } elsif ($line =~ m/^tag (.+)$/) {
3168                         $tag{'name'} = $1;
3169                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3170                         $tag{'author'} = $1;
3171                         $tag{'author_epoch'} = $2;
3172                         $tag{'author_tz'} = $3;
3173                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3174                                 $tag{'author_name'}  = $1;
3175                                 $tag{'author_email'} = $2;
3176                         } else {
3177                                 $tag{'author_name'} = $tag{'author'};
3178                         }
3179                 } elsif ($line =~ m/--BEGIN/) {
3180                         push @comment, $line;
3181                         last;
3182                 } elsif ($line eq "") {
3183                         last;
3184                 }
3185         }
3186         push @comment, <$fd>;
3187         $tag{'comment'} = \@comment;
3188         close $fd or return;
3189         if (!defined $tag{'name'}) {
3190                 return
3191         };
3192         return %tag
3193 }
3194
3195 sub parse_commit_text {
3196         my ($commit_text, $withparents) = @_;
3197         my @commit_lines = split '\n', $commit_text;
3198         my %co;
3199
3200         pop @commit_lines; # Remove '\0'
3201
3202         if (! @commit_lines) {
3203                 return;
3204         }
3205
3206         my $header = shift @commit_lines;
3207         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3208                 return;
3209         }
3210         ($co{'id'}, my @parents) = split ' ', $header;
3211         while (my $line = shift @commit_lines) {
3212                 last if $line eq "\n";
3213                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3214                         $co{'tree'} = $1;
3215                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3216                         push @parents, $1;
3217                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3218                         $co{'author'} = to_utf8($1);
3219                         $co{'author_epoch'} = $2;
3220                         $co{'author_tz'} = $3;
3221                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3222                                 $co{'author_name'}  = $1;
3223                                 $co{'author_email'} = $2;
3224                         } else {
3225                                 $co{'author_name'} = $co{'author'};
3226                         }
3227                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3228                         $co{'committer'} = to_utf8($1);
3229                         $co{'committer_epoch'} = $2;
3230                         $co{'committer_tz'} = $3;
3231                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3232                                 $co{'committer_name'}  = $1;
3233                                 $co{'committer_email'} = $2;
3234                         } else {
3235                                 $co{'committer_name'} = $co{'committer'};
3236                         }
3237                 }
3238         }
3239         if (!defined $co{'tree'}) {
3240                 return;
3241         };
3242         $co{'parents'} = \@parents;
3243         $co{'parent'} = $parents[0];
3244
3245         foreach my $title (@commit_lines) {
3246                 $title =~ s/^    //;
3247                 if ($title ne "") {
3248                         $co{'title'} = chop_str($title, 80, 5);
3249                         # remove leading stuff of merges to make the interesting part visible
3250                         if (length($title) > 50) {
3251                                 $title =~ s/^Automatic //;
3252                                 $title =~ s/^merge (of|with) /Merge ... /i;
3253                                 if (length($title) > 50) {
3254                                         $title =~ s/(http|rsync):\/\///;
3255                                 }
3256                                 if (length($title) > 50) {
3257                                         $title =~ s/(master|www|rsync)\.//;
3258                                 }
3259                                 if (length($title) > 50) {
3260                                         $title =~ s/kernel.org:?//;
3261                                 }
3262                                 if (length($title) > 50) {
3263                                         $title =~ s/\/pub\/scm//;
3264                                 }
3265                         }
3266                         $co{'title_short'} = chop_str($title, 50, 5);
3267                         last;
3268                 }
3269         }
3270         if (! defined $co{'title'} || $co{'title'} eq "") {
3271                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3272         }
3273         # remove added spaces
3274         foreach my $line (@commit_lines) {
3275                 $line =~ s/^    //;
3276         }
3277         $co{'comment'} = \@commit_lines;
3278
3279         my $age = time - $co{'committer_epoch'};
3280         $co{'age'} = $age;
3281         $co{'age_string'} = age_string($age);
3282         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3283         if ($age > 60*60*24*7*2) {
3284                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3285                 $co{'age_string_age'} = $co{'age_string'};
3286         } else {
3287                 $co{'age_string_date'} = $co{'age_string'};
3288                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3289         }
3290         return %co;
3291 }
3292
3293 sub parse_commit {
3294         my ($commit_id) = @_;
3295         my %co;
3296
3297         local $/ = "\0";
3298
3299         open my $fd, "-|", git_cmd(), "rev-list",
3300                 "--parents",
3301                 "--header",
3302                 "--max-count=1",
3303                 $commit_id,
3304                 "--",
3305                 or die_error(500, "Open git-rev-list failed");
3306         %co = parse_commit_text(<$fd>, 1);
3307         close $fd;
3308
3309         return %co;
3310 }
3311
3312 sub parse_commits {
3313         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3314         my @cos;
3315
3316         $maxcount ||= 1;
3317         $skip ||= 0;
3318
3319         local $/ = "\0";
3320
3321         open my $fd, "-|", git_cmd(), "rev-list",
3322                 "--header",
3323                 @args,
3324                 ("--max-count=" . $maxcount),
3325                 ("--skip=" . $skip),
3326                 @extra_options,
3327                 $commit_id,
3328                 "--",
3329                 ($filename ? ($filename) : ())
3330                 or die_error(500, "Open git-rev-list failed");
3331         while (my $line = <$fd>) {
3332                 my %co = parse_commit_text($line);
3333                 push @cos, \%co;
3334         }
3335         close $fd;
3336
3337         return wantarray ? @cos : \@cos;
3338 }
3339
3340 # parse line of git-diff-tree "raw" output
3341 sub parse_difftree_raw_line {
3342         my $line = shift;
3343         my %res;
3344
3345         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3346         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3347         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3348                 $res{'from_mode'} = $1;
3349                 $res{'to_mode'} = $2;
3350                 $res{'from_id'} = $3;
3351                 $res{'to_id'} = $4;
3352                 $res{'status'} = $5;
3353                 $res{'similarity'} = $6;
3354                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3355                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3356                 } else {
3357                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3358                 }
3359         }
3360         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3361         # combined diff (for merge commit)
3362         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3363                 $res{'nparents'}  = length($1);
3364                 $res{'from_mode'} = [ split(' ', $2) ];
3365                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3366                 $res{'from_id'} = [ split(' ', $3) ];
3367                 $res{'to_id'} = pop @{$res{'from_id'}};
3368                 $res{'status'} = [ split('', $4) ];
3369                 $res{'to_file'} = unquote($5);
3370         }
3371         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3372         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3373                 $res{'commit'} = $1;
3374         }
3375
3376         return wantarray ? %res : \%res;
3377 }
3378
3379 # wrapper: return parsed line of git-diff-tree "raw" output
3380 # (the argument might be raw line, or parsed info)
3381 sub parsed_difftree_line {
3382         my $line_or_ref = shift;
3383
3384         if (ref($line_or_ref) eq "HASH") {
3385                 # pre-parsed (or generated by hand)
3386                 return $line_or_ref;
3387         } else {
3388                 return parse_difftree_raw_line($line_or_ref);
3389         }
3390 }
3391
3392 # parse line of git-ls-tree output
3393 sub parse_ls_tree_line {
3394         my $line = shift;
3395         my %opts = @_;
3396         my %res;
3397
3398         if ($opts{'-l'}) {
3399                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3400                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3401
3402                 $res{'mode'} = $1;
3403                 $res{'type'} = $2;
3404                 $res{'hash'} = $3;
3405                 $res{'size'} = $4;
3406                 if ($opts{'-z'}) {
3407                         $res{'name'} = $5;
3408                 } else {
3409                         $res{'name'} = unquote($5);
3410                 }
3411         } else {
3412                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3413                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3414
3415                 $res{'mode'} = $1;
3416                 $res{'type'} = $2;
3417                 $res{'hash'} = $3;
3418                 if ($opts{'-z'}) {
3419                         $res{'name'} = $4;
3420                 } else {
3421                         $res{'name'} = unquote($4);
3422                 }
3423         }
3424
3425         return wantarray ? %res : \%res;
3426 }
3427
3428 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3429 sub parse_from_to_diffinfo {
3430         my ($diffinfo, $from, $to, @parents) = @_;
3431
3432         if ($diffinfo->{'nparents'}) {
3433                 # combined diff
3434                 $from->{'file'} = [];
3435                 $from->{'href'} = [];
3436                 fill_from_file_info($diffinfo, @parents)
3437                         unless exists $diffinfo->{'from_file'};
3438                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3439                         $from->{'file'}[$i] =
3440                                 defined $diffinfo->{'from_file'}[$i] ?
3441                                         $diffinfo->{'from_file'}[$i] :
3442                                         $diffinfo->{'to_file'};
3443                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3444                                 $from->{'href'}[$i] = href(action=>"blob",
3445                                                            hash_base=>$parents[$i],
3446                                                            hash=>$diffinfo->{'from_id'}[$i],
3447                                                            file_name=>$from->{'file'}[$i]);
3448                         } else {
3449                                 $from->{'href'}[$i] = undef;
3450                         }
3451                 }
3452         } else {
3453                 # ordinary (not combined) diff
3454                 $from->{'file'} = $diffinfo->{'from_file'};
3455                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3456                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3457                                                hash=>$diffinfo->{'from_id'},
3458                                                file_name=>$from->{'file'});
3459                 } else {
3460                         delete $from->{'href'};
3461                 }
3462         }
3463
3464         $to->{'file'} = $diffinfo->{'to_file'};
3465         if (!is_deleted($diffinfo)) { # file exists in result
3466                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3467                                      hash=>$diffinfo->{'to_id'},
3468                                      file_name=>$to->{'file'});
3469         } else {
3470                 delete $to->{'href'};
3471         }
3472 }
3473
3474 ## ......................................................................
3475 ## parse to array of hashes functions
3476
3477 sub git_get_heads_list {
3478         my ($limit, @classes) = @_;
3479         @classes = ('heads') unless @classes;
3480         my @patterns = map { "refs/$_" } @classes;
3481         my @headslist;
3482
3483         open my $fd, '-|', git_cmd(), 'for-each-ref',
3484                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3485                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3486                 @patterns
3487                 or return;
3488         while (my $line = <$fd>) {
3489                 my %ref_item;
3490
3491                 chomp $line;
3492                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3493                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3494                 my ($committer, $epoch, $tz) =
3495                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3496                 $ref_item{'fullname'}  = $name;
3497                 $name =~ s!^refs/(?:head|remote)s/!!;
3498
3499                 $ref_item{'name'}  = $name;
3500                 $ref_item{'id'}    = $hash;
3501                 $ref_item{'title'} = $title || '(no commit message)';
3502                 $ref_item{'epoch'} = $epoch;
3503                 if ($epoch) {
3504                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3505                 } else {
3506                         $ref_item{'age'} = "unknown";
3507                 }
3508
3509                 push @headslist, \%ref_item;
3510         }
3511         close $fd;
3512
3513         return wantarray ? @headslist : \@headslist;
3514 }
3515
3516 sub git_get_tags_list {
3517         my $limit = shift;
3518         my @tagslist;
3519
3520         open my $fd, '-|', git_cmd(), 'for-each-ref',
3521                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3522                 '--format=%(objectname) %(objecttype) %(refname) '.
3523                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3524                 'refs/tags'
3525                 or return;
3526         while (my $line = <$fd>) {
3527                 my %ref_item;
3528
3529                 chomp $line;
3530                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3531                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3532                 my ($creator, $epoch, $tz) =
3533                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3534                 $ref_item{'fullname'} = $name;
3535                 $name =~ s!^refs/tags/!!;
3536
3537                 $ref_item{'type'} = $type;
3538                 $ref_item{'id'} = $id;
3539                 $ref_item{'name'} = $name;
3540                 if ($type eq "tag") {
3541                         $ref_item{'subject'} = $title;
3542                         $ref_item{'reftype'} = $reftype;
3543                         $ref_item{'refid'}   = $refid;
3544                 } else {
3545                         $ref_item{'reftype'} = $type;
3546                         $ref_item{'refid'}   = $id;
3547                 }
3548
3549                 if ($type eq "tag" || $type eq "commit") {
3550                         $ref_item{'epoch'} = $epoch;
3551                         if ($epoch) {
3552                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3553                         } else {
3554                                 $ref_item{'age'} = "unknown";
3555                         }
3556                 }
3557
3558                 push @tagslist, \%ref_item;
3559         }
3560         close $fd;
3561
3562         return wantarray ? @tagslist : \@tagslist;
3563 }
3564
3565 ## ----------------------------------------------------------------------
3566 ## filesystem-related functions
3567
3568 sub get_file_owner {
3569         my $path = shift;
3570
3571         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3572         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3573         if (!defined $gcos) {
3574                 return undef;
3575         }
3576         my $owner = $gcos;
3577         $owner =~ s/[,;].*$//;
3578         return to_utf8($owner);
3579 }
3580
3581 # assume that file exists
3582 sub insert_file {
3583         my $filename = shift;
3584
3585         open my $fd, '<', $filename;
3586         print map { to_utf8($_) } <$fd>;
3587         close $fd;
3588 }
3589
3590 ## ......................................................................
3591 ## mimetype related functions
3592
3593 sub mimetype_guess_file {
3594         my $filename = shift;
3595         my $mimemap = shift;
3596         -r $mimemap or return undef;
3597
3598         my %mimemap;
3599         open(my $mh, '<', $mimemap) or return undef;
3600         while (<$mh>) {
3601                 next if m/^#/; # skip comments
3602                 my ($mimetype, @exts) = split(/\s+/);
3603                 foreach my $ext (@exts) {
3604                         $mimemap{$ext} = $mimetype;
3605                 }
3606         }
3607         close($mh);
3608
3609         $filename =~ /\.([^.]*)$/;
3610         return $mimemap{$1};
3611 }
3612
3613 sub mimetype_guess {
3614         my $filename = shift;
3615         my $mime;
3616         $filename =~ /\./ or return undef;
3617
3618         if ($mimetypes_file) {
3619                 my $file = $mimetypes_file;
3620                 if ($file !~ m!^/!) { # if it is relative path
3621                         # it is relative to project
3622                         $file = "$projectroot/$project/$file";
3623                 }
3624                 $mime = mimetype_guess_file($filename, $file);
3625         }
3626         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3627         return $mime;
3628 }
3629
3630 sub blob_mimetype {
3631         my $fd = shift;
3632         my $filename = shift;
3633
3634         if ($filename) {
3635                 my $mime = mimetype_guess($filename);
3636                 $mime and return $mime;
3637         }
3638
3639         # just in case
3640         return $default_blob_plain_mimetype unless $fd;
3641
3642         if (-T $fd) {
3643                 return 'text/plain';
3644         } elsif (! $filename) {
3645                 return 'application/octet-stream';
3646         } elsif ($filename =~ m/\.png$/i) {
3647                 return 'image/png';
3648         } elsif ($filename =~ m/\.gif$/i) {
3649                 return 'image/gif';
3650         } elsif ($filename =~ m/\.jpe?g$/i) {
3651                 return 'image/jpeg';
3652         } else {
3653                 return 'application/octet-stream';
3654         }
3655 }
3656
3657 sub blob_contenttype {
3658         my ($fd, $file_name, $type) = @_;
3659
3660         $type ||= blob_mimetype($fd, $file_name);
3661         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3662                 $type .= "; charset=$default_text_plain_charset";
3663         }
3664
3665         return $type;
3666 }
3667
3668 # guess file syntax for syntax highlighting; return undef if no highlighting
3669 # the name of syntax can (in the future) depend on syntax highlighter used
3670 sub guess_file_syntax {
3671         my ($highlight, $mimetype, $file_name) = @_;
3672         return undef unless ($highlight && defined $file_name);
3673         my $basename = basename($file_name, '.in');
3674         return $highlight_basename{$basename}
3675                 if exists $highlight_basename{$basename};
3676
3677         $basename =~ /\.([^.]*)$/;
3678         my $ext = $1 or return undef;
3679         return $highlight_ext{$ext}
3680                 if exists $highlight_ext{$ext};
3681
3682         return undef;
3683 }
3684
3685 # run highlighter and return FD of its output,
3686 # or return original FD if no highlighting
3687 sub run_highlighter {
3688         my ($fd, $highlight, $syntax) = @_;
3689         return $fd unless ($highlight && defined $syntax);
3690
3691         close $fd;
3692         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3693                   quote_command($highlight_bin).
3694                   " --replace-tabs=8 --fragment --syntax $syntax |"
3695                 or die_error(500, "Couldn't open file or run syntax highlighter");
3696         return $fd;
3697 }
3698
3699 ## ======================================================================
3700 ## functions printing HTML: header, footer, error page
3701
3702 sub get_page_title {
3703         my $title = to_utf8($site_name);
3704
3705         return $title unless (defined $project);
3706         $title .= " - " . to_utf8($project);
3707
3708         return $title unless (defined $action);
3709         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3710
3711         return $title unless (defined $file_name);
3712         $title .= " - " . esc_path($file_name);
3713         if ($action eq "tree" && $file_name !~ m|/$|) {
3714                 $title .= "/";
3715         }
3716
3717         return $title;
3718 }
3719
3720 sub get_content_type_html {
3721         # require explicit support from the UA if we are to send the page as
3722         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3723         # we have to do this because MSIE sometimes globs '*/*', pretending to
3724         # support xhtml+xml but choking when it gets what it asked for.
3725         if (defined $cgi->http('HTTP_ACCEPT') &&
3726             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3727             $cgi->Accept('application/xhtml+xml') != 0) {
3728                 return 'application/xhtml+xml';
3729         } else {
3730                 return 'text/html';
3731         }
3732 }
3733
3734 sub print_feed_meta {
3735         if (defined $project) {
3736                 my %href_params = get_feed_info();
3737                 if (!exists $href_params{'-title'}) {
3738                         $href_params{'-title'} = 'log';
3739                 }
3740
3741                 foreach my $format (qw(RSS Atom)) {
3742                         my $type = lc($format);
3743                         my %link_attr = (
3744                                 '-rel' => 'alternate',
3745                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3746                                 '-type' => "application/$type+xml"
3747                         );
3748
3749                         $href_params{'action'} = $type;
3750                         $link_attr{'-href'} = href(%href_params);
3751                         print "<link ".
3752                               "rel=\"$link_attr{'-rel'}\" ".
3753                               "title=\"$link_attr{'-title'}\" ".
3754                               "href=\"$link_attr{'-href'}\" ".
3755                               "type=\"$link_attr{'-type'}\" ".
3756                               "/>\n";
3757
3758                         $href_params{'extra_options'} = '--no-merges';
3759                         $link_attr{'-href'} = href(%href_params);
3760                         $link_attr{'-title'} .= ' (no merges)';
3761                         print "<link ".
3762                               "rel=\"$link_attr{'-rel'}\" ".
3763                               "title=\"$link_attr{'-title'}\" ".
3764                               "href=\"$link_attr{'-href'}\" ".
3765                               "type=\"$link_attr{'-type'}\" ".
3766                               "/>\n";
3767                 }
3768
3769         } else {
3770                 printf('<link rel="alternate" title="%s projects list" '.
3771                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3772                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3773                 printf('<link rel="alternate" title="%s projects feeds" '.
3774                        'href="%s" type="text/x-opml" />'."\n",
3775                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3776         }
3777 }
3778
3779 sub print_header_links {
3780         my $status = shift;
3781
3782         # print out each stylesheet that exist, providing backwards capability
3783         # for those people who defined $stylesheet in a config file
3784         if (defined $stylesheet) {
3785                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3786         } else {
3787                 foreach my $stylesheet (@stylesheets) {
3788                         next unless $stylesheet;
3789                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3790                 }
3791         }
3792         print_feed_meta()
3793                 if ($status eq '200 OK');
3794         if (defined $favicon) {
3795                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3796         }
3797 }
3798
3799 sub print_nav_breadcrumbs {
3800         my %opts = @_;
3801
3802         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3803         if (defined $project) {
3804                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3805                 if (defined $action) {
3806                         my $action_print = $action ;
3807                         if (defined $opts{-action_extra}) {
3808                                 $action_print = $cgi->a({-href => href(action=>$action)},
3809                                         $action);
3810                         }
3811                         print " / $action_print";
3812                 }
3813                 if (defined $opts{-action_extra}) {
3814                         print " / $opts{-action_extra}";
3815                 }
3816                 print "\n";
3817         }
3818 }
3819
3820 sub print_search_form {
3821         if (!defined $searchtext) {
3822                 $searchtext = "";
3823         }
3824         my $search_hash;
3825         if (defined $hash_base) {
3826                 $search_hash = $hash_base;
3827         } elsif (defined $hash) {
3828                 $search_hash = $hash;
3829         } else {
3830                 $search_hash = "HEAD";
3831         }
3832         my $action = $my_uri;
3833         my $use_pathinfo = gitweb_check_feature('pathinfo');
3834         if ($use_pathinfo) {
3835                 $action .= "/".esc_url($project);
3836         }
3837         print $cgi->startform(-method => "get", -action => $action) .
3838               "<div class=\"search\">\n" .
3839               (!$use_pathinfo &&
3840               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3841               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3842               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3843               $cgi->popup_menu(-name => 'st', -default => 'commit',
3844                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3845               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3846               " search:\n",
3847               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3848               "<span title=\"Extended regular expression\">" .
3849               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3850                              -checked => $search_use_regexp) .
3851               "</span>" .
3852               "</div>" .
3853               $cgi->end_form() . "\n";
3854 }
3855
3856 sub git_header_html {
3857         my $status = shift || "200 OK";
3858         my $expires = shift;
3859         my %opts = @_;
3860
3861         my $title = get_page_title();
3862         my $content_type = get_content_type_html();
3863         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3864                            -status=> $status, -expires => $expires)
3865                 unless ($opts{'-no_http_header'});
3866         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3867         print <<EOF;
3868 <?xml version="1.0" encoding="utf-8"?>
3869 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3870 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3871 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3872 <!-- git core binaries version $git_version -->
3873 <head>
3874 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3875 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3876 <meta name="robots" content="index, nofollow"/>
3877 <title>$title</title>
3878 EOF
3879         # the stylesheet, favicon etc urls won't work correctly with path_info
3880         # unless we set the appropriate base URL
3881         if ($ENV{'PATH_INFO'}) {
3882                 print "<base href=\"".esc_url($base_url)."\" />\n";
3883         }
3884         print_header_links($status);
3885
3886         if (defined $site_html_head_string) {
3887                 print to_utf8($site_html_head_string);
3888         }
3889
3890         print "</head>\n" .
3891               "<body>\n";
3892
3893         if (defined $site_header && -f $site_header) {
3894                 insert_file($site_header);
3895         }
3896
3897         print "<div class=\"page_header\">\n";
3898         if (defined $logo) {
3899                 print $cgi->a({-href => esc_url($logo_url),
3900                                -title => $logo_label},
3901                               $cgi->img({-src => esc_url($logo),
3902                                          -width => 72, -height => 27,
3903                                          -alt => "git",
3904                                          -class => "logo"}));
3905         }
3906         print_nav_breadcrumbs(%opts);
3907         print "</div>\n";
3908
3909         my $have_search = gitweb_check_feature('search');
3910         if (defined $project && $have_search) {
3911                 print_search_form();
3912         }
3913 }
3914
3915 sub git_footer_html {
3916         my $feed_class = 'rss_logo';
3917
3918         print "<div class=\"page_footer\">\n";
3919         if (defined $project) {
3920                 my $descr = git_get_project_description($project);
3921                 if (defined $descr) {
3922                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3923                 }
3924
3925                 my %href_params = get_feed_info();
3926                 if (!%href_params) {
3927                         $feed_class .= ' generic';
3928                 }
3929                 $href_params{'-title'} ||= 'log';
3930
3931                 foreach my $format (qw(RSS Atom)) {
3932                         $href_params{'action'} = lc($format);
3933                         print $cgi->a({-href => href(%href_params),
3934                                       -title => "$href_params{'-title'} $format feed",
3935                                       -class => $feed_class}, $format)."\n";
3936                 }
3937
3938         } else {
3939                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3940                               -class => $feed_class}, "OPML") . " ";
3941                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3942                               -class => $feed_class}, "TXT") . "\n";
3943         }
3944         print "</div>\n"; # class="page_footer"
3945
3946         if (defined $t0 && gitweb_check_feature('timed')) {
3947                 print "<div id=\"generating_info\">\n";
3948                 print 'This page took '.
3949                       '<span id="generating_time" class="time_span">'.
3950                       tv_interval($t0, [ gettimeofday() ]).
3951                       ' seconds </span>'.
3952                       ' and '.
3953                       '<span id="generating_cmd">'.
3954                       $number_of_git_cmds.
3955                       '</span> git commands '.
3956                       " to generate.\n";
3957                 print "</div>\n"; # class="page_footer"
3958         }
3959
3960         if (defined $site_footer && -f $site_footer) {
3961                 insert_file($site_footer);
3962         }
3963
3964         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3965         if (defined $action &&
3966             $action eq 'blame_incremental') {
3967                 print qq!<script type="text/javascript">\n!.
3968                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3969                       qq!           "!. href() .qq!");\n!.
3970                       qq!</script>\n!;
3971         } else {
3972                 my ($jstimezone, $tz_cookie, $datetime_class) =
3973                         gitweb_get_feature('javascript-timezone');
3974
3975                 print qq!<script type="text/javascript">\n!.
3976                       qq!window.onload = function () {\n!;
3977                 if (gitweb_check_feature('javascript-actions')) {
3978                         print qq!       fixLinks();\n!;
3979                 }
3980                 if ($jstimezone && $tz_cookie && $datetime_class) {
3981                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
3982                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
3983                 }
3984                 print qq!};\n!.
3985                       qq!</script>\n!;
3986         }
3987
3988         print "</body>\n" .
3989               "</html>";
3990 }
3991
3992 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3993 # Example: die_error(404, 'Hash not found')
3994 # By convention, use the following status codes (as defined in RFC 2616):
3995 # 400: Invalid or missing CGI parameters, or
3996 #      requested object exists but has wrong type.
3997 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3998 #      this server or project.
3999 # 404: Requested object/revision/project doesn't exist.
4000 # 500: The server isn't configured properly, or
4001 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4002 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4003 # 503: The server is currently unavailable (because it is overloaded,
4004 #      or down for maintenance).  Generally, this is a temporary state.
4005 sub die_error {
4006         my $status = shift || 500;
4007         my $error = esc_html(shift) || "Internal Server Error";
4008         my $extra = shift;
4009         my %opts = @_;
4010
4011         my %http_responses = (
4012                 400 => '400 Bad Request',
4013                 403 => '403 Forbidden',
4014                 404 => '404 Not Found',
4015                 500 => '500 Internal Server Error',
4016                 503 => '503 Service Unavailable',
4017         );
4018         git_header_html($http_responses{$status}, undef, %opts);
4019         print <<EOF;
4020 <div class="page_body">
4021 <br /><br />
4022 $status - $error
4023 <br />
4024 EOF
4025         if (defined $extra) {
4026                 print "<hr />\n" .
4027                       "$extra\n";
4028         }
4029         print "</div>\n";
4030
4031         git_footer_html();
4032         goto DONE_GITWEB
4033                 unless ($opts{'-error_handler'});
4034 }
4035
4036 ## ----------------------------------------------------------------------
4037 ## functions printing or outputting HTML: navigation
4038
4039 sub git_print_page_nav {
4040         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4041         $extra = '' if !defined $extra; # pager or formats
4042
4043         my @navs = qw(summary shortlog log commit commitdiff tree);
4044         if ($suppress) {
4045                 @navs = grep { $_ ne $suppress } @navs;
4046         }
4047
4048         my %arg = map { $_ => {action=>$_} } @navs;
4049         if (defined $head) {
4050                 for (qw(commit commitdiff)) {
4051                         $arg{$_}{'hash'} = $head;
4052                 }
4053                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4054                         for (qw(shortlog log)) {
4055                                 $arg{$_}{'hash'} = $head;
4056                         }
4057                 }
4058         }
4059
4060         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4061         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4062
4063         my @actions = gitweb_get_feature('actions');
4064         my %repl = (
4065                 '%' => '%',
4066                 'n' => $project,         # project name
4067                 'f' => $git_dir,         # project path within filesystem
4068                 'h' => $treehead || '',  # current hash ('h' parameter)
4069                 'b' => $treebase || '',  # hash base ('hb' parameter)
4070         );
4071         while (@actions) {
4072                 my ($label, $link, $pos) = splice(@actions,0,3);
4073                 # insert
4074                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4075                 # munch munch
4076                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4077                 $arg{$label}{'_href'} = $link;
4078         }
4079
4080         print "<div class=\"page_nav\">\n" .
4081                 (join " | ",
4082                  map { $_ eq $current ?
4083                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4084                  } @navs);
4085         print "<br/>\n$extra<br/>\n" .
4086               "</div>\n";
4087 }
4088
4089 # returns a submenu for the nagivation of the refs views (tags, heads,
4090 # remotes) with the current view disabled and the remotes view only
4091 # available if the feature is enabled
4092 sub format_ref_views {
4093         my ($current) = @_;
4094         my @ref_views = qw{tags heads};
4095         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4096         return join " | ", map {
4097                 $_ eq $current ? $_ :
4098                 $cgi->a({-href => href(action=>$_)}, $_)
4099         } @ref_views
4100 }
4101
4102 sub format_paging_nav {
4103         my ($action, $page, $has_next_link) = @_;
4104         my $paging_nav;
4105
4106
4107         if ($page > 0) {
4108                 $paging_nav .=
4109                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4110                         " &sdot; " .
4111                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4112                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4113         } else {
4114                 $paging_nav .= "first &sdot; prev";
4115         }
4116
4117         if ($has_next_link) {
4118                 $paging_nav .= " &sdot; " .
4119                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4120                                  -accesskey => "n", -title => "Alt-n"}, "next");
4121         } else {
4122                 $paging_nav .= " &sdot; next";
4123         }
4124
4125         return $paging_nav;
4126 }
4127
4128 ## ......................................................................
4129 ## functions printing or outputting HTML: div
4130
4131 sub git_print_header_div {
4132         my ($action, $title, $hash, $hash_base) = @_;
4133         my %args = ();
4134
4135         $args{'action'} = $action;
4136         $args{'hash'} = $hash if $hash;
4137         $args{'hash_base'} = $hash_base if $hash_base;
4138
4139         print "<div class=\"header\">\n" .
4140               $cgi->a({-href => href(%args), -class => "title"},
4141               $title ? $title : $action) .
4142               "\n</div>\n";
4143 }
4144
4145 sub format_repo_url {
4146         my ($name, $url) = @_;
4147         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4148 }
4149
4150 # Group output by placing it in a DIV element and adding a header.
4151 # Options for start_div() can be provided by passing a hash reference as the
4152 # first parameter to the function.
4153 # Options to git_print_header_div() can be provided by passing an array
4154 # reference. This must follow the options to start_div if they are present.
4155 # The content can be a scalar, which is output as-is, a scalar reference, which
4156 # is output after html escaping, an IO handle passed either as *handle or
4157 # *handle{IO}, or a function reference. In the latter case all following
4158 # parameters will be taken as argument to the content function call.
4159 sub git_print_section {
4160         my ($div_args, $header_args, $content);
4161         my $arg = shift;
4162         if (ref($arg) eq 'HASH') {
4163                 $div_args = $arg;
4164                 $arg = shift;
4165         }
4166         if (ref($arg) eq 'ARRAY') {
4167                 $header_args = $arg;
4168                 $arg = shift;
4169         }
4170         $content = $arg;
4171
4172         print $cgi->start_div($div_args);
4173         git_print_header_div(@$header_args);
4174
4175         if (ref($content) eq 'CODE') {
4176                 $content->(@_);
4177         } elsif (ref($content) eq 'SCALAR') {
4178                 print esc_html($$content);
4179         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4180                 print <$content>;
4181         } elsif (!ref($content) && defined($content)) {
4182                 print $content;
4183         }
4184
4185         print $cgi->end_div;
4186 }
4187
4188 sub format_timestamp_html {
4189         my $date = shift;
4190         my $strtime = $date->{'rfc2822'};
4191
4192         my (undef, undef, $datetime_class) =
4193                 gitweb_get_feature('javascript-timezone');
4194         if ($datetime_class) {
4195                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4196         }
4197
4198         my $localtime_format = '(%02d:%02d %s)';
4199         if ($date->{'hour_local'} < 6) {
4200                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4201         }
4202         $strtime .= ' ' .
4203                     sprintf($localtime_format,
4204                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4205
4206         return $strtime;
4207 }
4208
4209 # Outputs the author name and date in long form
4210 sub git_print_authorship {
4211         my $co = shift;
4212         my %opts = @_;
4213         my $tag = $opts{-tag} || 'div';
4214         my $author = $co->{'author_name'};
4215
4216         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4217         print "<$tag class=\"author_date\">" .
4218               format_search_author($author, "author", esc_html($author)) .
4219               " [".format_timestamp_html(\%ad)."]".
4220               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4221               "</$tag>\n";
4222 }
4223
4224 # Outputs table rows containing the full author or committer information,
4225 # in the format expected for 'commit' view (& similar).
4226 # Parameters are a commit hash reference, followed by the list of people
4227 # to output information for. If the list is empty it defaults to both
4228 # author and committer.
4229 sub git_print_authorship_rows {
4230         my $co = shift;
4231         # too bad we can't use @people = @_ || ('author', 'committer')
4232         my @people = @_;
4233         @people = ('author', 'committer') unless @people;
4234         foreach my $who (@people) {
4235                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4236                 print "<tr><td>$who</td><td>" .
4237                       format_search_author($co->{"${who}_name"}, $who,
4238                                            esc_html($co->{"${who}_name"})) . " " .
4239                       format_search_author($co->{"${who}_email"}, $who,
4240                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4241                       "</td><td rowspan=\"2\">" .
4242                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4243                       "</td></tr>\n" .
4244                       "<tr>" .
4245                       "<td></td><td>" .
4246                       format_timestamp_html(\%wd) .
4247                       "</td>" .
4248                       "</tr>\n";
4249         }
4250 }
4251
4252 sub git_print_page_path {
4253         my $name = shift;
4254         my $type = shift;
4255         my $hb = shift;
4256
4257
4258         print "<div class=\"page_path\">";
4259         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4260                       -title => 'tree root'}, to_utf8("[$project]"));
4261         print " / ";
4262         if (defined $name) {
4263                 my @dirname = split '/', $name;
4264                 my $basename = pop @dirname;
4265                 my $fullname = '';
4266
4267                 foreach my $dir (@dirname) {
4268                         $fullname .= ($fullname ? '/' : '') . $dir;
4269                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4270                                                      hash_base=>$hb),
4271                                       -title => $fullname}, esc_path($dir));
4272                         print " / ";
4273                 }
4274                 if (defined $type && $type eq 'blob') {
4275                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4276                                                      hash_base=>$hb),
4277                                       -title => $name}, esc_path($basename));
4278                 } elsif (defined $type && $type eq 'tree') {
4279                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4280                                                      hash_base=>$hb),
4281                                       -title => $name}, esc_path($basename));
4282                         print " / ";
4283                 } else {
4284                         print esc_path($basename);
4285                 }
4286         }
4287         print "<br/></div>\n";
4288 }
4289
4290 sub git_print_log {
4291         my $log = shift;
4292         my %opts = @_;
4293
4294         if ($opts{'-remove_title'}) {
4295                 # remove title, i.e. first line of log
4296                 shift @$log;
4297         }
4298         # remove leading empty lines
4299         while (defined $log->[0] && $log->[0] eq "") {
4300                 shift @$log;
4301         }
4302
4303         # print log
4304         my $signoff = 0;
4305         my $empty = 0;
4306         foreach my $line (@$log) {
4307                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4308                         $signoff = 1;
4309                         $empty = 0;
4310                         if (! $opts{'-remove_signoff'}) {
4311                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4312                                 next;
4313                         } else {
4314                                 # remove signoff lines
4315                                 next;
4316                         }
4317                 } else {
4318                         $signoff = 0;
4319                 }
4320
4321                 # print only one empty line
4322                 # do not print empty line after signoff
4323                 if ($line eq "") {
4324                         next if ($empty || $signoff);
4325                         $empty = 1;
4326                 } else {
4327                         $empty = 0;
4328                 }
4329
4330                 print format_log_line_html($line) . "<br/>\n";
4331         }
4332
4333         if ($opts{'-final_empty_line'}) {
4334                 # end with single empty line
4335                 print "<br/>\n" unless $empty;
4336         }
4337 }
4338
4339 # return link target (what link points to)
4340 sub git_get_link_target {
4341         my $hash = shift;
4342         my $link_target;
4343
4344         # read link
4345         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4346                 or return;
4347         {
4348                 local $/ = undef;
4349                 $link_target = <$fd>;
4350         }
4351         close $fd
4352                 or return;
4353
4354         return $link_target;
4355 }
4356
4357 # given link target, and the directory (basedir) the link is in,
4358 # return target of link relative to top directory (top tree);
4359 # return undef if it is not possible (including absolute links).
4360 sub normalize_link_target {
4361         my ($link_target, $basedir) = @_;
4362
4363         # absolute symlinks (beginning with '/') cannot be normalized
4364         return if (substr($link_target, 0, 1) eq '/');
4365
4366         # normalize link target to path from top (root) tree (dir)
4367         my $path;
4368         if ($basedir) {
4369                 $path = $basedir . '/' . $link_target;
4370         } else {
4371                 # we are in top (root) tree (dir)
4372                 $path = $link_target;
4373         }
4374
4375         # remove //, /./, and /../
4376         my @path_parts;
4377         foreach my $part (split('/', $path)) {
4378                 # discard '.' and ''
4379                 next if (!$part || $part eq '.');
4380                 # handle '..'
4381                 if ($part eq '..') {
4382                         if (@path_parts) {
4383                                 pop @path_parts;
4384                         } else {
4385                                 # link leads outside repository (outside top dir)
4386                                 return;
4387                         }
4388                 } else {
4389                         push @path_parts, $part;
4390                 }
4391         }
4392         $path = join('/', @path_parts);
4393
4394         return $path;
4395 }
4396
4397 # print tree entry (row of git_tree), but without encompassing <tr> element
4398 sub git_print_tree_entry {
4399         my ($t, $basedir, $hash_base, $have_blame) = @_;
4400
4401         my %base_key = ();
4402         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4403
4404         # The format of a table row is: mode list link.  Where mode is
4405         # the mode of the entry, list is the name of the entry, an href,
4406         # and link is the action links of the entry.
4407
4408         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4409         if (exists $t->{'size'}) {
4410                 print "<td class=\"size\">$t->{'size'}</td>\n";
4411         }
4412         if ($t->{'type'} eq "blob") {
4413                 print "<td class=\"list\">" .
4414                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4415                                                file_name=>"$basedir$t->{'name'}", %base_key),
4416                                 -class => "list"}, esc_path($t->{'name'}));
4417                 if (S_ISLNK(oct $t->{'mode'})) {
4418                         my $link_target = git_get_link_target($t->{'hash'});
4419                         if ($link_target) {
4420                                 my $norm_target = normalize_link_target($link_target, $basedir);
4421                                 if (defined $norm_target) {
4422                                         print " -> " .
4423                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4424                                                                      file_name=>$norm_target),
4425                                                        -title => $norm_target}, esc_path($link_target));
4426                                 } else {
4427                                         print " -> " . esc_path($link_target);
4428                                 }
4429                         }
4430                 }
4431                 print "</td>\n";
4432                 print "<td class=\"link\">";
4433                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4434                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4435                               "blob");
4436                 if ($have_blame) {
4437                         print " | " .
4438                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4439                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4440                                       "blame");
4441                 }
4442                 if (defined $hash_base) {
4443                         print " | " .
4444                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4445                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4446                                       "history");
4447                 }
4448                 print " | " .
4449                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4450                                                file_name=>"$basedir$t->{'name'}")},
4451                                 "raw");
4452                 print "</td>\n";
4453
4454         } elsif ($t->{'type'} eq "tree") {
4455                 print "<td class=\"list\">";
4456                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4457                                              file_name=>"$basedir$t->{'name'}",
4458                                              %base_key)},
4459                               esc_path($t->{'name'}));
4460                 print "</td>\n";
4461                 print "<td class=\"link\">";
4462                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4463                                              file_name=>"$basedir$t->{'name'}",
4464                                              %base_key)},
4465                               "tree");
4466                 if (defined $hash_base) {
4467                         print " | " .
4468                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4469                                                      file_name=>"$basedir$t->{'name'}")},
4470                                       "history");
4471                 }
4472                 print "</td>\n";
4473         } else {
4474                 # unknown object: we can only present history for it
4475                 # (this includes 'commit' object, i.e. submodule support)
4476                 print "<td class=\"list\">" .
4477                       esc_path($t->{'name'}) .
4478                       "</td>\n";
4479                 print "<td class=\"link\">";
4480                 if (defined $hash_base) {
4481                         print $cgi->a({-href => href(action=>"history",
4482                                                      hash_base=>$hash_base,
4483                                                      file_name=>"$basedir$t->{'name'}")},
4484                                       "history");
4485                 }
4486                 print "</td>\n";
4487         }
4488 }
4489
4490 ## ......................................................................
4491 ## functions printing large fragments of HTML
4492
4493 # get pre-image filenames for merge (combined) diff
4494 sub fill_from_file_info {
4495         my ($diff, @parents) = @_;
4496
4497         $diff->{'from_file'} = [ ];
4498         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4499         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4500                 if ($diff->{'status'}[$i] eq 'R' ||
4501                     $diff->{'status'}[$i] eq 'C') {
4502                         $diff->{'from_file'}[$i] =
4503                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4504                 }
4505         }
4506
4507         return $diff;
4508 }
4509
4510 # is current raw difftree line of file deletion
4511 sub is_deleted {
4512         my $diffinfo = shift;
4513
4514         return $diffinfo->{'to_id'} eq ('0' x 40);
4515 }
4516
4517 # does patch correspond to [previous] difftree raw line
4518 # $diffinfo  - hashref of parsed raw diff format
4519 # $patchinfo - hashref of parsed patch diff format
4520 #              (the same keys as in $diffinfo)
4521 sub is_patch_split {
4522         my ($diffinfo, $patchinfo) = @_;
4523
4524         return defined $diffinfo && defined $patchinfo
4525                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4526 }
4527
4528
4529 sub git_difftree_body {
4530         my ($difftree, $hash, @parents) = @_;
4531         my ($parent) = $parents[0];
4532         my $have_blame = gitweb_check_feature('blame');
4533         print "<div class=\"list_head\">\n";
4534         if ($#{$difftree} > 10) {
4535                 print(($#{$difftree} + 1) . " files changed:\n");
4536         }
4537         print "</div>\n";
4538
4539         print "<table class=\"" .
4540               (@parents > 1 ? "combined " : "") .
4541               "diff_tree\">\n";
4542
4543         # header only for combined diff in 'commitdiff' view
4544         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4545         if ($has_header) {
4546                 # table header
4547                 print "<thead><tr>\n" .
4548                        "<th></th><th></th>\n"; # filename, patchN link
4549                 for (my $i = 0; $i < @parents; $i++) {
4550                         my $par = $parents[$i];
4551                         print "<th>" .
4552                               $cgi->a({-href => href(action=>"commitdiff",
4553                                                      hash=>$hash, hash_parent=>$par),
4554                                        -title => 'commitdiff to parent number ' .
4555                                                   ($i+1) . ': ' . substr($par,0,7)},
4556                                       $i+1) .
4557                               "&nbsp;</th>\n";
4558                 }
4559                 print "</tr></thead>\n<tbody>\n";
4560         }
4561
4562         my $alternate = 1;
4563         my $patchno = 0;
4564         foreach my $line (@{$difftree}) {
4565                 my $diff = parsed_difftree_line($line);
4566
4567                 if ($alternate) {
4568                         print "<tr class=\"dark\">\n";
4569                 } else {
4570                         print "<tr class=\"light\">\n";
4571                 }
4572                 $alternate ^= 1;
4573
4574                 if (exists $diff->{'nparents'}) { # combined diff
4575
4576                         fill_from_file_info($diff, @parents)
4577                                 unless exists $diff->{'from_file'};
4578
4579                         if (!is_deleted($diff)) {
4580                                 # file exists in the result (child) commit
4581                                 print "<td>" .
4582                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4583                                                              file_name=>$diff->{'to_file'},
4584                                                              hash_base=>$hash),
4585                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4586                                       "</td>\n";
4587                         } else {
4588                                 print "<td>" .
4589                                       esc_path($diff->{'to_file'}) .
4590                                       "</td>\n";
4591                         }
4592
4593                         if ($action eq 'commitdiff') {
4594                                 # link to patch
4595                                 $patchno++;
4596                                 print "<td class=\"link\">" .
4597                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4598                                               "patch") .
4599                                       " | " .
4600                                       "</td>\n";
4601                         }
4602
4603                         my $has_history = 0;
4604                         my $not_deleted = 0;
4605                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4606                                 my $hash_parent = $parents[$i];
4607                                 my $from_hash = $diff->{'from_id'}[$i];
4608                                 my $from_path = $diff->{'from_file'}[$i];
4609                                 my $status = $diff->{'status'}[$i];
4610
4611                                 $has_history ||= ($status ne 'A');
4612                                 $not_deleted ||= ($status ne 'D');
4613
4614                                 if ($status eq 'A') {
4615                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4616                                 } elsif ($status eq 'D') {
4617                                         print "<td class=\"link\">" .
4618                                               $cgi->a({-href => href(action=>"blob",
4619                                                                      hash_base=>$hash,
4620                                                                      hash=>$from_hash,
4621                                                                      file_name=>$from_path)},
4622                                                       "blob" . ($i+1)) .
4623                                               " | </td>\n";
4624                                 } else {
4625                                         if ($diff->{'to_id'} eq $from_hash) {
4626                                                 print "<td class=\"link nochange\">";
4627                                         } else {
4628                                                 print "<td class=\"link\">";
4629                                         }
4630                                         print $cgi->a({-href => href(action=>"blobdiff",
4631                                                                      hash=>$diff->{'to_id'},
4632                                                                      hash_parent=>$from_hash,
4633                                                                      hash_base=>$hash,
4634                                                                      hash_parent_base=>$hash_parent,
4635                                                                      file_name=>$diff->{'to_file'},
4636                                                                      file_parent=>$from_path)},
4637                                                       "diff" . ($i+1)) .
4638                                               " | </td>\n";
4639                                 }
4640                         }
4641
4642                         print "<td class=\"link\">";
4643                         if ($not_deleted) {
4644                                 print $cgi->a({-href => href(action=>"blob",
4645                                                              hash=>$diff->{'to_id'},
4646                                                              file_name=>$diff->{'to_file'},
4647                                                              hash_base=>$hash)},
4648                                               "blob");
4649                                 print " | " if ($has_history);
4650                         }
4651                         if ($has_history) {
4652                                 print $cgi->a({-href => href(action=>"history",
4653                                                              file_name=>$diff->{'to_file'},
4654                                                              hash_base=>$hash)},
4655                                               "history");
4656                         }
4657                         print "</td>\n";
4658
4659                         print "</tr>\n";
4660                         next; # instead of 'else' clause, to avoid extra indent
4661                 }
4662                 # else ordinary diff
4663
4664                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4665                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4666                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4667                         $to_mode_oct = oct $diff->{'to_mode'};
4668                         if (S_ISREG($to_mode_oct)) { # only for regular file
4669                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4670                         }
4671                         $to_file_type = file_type($diff->{'to_mode'});
4672                 }
4673                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4674                         $from_mode_oct = oct $diff->{'from_mode'};
4675                         if (S_ISREG($from_mode_oct)) { # only for regular file
4676                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4677                         }
4678                         $from_file_type = file_type($diff->{'from_mode'});
4679                 }
4680
4681                 if ($diff->{'status'} eq "A") { # created
4682                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4683                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4684                         $mode_chng   .= "]</span>";
4685                         print "<td>";
4686                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4687                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4688                                       -class => "list"}, esc_path($diff->{'file'}));
4689                         print "</td>\n";
4690                         print "<td>$mode_chng</td>\n";
4691                         print "<td class=\"link\">";
4692                         if ($action eq 'commitdiff') {
4693                                 # link to patch
4694                                 $patchno++;
4695                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4696                                               "patch") .
4697                                       " | ";
4698                         }
4699                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4700                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4701                                       "blob");
4702                         print "</td>\n";
4703
4704                 } elsif ($diff->{'status'} eq "D") { # deleted
4705                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4706                         print "<td>";
4707                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4708                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4709                                        -class => "list"}, esc_path($diff->{'file'}));
4710                         print "</td>\n";
4711                         print "<td>$mode_chng</td>\n";
4712                         print "<td class=\"link\">";
4713                         if ($action eq 'commitdiff') {
4714                                 # link to patch
4715                                 $patchno++;
4716                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4717                                               "patch") .
4718                                       " | ";
4719                         }
4720                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4721                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4722                                       "blob") . " | ";
4723                         if ($have_blame) {
4724                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4725                                                              file_name=>$diff->{'file'})},
4726                                               "blame") . " | ";
4727                         }
4728                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4729                                                      file_name=>$diff->{'file'})},
4730                                       "history");
4731                         print "</td>\n";
4732
4733                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4734                         my $mode_chnge = "";
4735                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4736                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4737                                 if ($from_file_type ne $to_file_type) {
4738                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4739                                 }
4740                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4741                                         if ($from_mode_str && $to_mode_str) {
4742                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4743                                         } elsif ($to_mode_str) {
4744                                                 $mode_chnge .= " mode: $to_mode_str";
4745                                         }
4746                                 }
4747                                 $mode_chnge .= "]</span>\n";
4748                         }
4749                         print "<td>";
4750                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4751                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4752                                       -class => "list"}, esc_path($diff->{'file'}));
4753                         print "</td>\n";
4754                         print "<td>$mode_chnge</td>\n";
4755                         print "<td class=\"link\">";
4756                         if ($action eq 'commitdiff') {
4757                                 # link to patch
4758                                 $patchno++;
4759                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4760                                               "patch") .
4761                                       " | ";
4762                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4763                                 # "commit" view and modified file (not onlu mode changed)
4764                                 print $cgi->a({-href => href(action=>"blobdiff",
4765                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4766                                                              hash_base=>$hash, hash_parent_base=>$parent,
4767                                                              file_name=>$diff->{'file'})},
4768                                               "diff") .
4769                                       " | ";
4770                         }
4771                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4772                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4773                                        "blob") . " | ";
4774                         if ($have_blame) {
4775                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4776                                                              file_name=>$diff->{'file'})},
4777                                               "blame") . " | ";
4778                         }
4779                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4780                                                      file_name=>$diff->{'file'})},
4781                                       "history");
4782                         print "</td>\n";
4783
4784                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4785                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4786                         my $nstatus = $status_name{$diff->{'status'}};
4787                         my $mode_chng = "";
4788                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4789                                 # mode also for directories, so we cannot use $to_mode_str
4790                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4791                         }
4792                         print "<td>" .
4793                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4794                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4795                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4796                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4797                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4798                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4799                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4800                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4801                               "<td class=\"link\">";
4802                         if ($action eq 'commitdiff') {
4803                                 # link to patch
4804                                 $patchno++;
4805                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4806                                               "patch") .
4807                                       " | ";
4808                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4809                                 # "commit" view and modified file (not only pure rename or copy)
4810                                 print $cgi->a({-href => href(action=>"blobdiff",
4811                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4812                                                              hash_base=>$hash, hash_parent_base=>$parent,
4813                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4814                                               "diff") .
4815                                       " | ";
4816                         }
4817                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4818                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4819                                       "blob") . " | ";
4820                         if ($have_blame) {
4821                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4822                                                              file_name=>$diff->{'to_file'})},
4823                                               "blame") . " | ";
4824                         }
4825                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4826                                                     file_name=>$diff->{'to_file'})},
4827                                       "history");
4828                         print "</td>\n";
4829
4830                 } # we should not encounter Unmerged (U) or Unknown (X) status
4831                 print "</tr>\n";
4832         }
4833         print "</tbody>" if $has_header;
4834         print "</table>\n";
4835 }
4836
4837 sub git_patchset_body {
4838         my ($fd, $difftree, $hash, @hash_parents) = @_;
4839         my ($hash_parent) = $hash_parents[0];
4840
4841         my $is_combined = (@hash_parents > 1);
4842         my $patch_idx = 0;
4843         my $patch_number = 0;
4844         my $patch_line;
4845         my $diffinfo;
4846         my $to_name;
4847         my (%from, %to);
4848
4849         print "<div class=\"patchset\">\n";
4850
4851         # skip to first patch
4852         while ($patch_line = <$fd>) {
4853                 chomp $patch_line;
4854
4855                 last if ($patch_line =~ m/^diff /);
4856         }
4857
4858  PATCH:
4859         while ($patch_line) {
4860
4861                 # parse "git diff" header line
4862                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4863                         # $1 is from_name, which we do not use
4864                         $to_name = unquote($2);
4865                         $to_name =~ s!^b/!!;
4866                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4867                         # $1 is 'cc' or 'combined', which we do not use
4868                         $to_name = unquote($2);
4869                 } else {
4870                         $to_name = undef;
4871                 }
4872
4873                 # check if current patch belong to current raw line
4874                 # and parse raw git-diff line if needed
4875                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4876                         # this is continuation of a split patch
4877                         print "<div class=\"patch cont\">\n";
4878                 } else {
4879                         # advance raw git-diff output if needed
4880                         $patch_idx++ if defined $diffinfo;
4881
4882                         # read and prepare patch information
4883                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4884
4885                         # compact combined diff output can have some patches skipped
4886                         # find which patch (using pathname of result) we are at now;
4887                         if ($is_combined) {
4888                                 while ($to_name ne $diffinfo->{'to_file'}) {
4889                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4890                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4891                                               "</div>\n";  # class="patch"
4892
4893                                         $patch_idx++;
4894                                         $patch_number++;
4895
4896                                         last if $patch_idx > $#$difftree;
4897                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4898                                 }
4899                         }
4900
4901                         # modifies %from, %to hashes
4902                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4903
4904                         # this is first patch for raw difftree line with $patch_idx index
4905                         # we index @$difftree array from 0, but number patches from 1
4906                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4907                 }
4908
4909                 # git diff header
4910                 #assert($patch_line =~ m/^diff /) if DEBUG;
4911                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4912                 $patch_number++;
4913                 # print "git diff" header
4914                 print format_git_diff_header_line($patch_line, $diffinfo,
4915                                                   \%from, \%to);
4916
4917                 # print extended diff header
4918                 print "<div class=\"diff extended_header\">\n";
4919         EXTENDED_HEADER:
4920                 while ($patch_line = <$fd>) {
4921                         chomp $patch_line;
4922
4923                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4924
4925                         print format_extended_diff_header_line($patch_line, $diffinfo,
4926                                                                \%from, \%to);
4927                 }
4928                 print "</div>\n"; # class="diff extended_header"
4929
4930                 # from-file/to-file diff header
4931                 if (! $patch_line) {
4932                         print "</div>\n"; # class="patch"
4933                         last PATCH;
4934                 }
4935                 next PATCH if ($patch_line =~ m/^diff /);
4936                 #assert($patch_line =~ m/^---/) if DEBUG;
4937
4938                 my $last_patch_line = $patch_line;
4939                 $patch_line = <$fd>;
4940                 chomp $patch_line;
4941                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4942
4943                 print format_diff_from_to_header($last_patch_line, $patch_line,
4944                                                  $diffinfo, \%from, \%to,
4945                                                  @hash_parents);
4946
4947                 # the patch itself
4948         LINE:
4949                 while ($patch_line = <$fd>) {
4950                         chomp $patch_line;
4951
4952                         next PATCH if ($patch_line =~ m/^diff /);
4953
4954                         print format_diff_line($patch_line, \%from, \%to);
4955                 }
4956
4957         } continue {
4958                 print "</div>\n"; # class="patch"
4959         }
4960
4961         # for compact combined (--cc) format, with chunk and patch simplification
4962         # the patchset might be empty, but there might be unprocessed raw lines
4963         for (++$patch_idx if $patch_number > 0;
4964              $patch_idx < @$difftree;
4965              ++$patch_idx) {
4966                 # read and prepare patch information
4967                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4968
4969                 # generate anchor for "patch" links in difftree / whatchanged part
4970                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4971                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4972                       "</div>\n";  # class="patch"
4973
4974                 $patch_number++;
4975         }
4976
4977         if ($patch_number == 0) {
4978                 if (@hash_parents > 1) {
4979                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4980                 } else {
4981                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4982                 }
4983         }
4984
4985         print "</div>\n"; # class="patchset"
4986 }
4987
4988 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4989
4990 # fills project list info (age, description, owner, category, forks)
4991 # for each project in the list, removing invalid projects from
4992 # returned list
4993 # NOTE: modifies $projlist, but does not remove entries from it
4994 sub fill_project_list_info {
4995         my $projlist = shift;
4996         my @projects;
4997
4998         my $show_ctags = gitweb_check_feature('ctags');
4999  PROJECT:
5000         foreach my $pr (@$projlist) {
5001                 my (@activity) = git_get_last_activity($pr->{'path'});
5002                 unless (@activity) {
5003                         next PROJECT;
5004                 }
5005                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5006                 if (!defined $pr->{'descr'}) {
5007                         my $descr = git_get_project_description($pr->{'path'}) || "";
5008                         $descr = to_utf8($descr);
5009                         $pr->{'descr_long'} = $descr;
5010                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5011                 }
5012                 if (!defined $pr->{'owner'}) {
5013                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5014                 }
5015                 if ($show_ctags) {
5016                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5017                 }
5018                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
5019                         my $cat = git_get_project_category($pr->{'path'}) ||
5020                                                            $project_list_default_category;
5021                         $pr->{'category'} = to_utf8($cat);
5022                 }
5023
5024                 push @projects, $pr;
5025         }
5026
5027         return @projects;
5028 }
5029
5030 sub sort_projects_list {
5031         my ($projlist, $order) = @_;
5032         my @projects;
5033
5034         my %order_info = (
5035                 project => { key => 'path', type => 'str' },
5036                 descr => { key => 'descr_long', type => 'str' },
5037                 owner => { key => 'owner', type => 'str' },
5038                 age => { key => 'age', type => 'num' }
5039         );
5040         my $oi = $order_info{$order};
5041         return @$projlist unless defined $oi;
5042         if ($oi->{'type'} eq 'str') {
5043                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5044         } else {
5045                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5046         }
5047
5048         return @projects;
5049 }
5050
5051 # returns a hash of categories, containing the list of project
5052 # belonging to each category
5053 sub build_projlist_by_category {
5054         my ($projlist, $from, $to) = @_;
5055         my %categories;
5056
5057         $from = 0 unless defined $from;
5058         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5059
5060         for (my $i = $from; $i <= $to; $i++) {
5061                 my $pr = $projlist->[$i];
5062                 push @{$categories{ $pr->{'category'} }}, $pr;
5063         }
5064
5065         return wantarray ? %categories : \%categories;
5066 }
5067
5068 # print 'sort by' <th> element, generating 'sort by $name' replay link
5069 # if that order is not selected
5070 sub print_sort_th {
5071         print format_sort_th(@_);
5072 }
5073
5074 sub format_sort_th {
5075         my ($name, $order, $header) = @_;
5076         my $sort_th = "";
5077         $header ||= ucfirst($name);
5078
5079         if ($order eq $name) {
5080                 $sort_th .= "<th>$header</th>\n";
5081         } else {
5082                 $sort_th .= "<th>" .
5083                             $cgi->a({-href => href(-replay=>1, order=>$name),
5084                                      -class => "header"}, $header) .
5085                             "</th>\n";
5086         }
5087
5088         return $sort_th;
5089 }
5090
5091 sub git_project_list_rows {
5092         my ($projlist, $from, $to, $check_forks) = @_;
5093
5094         $from = 0 unless defined $from;
5095         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5096
5097         my $alternate = 1;
5098         for (my $i = $from; $i <= $to; $i++) {
5099                 my $pr = $projlist->[$i];
5100
5101                 if ($alternate) {
5102                         print "<tr class=\"dark\">\n";
5103                 } else {
5104                         print "<tr class=\"light\">\n";
5105                 }
5106                 $alternate ^= 1;
5107
5108                 if ($check_forks) {
5109                         print "<td>";
5110                         if ($pr->{'forks'}) {
5111                                 my $nforks = scalar @{$pr->{'forks'}};
5112                                 if ($nforks > 0) {
5113                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5114                                                        -title => "$nforks forks"}, "+");
5115                                 } else {
5116                                         print $cgi->span({-title => "$nforks forks"}, "+");
5117                                 }
5118                         }
5119                         print "</td>\n";
5120                 }
5121                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5122                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5123                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5124                                         -class => "list", -title => $pr->{'descr_long'}},
5125                                         esc_html($pr->{'descr'})) . "</td>\n" .
5126                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5127                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5128                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5129                       "<td class=\"link\">" .
5130                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5131                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5132                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5133                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5134                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5135                       "</td>\n" .
5136                       "</tr>\n";
5137         }
5138 }
5139
5140 sub git_project_list_body {
5141         # actually uses global variable $project
5142         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5143         my @projects = @$projlist;
5144
5145         my $check_forks = gitweb_check_feature('forks');
5146         my $show_ctags  = gitweb_check_feature('ctags');
5147         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5148         $check_forks = undef
5149                 if ($tagfilter || $searchtext);
5150
5151         # filtering out forks before filling info allows to do less work
5152         @projects = filter_forks_from_projects_list(\@projects)
5153                 if ($check_forks);
5154         @projects = fill_project_list_info(\@projects);
5155         # searching projects require filling to be run before it
5156         @projects = search_projects_list(\@projects,
5157                                          'searchtext' => $searchtext,
5158                                          'tagfilter'  => $tagfilter)
5159                 if ($tagfilter || $searchtext);
5160
5161         $order ||= $default_projects_order;
5162         $from = 0 unless defined $from;
5163         $to = $#projects if (!defined $to || $#projects < $to);
5164
5165         # short circuit
5166         if ($from > $to) {
5167                 print "<center>\n".
5168                       "<b>No such projects found</b><br />\n".
5169                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5170                       "</center>\n<br />\n";
5171                 return;
5172         }
5173
5174         @projects = sort_projects_list(\@projects, $order);
5175
5176         if ($show_ctags) {
5177                 my $ctags = git_gather_all_ctags(\@projects);
5178                 my $cloud = git_populate_project_tagcloud($ctags);
5179                 print git_show_project_tagcloud($cloud, 64);
5180         }
5181
5182         print "<table class=\"project_list\">\n";
5183         unless ($no_header) {
5184                 print "<tr>\n";
5185                 if ($check_forks) {
5186                         print "<th></th>\n";
5187                 }
5188                 print_sort_th('project', $order, 'Project');
5189                 print_sort_th('descr', $order, 'Description');
5190                 print_sort_th('owner', $order, 'Owner');
5191                 print_sort_th('age', $order, 'Last Change');
5192                 print "<th></th>\n" . # for links
5193                       "</tr>\n";
5194         }
5195
5196         if ($projects_list_group_categories) {
5197                 # only display categories with projects in the $from-$to window
5198                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5199                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5200                 foreach my $cat (sort keys %categories) {
5201                         unless ($cat eq "") {
5202                                 print "<tr>\n";
5203                                 if ($check_forks) {
5204                                         print "<td></td>\n";
5205                                 }
5206                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5207                                 print "</tr>\n";
5208                         }
5209
5210                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5211                 }
5212         } else {
5213                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5214         }
5215
5216         if (defined $extra) {
5217                 print "<tr>\n";
5218                 if ($check_forks) {
5219                         print "<td></td>\n";
5220                 }
5221                 print "<td colspan=\"5\">$extra</td>\n" .
5222                       "</tr>\n";
5223         }
5224         print "</table>\n";
5225 }
5226
5227 sub git_log_body {
5228         # uses global variable $project
5229         my ($commitlist, $from, $to, $refs, $extra) = @_;
5230
5231         $from = 0 unless defined $from;
5232         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5233
5234         for (my $i = 0; $i <= $to; $i++) {
5235                 my %co = %{$commitlist->[$i]};
5236                 next if !%co;
5237                 my $commit = $co{'id'};
5238                 my $ref = format_ref_marker($refs, $commit);
5239                 git_print_header_div('commit',
5240                                "<span class=\"age\">$co{'age_string'}</span>" .
5241                                esc_html($co{'title'}) . $ref,
5242                                $commit);
5243                 print "<div class=\"title_text\">\n" .
5244                       "<div class=\"log_link\">\n" .
5245                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5246                       " | " .
5247                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5248                       " | " .
5249                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5250                       "<br/>\n" .
5251                       "</div>\n";
5252                       git_print_authorship(\%co, -tag => 'span');
5253                       print "<br/>\n</div>\n";
5254
5255                 print "<div class=\"log_body\">\n";
5256                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5257                 print "</div>\n";
5258         }
5259         if ($extra) {
5260                 print "<div class=\"page_nav\">\n";
5261                 print "$extra\n";
5262                 print "</div>\n";
5263         }
5264 }
5265
5266 sub git_shortlog_body {
5267         # uses global variable $project
5268         my ($commitlist, $from, $to, $refs, $extra) = @_;
5269
5270         $from = 0 unless defined $from;
5271         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5272
5273         print "<table class=\"shortlog\">\n";
5274         my $alternate = 1;
5275         for (my $i = $from; $i <= $to; $i++) {
5276                 my %co = %{$commitlist->[$i]};
5277                 my $commit = $co{'id'};
5278                 my $ref = format_ref_marker($refs, $commit);
5279                 if ($alternate) {
5280                         print "<tr class=\"dark\">\n";
5281                 } else {
5282                         print "<tr class=\"light\">\n";
5283                 }
5284                 $alternate ^= 1;
5285                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5286                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5287                       format_author_html('td', \%co, 10) . "<td>";
5288                 print format_subject_html($co{'title'}, $co{'title_short'},
5289                                           href(action=>"commit", hash=>$commit), $ref);
5290                 print "</td>\n" .
5291                       "<td class=\"link\">" .
5292                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5293                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5294                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5295                 my $snapshot_links = format_snapshot_links($commit);
5296                 if (defined $snapshot_links) {
5297                         print " | " . $snapshot_links;
5298                 }
5299                 print "</td>\n" .
5300                       "</tr>\n";
5301         }
5302         if (defined $extra) {
5303                 print "<tr>\n" .
5304                       "<td colspan=\"4\">$extra</td>\n" .
5305                       "</tr>\n";
5306         }
5307         print "</table>\n";
5308 }
5309
5310 sub git_history_body {
5311         # Warning: assumes constant type (blob or tree) during history
5312         my ($commitlist, $from, $to, $refs, $extra,
5313             $file_name, $file_hash, $ftype) = @_;
5314
5315         $from = 0 unless defined $from;
5316         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5317
5318         print "<table class=\"history\">\n";
5319         my $alternate = 1;
5320         for (my $i = $from; $i <= $to; $i++) {
5321                 my %co = %{$commitlist->[$i]};
5322                 if (!%co) {
5323                         next;
5324                 }
5325                 my $commit = $co{'id'};
5326
5327                 my $ref = format_ref_marker($refs, $commit);
5328
5329                 if ($alternate) {
5330                         print "<tr class=\"dark\">\n";
5331                 } else {
5332                         print "<tr class=\"light\">\n";
5333                 }
5334                 $alternate ^= 1;
5335                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5336         # shortlog:   format_author_html('td', \%co, 10)
5337                       format_author_html('td', \%co, 15, 3) . "<td>";
5338                 # originally git_history used chop_str($co{'title'}, 50)
5339                 print format_subject_html($co{'title'}, $co{'title_short'},
5340                                           href(action=>"commit", hash=>$commit), $ref);
5341                 print "</td>\n" .
5342                       "<td class=\"link\">" .
5343                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5344                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5345
5346                 if ($ftype eq 'blob') {
5347                         my $blob_current = $file_hash;
5348                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5349                         if (defined $blob_current && defined $blob_parent &&
5350                                         $blob_current ne $blob_parent) {
5351                                 print " | " .
5352                                         $cgi->a({-href => href(action=>"blobdiff",
5353                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5354                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5355                                                                file_name=>$file_name)},
5356                                                 "diff to current");
5357                         }
5358                 }
5359                 print "</td>\n" .
5360                       "</tr>\n";
5361         }
5362         if (defined $extra) {
5363                 print "<tr>\n" .
5364                       "<td colspan=\"4\">$extra</td>\n" .
5365                       "</tr>\n";
5366         }
5367         print "</table>\n";
5368 }
5369
5370 sub git_tags_body {
5371         # uses global variable $project
5372         my ($taglist, $from, $to, $extra) = @_;
5373         $from = 0 unless defined $from;
5374         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5375
5376         print "<table class=\"tags\">\n";
5377         my $alternate = 1;
5378         for (my $i = $from; $i <= $to; $i++) {
5379                 my $entry = $taglist->[$i];
5380                 my %tag = %$entry;
5381                 my $comment = $tag{'subject'};
5382                 my $comment_short;
5383                 if (defined $comment) {
5384                         $comment_short = chop_str($comment, 30, 5);
5385                 }
5386                 if ($alternate) {
5387                         print "<tr class=\"dark\">\n";
5388                 } else {
5389                         print "<tr class=\"light\">\n";
5390                 }
5391                 $alternate ^= 1;
5392                 if (defined $tag{'age'}) {
5393                         print "<td><i>$tag{'age'}</i></td>\n";
5394                 } else {
5395                         print "<td></td>\n";
5396                 }
5397                 print "<td>" .
5398                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5399                                -class => "list name"}, esc_html($tag{'name'})) .
5400                       "</td>\n" .
5401                       "<td>";
5402                 if (defined $comment) {
5403                         print format_subject_html($comment, $comment_short,
5404                                                   href(action=>"tag", hash=>$tag{'id'}));
5405                 }
5406                 print "</td>\n" .
5407                       "<td class=\"selflink\">";
5408                 if ($tag{'type'} eq "tag") {
5409                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5410                 } else {
5411                         print "&nbsp;";
5412                 }
5413                 print "</td>\n" .
5414                       "<td class=\"link\">" . " | " .
5415                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5416                 if ($tag{'reftype'} eq "commit") {
5417                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5418                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5419                 } elsif ($tag{'reftype'} eq "blob") {
5420                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5421                 }
5422                 print "</td>\n" .
5423                       "</tr>";
5424         }
5425         if (defined $extra) {
5426                 print "<tr>\n" .
5427                       "<td colspan=\"5\">$extra</td>\n" .
5428                       "</tr>\n";
5429         }
5430         print "</table>\n";
5431 }
5432
5433 sub git_heads_body {
5434         # uses global variable $project
5435         my ($headlist, $head, $from, $to, $extra) = @_;
5436         $from = 0 unless defined $from;
5437         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5438
5439         print "<table class=\"heads\">\n";
5440         my $alternate = 1;
5441         for (my $i = $from; $i <= $to; $i++) {
5442                 my $entry = $headlist->[$i];
5443                 my %ref = %$entry;
5444                 my $curr = $ref{'id'} eq $head;
5445                 if ($alternate) {
5446                         print "<tr class=\"dark\">\n";
5447                 } else {
5448                         print "<tr class=\"light\">\n";
5449                 }
5450                 $alternate ^= 1;
5451                 print "<td><i>$ref{'age'}</i></td>\n" .
5452                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5453                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5454                                -class => "list name"},esc_html($ref{'name'})) .
5455                       "</td>\n" .
5456                       "<td class=\"link\">" .
5457                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5458                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5459                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5460                       "</td>\n" .
5461                       "</tr>";
5462         }
5463         if (defined $extra) {
5464                 print "<tr>\n" .
5465                       "<td colspan=\"3\">$extra</td>\n" .
5466                       "</tr>\n";
5467         }
5468         print "</table>\n";
5469 }
5470
5471 # Display a single remote block
5472 sub git_remote_block {
5473         my ($remote, $rdata, $limit, $head) = @_;
5474
5475         my $heads = $rdata->{'heads'};
5476         my $fetch = $rdata->{'fetch'};
5477         my $push = $rdata->{'push'};
5478
5479         my $urls_table = "<table class=\"projects_list\">\n" ;
5480
5481         if (defined $fetch) {
5482                 if ($fetch eq $push) {
5483                         $urls_table .= format_repo_url("URL", $fetch);
5484                 } else {
5485                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5486                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5487                 }
5488         } elsif (defined $push) {
5489                 $urls_table .= format_repo_url("Push URL", $push);
5490         } else {
5491                 $urls_table .= format_repo_url("", "No remote URL");
5492         }
5493
5494         $urls_table .= "</table>\n";
5495
5496         my $dots;
5497         if (defined $limit && $limit < @$heads) {
5498                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5499         }
5500
5501         print $urls_table;
5502         git_heads_body($heads, $head, 0, $limit, $dots);
5503 }
5504
5505 # Display a list of remote names with the respective fetch and push URLs
5506 sub git_remotes_list {
5507         my ($remotedata, $limit) = @_;
5508         print "<table class=\"heads\">\n";
5509         my $alternate = 1;
5510         my @remotes = sort keys %$remotedata;
5511
5512         my $limited = $limit && $limit < @remotes;
5513
5514         $#remotes = $limit - 1 if $limited;
5515
5516         while (my $remote = shift @remotes) {
5517                 my $rdata = $remotedata->{$remote};
5518                 my $fetch = $rdata->{'fetch'};
5519                 my $push = $rdata->{'push'};
5520                 if ($alternate) {
5521                         print "<tr class=\"dark\">\n";
5522                 } else {
5523                         print "<tr class=\"light\">\n";
5524                 }
5525                 $alternate ^= 1;
5526                 print "<td>" .
5527                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5528                                -class=> "list name"},esc_html($remote)) .
5529                       "</td>";
5530                 print "<td class=\"link\">" .
5531                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5532                       " | " .
5533                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5534                       "</td>";
5535
5536                 print "</tr>\n";
5537         }
5538
5539         if ($limited) {
5540                 print "<tr>\n" .
5541                       "<td colspan=\"3\">" .
5542                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5543                       "</td>\n" . "</tr>\n";
5544         }
5545
5546         print "</table>";
5547 }
5548
5549 # Display remote heads grouped by remote, unless there are too many
5550 # remotes, in which case we only display the remote names
5551 sub git_remotes_body {
5552         my ($remotedata, $limit, $head) = @_;
5553         if ($limit and $limit < keys %$remotedata) {
5554                 git_remotes_list($remotedata, $limit);
5555         } else {
5556                 fill_remote_heads($remotedata);
5557                 while (my ($remote, $rdata) = each %$remotedata) {
5558                         git_print_section({-class=>"remote", -id=>$remote},
5559                                 ["remotes", $remote, $remote], sub {
5560                                         git_remote_block($remote, $rdata, $limit, $head);
5561                                 });
5562                 }
5563         }
5564 }
5565
5566 sub git_search_message {
5567         my %co = @_;
5568
5569         my $greptype;
5570         if ($searchtype eq 'commit') {
5571                 $greptype = "--grep=";
5572         } elsif ($searchtype eq 'author') {
5573                 $greptype = "--author=";
5574         } elsif ($searchtype eq 'committer') {
5575                 $greptype = "--committer=";
5576         }
5577         $greptype .= $searchtext;
5578         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5579                                        $greptype, '--regexp-ignore-case',
5580                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5581
5582         my $paging_nav = '';
5583         if ($page > 0) {
5584                 $paging_nav .=
5585                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5586                                 "first") .
5587                         " &sdot; " .
5588                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5589                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5590         } else {
5591                 $paging_nav .= "first &sdot; prev";
5592         }
5593         my $next_link = '';
5594         if ($#commitlist >= 100) {
5595                 $next_link =
5596                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5597                                  -accesskey => "n", -title => "Alt-n"}, "next");
5598                 $paging_nav .= " &sdot; $next_link";
5599         } else {
5600                 $paging_nav .= " &sdot; next";
5601         }
5602
5603         git_header_html();
5604
5605         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5606         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5607         if ($page == 0 && !@commitlist) {
5608                 print "<p>No match.</p>\n";
5609         } else {
5610                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5611         }
5612
5613         git_footer_html();
5614 }
5615
5616 sub git_search_changes {
5617         my %co = @_;
5618
5619         local $/ = "\n";
5620         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5621                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5622                 ($search_use_regexp ? '--pickaxe-regex' : ())
5623                         or die_error(500, "Open git-log failed");
5624
5625         git_header_html();
5626
5627         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5628         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5629
5630         print "<table class=\"pickaxe search\">\n";
5631         my $alternate = 1;
5632         undef %co;
5633         my @files;
5634         while (my $line = <$fd>) {
5635                 chomp $line;
5636                 next unless $line;
5637
5638                 my %set = parse_difftree_raw_line($line);
5639                 if (defined $set{'commit'}) {
5640                         # finish previous commit
5641                         if (%co) {
5642                                 print "</td>\n" .
5643                                       "<td class=\"link\">" .
5644                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5645                                               "commit") .
5646                                       " | " .
5647                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5648                                                              hash_base=>$co{'id'})},
5649                                               "tree") .
5650                                       "</td>\n" .
5651                                       "</tr>\n";
5652                         }
5653
5654                         if ($alternate) {
5655                                 print "<tr class=\"dark\">\n";
5656                         } else {
5657                                 print "<tr class=\"light\">\n";
5658                         }
5659                         $alternate ^= 1;
5660                         %co = parse_commit($set{'commit'});
5661                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5662                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5663                               "<td><i>$author</i></td>\n" .
5664                               "<td>" .
5665                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5666                                       -class => "list subject"},
5667                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5668                 } elsif (defined $set{'to_id'}) {
5669                         next if ($set{'to_id'} =~ m/^0{40}$/);
5670
5671                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5672                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5673                                       -class => "list"},
5674                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5675                               "<br/>\n";
5676                 }
5677         }
5678         close $fd;
5679
5680         # finish last commit (warning: repetition!)
5681         if (%co) {
5682                 print "</td>\n" .
5683                       "<td class=\"link\">" .
5684                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5685                               "commit") .
5686                       " | " .
5687                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5688                                              hash_base=>$co{'id'})},
5689                               "tree") .
5690                       "</td>\n" .
5691                       "</tr>\n";
5692         }
5693
5694         print "</table>\n";
5695
5696         git_footer_html();
5697 }
5698
5699 sub git_search_files {
5700         my %co = @_;
5701
5702         local $/ = "\n";
5703         open my $fd, "-|", git_cmd(), 'grep', '-n',
5704                 $search_use_regexp ? ('-E', '-i') : '-F',
5705                 $searchtext, $co{'tree'}
5706                         or die_error(500, "Open git-grep failed");
5707
5708         git_header_html();
5709
5710         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5711         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5712
5713         print "<table class=\"grep_search\">\n";
5714         my $alternate = 1;
5715         my $matches = 0;
5716         my $lastfile = '';
5717         while (my $line = <$fd>) {
5718                 chomp $line;
5719                 my ($file, $lno, $ltext, $binary);
5720                 last if ($matches++ > 1000);
5721                 if ($line =~ /^Binary file (.+) matches$/) {
5722                         $file = $1;
5723                         $binary = 1;
5724                 } else {
5725                         (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
5726                 }
5727                 if ($file ne $lastfile) {
5728                         $lastfile and print "</td></tr>\n";
5729                         if ($alternate++) {
5730                                 print "<tr class=\"dark\">\n";
5731                         } else {
5732                                 print "<tr class=\"light\">\n";
5733                         }
5734                         print "<td class=\"list\">".
5735                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5736                                                        file_name=>"$file"),
5737                                         -class => "list"}, esc_path($file));
5738                         print "</td><td>\n";
5739                         $lastfile = $file;
5740                 }
5741                 if ($binary) {
5742                         print "<div class=\"binary\">Binary file</div>\n";
5743                 } else {
5744                         $ltext = untabify($ltext);
5745                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5746                                 $ltext = esc_html($1, -nbsp=>1);
5747                                 $ltext .= '<span class="match">';
5748                                 $ltext .= esc_html($2, -nbsp=>1);
5749                                 $ltext .= '</span>';
5750                                 $ltext .= esc_html($3, -nbsp=>1);
5751                         } else {
5752                                 $ltext = esc_html($ltext, -nbsp=>1);
5753                         }
5754                         print "<div class=\"pre\">" .
5755                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5756                                                        file_name=>"$file").'#l'.$lno,
5757                                         -class => "linenr"}, sprintf('%4i', $lno))
5758                                 . ' ' .  $ltext . "</div>\n";
5759                 }
5760         }
5761         if ($lastfile) {
5762                 print "</td></tr>\n";
5763                 if ($matches > 1000) {
5764                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5765                 }
5766         } else {
5767                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
5768         }
5769         close $fd;
5770
5771         print "</table>\n";
5772
5773         git_footer_html();
5774 }
5775
5776 sub git_search_grep_body {
5777         my ($commitlist, $from, $to, $extra) = @_;
5778         $from = 0 unless defined $from;
5779         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5780
5781         print "<table class=\"commit_search\">\n";
5782         my $alternate = 1;
5783         for (my $i = $from; $i <= $to; $i++) {
5784                 my %co = %{$commitlist->[$i]};
5785                 if (!%co) {
5786                         next;
5787                 }
5788                 my $commit = $co{'id'};
5789                 if ($alternate) {
5790                         print "<tr class=\"dark\">\n";
5791                 } else {
5792                         print "<tr class=\"light\">\n";
5793                 }
5794                 $alternate ^= 1;
5795                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5796                       format_author_html('td', \%co, 15, 5) .
5797                       "<td>" .
5798                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5799                                -class => "list subject"},
5800                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5801                 my $comment = $co{'comment'};
5802                 foreach my $line (@$comment) {
5803                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5804                                 my ($lead, $match, $trail) = ($1, $2, $3);
5805                                 $match = chop_str($match, 70, 5, 'center');
5806                                 my $contextlen = int((80 - length($match))/2);
5807                                 $contextlen = 30 if ($contextlen > 30);
5808                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5809                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5810
5811                                 $lead  = esc_html($lead);
5812                                 $match = esc_html($match);
5813                                 $trail = esc_html($trail);
5814
5815                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5816                         }
5817                 }
5818                 print "</td>\n" .
5819                       "<td class=\"link\">" .
5820                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5821                       " | " .
5822                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5823                       " | " .
5824                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5825                 print "</td>\n" .
5826                       "</tr>\n";
5827         }
5828         if (defined $extra) {
5829                 print "<tr>\n" .
5830                       "<td colspan=\"3\">$extra</td>\n" .
5831                       "</tr>\n";
5832         }
5833         print "</table>\n";
5834 }
5835
5836 ## ======================================================================
5837 ## ======================================================================
5838 ## actions
5839
5840 sub git_project_list {
5841         my $order = $input_params{'order'};
5842         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5843                 die_error(400, "Unknown order parameter");
5844         }
5845
5846         my @list = git_get_projects_list();
5847         if (!@list) {
5848                 die_error(404, "No projects found");
5849         }
5850
5851         git_header_html();
5852         if (defined $home_text && -f $home_text) {
5853                 print "<div class=\"index_include\">\n";
5854                 insert_file($home_text);
5855                 print "</div>\n";
5856         }
5857         print $cgi->startform(-method => "get") .
5858               "<p class=\"projsearch\">Search:\n" .
5859               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5860               "</p>" .
5861               $cgi->end_form() . "\n";
5862         git_project_list_body(\@list, $order);
5863         git_footer_html();
5864 }
5865
5866 sub git_forks {
5867         my $order = $input_params{'order'};
5868         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5869                 die_error(400, "Unknown order parameter");
5870         }
5871
5872         my @list = git_get_projects_list($project);
5873         if (!@list) {
5874                 die_error(404, "No forks found");
5875         }
5876
5877         git_header_html();
5878         git_print_page_nav('','');
5879         git_print_header_div('summary', "$project forks");
5880         git_project_list_body(\@list, $order);
5881         git_footer_html();
5882 }
5883
5884 sub git_project_index {
5885         my @projects = git_get_projects_list();
5886         if (!@projects) {
5887                 die_error(404, "No projects found");
5888         }
5889
5890         print $cgi->header(
5891                 -type => 'text/plain',
5892                 -charset => 'utf-8',
5893                 -content_disposition => 'inline; filename="index.aux"');
5894
5895         foreach my $pr (@projects) {
5896                 if (!exists $pr->{'owner'}) {
5897                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5898                 }
5899
5900                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5901                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5902                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5903                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5904                 $path  =~ s/ /\+/g;
5905                 $owner =~ s/ /\+/g;
5906
5907                 print "$path $owner\n";
5908         }
5909 }
5910
5911 sub git_summary {
5912         my $descr = git_get_project_description($project) || "none";
5913         my %co = parse_commit("HEAD");
5914         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5915         my $head = $co{'id'};
5916         my $remote_heads = gitweb_check_feature('remote_heads');
5917
5918         my $owner = git_get_project_owner($project);
5919
5920         my $refs = git_get_references();
5921         # These get_*_list functions return one more to allow us to see if
5922         # there are more ...
5923         my @taglist  = git_get_tags_list(16);
5924         my @headlist = git_get_heads_list(16);
5925         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5926         my @forklist;
5927         my $check_forks = gitweb_check_feature('forks');
5928
5929         if ($check_forks) {
5930                 # find forks of a project
5931                 @forklist = git_get_projects_list($project);
5932                 # filter out forks of forks
5933                 @forklist = filter_forks_from_projects_list(\@forklist)
5934                         if (@forklist);
5935         }
5936
5937         git_header_html();
5938         git_print_page_nav('summary','', $head);
5939
5940         print "<div class=\"title\">&nbsp;</div>\n";
5941         print "<table class=\"projects_list\">\n" .
5942               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5943               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5944         if (defined $cd{'rfc2822'}) {
5945                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
5946                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
5947         }
5948
5949         # use per project git URL list in $projectroot/$project/cloneurl
5950         # or make project git URL from git base URL and project name
5951         my $url_tag = "URL";
5952         my @url_list = git_get_project_url_list($project);
5953         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5954         foreach my $git_url (@url_list) {
5955                 next unless $git_url;
5956                 print format_repo_url($url_tag, $git_url);
5957                 $url_tag = "";
5958         }
5959
5960         # Tag cloud
5961         my $show_ctags = gitweb_check_feature('ctags');
5962         if ($show_ctags) {
5963                 my $ctags = git_get_project_ctags($project);
5964                 if (%$ctags) {
5965                         # without ability to add tags, don't show if there are none
5966                         my $cloud = git_populate_project_tagcloud($ctags);
5967                         print "<tr id=\"metadata_ctags\">" .
5968                               "<td>content tags</td>" .
5969                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
5970                               "</tr>\n";
5971                 }
5972         }
5973
5974         print "</table>\n";
5975
5976         # If XSS prevention is on, we don't include README.html.
5977         # TODO: Allow a readme in some safe format.
5978         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5979                 print "<div class=\"title\">readme</div>\n" .
5980                       "<div class=\"readme\">\n";
5981                 insert_file("$projectroot/$project/README.html");
5982                 print "\n</div>\n"; # class="readme"
5983         }
5984
5985         # we need to request one more than 16 (0..15) to check if
5986         # those 16 are all
5987         my @commitlist = $head ? parse_commits($head, 17) : ();
5988         if (@commitlist) {
5989                 git_print_header_div('shortlog');
5990                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5991                                   $#commitlist <=  15 ? undef :
5992                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5993         }
5994
5995         if (@taglist) {
5996                 git_print_header_div('tags');
5997                 git_tags_body(\@taglist, 0, 15,
5998                               $#taglist <=  15 ? undef :
5999                               $cgi->a({-href => href(action=>"tags")}, "..."));
6000         }
6001
6002         if (@headlist) {
6003                 git_print_header_div('heads');
6004                 git_heads_body(\@headlist, $head, 0, 15,
6005                                $#headlist <= 15 ? undef :
6006                                $cgi->a({-href => href(action=>"heads")}, "..."));
6007         }
6008
6009         if (%remotedata) {
6010                 git_print_header_div('remotes');
6011                 git_remotes_body(\%remotedata, 15, $head);
6012         }
6013
6014         if (@forklist) {
6015                 git_print_header_div('forks');
6016                 git_project_list_body(\@forklist, 'age', 0, 15,
6017                                       $#forklist <= 15 ? undef :
6018                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6019                                       'no_header');
6020         }
6021
6022         git_footer_html();
6023 }
6024
6025 sub git_tag {
6026         my %tag = parse_tag($hash);
6027
6028         if (! %tag) {
6029                 die_error(404, "Unknown tag object");
6030         }
6031
6032         my $head = git_get_head_hash($project);
6033         git_header_html();
6034         git_print_page_nav('','', $head,undef,$head);
6035         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6036         print "<div class=\"title_text\">\n" .
6037               "<table class=\"object_header\">\n" .
6038               "<tr>\n" .
6039               "<td>object</td>\n" .
6040               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6041                                $tag{'object'}) . "</td>\n" .
6042               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6043                                               $tag{'type'}) . "</td>\n" .
6044               "</tr>\n";
6045         if (defined($tag{'author'})) {
6046                 git_print_authorship_rows(\%tag, 'author');
6047         }
6048         print "</table>\n\n" .
6049               "</div>\n";
6050         print "<div class=\"page_body\">";
6051         my $comment = $tag{'comment'};
6052         foreach my $line (@$comment) {
6053                 chomp $line;
6054                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6055         }
6056         print "</div>\n";
6057         git_footer_html();
6058 }
6059
6060 sub git_blame_common {
6061         my $format = shift || 'porcelain';
6062         if ($format eq 'porcelain' && $cgi->param('js')) {
6063                 $format = 'incremental';
6064                 $action = 'blame_incremental'; # for page title etc
6065         }
6066
6067         # permissions
6068         gitweb_check_feature('blame')
6069                 or die_error(403, "Blame view not allowed");
6070
6071         # error checking
6072         die_error(400, "No file name given") unless $file_name;
6073         $hash_base ||= git_get_head_hash($project);
6074         die_error(404, "Couldn't find base commit") unless $hash_base;
6075         my %co = parse_commit($hash_base)
6076                 or die_error(404, "Commit not found");
6077         my $ftype = "blob";
6078         if (!defined $hash) {
6079                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6080                         or die_error(404, "Error looking up file");
6081         } else {
6082                 $ftype = git_get_type($hash);
6083                 if ($ftype !~ "blob") {
6084                         die_error(400, "Object is not a blob");
6085                 }
6086         }
6087
6088         my $fd;
6089         if ($format eq 'incremental') {
6090                 # get file contents (as base)
6091                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6092                         or die_error(500, "Open git-cat-file failed");
6093         } elsif ($format eq 'data') {
6094                 # run git-blame --incremental
6095                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6096                         $hash_base, "--", $file_name
6097                         or die_error(500, "Open git-blame --incremental failed");
6098         } else {
6099                 # run git-blame --porcelain
6100                 open $fd, "-|", git_cmd(), "blame", '-p',
6101                         $hash_base, '--', $file_name
6102                         or die_error(500, "Open git-blame --porcelain failed");
6103         }
6104
6105         # incremental blame data returns early
6106         if ($format eq 'data') {
6107                 print $cgi->header(
6108                         -type=>"text/plain", -charset => "utf-8",
6109                         -status=> "200 OK");
6110                 local $| = 1; # output autoflush
6111                 while (my $line = <$fd>) {
6112                         print to_utf8($line);
6113                 }
6114                 close $fd
6115                         or print "ERROR $!\n";
6116
6117                 print 'END';
6118                 if (defined $t0 && gitweb_check_feature('timed')) {
6119                         print ' '.
6120                               tv_interval($t0, [ gettimeofday() ]).
6121                               ' '.$number_of_git_cmds;
6122                 }
6123                 print "\n";
6124
6125                 return;
6126         }
6127
6128         # page header
6129         git_header_html();
6130         my $formats_nav =
6131                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6132                         "blob") .
6133                 " | ";
6134         if ($format eq 'incremental') {
6135                 $formats_nav .=
6136                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6137                                 "blame") . " (non-incremental)";
6138         } else {
6139                 $formats_nav .=
6140                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6141                                 "blame") . " (incremental)";
6142         }
6143         $formats_nav .=
6144                 " | " .
6145                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6146                         "history") .
6147                 " | " .
6148                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6149                         "HEAD");
6150         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6151         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6152         git_print_page_path($file_name, $ftype, $hash_base);
6153
6154         # page body
6155         if ($format eq 'incremental') {
6156                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6157                       "This page requires JavaScript to run.\n Use ".
6158                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6159                               'this page').
6160                       " instead.\n".
6161                       "</b></center></div>\n</noscript>\n";
6162
6163                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6164         }
6165
6166         print qq!<div class="page_body">\n!;
6167         print qq!<div id="progress_info">... / ...</div>\n!
6168                 if ($format eq 'incremental');
6169         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6170               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6171               qq!<thead>\n!.
6172               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6173               qq!</thead>\n!.
6174               qq!<tbody>\n!;
6175
6176         my @rev_color = qw(light dark);
6177         my $num_colors = scalar(@rev_color);
6178         my $current_color = 0;
6179
6180         if ($format eq 'incremental') {
6181                 my $color_class = $rev_color[$current_color];
6182
6183                 #contents of a file
6184                 my $linenr = 0;
6185         LINE:
6186                 while (my $line = <$fd>) {
6187                         chomp $line;
6188                         $linenr++;
6189
6190                         print qq!<tr id="l$linenr" class="$color_class">!.
6191                               qq!<td class="sha1"><a href=""> </a></td>!.
6192                               qq!<td class="linenr">!.
6193                               qq!<a class="linenr" href="">$linenr</a></td>!;
6194                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6195                         print qq!</tr>\n!;
6196                 }
6197
6198         } else { # porcelain, i.e. ordinary blame
6199                 my %metainfo = (); # saves information about commits
6200
6201                 # blame data
6202         LINE:
6203                 while (my $line = <$fd>) {
6204                         chomp $line;
6205                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6206                         # no <lines in group> for subsequent lines in group of lines
6207                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6208                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6209                         if (!exists $metainfo{$full_rev}) {
6210                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6211                         }
6212                         my $meta = $metainfo{$full_rev};
6213                         my $data;
6214                         while ($data = <$fd>) {
6215                                 chomp $data;
6216                                 last if ($data =~ s/^\t//); # contents of line
6217                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6218                                         $meta->{$1} = $2 unless exists $meta->{$1};
6219                                 }
6220                                 if ($data =~ /^previous /) {
6221                                         $meta->{'nprevious'}++;
6222                                 }
6223                         }
6224                         my $short_rev = substr($full_rev, 0, 8);
6225                         my $author = $meta->{'author'};
6226                         my %date =
6227                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6228                         my $date = $date{'iso-tz'};
6229                         if ($group_size) {
6230                                 $current_color = ($current_color + 1) % $num_colors;
6231                         }
6232                         my $tr_class = $rev_color[$current_color];
6233                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6234                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6235                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6236                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6237                         if ($group_size) {
6238                                 print "<td class=\"sha1\"";
6239                                 print " title=\"". esc_html($author) . ", $date\"";
6240                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6241                                 print ">";
6242                                 print $cgi->a({-href => href(action=>"commit",
6243                                                              hash=>$full_rev,
6244                                                              file_name=>$file_name)},
6245                                               esc_html($short_rev));
6246                                 if ($group_size >= 2) {
6247                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6248                                         if (@author_initials) {
6249                                                 print "<br />" .
6250                                                       esc_html(join('', @author_initials));
6251                                                 #           or join('.', ...)
6252                                         }
6253                                 }
6254                                 print "</td>\n";
6255                         }
6256                         # 'previous' <sha1 of parent commit> <filename at commit>
6257                         if (exists $meta->{'previous'} &&
6258                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6259                                 $meta->{'parent'} = $1;
6260                                 $meta->{'file_parent'} = unquote($2);
6261                         }
6262                         my $linenr_commit =
6263                                 exists($meta->{'parent'}) ?
6264                                 $meta->{'parent'} : $full_rev;
6265                         my $linenr_filename =
6266                                 exists($meta->{'file_parent'}) ?
6267                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6268                         my $blamed = href(action => 'blame',
6269                                           file_name => $linenr_filename,
6270                                           hash_base => $linenr_commit);
6271                         print "<td class=\"linenr\">";
6272                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6273                                         -class => "linenr" },
6274                                       esc_html($lineno));
6275                         print "</td>";
6276                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6277                         print "</tr>\n";
6278                 } # end while
6279
6280         }
6281
6282         # footer
6283         print "</tbody>\n".
6284               "</table>\n"; # class="blame"
6285         print "</div>\n";   # class="blame_body"
6286         close $fd
6287                 or print "Reading blob failed\n";
6288
6289         git_footer_html();
6290 }
6291
6292 sub git_blame {
6293         git_blame_common();
6294 }
6295
6296 sub git_blame_incremental {
6297         git_blame_common('incremental');
6298 }
6299
6300 sub git_blame_data {
6301         git_blame_common('data');
6302 }
6303
6304 sub git_tags {
6305         my $head = git_get_head_hash($project);
6306         git_header_html();
6307         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6308         git_print_header_div('summary', $project);
6309
6310         my @tagslist = git_get_tags_list();
6311         if (@tagslist) {
6312                 git_tags_body(\@tagslist);
6313         }
6314         git_footer_html();
6315 }
6316
6317 sub git_heads {
6318         my $head = git_get_head_hash($project);
6319         git_header_html();
6320         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6321         git_print_header_div('summary', $project);
6322
6323         my @headslist = git_get_heads_list();
6324         if (@headslist) {
6325                 git_heads_body(\@headslist, $head);
6326         }
6327         git_footer_html();
6328 }
6329
6330 # used both for single remote view and for list of all the remotes
6331 sub git_remotes {
6332         gitweb_check_feature('remote_heads')
6333                 or die_error(403, "Remote heads view is disabled");
6334
6335         my $head = git_get_head_hash($project);
6336         my $remote = $input_params{'hash'};
6337
6338         my $remotedata = git_get_remotes_list($remote);
6339         die_error(500, "Unable to get remote information") unless defined $remotedata;
6340
6341         unless (%$remotedata) {
6342                 die_error(404, defined $remote ?
6343                         "Remote $remote not found" :
6344                         "No remotes found");
6345         }
6346
6347         git_header_html(undef, undef, -action_extra => $remote);
6348         git_print_page_nav('', '',  $head, undef, $head,
6349                 format_ref_views($remote ? '' : 'remotes'));
6350
6351         fill_remote_heads($remotedata);
6352         if (defined $remote) {
6353                 git_print_header_div('remotes', "$remote remote for $project");
6354                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6355         } else {
6356                 git_print_header_div('summary', "$project remotes");
6357                 git_remotes_body($remotedata, undef, $head);
6358         }
6359
6360         git_footer_html();
6361 }
6362
6363 sub git_blob_plain {
6364         my $type = shift;
6365         my $expires;
6366
6367         if (!defined $hash) {
6368                 if (defined $file_name) {
6369                         my $base = $hash_base || git_get_head_hash($project);
6370                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6371                                 or die_error(404, "Cannot find file");
6372                 } else {
6373                         die_error(400, "No file name defined");
6374                 }
6375         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6376                 # blobs defined by non-textual hash id's can be cached
6377                 $expires = "+1d";
6378         }
6379
6380         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6381                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6382
6383         # content-type (can include charset)
6384         $type = blob_contenttype($fd, $file_name, $type);
6385
6386         # "save as" filename, even when no $file_name is given
6387         my $save_as = "$hash";
6388         if (defined $file_name) {
6389                 $save_as = $file_name;
6390         } elsif ($type =~ m/^text\//) {
6391                 $save_as .= '.txt';
6392         }
6393
6394         # With XSS prevention on, blobs of all types except a few known safe
6395         # ones are served with "Content-Disposition: attachment" to make sure
6396         # they don't run in our security domain.  For certain image types,
6397         # blob view writes an <img> tag referring to blob_plain view, and we
6398         # want to be sure not to break that by serving the image as an
6399         # attachment (though Firefox 3 doesn't seem to care).
6400         my $sandbox = $prevent_xss &&
6401                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6402
6403         # serve text/* as text/plain
6404         if ($prevent_xss &&
6405             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6406              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6407                 my $rest = $1;
6408                 $rest = defined $rest ? $rest : '';
6409                 $type = "text/plain$rest";
6410         }
6411
6412         print $cgi->header(
6413                 -type => $type,
6414                 -expires => $expires,
6415                 -content_disposition =>
6416                         ($sandbox ? 'attachment' : 'inline')
6417                         . '; filename="' . $save_as . '"');
6418         local $/ = undef;
6419         binmode STDOUT, ':raw';
6420         print <$fd>;
6421         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6422         close $fd;
6423 }
6424
6425 sub git_blob {
6426         my $expires;
6427
6428         if (!defined $hash) {
6429                 if (defined $file_name) {
6430                         my $base = $hash_base || git_get_head_hash($project);
6431                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6432                                 or die_error(404, "Cannot find file");
6433                 } else {
6434                         die_error(400, "No file name defined");
6435                 }
6436         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6437                 # blobs defined by non-textual hash id's can be cached
6438                 $expires = "+1d";
6439         }
6440
6441         my $have_blame = gitweb_check_feature('blame');
6442         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6443                 or die_error(500, "Couldn't cat $file_name, $hash");
6444         my $mimetype = blob_mimetype($fd, $file_name);
6445         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6446         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6447                 close $fd;
6448                 return git_blob_plain($mimetype);
6449         }
6450         # we can have blame only for text/* mimetype
6451         $have_blame &&= ($mimetype =~ m!^text/!);
6452
6453         my $highlight = gitweb_check_feature('highlight');
6454         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6455         $fd = run_highlighter($fd, $highlight, $syntax)
6456                 if $syntax;
6457
6458         git_header_html(undef, $expires);
6459         my $formats_nav = '';
6460         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6461                 if (defined $file_name) {
6462                         if ($have_blame) {
6463                                 $formats_nav .=
6464                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6465                                                 "blame") .
6466                                         " | ";
6467                         }
6468                         $formats_nav .=
6469                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6470                                         "history") .
6471                                 " | " .
6472                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6473                                         "raw") .
6474                                 " | " .
6475                                 $cgi->a({-href => href(action=>"blob",
6476                                                        hash_base=>"HEAD", file_name=>$file_name)},
6477                                         "HEAD");
6478                 } else {
6479                         $formats_nav .=
6480                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6481                                         "raw");
6482                 }
6483                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6484                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6485         } else {
6486                 print "<div class=\"page_nav\">\n" .
6487                       "<br/><br/></div>\n" .
6488                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6489         }
6490         git_print_page_path($file_name, "blob", $hash_base);
6491         print "<div class=\"page_body\">\n";
6492         if ($mimetype =~ m!^image/!) {
6493                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6494                 if ($file_name) {
6495                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6496                 }
6497                 print qq! src="! .
6498                       href(action=>"blob_plain", hash=>$hash,
6499                            hash_base=>$hash_base, file_name=>$file_name) .
6500                       qq!" />\n!;
6501         } else {
6502                 my $nr;
6503                 while (my $line = <$fd>) {
6504                         chomp $line;
6505                         $nr++;
6506                         $line = untabify($line);
6507                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6508                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6509                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6510                 }
6511         }
6512         close $fd
6513                 or print "Reading blob failed.\n";
6514         print "</div>";
6515         git_footer_html();
6516 }
6517
6518 sub git_tree {
6519         if (!defined $hash_base) {
6520                 $hash_base = "HEAD";
6521         }
6522         if (!defined $hash) {
6523                 if (defined $file_name) {
6524                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6525                 } else {
6526                         $hash = $hash_base;
6527                 }
6528         }
6529         die_error(404, "No such tree") unless defined($hash);
6530
6531         my $show_sizes = gitweb_check_feature('show-sizes');
6532         my $have_blame = gitweb_check_feature('blame');
6533
6534         my @entries = ();
6535         {
6536                 local $/ = "\0";
6537                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6538                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6539                         or die_error(500, "Open git-ls-tree failed");
6540                 @entries = map { chomp; $_ } <$fd>;
6541                 close $fd
6542                         or die_error(404, "Reading tree failed");
6543         }
6544
6545         my $refs = git_get_references();
6546         my $ref = format_ref_marker($refs, $hash_base);
6547         git_header_html();
6548         my $basedir = '';
6549         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6550                 my @views_nav = ();
6551                 if (defined $file_name) {
6552                         push @views_nav,
6553                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6554                                         "history"),
6555                                 $cgi->a({-href => href(action=>"tree",
6556                                                        hash_base=>"HEAD", file_name=>$file_name)},
6557                                         "HEAD"),
6558                 }
6559                 my $snapshot_links = format_snapshot_links($hash);
6560                 if (defined $snapshot_links) {
6561                         # FIXME: Should be available when we have no hash base as well.
6562                         push @views_nav, $snapshot_links;
6563                 }
6564                 git_print_page_nav('tree','', $hash_base, undef, undef,
6565                                    join(' | ', @views_nav));
6566                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6567         } else {
6568                 undef $hash_base;
6569                 print "<div class=\"page_nav\">\n";
6570                 print "<br/><br/></div>\n";
6571                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6572         }
6573         if (defined $file_name) {
6574                 $basedir = $file_name;
6575                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6576                         $basedir .= '/';
6577                 }
6578                 git_print_page_path($file_name, 'tree', $hash_base);
6579         }
6580         print "<div class=\"page_body\">\n";
6581         print "<table class=\"tree\">\n";
6582         my $alternate = 1;
6583         # '..' (top directory) link if possible
6584         if (defined $hash_base &&
6585             defined $file_name && $file_name =~ m![^/]+$!) {
6586                 if ($alternate) {
6587                         print "<tr class=\"dark\">\n";
6588                 } else {
6589                         print "<tr class=\"light\">\n";
6590                 }
6591                 $alternate ^= 1;
6592
6593                 my $up = $file_name;
6594                 $up =~ s!/?[^/]+$!!;
6595                 undef $up unless $up;
6596                 # based on git_print_tree_entry
6597                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6598                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6599                 print '<td class="list">';
6600                 print $cgi->a({-href => href(action=>"tree",
6601                                              hash_base=>$hash_base,
6602                                              file_name=>$up)},
6603                               "..");
6604                 print "</td>\n";
6605                 print "<td class=\"link\"></td>\n";
6606
6607                 print "</tr>\n";
6608         }
6609         foreach my $line (@entries) {
6610                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6611
6612                 if ($alternate) {
6613                         print "<tr class=\"dark\">\n";
6614                 } else {
6615                         print "<tr class=\"light\">\n";
6616                 }
6617                 $alternate ^= 1;
6618
6619                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6620
6621                 print "</tr>\n";
6622         }
6623         print "</table>\n" .
6624               "</div>";
6625         git_footer_html();
6626 }
6627
6628 sub snapshot_name {
6629         my ($project, $hash) = @_;
6630
6631         # path/to/project.git  -> project
6632         # path/to/project/.git -> project
6633         my $name = to_utf8($project);
6634         $name =~ s,([^/])/*\.git$,$1,;
6635         $name = basename($name);
6636         # sanitize name
6637         $name =~ s/[[:cntrl:]]/?/g;
6638
6639         my $ver = $hash;
6640         if ($hash =~ /^[0-9a-fA-F]+$/) {
6641                 # shorten SHA-1 hash
6642                 my $full_hash = git_get_full_hash($project, $hash);
6643                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6644                         $ver = git_get_short_hash($project, $hash);
6645                 }
6646         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6647                 # tags don't need shortened SHA-1 hash
6648                 $ver = $1;
6649         } else {
6650                 # branches and other need shortened SHA-1 hash
6651                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6652                         $ver = $1;
6653                 }
6654                 $ver .= '-' . git_get_short_hash($project, $hash);
6655         }
6656         # in case of hierarchical branch names
6657         $ver =~ s!/!.!g;
6658
6659         # name = project-version_string
6660         $name = "$name-$ver";
6661
6662         return wantarray ? ($name, $name) : $name;
6663 }
6664
6665 sub git_snapshot {
6666         my $format = $input_params{'snapshot_format'};
6667         if (!@snapshot_fmts) {
6668                 die_error(403, "Snapshots not allowed");
6669         }
6670         # default to first supported snapshot format
6671         $format ||= $snapshot_fmts[0];
6672         if ($format !~ m/^[a-z0-9]+$/) {
6673                 die_error(400, "Invalid snapshot format parameter");
6674         } elsif (!exists($known_snapshot_formats{$format})) {
6675                 die_error(400, "Unknown snapshot format");
6676         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6677                 die_error(403, "Snapshot format not allowed");
6678         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6679                 die_error(403, "Unsupported snapshot format");
6680         }
6681
6682         my $type = git_get_type("$hash^{}");
6683         if (!$type) {
6684                 die_error(404, 'Object does not exist');
6685         }  elsif ($type eq 'blob') {
6686                 die_error(400, 'Object is not a tree-ish');
6687         }
6688
6689         my ($name, $prefix) = snapshot_name($project, $hash);
6690         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6691         my $cmd = quote_command(
6692                 git_cmd(), 'archive',
6693                 "--format=$known_snapshot_formats{$format}{'format'}",
6694                 "--prefix=$prefix/", $hash);
6695         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6696                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6697         }
6698
6699         $filename =~ s/(["\\])/\\$1/g;
6700         print $cgi->header(
6701                 -type => $known_snapshot_formats{$format}{'type'},
6702                 -content_disposition => 'inline; filename="' . $filename . '"',
6703                 -status => '200 OK');
6704
6705         open my $fd, "-|", $cmd
6706                 or die_error(500, "Execute git-archive failed");
6707         binmode STDOUT, ':raw';
6708         print <$fd>;
6709         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6710         close $fd;
6711 }
6712
6713 sub git_log_generic {
6714         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6715
6716         my $head = git_get_head_hash($project);
6717         if (!defined $base) {
6718                 $base = $head;
6719         }
6720         if (!defined $page) {
6721                 $page = 0;
6722         }
6723         my $refs = git_get_references();
6724
6725         my $commit_hash = $base;
6726         if (defined $parent) {
6727                 $commit_hash = "$parent..$base";
6728         }
6729         my @commitlist =
6730                 parse_commits($commit_hash, 101, (100 * $page),
6731                               defined $file_name ? ($file_name, "--full-history") : ());
6732
6733         my $ftype;
6734         if (!defined $file_hash && defined $file_name) {
6735                 # some commits could have deleted file in question,
6736                 # and not have it in tree, but one of them has to have it
6737                 for (my $i = 0; $i < @commitlist; $i++) {
6738                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6739                         last if defined $file_hash;
6740                 }
6741         }
6742         if (defined $file_hash) {
6743                 $ftype = git_get_type($file_hash);
6744         }
6745         if (defined $file_name && !defined $ftype) {
6746                 die_error(500, "Unknown type of object");
6747         }
6748         my %co;
6749         if (defined $file_name) {
6750                 %co = parse_commit($base)
6751                         or die_error(404, "Unknown commit object");
6752         }
6753
6754
6755         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6756         my $next_link = '';
6757         if ($#commitlist >= 100) {
6758                 $next_link =
6759                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6760                                  -accesskey => "n", -title => "Alt-n"}, "next");
6761         }
6762         my $patch_max = gitweb_get_feature('patches');
6763         if ($patch_max && !defined $file_name) {
6764                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6765                         $paging_nav .= " &sdot; " .
6766                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6767                                         "patches");
6768                 }
6769         }
6770
6771         git_header_html();
6772         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6773         if (defined $file_name) {
6774                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6775         } else {
6776                 git_print_header_div('summary', $project)
6777         }
6778         git_print_page_path($file_name, $ftype, $hash_base)
6779                 if (defined $file_name);
6780
6781         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6782                      $file_name, $file_hash, $ftype);
6783
6784         git_footer_html();
6785 }
6786
6787 sub git_log {
6788         git_log_generic('log', \&git_log_body,
6789                         $hash, $hash_parent);
6790 }
6791
6792 sub git_commit {
6793         $hash ||= $hash_base || "HEAD";
6794         my %co = parse_commit($hash)
6795             or die_error(404, "Unknown commit object");
6796
6797         my $parent  = $co{'parent'};
6798         my $parents = $co{'parents'}; # listref
6799
6800         # we need to prepare $formats_nav before any parameter munging
6801         my $formats_nav;
6802         if (!defined $parent) {
6803                 # --root commitdiff
6804                 $formats_nav .= '(initial)';
6805         } elsif (@$parents == 1) {
6806                 # single parent commit
6807                 $formats_nav .=
6808                         '(parent: ' .
6809                         $cgi->a({-href => href(action=>"commit",
6810                                                hash=>$parent)},
6811                                 esc_html(substr($parent, 0, 7))) .
6812                         ')';
6813         } else {
6814                 # merge commit
6815                 $formats_nav .=
6816                         '(merge: ' .
6817                         join(' ', map {
6818                                 $cgi->a({-href => href(action=>"commit",
6819                                                        hash=>$_)},
6820                                         esc_html(substr($_, 0, 7)));
6821                         } @$parents ) .
6822                         ')';
6823         }
6824         if (gitweb_check_feature('patches') && @$parents <= 1) {
6825                 $formats_nav .= " | " .
6826                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6827                                 "patch");
6828         }
6829
6830         if (!defined $parent) {
6831                 $parent = "--root";
6832         }
6833         my @difftree;
6834         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6835                 @diff_opts,
6836                 (@$parents <= 1 ? $parent : '-c'),
6837                 $hash, "--"
6838                 or die_error(500, "Open git-diff-tree failed");
6839         @difftree = map { chomp; $_ } <$fd>;
6840         close $fd or die_error(404, "Reading git-diff-tree failed");
6841
6842         # non-textual hash id's can be cached
6843         my $expires;
6844         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6845                 $expires = "+1d";
6846         }
6847         my $refs = git_get_references();
6848         my $ref = format_ref_marker($refs, $co{'id'});
6849
6850         git_header_html(undef, $expires);
6851         git_print_page_nav('commit', '',
6852                            $hash, $co{'tree'}, $hash,
6853                            $formats_nav);
6854
6855         if (defined $co{'parent'}) {
6856                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6857         } else {
6858                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6859         }
6860         print "<div class=\"title_text\">\n" .
6861               "<table class=\"object_header\">\n";
6862         git_print_authorship_rows(\%co);
6863         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6864         print "<tr>" .
6865               "<td>tree</td>" .
6866               "<td class=\"sha1\">" .
6867               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6868                        class => "list"}, $co{'tree'}) .
6869               "</td>" .
6870               "<td class=\"link\">" .
6871               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6872                       "tree");
6873         my $snapshot_links = format_snapshot_links($hash);
6874         if (defined $snapshot_links) {
6875                 print " | " . $snapshot_links;
6876         }
6877         print "</td>" .
6878               "</tr>\n";
6879
6880         foreach my $par (@$parents) {
6881                 print "<tr>" .
6882                       "<td>parent</td>" .
6883                       "<td class=\"sha1\">" .
6884                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6885                                class => "list"}, $par) .
6886                       "</td>" .
6887                       "<td class=\"link\">" .
6888                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6889                       " | " .
6890                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6891                       "</td>" .
6892                       "</tr>\n";
6893         }
6894         print "</table>".
6895               "</div>\n";
6896
6897         print "<div class=\"page_body\">\n";
6898         git_print_log($co{'comment'});
6899         print "</div>\n";
6900
6901         git_difftree_body(\@difftree, $hash, @$parents);
6902
6903         git_footer_html();
6904 }
6905
6906 sub git_object {
6907         # object is defined by:
6908         # - hash or hash_base alone
6909         # - hash_base and file_name
6910         my $type;
6911
6912         # - hash or hash_base alone
6913         if ($hash || ($hash_base && !defined $file_name)) {
6914                 my $object_id = $hash || $hash_base;
6915
6916                 open my $fd, "-|", quote_command(
6917                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6918                         or die_error(404, "Object does not exist");
6919                 $type = <$fd>;
6920                 chomp $type;
6921                 close $fd
6922                         or die_error(404, "Object does not exist");
6923
6924         # - hash_base and file_name
6925         } elsif ($hash_base && defined $file_name) {
6926                 $file_name =~ s,/+$,,;
6927
6928                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6929                         or die_error(404, "Base object does not exist");
6930
6931                 # here errors should not hapen
6932                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6933                         or die_error(500, "Open git-ls-tree failed");
6934                 my $line = <$fd>;
6935                 close $fd;
6936
6937                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6938                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6939                         die_error(404, "File or directory for given base does not exist");
6940                 }
6941                 $type = $2;
6942                 $hash = $3;
6943         } else {
6944                 die_error(400, "Not enough information to find object");
6945         }
6946
6947         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6948                                           hash=>$hash, hash_base=>$hash_base,
6949                                           file_name=>$file_name),
6950                              -status => '302 Found');
6951 }
6952
6953 sub git_blobdiff {
6954         my $format = shift || 'html';
6955
6956         my $fd;
6957         my @difftree;
6958         my %diffinfo;
6959         my $expires;
6960
6961         # preparing $fd and %diffinfo for git_patchset_body
6962         # new style URI
6963         if (defined $hash_base && defined $hash_parent_base) {
6964                 if (defined $file_name) {
6965                         # read raw output
6966                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6967                                 $hash_parent_base, $hash_base,
6968                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6969                                 or die_error(500, "Open git-diff-tree failed");
6970                         @difftree = map { chomp; $_ } <$fd>;
6971                         close $fd
6972                                 or die_error(404, "Reading git-diff-tree failed");
6973                         @difftree
6974                                 or die_error(404, "Blob diff not found");
6975
6976                 } elsif (defined $hash &&
6977                          $hash =~ /[0-9a-fA-F]{40}/) {
6978                         # try to find filename from $hash
6979
6980                         # read filtered raw output
6981                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6982                                 $hash_parent_base, $hash_base, "--"
6983                                 or die_error(500, "Open git-diff-tree failed");
6984                         @difftree =
6985                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6986                                 # $hash == to_id
6987                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6988                                 map { chomp; $_ } <$fd>;
6989                         close $fd
6990                                 or die_error(404, "Reading git-diff-tree failed");
6991                         @difftree
6992                                 or die_error(404, "Blob diff not found");
6993
6994                 } else {
6995                         die_error(400, "Missing one of the blob diff parameters");
6996                 }
6997
6998                 if (@difftree > 1) {
6999                         die_error(400, "Ambiguous blob diff specification");
7000                 }
7001
7002                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7003                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7004                 $file_name   ||= $diffinfo{'to_file'};
7005
7006                 $hash_parent ||= $diffinfo{'from_id'};
7007                 $hash        ||= $diffinfo{'to_id'};
7008
7009                 # non-textual hash id's can be cached
7010                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7011                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7012                         $expires = '+1d';
7013                 }
7014
7015                 # open patch output
7016                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7017                         '-p', ($format eq 'html' ? "--full-index" : ()),
7018                         $hash_parent_base, $hash_base,
7019                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7020                         or die_error(500, "Open git-diff-tree failed");
7021         }
7022
7023         # old/legacy style URI -- not generated anymore since 1.4.3.
7024         if (!%diffinfo) {
7025                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7026         }
7027
7028         # header
7029         if ($format eq 'html') {
7030                 my $formats_nav =
7031                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7032                                 "raw");
7033                 git_header_html(undef, $expires);
7034                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7035                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7036                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7037                 } else {
7038                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7039                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7040                 }
7041                 if (defined $file_name) {
7042                         git_print_page_path($file_name, "blob", $hash_base);
7043                 } else {
7044                         print "<div class=\"page_path\"></div>\n";
7045                 }
7046
7047         } elsif ($format eq 'plain') {
7048                 print $cgi->header(
7049                         -type => 'text/plain',
7050                         -charset => 'utf-8',
7051                         -expires => $expires,
7052                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7053
7054                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7055
7056         } else {
7057                 die_error(400, "Unknown blobdiff format");
7058         }
7059
7060         # patch
7061         if ($format eq 'html') {
7062                 print "<div class=\"page_body\">\n";
7063
7064                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
7065                 close $fd;
7066
7067                 print "</div>\n"; # class="page_body"
7068                 git_footer_html();
7069
7070         } else {
7071                 while (my $line = <$fd>) {
7072                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7073                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7074
7075                         print $line;
7076
7077                         last if $line =~ m!^\+\+\+!;
7078                 }
7079                 local $/ = undef;
7080                 print <$fd>;
7081                 close $fd;
7082         }
7083 }
7084
7085 sub git_blobdiff_plain {
7086         git_blobdiff('plain');
7087 }
7088
7089 sub git_commitdiff {
7090         my %params = @_;
7091         my $format = $params{-format} || 'html';
7092
7093         my ($patch_max) = gitweb_get_feature('patches');
7094         if ($format eq 'patch') {
7095                 die_error(403, "Patch view not allowed") unless $patch_max;
7096         }
7097
7098         $hash ||= $hash_base || "HEAD";
7099         my %co = parse_commit($hash)
7100             or die_error(404, "Unknown commit object");
7101
7102         # choose format for commitdiff for merge
7103         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7104                 $hash_parent = '--cc';
7105         }
7106         # we need to prepare $formats_nav before almost any parameter munging
7107         my $formats_nav;
7108         if ($format eq 'html') {
7109                 $formats_nav =
7110                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7111                                 "raw");
7112                 if ($patch_max && @{$co{'parents'}} <= 1) {
7113                         $formats_nav .= " | " .
7114                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7115                                         "patch");
7116                 }
7117
7118                 if (defined $hash_parent &&
7119                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7120                         # commitdiff with two commits given
7121                         my $hash_parent_short = $hash_parent;
7122                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7123                                 $hash_parent_short = substr($hash_parent, 0, 7);
7124                         }
7125                         $formats_nav .=
7126                                 ' (from';
7127                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7128                                 if ($co{'parents'}[$i] eq $hash_parent) {
7129                                         $formats_nav .= ' parent ' . ($i+1);
7130                                         last;
7131                                 }
7132                         }
7133                         $formats_nav .= ': ' .
7134                                 $cgi->a({-href => href(action=>"commitdiff",
7135                                                        hash=>$hash_parent)},
7136                                         esc_html($hash_parent_short)) .
7137                                 ')';
7138                 } elsif (!$co{'parent'}) {
7139                         # --root commitdiff
7140                         $formats_nav .= ' (initial)';
7141                 } elsif (scalar @{$co{'parents'}} == 1) {
7142                         # single parent commit
7143                         $formats_nav .=
7144                                 ' (parent: ' .
7145                                 $cgi->a({-href => href(action=>"commitdiff",
7146                                                        hash=>$co{'parent'})},
7147                                         esc_html(substr($co{'parent'}, 0, 7))) .
7148                                 ')';
7149                 } else {
7150                         # merge commit
7151                         if ($hash_parent eq '--cc') {
7152                                 $formats_nav .= ' | ' .
7153                                         $cgi->a({-href => href(action=>"commitdiff",
7154                                                                hash=>$hash, hash_parent=>'-c')},
7155                                                 'combined');
7156                         } else { # $hash_parent eq '-c'
7157                                 $formats_nav .= ' | ' .
7158                                         $cgi->a({-href => href(action=>"commitdiff",
7159                                                                hash=>$hash, hash_parent=>'--cc')},
7160                                                 'compact');
7161                         }
7162                         $formats_nav .=
7163                                 ' (merge: ' .
7164                                 join(' ', map {
7165                                         $cgi->a({-href => href(action=>"commitdiff",
7166                                                                hash=>$_)},
7167                                                 esc_html(substr($_, 0, 7)));
7168                                 } @{$co{'parents'}} ) .
7169                                 ')';
7170                 }
7171         }
7172
7173         my $hash_parent_param = $hash_parent;
7174         if (!defined $hash_parent_param) {
7175                 # --cc for multiple parents, --root for parentless
7176                 $hash_parent_param =
7177                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7178         }
7179
7180         # read commitdiff
7181         my $fd;
7182         my @difftree;
7183         if ($format eq 'html') {
7184                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7185                         "--no-commit-id", "--patch-with-raw", "--full-index",
7186                         $hash_parent_param, $hash, "--"
7187                         or die_error(500, "Open git-diff-tree failed");
7188
7189                 while (my $line = <$fd>) {
7190                         chomp $line;
7191                         # empty line ends raw part of diff-tree output
7192                         last unless $line;
7193                         push @difftree, scalar parse_difftree_raw_line($line);
7194                 }
7195
7196         } elsif ($format eq 'plain') {
7197                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7198                         '-p', $hash_parent_param, $hash, "--"
7199                         or die_error(500, "Open git-diff-tree failed");
7200         } elsif ($format eq 'patch') {
7201                 # For commit ranges, we limit the output to the number of
7202                 # patches specified in the 'patches' feature.
7203                 # For single commits, we limit the output to a single patch,
7204                 # diverging from the git-format-patch default.
7205                 my @commit_spec = ();
7206                 if ($hash_parent) {
7207                         if ($patch_max > 0) {
7208                                 push @commit_spec, "-$patch_max";
7209                         }
7210                         push @commit_spec, '-n', "$hash_parent..$hash";
7211                 } else {
7212                         if ($params{-single}) {
7213                                 push @commit_spec, '-1';
7214                         } else {
7215                                 if ($patch_max > 0) {
7216                                         push @commit_spec, "-$patch_max";
7217                                 }
7218                                 push @commit_spec, "-n";
7219                         }
7220                         push @commit_spec, '--root', $hash;
7221                 }
7222                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7223                         '--encoding=utf8', '--stdout', @commit_spec
7224                         or die_error(500, "Open git-format-patch failed");
7225         } else {
7226                 die_error(400, "Unknown commitdiff format");
7227         }
7228
7229         # non-textual hash id's can be cached
7230         my $expires;
7231         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7232                 $expires = "+1d";
7233         }
7234
7235         # write commit message
7236         if ($format eq 'html') {
7237                 my $refs = git_get_references();
7238                 my $ref = format_ref_marker($refs, $co{'id'});
7239
7240                 git_header_html(undef, $expires);
7241                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7242                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7243                 print "<div class=\"title_text\">\n" .
7244                       "<table class=\"object_header\">\n";
7245                 git_print_authorship_rows(\%co);
7246                 print "</table>".
7247                       "</div>\n";
7248                 print "<div class=\"page_body\">\n";
7249                 if (@{$co{'comment'}} > 1) {
7250                         print "<div class=\"log\">\n";
7251                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7252                         print "</div>\n"; # class="log"
7253                 }
7254
7255         } elsif ($format eq 'plain') {
7256                 my $refs = git_get_references("tags");
7257                 my $tagname = git_get_rev_name_tags($hash);
7258                 my $filename = basename($project) . "-$hash.patch";
7259
7260                 print $cgi->header(
7261                         -type => 'text/plain',
7262                         -charset => 'utf-8',
7263                         -expires => $expires,
7264                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7265                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7266                 print "From: " . to_utf8($co{'author'}) . "\n";
7267                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7268                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7269
7270                 print "X-Git-Tag: $tagname\n" if $tagname;
7271                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7272
7273                 foreach my $line (@{$co{'comment'}}) {
7274                         print to_utf8($line) . "\n";
7275                 }
7276                 print "---\n\n";
7277         } elsif ($format eq 'patch') {
7278                 my $filename = basename($project) . "-$hash.patch";
7279
7280                 print $cgi->header(
7281                         -type => 'text/plain',
7282                         -charset => 'utf-8',
7283                         -expires => $expires,
7284                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7285         }
7286
7287         # write patch
7288         if ($format eq 'html') {
7289                 my $use_parents = !defined $hash_parent ||
7290                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7291                 git_difftree_body(\@difftree, $hash,
7292                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7293                 print "<br/>\n";
7294
7295                 git_patchset_body($fd, \@difftree, $hash,
7296                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7297                 close $fd;
7298                 print "</div>\n"; # class="page_body"
7299                 git_footer_html();
7300
7301         } elsif ($format eq 'plain') {
7302                 local $/ = undef;
7303                 print <$fd>;
7304                 close $fd
7305                         or print "Reading git-diff-tree failed\n";
7306         } elsif ($format eq 'patch') {
7307                 local $/ = undef;
7308                 print <$fd>;
7309                 close $fd
7310                         or print "Reading git-format-patch failed\n";
7311         }
7312 }
7313
7314 sub git_commitdiff_plain {
7315         git_commitdiff(-format => 'plain');
7316 }
7317
7318 # format-patch-style patches
7319 sub git_patch {
7320         git_commitdiff(-format => 'patch', -single => 1);
7321 }
7322
7323 sub git_patches {
7324         git_commitdiff(-format => 'patch');
7325 }
7326
7327 sub git_history {
7328         git_log_generic('history', \&git_history_body,
7329                         $hash_base, $hash_parent_base,
7330                         $file_name, $hash);
7331 }
7332
7333 sub git_search {
7334         $searchtype ||= 'commit';
7335
7336         # check if appropriate features are enabled
7337         gitweb_check_feature('search')
7338                 or die_error(403, "Search is disabled");
7339         if ($searchtype eq 'pickaxe') {
7340                 # pickaxe may take all resources of your box and run for several minutes
7341                 # with every query - so decide by yourself how public you make this feature
7342                 gitweb_check_feature('pickaxe')
7343                         or die_error(403, "Pickaxe search is disabled");
7344         }
7345         if ($searchtype eq 'grep') {
7346                 # grep search might be potentially CPU-intensive, too
7347                 gitweb_check_feature('grep')
7348                         or die_error(403, "Grep search is disabled");
7349         }
7350
7351         if (!defined $searchtext) {
7352                 die_error(400, "Text field is empty");
7353         }
7354         if (!defined $hash) {
7355                 $hash = git_get_head_hash($project);
7356         }
7357         my %co = parse_commit($hash);
7358         if (!%co) {
7359                 die_error(404, "Unknown commit object");
7360         }
7361         if (!defined $page) {
7362                 $page = 0;
7363         }
7364
7365         if ($searchtype eq 'commit' ||
7366             $searchtype eq 'author' ||
7367             $searchtype eq 'committer') {
7368                 git_search_message(%co);
7369         } elsif ($searchtype eq 'pickaxe') {
7370                 git_search_changes(%co);
7371         } elsif ($searchtype eq 'grep') {
7372                 git_search_files(%co);
7373         } else {
7374                 die_error(400, "Unknown search type");
7375         }
7376 }
7377
7378 sub git_search_help {
7379         git_header_html();
7380         git_print_page_nav('','', $hash,$hash,$hash);
7381         print <<EOT;
7382 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7383 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7384 the pattern entered is recognized as the POSIX extended
7385 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7386 insensitive).</p>
7387 <dl>
7388 <dt><b>commit</b></dt>
7389 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7390 EOT
7391         my $have_grep = gitweb_check_feature('grep');
7392         if ($have_grep) {
7393                 print <<EOT;
7394 <dt><b>grep</b></dt>
7395 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7396     a different one) are searched for the given pattern. On large trees, this search can take
7397 a while and put some strain on the server, so please use it with some consideration. Note that
7398 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7399 case-sensitive.</dd>
7400 EOT
7401         }
7402         print <<EOT;
7403 <dt><b>author</b></dt>
7404 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7405 <dt><b>committer</b></dt>
7406 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7407 EOT
7408         my $have_pickaxe = gitweb_check_feature('pickaxe');
7409         if ($have_pickaxe) {
7410                 print <<EOT;
7411 <dt><b>pickaxe</b></dt>
7412 <dd>All commits that caused the string to appear or disappear from any file (changes that
7413 added, removed or "modified" the string) will be listed. This search can take a while and
7414 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7415 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7416 EOT
7417         }
7418         print "</dl>\n";
7419         git_footer_html();
7420 }
7421
7422 sub git_shortlog {
7423         git_log_generic('shortlog', \&git_shortlog_body,
7424                         $hash, $hash_parent);
7425 }
7426
7427 ## ......................................................................
7428 ## feeds (RSS, Atom; OPML)
7429
7430 sub git_feed {
7431         my $format = shift || 'atom';
7432         my $have_blame = gitweb_check_feature('blame');
7433
7434         # Atom: http://www.atomenabled.org/developers/syndication/
7435         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7436         if ($format ne 'rss' && $format ne 'atom') {
7437                 die_error(400, "Unknown web feed format");
7438         }
7439
7440         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7441         my $head = $hash || 'HEAD';
7442         my @commitlist = parse_commits($head, 150, 0, $file_name);
7443
7444         my %latest_commit;
7445         my %latest_date;
7446         my $content_type = "application/$format+xml";
7447         if (defined $cgi->http('HTTP_ACCEPT') &&
7448                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7449                 # browser (feed reader) prefers text/xml
7450                 $content_type = 'text/xml';
7451         }
7452         if (defined($commitlist[0])) {
7453                 %latest_commit = %{$commitlist[0]};
7454                 my $latest_epoch = $latest_commit{'committer_epoch'};
7455                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7456                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7457                 if (defined $if_modified) {
7458                         my $since;
7459                         if (eval { require HTTP::Date; 1; }) {
7460                                 $since = HTTP::Date::str2time($if_modified);
7461                         } elsif (eval { require Time::ParseDate; 1; }) {
7462                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7463                         }
7464                         if (defined $since && $latest_epoch <= $since) {
7465                                 print $cgi->header(
7466                                         -type => $content_type,
7467                                         -charset => 'utf-8',
7468                                         -last_modified => $latest_date{'rfc2822'},
7469                                         -status => '304 Not Modified');
7470                                 return;
7471                         }
7472                 }
7473                 print $cgi->header(
7474                         -type => $content_type,
7475                         -charset => 'utf-8',
7476                         -last_modified => $latest_date{'rfc2822'});
7477         } else {
7478                 print $cgi->header(
7479                         -type => $content_type,
7480                         -charset => 'utf-8');
7481         }
7482
7483         # Optimization: skip generating the body if client asks only
7484         # for Last-Modified date.
7485         return if ($cgi->request_method() eq 'HEAD');
7486
7487         # header variables
7488         my $title = "$site_name - $project/$action";
7489         my $feed_type = 'log';
7490         if (defined $hash) {
7491                 $title .= " - '$hash'";
7492                 $feed_type = 'branch log';
7493                 if (defined $file_name) {
7494                         $title .= " :: $file_name";
7495                         $feed_type = 'history';
7496                 }
7497         } elsif (defined $file_name) {
7498                 $title .= " - $file_name";
7499                 $feed_type = 'history';
7500         }
7501         $title .= " $feed_type";
7502         my $descr = git_get_project_description($project);
7503         if (defined $descr) {
7504                 $descr = esc_html($descr);
7505         } else {
7506                 $descr = "$project " .
7507                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7508                          " feed";
7509         }
7510         my $owner = git_get_project_owner($project);
7511         $owner = esc_html($owner);
7512
7513         #header
7514         my $alt_url;
7515         if (defined $file_name) {
7516                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7517         } elsif (defined $hash) {
7518                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7519         } else {
7520                 $alt_url = href(-full=>1, action=>"summary");
7521         }
7522         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7523         if ($format eq 'rss') {
7524                 print <<XML;
7525 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7526 <channel>
7527 XML
7528                 print "<title>$title</title>\n" .
7529                       "<link>$alt_url</link>\n" .
7530                       "<description>$descr</description>\n" .
7531                       "<language>en</language>\n" .
7532                       # project owner is responsible for 'editorial' content
7533                       "<managingEditor>$owner</managingEditor>\n";
7534                 if (defined $logo || defined $favicon) {
7535                         # prefer the logo to the favicon, since RSS
7536                         # doesn't allow both
7537                         my $img = esc_url($logo || $favicon);
7538                         print "<image>\n" .
7539                               "<url>$img</url>\n" .
7540                               "<title>$title</title>\n" .
7541                               "<link>$alt_url</link>\n" .
7542                               "</image>\n";
7543                 }
7544                 if (%latest_date) {
7545                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7546                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7547                 }
7548                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7549         } elsif ($format eq 'atom') {
7550                 print <<XML;
7551 <feed xmlns="http://www.w3.org/2005/Atom">
7552 XML
7553                 print "<title>$title</title>\n" .
7554                       "<subtitle>$descr</subtitle>\n" .
7555                       '<link rel="alternate" type="text/html" href="' .
7556                       $alt_url . '" />' . "\n" .
7557                       '<link rel="self" type="' . $content_type . '" href="' .
7558                       $cgi->self_url() . '" />' . "\n" .
7559                       "<id>" . href(-full=>1) . "</id>\n" .
7560                       # use project owner for feed author
7561                       "<author><name>$owner</name></author>\n";
7562                 if (defined $favicon) {
7563                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7564                 }
7565                 if (defined $logo) {
7566                         # not twice as wide as tall: 72 x 27 pixels
7567                         print "<logo>" . esc_url($logo) . "</logo>\n";
7568                 }
7569                 if (! %latest_date) {
7570                         # dummy date to keep the feed valid until commits trickle in:
7571                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7572                 } else {
7573                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7574                 }
7575                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7576         }
7577
7578         # contents
7579         for (my $i = 0; $i <= $#commitlist; $i++) {
7580                 my %co = %{$commitlist[$i]};
7581                 my $commit = $co{'id'};
7582                 # we read 150, we always show 30 and the ones more recent than 48 hours
7583                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7584                         last;
7585                 }
7586                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7587
7588                 # get list of changed files
7589                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7590                         $co{'parent'} || "--root",
7591                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7592                         or next;
7593                 my @difftree = map { chomp; $_ } <$fd>;
7594                 close $fd
7595                         or next;
7596
7597                 # print element (entry, item)
7598                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7599                 if ($format eq 'rss') {
7600                         print "<item>\n" .
7601                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7602                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7603                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7604                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7605                               "<link>$co_url</link>\n" .
7606                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7607                               "<content:encoded>" .
7608                               "<![CDATA[\n";
7609                 } elsif ($format eq 'atom') {
7610                         print "<entry>\n" .
7611                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7612                               "<updated>$cd{'iso-8601'}</updated>\n" .
7613                               "<author>\n" .
7614                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7615                         if ($co{'author_email'}) {
7616                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7617                         }
7618                         print "</author>\n" .
7619                               # use committer for contributor
7620                               "<contributor>\n" .
7621                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7622                         if ($co{'committer_email'}) {
7623                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7624                         }
7625                         print "</contributor>\n" .
7626                               "<published>$cd{'iso-8601'}</published>\n" .
7627                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7628                               "<id>$co_url</id>\n" .
7629                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7630                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7631                 }
7632                 my $comment = $co{'comment'};
7633                 print "<pre>\n";
7634                 foreach my $line (@$comment) {
7635                         $line = esc_html($line);
7636                         print "$line\n";
7637                 }
7638                 print "</pre><ul>\n";
7639                 foreach my $difftree_line (@difftree) {
7640                         my %difftree = parse_difftree_raw_line($difftree_line);
7641                         next if !$difftree{'from_id'};
7642
7643                         my $file = $difftree{'file'} || $difftree{'to_file'};
7644
7645                         print "<li>" .
7646                               "[" .
7647                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7648                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7649                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7650                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7651                                       -title => "diff"}, 'D');
7652                         if ($have_blame) {
7653                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7654                                                              file_name=>$file, hash_base=>$commit),
7655                                               -title => "blame"}, 'B');
7656                         }
7657                         # if this is not a feed of a file history
7658                         if (!defined $file_name || $file_name ne $file) {
7659                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7660                                                              file_name=>$file, hash=>$commit),
7661                                               -title => "history"}, 'H');
7662                         }
7663                         $file = esc_path($file);
7664                         print "] ".
7665                               "$file</li>\n";
7666                 }
7667                 if ($format eq 'rss') {
7668                         print "</ul>]]>\n" .
7669                               "</content:encoded>\n" .
7670                               "</item>\n";
7671                 } elsif ($format eq 'atom') {
7672                         print "</ul>\n</div>\n" .
7673                               "</content>\n" .
7674                               "</entry>\n";
7675                 }
7676         }
7677
7678         # end of feed
7679         if ($format eq 'rss') {
7680                 print "</channel>\n</rss>\n";
7681         } elsif ($format eq 'atom') {
7682                 print "</feed>\n";
7683         }
7684 }
7685
7686 sub git_rss {
7687         git_feed('rss');
7688 }
7689
7690 sub git_atom {
7691         git_feed('atom');
7692 }
7693
7694 sub git_opml {
7695         my @list = git_get_projects_list();
7696         if (!@list) {
7697                 die_error(404, "No projects found");
7698         }
7699
7700         print $cgi->header(
7701                 -type => 'text/xml',
7702                 -charset => 'utf-8',
7703                 -content_disposition => 'inline; filename="opml.xml"');
7704
7705         my $title = esc_html($site_name);
7706         print <<XML;
7707 <?xml version="1.0" encoding="utf-8"?>
7708 <opml version="1.0">
7709 <head>
7710   <title>$title OPML Export</title>
7711 </head>
7712 <body>
7713 <outline text="git RSS feeds">
7714 XML
7715
7716         foreach my $pr (@list) {
7717                 my %proj = %$pr;
7718                 my $head = git_get_head_hash($proj{'path'});
7719                 if (!defined $head) {
7720                         next;
7721                 }
7722                 $git_dir = "$projectroot/$proj{'path'}";
7723                 my %co = parse_commit($head);
7724                 if (!%co) {
7725                         next;
7726                 }
7727
7728                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7729                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7730                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7731                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7732         }
7733         print <<XML;
7734 </outline>
7735 </body>
7736 </opml>
7737 XML
7738 }