![[tokkee]](http://tokkee.org/images/avatar.png){kind=avatar}
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use 5.008;
5 use warnings;
6 use strict;
7 use vars qw/ $AUTHOR $VERSION
8 $sha1 $sha1_short $_revision $_repository
9 $_q $_authors $_authors_prog %users/;
10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
11 $VERSION = '@@GIT_VERSION@@';
13 # From which subdir have we been invoked?
14 my $cmd_dir_prefix = eval {
15 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
16 } || '';
18 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
19 $ENV{GIT_DIR} ||= '.git';
20 $Git::SVN::default_repo_id = 'svn';
21 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
22 $Git::SVN::Ra::_log_window_size = 100;
23 $Git::SVN::_minimize_url = 'unset';
25 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
26 $ENV{SVN_SSH} = $ENV{GIT_SSH};
27 }
29 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
30 $ENV{SVN_SSH} =~ s/\\/\\\\/g;
31 $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
32 }
34 $Git::SVN::Log::TZ = $ENV{TZ};
35 $ENV{TZ} = 'UTC';
36 $| = 1; # unbuffer STDOUT
38 sub fatal (@) { print STDERR "@_\n"; exit 1 }
39 sub _req_svn {
40 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
41 require SVN::Ra;
42 require SVN::Delta;
43 if ($SVN::Core::VERSION lt '1.1.0') {
44 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
45 }
46 }
47 my $can_compress = eval { require Compress::Zlib; 1};
48 push @Git::SVN::Ra::ISA, 'SVN::Ra';
49 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
50 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
51 use Carp qw/croak/;
52 use Digest::MD5;
53 use IO::File qw//;
54 use File::Basename qw/dirname basename/;
55 use File::Path qw/mkpath/;
56 use File::Spec;
57 use File::Find;
58 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
59 use IPC::Open3;
60 use Git;
61 use Memoize; # core since 5.8.0, Jul 2002
63 BEGIN {
64 # import functions from Git into our packages, en masse
65 no strict 'refs';
66 foreach (qw/command command_oneline command_noisy command_output_pipe
67 command_input_pipe command_close_pipe
68 command_bidi_pipe command_close_bidi_pipe/) {
69 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
70 Git::SVN::Migration Git::SVN::Log Git::SVN),
71 __PACKAGE__) {
72 *{"${package}::$_"} = \&{"Git::$_"};
73 }
74 }
75 Memoize::memoize 'Git::config';
76 Memoize::memoize 'Git::config_bool';
77 }
79 my ($SVN);
81 $sha1 = qr/[a-f\d]{40}/;
82 $sha1_short = qr/[a-f\d]{4,40}/;
83 my ($_stdin, $_help, $_edit,
84 $_message, $_file, $_branch_dest,
85 $_template, $_shared,
86 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
87 $_merge, $_strategy, $_dry_run, $_local,
88 $_prefix, $_no_checkout, $_url, $_verbose,
89 $_git_format, $_commit_url, $_tag, $_merge_info, $_interactive);
90 $Git::SVN::_follow_parent = 1;
91 $SVN::Git::Fetcher::_placeholder_filename = ".gitignore";
92 $_q ||= 0;
93 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
94 'config-dir=s' => \$Git::SVN::Ra::config_dir,
95 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
96 'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex,
97 'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
98 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
99 'authors-file|A=s' => \$_authors,
100 'authors-prog=s' => \$_authors_prog,
101 'repack:i' => \$Git::SVN::_repack,
102 'noMetadata' => \$Git::SVN::_no_metadata,
103 'useSvmProps' => \$Git::SVN::_use_svm_props,
104 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
105 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
106 'no-checkout' => \$_no_checkout,
107 'quiet|q+' => \$_q,
108 'repack-flags|repack-args|repack-opts=s' =>
109 \$Git::SVN::_repack_flags,
110 'use-log-author' => \$Git::SVN::_use_log_author,
111 'add-author-from' => \$Git::SVN::_add_author_from,
112 'localtime' => \$Git::SVN::_localtime,
113 %remote_opts );
115 my ($_trunk, @_tags, @_branches, $_stdlayout);
116 my %icv;
117 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
118 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
119 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
120 'stdlayout|s' => \$_stdlayout,
121 'minimize-url|m!' => \$Git::SVN::_minimize_url,
122 'no-metadata' => sub { $icv{noMetadata} = 1 },
123 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
124 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
125 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
126 'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
127 %remote_opts );
128 my %cmt_opts = ( 'edit|e' => \$_edit,
129 'rmdir' => \$SVN::Git::Editor::_rmdir,
130 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
131 'l=i' => \$SVN::Git::Editor::_rename_limit,
132 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
133 );
135 my %cmd = (
136 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
137 { 'revision|r=s' => \$_revision,
138 'fetch-all|all' => \$_fetch_all,
139 'parent|p' => \$_fetch_parent,
140 %fc_opts } ],
141 clone => [ \&cmd_clone, "Initialize and fetch revisions",
142 { 'revision|r=s' => \$_revision,
143 'preserve-empty-dirs' =>
144 \$SVN::Git::Fetcher::_preserve_empty_dirs,
145 'placeholder-filename=s' =>
146 \$SVN::Git::Fetcher::_placeholder_filename,
147 %fc_opts, %init_opts } ],
148 init => [ \&cmd_init, "Initialize a repo for tracking" .
149 " (requires URL argument)",
150 \%init_opts ],
151 'multi-init' => [ \&cmd_multi_init,
152 "Deprecated alias for ".
153 "'$0 init -T<trunk> -b<branches> -t<tags>'",
154 \%init_opts ],
155 dcommit => [ \&cmd_dcommit,
156 'Commit several diffs to merge with upstream',
157 { 'merge|m|M' => \$_merge,
158 'strategy|s=s' => \$_strategy,
159 'verbose|v' => \$_verbose,
160 'dry-run|n' => \$_dry_run,
161 'fetch-all|all' => \$_fetch_all,
162 'commit-url=s' => \$_commit_url,
163 'revision|r=i' => \$_revision,
164 'no-rebase' => \$_no_rebase,
165 'mergeinfo=s' => \$_merge_info,
166 'interactive|i' => \$_interactive,
167 %cmt_opts, %fc_opts } ],
168 branch => [ \&cmd_branch,
169 'Create a branch in the SVN repository',
170 { 'message|m=s' => \$_message,
171 'destination|d=s' => \$_branch_dest,
172 'dry-run|n' => \$_dry_run,
173 'tag|t' => \$_tag,
174 'username=s' => \$Git::SVN::Prompt::_username,
175 'commit-url=s' => \$_commit_url } ],
176 tag => [ sub { $_tag = 1; cmd_branch(@_) },
177 'Create a tag in the SVN repository',
178 { 'message|m=s' => \$_message,
179 'destination|d=s' => \$_branch_dest,
180 'dry-run|n' => \$_dry_run,
181 'username=s' => \$Git::SVN::Prompt::_username,
182 'commit-url=s' => \$_commit_url } ],
183 'set-tree' => [ \&cmd_set_tree,
184 "Set an SVN repository to a git tree-ish",
185 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
186 'create-ignore' => [ \&cmd_create_ignore,
187 'Create a .gitignore per svn:ignore',
188 { 'revision|r=i' => \$_revision
189 } ],
190 'mkdirs' => [ \&cmd_mkdirs ,
191 "recreate empty directories after a checkout",
192 { 'revision|r=i' => \$_revision } ],
193 'propget' => [ \&cmd_propget,
194 'Print the value of a property on a file or directory',
195 { 'revision|r=i' => \$_revision } ],
196 'proplist' => [ \&cmd_proplist,
197 'List all properties of a file or directory',
198 { 'revision|r=i' => \$_revision } ],
199 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
200 { 'revision|r=i' => \$_revision
201 } ],
202 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
203 { 'revision|r=i' => \$_revision
204 } ],
205 'multi-fetch' => [ \&cmd_multi_fetch,
206 "Deprecated alias for $0 fetch --all",
207 { 'revision|r=s' => \$_revision, %fc_opts } ],
208 'migrate' => [ sub { },
209 # no-op, we automatically run this anyways,
210 'Migrate configuration/metadata/layout from
211 previous versions of git-svn',
212 { 'minimize' => \$Git::SVN::Migration::_minimize,
213 %remote_opts } ],
214 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
215 { 'limit=i' => \$Git::SVN::Log::limit,
216 'revision|r=s' => \$_revision,
217 'verbose|v' => \$Git::SVN::Log::verbose,
218 'incremental' => \$Git::SVN::Log::incremental,
219 'oneline' => \$Git::SVN::Log::oneline,
220 'show-commit' => \$Git::SVN::Log::show_commit,
221 'non-recursive' => \$Git::SVN::Log::non_recursive,
222 'authors-file|A=s' => \$_authors,
223 'color' => \$Git::SVN::Log::color,
224 'pager=s' => \$Git::SVN::Log::pager
225 } ],
226 'find-rev' => [ \&cmd_find_rev,
227 "Translate between SVN revision numbers and tree-ish",
228 {} ],
229 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
230 { 'merge|m|M' => \$_merge,
231 'verbose|v' => \$_verbose,
232 'strategy|s=s' => \$_strategy,
233 'local|l' => \$_local,
234 'fetch-all|all' => \$_fetch_all,
235 'dry-run|n' => \$_dry_run,
236 %fc_opts } ],
237 'commit-diff' => [ \&cmd_commit_diff,
238 'Commit a diff between two trees',
239 { 'message|m=s' => \$_message,
240 'file|F=s' => \$_file,
241 'revision|r=s' => \$_revision,
242 %cmt_opts } ],
243 'info' => [ \&cmd_info,
244 "Show info about the latest SVN revision
245 on the current branch",
246 { 'url' => \$_url, } ],
247 'blame' => [ \&Git::SVN::Log::cmd_blame,
248 "Show what revision and author last modified each line of a file",
249 { 'git-format' => \$_git_format } ],
250 'reset' => [ \&cmd_reset,
251 "Undo fetches back to the specified SVN revision",
252 { 'revision|r=s' => \$_revision,
253 'parent|p' => \$_fetch_parent } ],
254 'gc' => [ \&cmd_gc,
255 "Compress unhandled.log files in .git/svn and remove " .
256 "index files in .git/svn",
257 {} ],
258 );
260 use Term::ReadLine;
261 package FakeTerm;
262 sub new {
263 my ($class, $reason) = @_;
264 return bless \$reason, shift;
265 }
266 sub readline {
267 my $self = shift;
268 die "Cannot use readline on FakeTerm: $$self";
269 }
270 package main;
272 my $term = eval {
273 $ENV{"GIT_SVN_NOTTY"}
274 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
275 : new Term::ReadLine 'git-svn';
276 };
277 if ($@) {
278 $term = new FakeTerm "$@: going non-interactive";
279 }
281 my $cmd;
282 for (my $i = 0; $i < @ARGV; $i++) {
283 if (defined $cmd{$ARGV[$i]}) {
284 $cmd = $ARGV[$i];
285 splice @ARGV, $i, 1;
286 last;
287 } elsif ($ARGV[$i] eq 'help') {
288 $cmd = $ARGV[$i+1];
289 usage(0);
290 }
291 };
293 # make sure we're always running at the top-level working directory
294 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
295 unless (-d $ENV{GIT_DIR}) {
296 if ($git_dir_user_set) {
297 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
298 "but it is not a directory\n";
299 }
300 my $git_dir = delete $ENV{GIT_DIR};
301 my $cdup = undef;
302 git_cmd_try {
303 $cdup = command_oneline(qw/rev-parse --show-cdup/);
304 $git_dir = '.' unless ($cdup);
305 chomp $cdup if ($cdup);
306 $cdup = "." unless ($cdup && length $cdup);
307 } "Already at toplevel, but $git_dir not found\n";
308 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
309 unless (-d $git_dir) {
310 die "$git_dir still not found after going to ",
311 "'$cdup'\n";
312 }
313 $ENV{GIT_DIR} = $git_dir;
314 }
315 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
316 }
318 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
320 read_git_config(\%opts);
321 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
322 Getopt::Long::Configure('pass_through');
323 }
324 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
325 'minimize-connections' => \$Git::SVN::Migration::_minimize,
326 'id|i=s' => \$Git::SVN::default_ref_id,
327 'svn-remote|remote|R=s' => sub {
328 $Git::SVN::no_reuse_existing = 1;
329 $Git::SVN::default_repo_id = $_[1] });
330 exit 1 if (!$rv && $cmd && $cmd ne 'log');
332 usage(0) if $_help;
333 version() if $_version;
334 usage(1) unless defined $cmd;
335 load_authors() if $_authors;
336 if (defined $_authors_prog) {
337 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
338 }
340 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
341 Git::SVN::Migration::migration_check();
342 }
343 Git::SVN::init_vars();
344 eval {
345 Git::SVN::verify_remotes_sanity();
346 $cmd{$cmd}->[0]->(@ARGV);
347 };
348 fatal $@ if $@;
349 post_fetch_checkout();
350 exit 0;
352 ####################### primary functions ######################
353 sub usage {
354 my $exit = shift || 0;
355 my $fd = $exit ? \*STDERR : \*STDOUT;
356 print $fd <<"";
357 git-svn - bidirectional operations between a single Subversion tree and git
358 Usage: git svn <command> [options] [arguments]\n
360 print $fd "Available commands:\n" unless $cmd;
362 foreach (sort keys %cmd) {
363 next if $cmd && $cmd ne $_;
364 next if /^multi-/; # don't show deprecated commands
365 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
366 foreach (sort keys %{$cmd{$_}->[2]}) {
367 # mixed-case options are for .git/config only
368 next if /[A-Z]/ && /^[a-z]+$/i;
369 # prints out arguments as they should be passed:
370 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
371 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
372 "--$_" : "-$_" }
373 split /\|/,$_)," $x\n";
374 }
375 }
376 print $fd <<"";
377 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
378 arbitrary identifier if you're tracking multiple SVN branches/repositories in
379 one git repository and want to keep them separate. See git-svn(1) for more
380 information.
382 exit $exit;
383 }
385 sub version {
386 ::_req_svn();
387 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
388 exit 0;
389 }
391 sub ask {
392 my ($prompt, %arg) = @_;
393 my $valid_re = $arg{valid_re};
394 my $default = $arg{default};
395 my $resp;
396 my $i = 0;
398 if ( !( defined($term->IN)
399 && defined( fileno($term->IN) )
400 && defined( $term->OUT )
401 && defined( fileno($term->OUT) ) ) ){
402 return defined($default) ? $default : undef;
403 }
405 while ($i++ < 10) {
406 $resp = $term->readline($prompt);
407 if (!defined $resp) { # EOF
408 print "\n";
409 return defined $default ? $default : undef;
410 }
411 if ($resp eq '' and defined $default) {
412 return $default;
413 }
414 if (!defined $valid_re or $resp =~ /$valid_re/) {
415 return $resp;
416 }
417 }
418 return undef;
419 }
421 sub do_git_init_db {
422 unless (-d $ENV{GIT_DIR}) {
423 my @init_db = ('init');
424 push @init_db, "--template=$_template" if defined $_template;
425 if (defined $_shared) {
426 if ($_shared =~ /[a-z]/) {
427 push @init_db, "--shared=$_shared";
428 } else {
429 push @init_db, "--shared";
430 }
431 }
432 command_noisy(@init_db);
433 $_repository = Git->repository(Repository => ".git");
434 }
435 my $set;
436 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
437 foreach my $i (keys %icv) {
438 die "'$set' and '$i' cannot both be set\n" if $set;
439 next unless defined $icv{$i};
440 command_noisy('config', "$pfx.$i", $icv{$i});
441 $set = $i;
442 }
443 my $ignore_paths_regex = \$SVN::Git::Fetcher::_ignore_regex;
444 command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
445 if defined $$ignore_paths_regex;
446 my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
447 command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
448 if defined $$ignore_refs_regex;
450 if (defined $SVN::Git::Fetcher::_preserve_empty_dirs) {
451 my $fname = \$SVN::Git::Fetcher::_placeholder_filename;
452 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
453 command_noisy('config', "$pfx.placeholder-filename", $$fname);
454 }
455 }
457 sub init_subdir {
458 my $repo_path = shift or return;
459 mkpath([$repo_path]) unless -d $repo_path;
460 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
461 $ENV{GIT_DIR} = '.git';
462 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
463 }
465 sub cmd_clone {
466 my ($url, $path) = @_;
467 if (!defined $path &&
468 (defined $_trunk || @_branches || @_tags ||
469 defined $_stdlayout) &&
470 $url !~ m#^[a-z\+]+://#) {
471 $path = $url;
472 }
473 $path = basename($url) if !defined $path || !length $path;
474 my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
475 cmd_init($url, $path);
476 command_oneline('config', 'svn.authorsfile', $authors_absolute)
477 if $_authors;
478 Git::SVN::fetch_all($Git::SVN::default_repo_id);
479 }
481 sub cmd_init {
482 if (defined $_stdlayout) {
483 $_trunk = 'trunk' if (!defined $_trunk);
484 @_tags = 'tags' if (! @_tags);
485 @_branches = 'branches' if (! @_branches);
486 }
487 if (defined $_trunk || @_branches || @_tags) {
488 return cmd_multi_init(@_);
489 }
490 my $url = shift or die "SVN repository location required ",
491 "as a command-line argument\n";
492 $url = canonicalize_url($url);
493 init_subdir(@_);
494 do_git_init_db();
496 if ($Git::SVN::_minimize_url eq 'unset') {
497 $Git::SVN::_minimize_url = 0;
498 }
500 Git::SVN->init($url);
501 }
503 sub cmd_fetch {
504 if (grep /^\d+=./, @_) {
505 die "'<rev>=<commit>' fetch arguments are ",
506 "no longer supported.\n";
507 }
508 my ($remote) = @_;
509 if (@_ > 1) {
510 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
511 }
512 $Git::SVN::no_reuse_existing = undef;
513 if ($_fetch_parent) {
514 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
515 unless ($gs) {
516 die "Unable to determine upstream SVN information from ",
517 "working tree history\n";
518 }
519 # just fetch, don't checkout.
520 $_no_checkout = 'true';
521 $_fetch_all ? $gs->fetch_all : $gs->fetch;
522 } elsif ($_fetch_all) {
523 cmd_multi_fetch();
524 } else {
525 $remote ||= $Git::SVN::default_repo_id;
526 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
527 }
528 }
530 sub cmd_set_tree {
531 my (@commits) = @_;
532 if ($_stdin || !@commits) {
533 print "Reading from stdin...\n";
534 @commits = ();
535 while (<STDIN>) {
536 if (/\b($sha1_short)\b/o) {
537 unshift @commits, $1;
538 }
539 }
540 }
541 my @revs;
542 foreach my $c (@commits) {
543 my @tmp = command('rev-parse',$c);
544 if (scalar @tmp == 1) {
545 push @revs, $tmp[0];
546 } elsif (scalar @tmp > 1) {
547 push @revs, reverse(command('rev-list',@tmp));
548 } else {
549 fatal "Failed to rev-parse $c";
550 }
551 }
552 my $gs = Git::SVN->new;
553 my ($r_last, $cmt_last) = $gs->last_rev_commit;
554 $gs->fetch;
555 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
556 fatal "There are new revisions that were fetched ",
557 "and need to be merged (or acknowledged) ",
558 "before committing.\nlast rev: $r_last\n",
559 " current: $gs->{last_rev}";
560 }
561 $gs->set_tree($_) foreach @revs;
562 print "Done committing ",scalar @revs," revisions to SVN\n";
563 unlink $gs->{index};
564 }
566 sub split_merge_info_range {
567 my ($range) = @_;
568 if ($range =~ /(\d+)-(\d+)/) {
569 return (int($1), int($2));
570 } else {
571 return (int($range), int($range));
572 }
573 }
575 sub combine_ranges {
576 my ($in) = @_;
578 my @fnums = ();
579 my @arr = split(/,/, $in);
580 for my $element (@arr) {
581 my ($start, $end) = split_merge_info_range($element);
582 push @fnums, $start;
583 }
585 my @sorted = @arr [ sort {
586 $fnums[$a] <=> $fnums[$b]
587 } 0..$#arr ];
589 my @return = ();
590 my $last = -1;
591 my $first = -1;
592 for my $element (@sorted) {
593 my ($start, $end) = split_merge_info_range($element);
595 if ($last == -1) {
596 $first = $start;
597 $last = $end;
598 next;
599 }
600 if ($start <= $last+1) {
601 if ($end > $last) {
602 $last = $end;
603 }
604 next;
605 }
606 if ($first == $last) {
607 push @return, "$first";
608 } else {
609 push @return, "$first-$last";
610 }
611 $first = $start;
612 $last = $end;
613 }
615 if ($first != -1) {
616 if ($first == $last) {
617 push @return, "$first";
618 } else {
619 push @return, "$first-$last";
620 }
621 }
623 return join(',', @return);
624 }
626 sub merge_revs_into_hash {
627 my ($hash, $minfo) = @_;
628 my @lines = split(' ', $minfo);
630 for my $line (@lines) {
631 my ($branchpath, $revs) = split(/:/, $line);
633 if (exists($hash->{$branchpath})) {
634 # Merge the two revision sets
635 my $combined = "$hash->{$branchpath},$revs";
636 $hash->{$branchpath} = combine_ranges($combined);
637 } else {
638 # Just do range combining for consolidation
639 $hash->{$branchpath} = combine_ranges($revs);
640 }
641 }
642 }
644 sub merge_merge_info {
645 my ($mergeinfo_one, $mergeinfo_two) = @_;
646 my %result_hash = ();
648 merge_revs_into_hash(\%result_hash, $mergeinfo_one);
649 merge_revs_into_hash(\%result_hash, $mergeinfo_two);
651 my $result = '';
652 # Sort below is for consistency's sake
653 for my $branchname (sort keys(%result_hash)) {
654 my $revlist = $result_hash{$branchname};
655 $result .= "$branchname:$revlist\n"
656 }
657 return $result;
658 }
660 sub populate_merge_info {
661 my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
663 my %parentshash;
664 read_commit_parents(\%parentshash, $d);
665 my @parents = @{$parentshash{$d}};
666 if ($#parents > 0) {
667 # Merge commit
668 my $all_parents_ok = 1;
669 my $aggregate_mergeinfo = '';
670 my $rooturl = $gs->repos_root;
672 if (defined($rewritten_parent)) {
673 # Replace first parent with newly-rewritten version
674 shift @parents;
675 unshift @parents, $rewritten_parent;
676 }
678 foreach my $parent (@parents) {
679 my ($branchurl, $svnrev, $paruuid) =
680 cmt_metadata($parent);
682 unless (defined($svnrev)) {
683 # Should have been caught be preflight check
684 fatal "merge commit $d has ancestor $parent, but that change "
685 ."does not have git-svn metadata!";
686 }
687 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
688 fatal "commit $parent git-svn metadata changed mid-run!";
689 }
690 my $branchpath = $1;
692 my $ra = Git::SVN::Ra->new($branchurl);
693 my (undef, undef, $props) =
694 $ra->get_dir(canonicalize_path("."), $svnrev);
695 my $par_mergeinfo = $props->{'svn:mergeinfo'};
696 unless (defined $par_mergeinfo) {
697 $par_mergeinfo = '';
698 }
699 # Merge previous mergeinfo values
700 $aggregate_mergeinfo =
701 merge_merge_info($aggregate_mergeinfo,
702 $par_mergeinfo, 0);
704 next if $parent eq $parents[0]; # Skip first parent
705 # Add new changes being placed in tree by merge
706 my @cmd = (qw/rev-list --reverse/,
707 $parent, qw/--not/);
708 foreach my $par (@parents) {
709 unless ($par eq $parent) {
710 push @cmd, $par;
711 }
712 }
713 my @revsin = ();
714 my ($revlist, $ctx) = command_output_pipe(@cmd);
715 while (<$revlist>) {
716 my $irev = $_;
717 chomp $irev;
718 my (undef, $csvnrev, undef) =
719 cmt_metadata($irev);
720 unless (defined $csvnrev) {
721 # A child is missing SVN annotations...
722 # this might be OK, or might not be.
723 warn "W:child $irev is merged into revision "
724 ."$d but does not have git-svn metadata. "
725 ."This means git-svn cannot determine the "
726 ."svn revision numbers to place into the "
727 ."svn:mergeinfo property. You must ensure "
728 ."a branch is entirely committed to "
729 ."SVN before merging it in order for "
730 ."svn:mergeinfo population to function "
731 ."properly";
732 }
733 push @revsin, $csvnrev;
734 }
735 command_close_pipe($revlist, $ctx);
737 last unless $all_parents_ok;
739 # We now have a list of all SVN revnos which are
740 # merged by this particular parent. Integrate them.
741 next if $#revsin == -1;
742 my $newmergeinfo = "$branchpath:" . join(',', @revsin);
743 $aggregate_mergeinfo =
744 merge_merge_info($aggregate_mergeinfo,
745 $newmergeinfo, 1);
746 }
747 if ($all_parents_ok and $aggregate_mergeinfo) {
748 return $aggregate_mergeinfo;
749 }
750 }
752 return undef;
753 }
755 sub cmd_dcommit {
756 my $head = shift;
757 command_noisy(qw/update-index --refresh/);
758 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
759 'Cannot dcommit with a dirty index. Commit your changes first, '
760 . "or stash them with `git stash'.\n";
761 $head ||= 'HEAD';
763 my $old_head;
764 if ($head ne 'HEAD') {
765 $old_head = eval {
766 command_oneline([qw/symbolic-ref -q HEAD/])
767 };
768 if ($old_head) {
769 $old_head =~ s{^refs/heads/}{};
770 } else {
771 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
772 }
773 command(['checkout', $head], STDERR => 0);
774 }
776 my @refs;
777 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
778 unless ($gs) {
779 die "Unable to determine upstream SVN information from ",
780 "$head history.\nPerhaps the repository is empty.";
781 }
783 if (defined $_commit_url) {
784 $url = $_commit_url;
785 } else {
786 $url = eval { command_oneline('config', '--get',
787 "svn-remote.$gs->{repo_id}.commiturl") };
788 if (!$url) {
789 $url = $gs->full_pushurl
790 }
791 }
793 my $last_rev = $_revision if defined $_revision;
794 if ($url) {
795 print "Committing to $url ...\n";
796 }
797 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
798 if ($_no_rebase && scalar(@$linear_refs) > 1) {
799 warn "Attempting to commit more than one change while ",
800 "--no-rebase is enabled.\n",
801 "If these changes depend on each other, re-running ",
802 "without --no-rebase may be required."
803 }
805 if (defined $_interactive){
806 my $ask_default = "y";
807 foreach my $d (@$linear_refs){
808 my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
809 while (<$fh>){
810 print $_;
811 }
812 command_close_pipe($fh, $ctx);
813 $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
814 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
815 default => $ask_default);
816 die "Commit this patch reply required" unless defined $_;
817 if (/^[nq]/i) {
818 exit(0);
819 } elsif (/^a/i) {
820 last;
821 }
822 }
823 }
825 my $expect_url = $url;
827 my $push_merge_info = eval {
828 command_oneline(qw/config --get svn.pushmergeinfo/)
829 };
830 if (not defined($push_merge_info)
831 or $push_merge_info eq "false"
832 or $push_merge_info eq "no"
833 or $push_merge_info eq "never") {
834 $push_merge_info = 0;
835 }
837 unless (defined($_merge_info) || ! $push_merge_info) {
838 # Preflight check of changes to ensure no issues with mergeinfo
839 # This includes check for uncommitted-to-SVN parents
840 # (other than the first parent, which we will handle),
841 # information from different SVN repos, and paths
842 # which are not underneath this repository root.
843 my $rooturl = $gs->repos_root;
844 foreach my $d (@$linear_refs) {
845 my %parentshash;
846 read_commit_parents(\%parentshash, $d);
847 my @realparents = @{$parentshash{$d}};
848 if ($#realparents > 0) {
849 # Merge commit
850 shift @realparents; # Remove/ignore first parent
851 foreach my $parent (@realparents) {
852 my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
853 unless (defined $paruuid) {
854 # A parent is missing SVN annotations...
855 # abort the whole operation.
856 fatal "$parent is merged into revision $d, "
857 ."but does not have git-svn metadata. "
858 ."Either dcommit the branch or use a "
859 ."local cherry-pick, FF merge, or rebase "
860 ."instead of an explicit merge commit.";
861 }
863 unless ($paruuid eq $uuid) {
864 # Parent has SVN metadata from different repository
865 fatal "merge parent $parent for change $d has "
866 ."git-svn uuid $paruuid, while current change "
867 ."has uuid $uuid!";
868 }
870 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
871 # This branch is very strange indeed.
872 fatal "merge parent $parent for $d is on branch "
873 ."$branchurl, which is not under the "
874 ."git-svn root $rooturl!";
875 }
876 }
877 }
878 }
879 }
881 my $rewritten_parent;
882 Git::SVN::remove_username($expect_url);
883 if (defined($_merge_info)) {
884 $_merge_info =~ tr{ }{\n};
885 }
886 while (1) {
887 my $d = shift @$linear_refs or last;
888 unless (defined $last_rev) {
889 (undef, $last_rev, undef) = cmt_metadata("$d~1");
890 unless (defined $last_rev) {
891 fatal "Unable to extract revision information ",
892 "from commit $d~1";
893 }
894 }
895 if ($_dry_run) {
896 print "diff-tree $d~1 $d\n";
897 } else {
898 my $cmt_rev;
900 unless (defined($_merge_info) || ! $push_merge_info) {
901 $_merge_info = populate_merge_info($d, $gs,
902 $uuid,
903 $linear_refs,
904 $rewritten_parent);
905 }
907 my %ed_opts = ( r => $last_rev,
908 log => get_commit_entry($d)->{log},
909 ra => Git::SVN::Ra->new($url),
910 config => SVN::Core::config_get_config(
911 $Git::SVN::Ra::config_dir
912 ),
913 tree_a => "$d~1",
914 tree_b => $d,
915 editor_cb => sub {
916 print "Committed r$_[0]\n";
917 $cmt_rev = $_[0];
918 },
919 mergeinfo => $_merge_info,
920 svn_path => '');
921 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
922 print "No changes\n$d~1 == $d\n";
923 } elsif ($parents->{$d} && @{$parents->{$d}}) {
924 $gs->{inject_parents_dcommit}->{$cmt_rev} =
925 $parents->{$d};
926 }
927 $_fetch_all ? $gs->fetch_all : $gs->fetch;
928 $last_rev = $cmt_rev;
929 next if $_no_rebase;
931 # we always want to rebase against the current HEAD,
932 # not any head that was passed to us
933 my @diff = command('diff-tree', $d,
934 $gs->refname, '--');
935 my @finish;
936 if (@diff) {
937 @finish = rebase_cmd();
938 print STDERR "W: $d and ", $gs->refname,
939 " differ, using @finish:\n",
940 join("\n", @diff), "\n";
941 } else {
942 print "No changes between current HEAD and ",
943 $gs->refname,
944 "\nResetting to the latest ",
945 $gs->refname, "\n";
946 @finish = qw/reset --mixed/;
947 }
948 command_noisy(@finish, $gs->refname);
950 $rewritten_parent = command_oneline(qw/rev-parse HEAD/);
952 if (@diff) {
953 @refs = ();
954 my ($url_, $rev_, $uuid_, $gs_) =
955 working_head_info('HEAD', \@refs);
956 my ($linear_refs_, $parents_) =
957 linearize_history($gs_, \@refs);
958 if (scalar(@$linear_refs) !=
959 scalar(@$linear_refs_)) {
960 fatal "# of revisions changed ",
961 "\nbefore:\n",
962 join("\n", @$linear_refs),
963 "\n\nafter:\n",
964 join("\n", @$linear_refs_), "\n",
965 'If you are attempting to commit ',
966 "merges, try running:\n\t",
967 'git rebase --interactive',
968 '--preserve-merges ',
969 $gs->refname,
970 "\nBefore dcommitting";
971 }
972 if ($url_ ne $expect_url) {
973 if ($url_ eq $gs->metadata_url) {
974 print
975 "Accepting rewritten URL:",
976 " $url_\n";
977 } else {
978 fatal
979 "URL mismatch after rebase:",
980 " $url_ != $expect_url";
981 }
982 }
983 if ($uuid_ ne $uuid) {
984 fatal "uuid mismatch after rebase: ",
985 "$uuid_ != $uuid";
986 }
987 # remap parents
988 my (%p, @l, $i);
989 for ($i = 0; $i < scalar @$linear_refs; $i++) {
990 my $new = $linear_refs_->[$i] or next;
991 $p{$new} =
992 $parents->{$linear_refs->[$i]};
993 push @l, $new;
994 }
995 $parents = \%p;
996 $linear_refs = \@l;
997 }
998 }
999 }
1001 if ($old_head) {
1002 my $new_head = command_oneline(qw/rev-parse HEAD/);
1003 my $new_is_symbolic = eval {
1004 command_oneline(qw/symbolic-ref -q HEAD/);
1005 };
1006 if ($new_is_symbolic) {
1007 print "dcommitted the branch ", $head, "\n";
1008 } else {
1009 print "dcommitted on a detached HEAD because you gave ",
1010 "a revision argument.\n",
1011 "The rewritten commit is: ", $new_head, "\n";
1012 }
1013 command(['checkout', $old_head], STDERR => 0);
1014 }
1016 unlink $gs->{index};
1017 }
1019 sub cmd_branch {
1020 my ($branch_name, $head) = @_;
1022 unless (defined $branch_name && length $branch_name) {
1023 die(($_tag ? "tag" : "branch") . " name required\n");
1024 }
1025 $head ||= 'HEAD';
1027 my (undef, $rev, undef, $gs) = working_head_info($head);
1028 my $src = $gs->full_pushurl;
1030 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1031 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1032 my $glob;
1033 if ($#{$allglobs} == 0) {
1034 $glob = $allglobs->[0];
1035 } else {
1036 unless(defined $_branch_dest) {
1037 die "Multiple ",
1038 $_tag ? "tag" : "branch",
1039 " paths defined for Subversion repository.\n",
1040 "You must specify where you want to create the ",
1041 $_tag ? "tag" : "branch",
1042 " with the --destination argument.\n";
1043 }
1044 foreach my $g (@{$allglobs}) {
1045 # SVN::Git::Editor could probably be moved to Git.pm..
1046 my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
1047 if ($_branch_dest =~ /$re/) {
1048 $glob = $g;
1049 last;
1050 }
1051 }
1052 unless (defined $glob) {
1053 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1054 foreach my $g (@{$allglobs}) {
1055 $g->{path}->{left} =~ /$dest_re/ or next;
1056 if (defined $glob) {
1057 die "Ambiguous destination: ",
1058 $_branch_dest, "\nmatches both '",
1059 $glob->{path}->{left}, "' and '",
1060 $g->{path}->{left}, "'\n";
1061 }
1062 $glob = $g;
1063 }
1064 unless (defined $glob) {
1065 die "Unknown ",
1066 $_tag ? "tag" : "branch",
1067 " destination $_branch_dest\n";
1068 }
1069 }
1070 }
1071 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1072 my $url;
1073 if (defined $_commit_url) {
1074 $url = $_commit_url;
1075 } else {
1076 $url = eval { command_oneline('config', '--get',
1077 "svn-remote.$gs->{repo_id}.commiturl") };
1078 if (!$url) {
1079 $url = $remote->{pushurl} || $remote->{url};
1080 }
1081 }
1082 my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1084 if ($dst =~ /^https:/ && $src =~ /^http:/) {
1085 $src=~s/^http:/https:/;
1086 }
1088 ::_req_svn();
1090 my $ctx = SVN::Client->new(
1091 auth => Git::SVN::Ra::_auth_providers(),
1092 log_msg => sub {
1093 ${ $_[0] } = defined $_message
1094 ? $_message
1095 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1096 . $branch_name;
1097 },
1098 );
1100 eval {
1101 $ctx->ls($dst, 'HEAD', 0);
1102 } and die "branch ${branch_name} already exists\n";
1104 print "Copying ${src} at r${rev} to ${dst}...\n";
1105 $ctx->copy($src, $rev, $dst)
1106 unless $_dry_run;
1108 $gs->fetch_all;
1109 }
1111 sub cmd_find_rev {
1112 my $revision_or_hash = shift or die "SVN or git revision required ",
1113 "as a command-line argument\n";
1114 my $result;
1115 if ($revision_or_hash =~ /^r\d+$/) {
1116 my $head = shift;
1117 $head ||= 'HEAD';
1118 my @refs;
1119 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1120 unless ($gs) {
1121 die "Unable to determine upstream SVN information from ",
1122 "$head history\n";
1123 }
1124 my $desired_revision = substr($revision_or_hash, 1);
1125 $result = $gs->rev_map_get($desired_revision, $uuid);
1126 } else {
1127 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1128 $result = $rev;
1129 }
1130 print "$result\n" if $result;
1131 }
1133 sub auto_create_empty_directories {
1134 my ($gs) = @_;
1135 my $var = eval { command_oneline('config', '--get', '--bool',
1136 "svn-remote.$gs->{repo_id}.automkdirs") };
1137 # By default, create empty directories by consulting the unhandled log,
1138 # but allow setting it to 'false' to skip it.
1139 return !($var && $var eq 'false');
1140 }
1142 sub cmd_rebase {
1143 command_noisy(qw/update-index --refresh/);
1144 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1145 unless ($gs) {
1146 die "Unable to determine upstream SVN information from ",
1147 "working tree history\n";
1148 }
1149 if ($_dry_run) {
1150 print "Remote Branch: " . $gs->refname . "\n";
1151 print "SVN URL: " . $url . "\n";
1152 return;
1153 }
1154 if (command(qw/diff-index HEAD --/)) {
1155 print STDERR "Cannot rebase with uncommited changes:\n";
1156 command_noisy('status');
1157 exit 1;
1158 }
1159 unless ($_local) {
1160 # rebase will checkout for us, so no need to do it explicitly
1161 $_no_checkout = 'true';
1162 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1163 }
1164 command_noisy(rebase_cmd(), $gs->refname);
1165 if (auto_create_empty_directories($gs)) {
1166 $gs->mkemptydirs;
1167 }
1168 }
1170 sub cmd_show_ignore {
1171 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1172 $gs ||= Git::SVN->new;
1173 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1174 $gs->prop_walk($gs->{path}, $r, sub {
1175 my ($gs, $path, $props) = @_;
1176 print STDOUT "\n# $path\n";
1177 my $s = $props->{'svn:ignore'} or return;
1178 $s =~ s/[\r\n]+/\n/g;
1179 $s =~ s/^\n+//;
1180 chomp $s;
1181 $s =~ s#^#$path#gm;
1182 print STDOUT "$s\n";
1183 });
1184 }
1186 sub cmd_show_externals {
1187 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1188 $gs ||= Git::SVN->new;
1189 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1190 $gs->prop_walk($gs->{path}, $r, sub {
1191 my ($gs, $path, $props) = @_;
1192 print STDOUT "\n# $path\n";
1193 my $s = $props->{'svn:externals'} or return;
1194 $s =~ s/[\r\n]+/\n/g;
1195 chomp $s;
1196 $s =~ s#^#$path#gm;
1197 print STDOUT "$s\n";
1198 });
1199 }
1201 sub cmd_create_ignore {
1202 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1203 $gs ||= Git::SVN->new;
1204 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1205 $gs->prop_walk($gs->{path}, $r, sub {
1206 my ($gs, $path, $props) = @_;
1207 # $path is of the form /path/to/dir/
1208 $path = '.' . $path;
1209 # SVN can have attributes on empty directories,
1210 # which git won't track
1211 mkpath([$path]) unless -d $path;
1212 my $ignore = $path . '.gitignore';
1213 my $s = $props->{'svn:ignore'} or return;
1214 open(GITIGNORE, '>', $ignore)
1215 or fatal("Failed to open `$ignore' for writing: $!");
1216 $s =~ s/[\r\n]+/\n/g;
1217 $s =~ s/^\n+//;
1218 chomp $s;
1219 # Prefix all patterns so that the ignore doesn't apply
1220 # to sub-directories.
1221 $s =~ s#^#/#gm;
1222 print GITIGNORE "$s\n";
1223 close(GITIGNORE)
1224 or fatal("Failed to close `$ignore': $!");
1225 command_noisy('add', '-f', $ignore);
1226 });
1227 }
1229 sub cmd_mkdirs {
1230 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1231 $gs ||= Git::SVN->new;
1232 $gs->mkemptydirs($_revision);
1233 }
1235 sub canonicalize_path {
1236 my ($path) = @_;
1237 my $dot_slash_added = 0;
1238 if (substr($path, 0, 1) ne "/") {
1239 $path = "./" . $path;
1240 $dot_slash_added = 1;
1241 }
1242 # File::Spec->canonpath doesn't collapse x/../y into y (for a
1243 # good reason), so let's do this manually.
1244 $path =~ s#/+#/#g;
1245 $path =~ s#/\.(?:/|$)#/#g;
1246 $path =~ s#/[^/]+/\.\.##g;
1247 $path =~ s#/$##g;
1248 $path =~ s#^\./## if $dot_slash_added;
1249 $path =~ s#^/##;
1250 $path =~ s#^\.$##;
1251 return $path;
1252 }
1254 sub canonicalize_url {
1255 my ($url) = @_;
1256 $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
1257 return $url;
1258 }
1260 # get_svnprops(PATH)
1261 # ------------------
1262 # Helper for cmd_propget and cmd_proplist below.
1263 sub get_svnprops {
1264 my $path = shift;
1265 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1266 $gs ||= Git::SVN->new;
1268 # prefix THE PATH by the sub-directory from which the user
1269 # invoked us.
1270 $path = $cmd_dir_prefix . $path;
1271 fatal("No such file or directory: $path") unless -e $path;
1272 my $is_dir = -d $path ? 1 : 0;
1273 $path = $gs->{path} . '/' . $path;
1275 # canonicalize the path (otherwise libsvn will abort or fail to
1276 # find the file)
1277 $path = canonicalize_path($path);
1279 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1280 my $props;
1281 if ($is_dir) {
1282 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1283 }
1284 else {
1285 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1286 }
1287 return $props;
1288 }
1290 # cmd_propget (PROP, PATH)
1291 # ------------------------
1292 # Print the SVN property PROP for PATH.
1293 sub cmd_propget {
1294 my ($prop, $path) = @_;
1295 $path = '.' if not defined $path;
1296 usage(1) if not defined $prop;
1297 my $props = get_svnprops($path);
1298 if (not defined $props->{$prop}) {
1299 fatal("`$path' does not have a `$prop' SVN property.");
1300 }
1301 print $props->{$prop} . "\n";
1302 }
1304 # cmd_proplist (PATH)
1305 # -------------------
1306 # Print the list of SVN properties for PATH.
1307 sub cmd_proplist {
1308 my $path = shift;
1309 $path = '.' if not defined $path;
1310 my $props = get_svnprops($path);
1311 print "Properties on '$path':\n";
1312 foreach (sort keys %{$props}) {
1313 print " $_\n";
1314 }
1315 }
1317 sub cmd_multi_init {
1318 my $url = shift;
1319 unless (defined $_trunk || @_branches || @_tags) {
1320 usage(1);
1321 }
1323 $_prefix = '' unless defined $_prefix;
1324 if (defined $url) {
1325 $url = canonicalize_url($url);
1326 init_subdir(@_);
1327 }
1328 do_git_init_db();
1329 if (defined $_trunk) {
1330 $_trunk =~ s#^/+##;
1331 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1332 # try both old-style and new-style lookups:
1333 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1334 unless ($gs_trunk) {
1335 my ($trunk_url, $trunk_path) =
1336 complete_svn_url($url, $_trunk);
1337 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1338 undef, $trunk_ref);
1339 }
1340 }
1341 return unless @_branches || @_tags;
1342 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1343 foreach my $path (@_branches) {
1344 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1345 }
1346 foreach my $path (@_tags) {
1347 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1348 }
1349 }
1351 sub cmd_multi_fetch {
1352 $Git::SVN::no_reuse_existing = undef;
1353 my $remotes = Git::SVN::read_all_remotes();
1354 foreach my $repo_id (sort keys %$remotes) {
1355 if ($remotes->{$repo_id}->{url}) {
1356 Git::SVN::fetch_all($repo_id, $remotes);
1357 }
1358 }
1359 }
1361 # this command is special because it requires no metadata
1362 sub cmd_commit_diff {
1363 my ($ta, $tb, $url) = @_;
1364 my $usage = "Usage: $0 commit-diff -r<revision> ".
1365 "<tree-ish> <tree-ish> [<URL>]";
1366 fatal($usage) if (!defined $ta || !defined $tb);
1367 my $svn_path = '';
1368 if (!defined $url) {
1369 my $gs = eval { Git::SVN->new };
1370 if (!$gs) {
1371 fatal("Needed URL or usable git-svn --id in ",
1372 "the command-line\n", $usage);
1373 }
1374 $url = $gs->{url};
1375 $svn_path = $gs->{path};
1376 }
1377 unless (defined $_revision) {
1378 fatal("-r|--revision is a required argument\n", $usage);
1379 }
1380 if (defined $_message && defined $_file) {
1381 fatal("Both --message/-m and --file/-F specified ",
1382 "for the commit message.\n",
1383 "I have no idea what you mean");
1384 }
1385 if (defined $_file) {
1386 $_message = file_to_s($_file);
1387 } else {
1388 $_message ||= get_commit_entry($tb)->{log};
1389 }
1390 my $ra ||= Git::SVN::Ra->new($url);
1391 my $r = $_revision;
1392 if ($r eq 'HEAD') {
1393 $r = $ra->get_latest_revnum;
1394 } elsif ($r !~ /^\d+$/) {
1395 die "revision argument: $r not understood by git-svn\n";
1396 }
1397 my %ed_opts = ( r => $r,
1398 log => $_message,
1399 ra => $ra,
1400 tree_a => $ta,
1401 tree_b => $tb,
1402 editor_cb => sub { print "Committed r$_[0]\n" },
1403 svn_path => $svn_path );
1404 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1405 print "No changes\n$ta == $tb\n";
1406 }
1407 }
1409 sub escape_uri_only {
1410 my ($uri) = @_;
1411 my @tmp;
1412 foreach (split m{/}, $uri) {
1413 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1414 push @tmp, $_;
1415 }
1416 join('/', @tmp);
1417 }
1419 sub escape_url {
1420 my ($url) = @_;
1421 if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1422 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1423 $url = "$scheme://$domain$uri";
1424 }
1425 $url;
1426 }
1428 sub cmd_info {
1429 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1430 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1431 if (exists $_[1]) {
1432 die "Too many arguments specified\n";
1433 }
1435 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1437 if (!$file_type && !$diff_status) {
1438 print STDERR "svn: '$path' is not under version control\n";
1439 exit 1;
1440 }
1442 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1443 unless ($gs) {
1444 die "Unable to determine upstream SVN information from ",
1445 "working tree history\n";
1446 }
1448 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1449 $path = "." if $path eq "";
1451 my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1453 if ($_url) {
1454 print escape_url($full_url), "\n";
1455 return;
1456 }
1458 my $result = "Path: $path\n";
1459 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1460 $result .= "URL: " . escape_url($full_url) . "\n";
1462 eval {
1463 my $repos_root = $gs->repos_root;
1464 Git::SVN::remove_username($repos_root);
1465 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1466 };
1467 if ($@) {
1468 $result .= "Repository Root: (offline)\n";
1469 }
1470 ::_req_svn();
1471 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1472 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1473 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1475 $result .= "Node Kind: " .
1476 ($file_type eq "dir" ? "directory" : "file") . "\n";
1478 my $schedule = $diff_status eq "A"
1479 ? "add"
1480 : ($diff_status eq "D" ? "delete" : "normal");
1481 $result .= "Schedule: $schedule\n";
1483 if ($diff_status eq "A") {
1484 print $result, "\n";
1485 return;
1486 }
1488 my ($lc_author, $lc_rev, $lc_date_utc);
1489 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1490 my $log = command_output_pipe(@args);
1491 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1492 while (<$log>) {
1493 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1494 $lc_author = $1;
1495 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1496 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1497 (undef, $lc_rev, undef) = ::extract_metadata($1);
1498 }
1499 }
1500 close $log;
1502 Git::SVN::Log::set_local_timezone();
1504 $result .= "Last Changed Author: $lc_author\n";
1505 $result .= "Last Changed Rev: $lc_rev\n";
1506 $result .= "Last Changed Date: " .
1507 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1509 if ($file_type ne "dir") {
1510 my $text_last_updated_date =
1511 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1512 $result .=
1513 "Text Last Updated: " .
1514 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1515 "\n";
1516 my $checksum;
1517 if ($diff_status eq "D") {
1518 my ($fh, $ctx) =
1519 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1520 if ($file_type eq "link") {
1521 my $file_name = <$fh>;
1522 $checksum = md5sum("link $file_name");
1523 } else {
1524 $checksum = md5sum($fh);
1525 }
1526 command_close_pipe($fh, $ctx);
1527 } elsif ($file_type eq "link") {
1528 my $file_name =
1529 command(qw(cat-file blob), "HEAD:$path");
1530 $checksum =
1531 md5sum("link " . $file_name);
1532 } else {
1533 open FILE, "<", $path or die $!;
1534 $checksum = md5sum(\*FILE);
1535 close FILE or die $!;
1536 }
1537 $result .= "Checksum: " . $checksum . "\n";
1538 }
1540 print $result, "\n";
1541 }
1543 sub cmd_reset {
1544 my $target = shift || $_revision or die "SVN revision required\n";
1545 $target = $1 if $target =~ /^r(\d+)$/;
1546 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1547 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1548 unless ($gs) {
1549 die "Unable to determine upstream SVN information from ".
1550 "history\n";
1551 }
1552 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1553 die "Cannot find SVN revision $target\n" unless defined($c);
1554 $gs->rev_map_set($r, $c, 'reset', $uuid);
1555 print "r$r = $c ($gs->{ref_id})\n";
1556 }
1558 sub cmd_gc {
1559 if (!$can_compress) {
1560 warn "Compress::Zlib could not be found; unhandled.log " .
1561 "files will not be compressed.\n";
1562 }
1563 find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1564 }
1566 ########################### utility functions #########################
1568 sub rebase_cmd {
1569 my @cmd = qw/rebase/;
1570 push @cmd, '-v' if $_verbose;
1571 push @cmd, qw/--merge/ if $_merge;
1572 push @cmd, "--strategy=$_strategy" if $_strategy;
1573 @cmd;
1574 }
1576 sub post_fetch_checkout {
1577 return if $_no_checkout;
1578 my $gs = $Git::SVN::_head or return;
1579 return if verify_ref('refs/heads/master^0');
1581 # look for "trunk" ref if it exists
1582 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1583 my $fetch = $remote->{fetch};
1584 if ($fetch) {
1585 foreach my $p (keys %$fetch) {
1586 basename($fetch->{$p}) eq 'trunk' or next;
1587 $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1588 last;
1589 }
1590 }
1592 my $valid_head = verify_ref('HEAD^0');
1593 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1594 return if ($valid_head || !verify_ref('HEAD^0'));
1596 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1597 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1598 return if -f $index;
1600 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1601 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1602 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1603 print STDERR "Checked out HEAD:\n ",
1604 $gs->full_url, " r", $gs->last_rev, "\n";
1605 if (auto_create_empty_directories($gs)) {
1606 $gs->mkemptydirs($gs->last_rev);
1607 }
1608 }
1610 sub complete_svn_url {
1611 my ($url, $path) = @_;
1612 $path =~ s#/+$##;
1613 if ($path !~ m#^[a-z\+]+://#) {
1614 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1615 fatal("E: '$path' is not a complete URL ",
1616 "and a separate URL is not specified");
1617 }
1618 return ($url, $path);
1619 }
1620 return ($path, '');
1621 }
1623 sub complete_url_ls_init {
1624 my ($ra, $repo_path, $switch, $pfx) = @_;
1625 unless ($repo_path) {
1626 print STDERR "W: $switch not specified\n";
1627 return;
1628 }
1629 $repo_path =~ s#/+$##;
1630 if ($repo_path =~ m#^[a-z\+]+://#) {
1631 $ra = Git::SVN::Ra->new($repo_path);
1632 $repo_path = '';
1633 } else {
1634 $repo_path =~ s#^/+##;
1635 unless ($ra) {
1636 fatal("E: '$repo_path' is not a complete URL ",
1637 "and a separate URL is not specified");
1638 }
1639 }
1640 my $url = $ra->{url};
1641 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1642 my $k = "svn-remote.$gs->{repo_id}.url";
1643 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1644 if ($orig_url && ($orig_url ne $gs->{url})) {
1645 die "$k already set: $orig_url\n",
1646 "wanted to set to: $gs->{url}\n";
1647 }
1648 command_oneline('config', $k, $gs->{url}) unless $orig_url;
1649 my $remote_path = "$gs->{path}/$repo_path";
1650 $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1651 $remote_path =~ s#/+#/#g;
1652 $remote_path =~ s#^/##g;
1653 $remote_path .= "/*" if $remote_path !~ /\*/;
1654 my ($n) = ($switch =~ /^--(\w+)/);
1655 if (length $pfx && $pfx !~ m#/$#) {
1656 die "--prefix='$pfx' must have a trailing slash '/'\n";
1657 }
1658 command_noisy('config',
1659 '--add',
1660 "svn-remote.$gs->{repo_id}.$n",
1661 "$remote_path:refs/remotes/$pfx*" .
1662 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1663 }
1665 sub verify_ref {
1666 my ($ref) = @_;
1667 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1668 { STDERR => 0 }); };
1669 }
1671 sub get_tree_from_treeish {
1672 my ($treeish) = @_;
1673 # $treeish can be a symbolic ref, too:
1674 my $type = command_oneline(qw/cat-file -t/, $treeish);
1675 my $expected;
1676 while ($type eq 'tag') {
1677 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1678 }
1679 if ($type eq 'commit') {
1680 $expected = (grep /^tree /, command(qw/cat-file commit/,
1681 $treeish))[0];
1682 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1683 die "Unable to get tree from $treeish\n" unless $expected;
1684 } elsif ($type eq 'tree') {
1685 $expected = $treeish;
1686 } else {
1687 die "$treeish is a $type, expected tree, tag or commit\n";
1688 }
1689 return $expected;
1690 }
1692 sub get_commit_entry {
1693 my ($treeish) = shift;
1694 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1695 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1696 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1697 open my $log_fh, '>', $commit_editmsg or croak $!;
1699 my $type = command_oneline(qw/cat-file -t/, $treeish);
1700 if ($type eq 'commit' || $type eq 'tag') {
1701 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1702 $type, $treeish);
1703 my $in_msg = 0;
1704 my $author;
1705 my $saw_from = 0;
1706 my $msgbuf = "";
1707 while (<$msg_fh>) {
1708 if (!$in_msg) {
1709 $in_msg = 1 if (/^\s*$/);
1710 $author = $1 if (/^author (.*>)/);
1711 } elsif (/^git-svn-id: /) {
1712 # skip this for now, we regenerate the
1713 # correct one on re-fetch anyways
1714 # TODO: set *:merge properties or like...
1715 } else {
1716 if (/^From:/ || /^Signed-off-by:/) {
1717 $saw_from = 1;
1718 }
1719 $msgbuf .= $_;
1720 }
1721 }
1722 $msgbuf =~ s/\s+$//s;
1723 if ($Git::SVN::_add_author_from && defined($author)
1724 && !$saw_from) {
1725 $msgbuf .= "\n\nFrom: $author";
1726 }
1727 print $log_fh $msgbuf or croak $!;
1728 command_close_pipe($msg_fh, $ctx);
1729 }
1730 close $log_fh or croak $!;
1732 if ($_edit || ($type eq 'tree')) {
1733 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1734 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1735 }
1736 rename $commit_editmsg, $commit_msg or croak $!;
1737 {
1738 require Encode;
1739 # SVN requires messages to be UTF-8 when entering the repo
1740 local $/;
1741 open $log_fh, '<', $commit_msg or croak $!;
1742 binmode $log_fh;
1743 chomp($log_entry{log} = <$log_fh>);
1745 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1746 my $msg = $log_entry{log};
1748 eval { $msg = Encode::decode($enc, $msg, 1) };
1749 if ($@) {
1750 die "Could not decode as $enc:\n", $msg,
1751 "\nPerhaps you need to set i18n.commitencoding\n";
1752 }
1754 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1755 die "Could not encode as UTF-8:\n$msg\n" if $@;
1757 $log_entry{log} = $msg;
1759 close $log_fh or croak $!;
1760 }
1761 unlink $commit_msg;
1762 \%log_entry;
1763 }
1765 sub s_to_file {
1766 my ($str, $file, $mode) = @_;
1767 open my $fd,'>',$file or croak $!;
1768 print $fd $str,"\n" or croak $!;
1769 close $fd or croak $!;
1770 chmod ($mode &~ umask, $file) if (defined $mode);
1771 }
1773 sub file_to_s {
1774 my $file = shift;
1775 open my $fd,'<',$file or croak "$!: file: $file\n";
1776 local $/;
1777 my $ret = <$fd>;
1778 close $fd or croak $!;
1779 $ret =~ s/\s*$//s;
1780 return $ret;
1781 }
1783 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1784 sub load_authors {
1785 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1786 my $log = $cmd eq 'log';
1787 while (<$authors>) {
1788 chomp;
1789 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1790 my ($user, $name, $email) = ($1, $2, $3);
1791 if ($log) {
1792 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1793 } else {
1794 $users{$user} = [$name, $email];
1795 }
1796 }
1797 close $authors or croak $!;
1798 }
1800 # convert GetOpt::Long specs for use by git-config
1801 sub read_git_config {
1802 my $opts = shift;
1803 my @config_only;
1804 foreach my $o (keys %$opts) {
1805 # if we have mixedCase and a long option-only, then
1806 # it's a config-only variable that we don't need for
1807 # the command-line.
1808 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1809 my $v = $opts->{$o};
1810 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1811 $key =~ s/-//g;
1812 my $arg = 'git config';
1813 $arg .= ' --int' if ($o =~ /[:=]i$/);
1814 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1815 if (ref $v eq 'ARRAY') {
1816 chomp(my @tmp = `$arg --get-all svn.$key`);
1817 @$v = @tmp if @tmp;
1818 } else {
1819 chomp(my $tmp = `$arg --get svn.$key`);
1820 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1821 $$v = $tmp;
1822 }
1823 }
1824 }
1825 delete @$opts{@config_only} if @config_only;
1826 }
1828 sub extract_metadata {
1829 my $id = shift or return (undef, undef, undef);
1830 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1831 \s([a-f\d\-]+)$/ix);
1832 if (!defined $rev || !$uuid || !$url) {
1833 # some of the original repositories I made had
1834 # identifiers like this:
1835 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1836 }
1837 return ($url, $rev, $uuid);
1838 }
1840 sub cmt_metadata {
1841 return extract_metadata((grep(/^git-svn-id: /,
1842 command(qw/cat-file commit/, shift)))[-1]);
1843 }
1845 sub cmt_sha2rev_batch {
1846 my %s2r;
1847 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1848 my $list = shift;
1850 foreach my $sha (@{$list}) {
1851 my $first = 1;
1852 my $size = 0;
1853 print $out $sha, "\n";
1855 while (my $line = <$in>) {
1856 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1857 last;
1858 } elsif ($first &&
1859 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1860 $first = 0;
1861 $size = $1;
1862 next;
1863 } elsif ($line =~ /^(git-svn-id: )/) {
1864 my (undef, $rev, undef) =
1865 extract_metadata($line);
1866 $s2r{$sha} = $rev;
1867 }
1869 $size -= length($line);
1870 last if ($size == 0);
1871 }
1872 }
1874 command_close_bidi_pipe($pid, $in, $out, $ctx);
1876 return \%s2r;
1877 }
1879 sub working_head_info {
1880 my ($head, $refs) = @_;
1881 my @args = qw/log --no-color --no-decorate --first-parent
1882 --pretty=medium/;
1883 my ($fh, $ctx) = command_output_pipe(@args, $head);
1884 my $hash;
1885 my %max;
1886 while (<$fh>) {
1887 if ( m{^commit ($::sha1)$} ) {
1888 unshift @$refs, $hash if $hash and $refs;
1889 $hash = $1;
1890 next;
1891 }
1892 next unless s{^\s*(git-svn-id:)}{$1};
1893 my ($url, $rev, $uuid) = extract_metadata($_);
1894 if (defined $url && defined $rev) {
1895 next if $max{$url} and $max{$url} < $rev;
1896 if (my $gs = Git::SVN->find_by_url($url)) {
1897 my $c = $gs->rev_map_get($rev, $uuid);
1898 if ($c && $c eq $hash) {
1899 close $fh; # break the pipe
1900 return ($url, $rev, $uuid, $gs);
1901 } else {
1902 $max{$url} ||= $gs->rev_map_max;
1903 }
1904 }
1905 }
1906 }
1907 command_close_pipe($fh, $ctx);
1908 (undef, undef, undef, undef);
1909 }
1911 sub read_commit_parents {
1912 my ($parents, $c) = @_;
1913 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1914 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1915 @{$parents->{$c}} = split(/ /, $p);
1916 }
1918 sub linearize_history {
1919 my ($gs, $refs) = @_;
1920 my %parents;
1921 foreach my $c (@$refs) {
1922 read_commit_parents(\%parents, $c);
1923 }
1925 my @linear_refs;
1926 my %skip = ();
1927 my $last_svn_commit = $gs->last_commit;
1928 foreach my $c (reverse @$refs) {
1929 next if $c eq $last_svn_commit;
1930 last if $skip{$c};
1932 unshift @linear_refs, $c;
1933 $skip{$c} = 1;
1935 # we only want the first parent to diff against for linear
1936 # history, we save the rest to inject when we finalize the
1937 # svn commit
1938 my $fp_a = verify_ref("$c~1");
1939 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1940 if (!$fp_a || !$fp_b) {
1941 die "Commit $c\n",
1942 "has no parent commit, and therefore ",
1943 "nothing to diff against.\n",
1944 "You should be working from a repository ",
1945 "originally created by git-svn\n";
1946 }
1947 if ($fp_a ne $fp_b) {
1948 die "$c~1 = $fp_a, however parsing commit $c ",
1949 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1950 }
1952 foreach my $p (@{$parents{$c}}) {
1953 $skip{$p} = 1;
1954 }
1955 }
1956 (\@linear_refs, \%parents);
1957 }
1959 sub find_file_type_and_diff_status {
1960 my ($path) = @_;
1961 return ('dir', '') if $path eq '';
1963 my $diff_output =
1964 command_oneline(qw(diff --cached --name-status --), $path) || "";
1965 my $diff_status = (split(' ', $diff_output))[0] || "";
1967 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1969 return (undef, undef) if !$diff_status && !$ls_tree;
1971 if ($diff_status eq "A") {
1972 return ("link", $diff_status) if -l $path;
1973 return ("dir", $diff_status) if -d $path;
1974 return ("file", $diff_status);
1975 }
1977 my $mode = (split(' ', $ls_tree))[0] || "";
1979 return ("link", $diff_status) if $mode eq "120000";
1980 return ("dir", $diff_status) if $mode eq "040000";
1981 return ("file", $diff_status);
1982 }
1984 sub md5sum {
1985 my $arg = shift;
1986 my $ref = ref $arg;
1987 my $md5 = Digest::MD5->new();
1988 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1989 $md5->addfile($arg) or croak $!;
1990 } elsif ($ref eq 'SCALAR') {
1991 $md5->add($$arg) or croak $!;
1992 } elsif (!$ref) {
1993 $md5->add($arg) or croak $!;
1994 } else {
1995 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1996 }
1997 return $md5->hexdigest();
1998 }
2000 sub gc_directory {
2001 if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
2002 my $out_filename = $_ . ".gz";
2003 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2004 binmode $in_fh;
2005 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2006 die "Unable to open $out_filename: $!\n";
2008 my $res;
2009 while ($res = sysread($in_fh, my $str, 1024)) {
2010 $gz->gzwrite($str) or
2011 die "Unable to write: ".$gz->gzerror()."!\n";
2012 }
2013 unlink $_ or die "unlink $File::Find::name: $!\n";
2014 } elsif (-f $_ && basename($_) eq "index") {
2015 unlink $_ or die "unlink $_: $!\n";
2016 }
2017 }
2019 package Git::SVN;
2020 use strict;
2021 use warnings;
2022 use Fcntl qw/:DEFAULT :seek/;
2023 use constant rev_map_fmt => 'NH40';
2024 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
2025 $_repack $_repack_flags $_use_svm_props $_head
2026 $_use_svnsync_props $no_reuse_existing $_minimize_url
2027 $_use_log_author $_add_author_from $_localtime/;
2028 use Carp qw/croak/;
2029 use File::Path qw/mkpath/;
2030 use File::Copy qw/copy/;
2031 use IPC::Open3;
2032 use Memoize; # core since 5.8.0, Jul 2002
2033 use Memoize::Storable;
2035 my ($_gc_nr, $_gc_period);
2037 # properties that we do not log:
2038 my %SKIP_PROP;
2039 BEGIN {
2040 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
2041 svn:special svn:executable
2042 svn:entry:committed-rev
2043 svn:entry:last-author
2044 svn:entry:uuid
2045 svn:entry:committed-date/;
2047 # some options are read globally, but can be overridden locally
2048 # per [svn-remote "..."] section. Command-line options will *NOT*
2049 # override options set in an [svn-remote "..."] section
2050 no strict 'refs';
2051 for my $option (qw/follow_parent no_metadata use_svm_props
2052 use_svnsync_props/) {
2053 my $key = $option;
2054 $key =~ tr/_//d;
2055 my $prop = "-$option";
2056 *$option = sub {
2057 my ($self) = @_;
2058 return $self->{$prop} if exists $self->{$prop};
2059 my $k = "svn-remote.$self->{repo_id}.$key";
2060 eval { command_oneline(qw/config --get/, $k) };
2061 if ($@) {
2062 $self->{$prop} = ${"Git::SVN::_$option"};
2063 } else {
2064 my $v = command_oneline(qw/config --bool/,$k);
2065 $self->{$prop} = $v eq 'false' ? 0 : 1;
2066 }
2067 return $self->{$prop};
2068 }
2069 }
2070 }
2073 my (%LOCKFILES, %INDEX_FILES);
2074 END {
2075 unlink keys %LOCKFILES if %LOCKFILES;
2076 unlink keys %INDEX_FILES if %INDEX_FILES;
2077 }
2079 sub resolve_local_globs {
2080 my ($url, $fetch, $glob_spec) = @_;
2081 return unless defined $glob_spec;
2082 my $ref = $glob_spec->{ref};
2083 my $path = $glob_spec->{path};
2084 foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
2085 next unless m#^$ref->{regex}$#;
2086 my $p = $1;
2087 my $pathname = desanitize_refname($path->full_path($p));
2088 my $refname = desanitize_refname($ref->full_path($p));
2089 if (my $existing = $fetch->{$pathname}) {
2090 if ($existing ne $refname) {
2091 die "Refspec conflict:\n",
2092 "existing: $existing\n",
2093 " globbed: $refname\n";
2094 }
2095 my $u = (::cmt_metadata("$refname"))[0];
2096 $u =~ s!^\Q$url\E(/|$)!! or die
2097 "$refname: '$url' not found in '$u'\n";
2098 if ($pathname ne $u) {
2099 warn "W: Refspec glob conflict ",
2100 "(ref: $refname):\n",
2101 "expected path: $pathname\n",
2102 " real path: $u\n",
2103 "Continuing ahead with $u\n";
2104 next;
2105 }
2106 } else {
2107 $fetch->{$pathname} = $refname;
2108 }
2109 }
2110 }
2112 sub parse_revision_argument {
2113 my ($base, $head) = @_;
2114 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
2115 return ($base, $head);
2116 }
2117 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
2118 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
2119 return ($head, $head) if ($::_revision eq 'HEAD');
2120 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
2121 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
2122 die "revision argument: $::_revision not understood by git-svn\n";
2123 }
2125 sub fetch_all {
2126 my ($repo_id, $remotes) = @_;
2127 if (ref $repo_id) {
2128 my $gs = $repo_id;
2129 $repo_id = undef;
2130 $repo_id = $gs->{repo_id};
2131 }
2132 $remotes ||= read_all_remotes();
2133 my $remote = $remotes->{$repo_id} or
2134 die "[svn-remote \"$repo_id\"] unknown\n";
2135 my $fetch = $remote->{fetch};
2136 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
2137 my (@gs, @globs);
2138 my $ra = Git::SVN::Ra->new($url);
2139 my $uuid = $ra->get_uuid;
2140 my $head = $ra->get_latest_revnum;
2142 # ignore errors, $head revision may not even exist anymore
2143 eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
2144 warn "W: $@\n" if $@;
2146 my $base = defined $fetch ? $head : 0;
2148 # read the max revs for wildcard expansion (branches/*, tags/*)
2149 foreach my $t (qw/branches tags/) {
2150 defined $remote->{$t} or next;
2151 push @globs, @{$remote->{$t}};
2153 my $max_rev = eval { tmp_config(qw/--int --get/,
2154 "svn-remote.$repo_id.${t}-maxRev") };
2155 if (defined $max_rev && ($max_rev < $base)) {
2156 $base = $max_rev;
2157 } elsif (!defined $max_rev) {
2158 $base = 0;
2159 }
2160 }
2162 if ($fetch) {
2163 foreach my $p (sort keys %$fetch) {
2164 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
2165 my $lr = $gs->rev_map_max;
2166 if (defined $lr) {
2167 $base = $lr if ($lr < $base);
2168 }
2169 push @gs, $gs;
2170 }
2171 }
2173 ($base, $head) = parse_revision_argument($base, $head);
2174 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
2175 }
2177 sub read_all_remotes {
2178 my $r = {};
2179 my $use_svm_props = eval { command_oneline(qw/config --bool
2180 svn.useSvmProps/) };
2181 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
2182 my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
2183 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
2184 if (m!^(.+)\.fetch=$svn_refspec$!) {
2185 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
2186 die("svn-remote.$remote: remote ref '$remote_ref' "
2187 . "must start with 'refs/'\n")
2188 unless $remote_ref =~ m{^refs/};
2189 $local_ref = uri_decode($local_ref);
2190 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
2191 $r->{$remote}->{svm} = {} if $use_svm_props;
2192 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
2193 $r->{$1}->{svm} = {};
2194 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
2195 $r->{$1}->{url} = $2;
2196 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
2197 $r->{$1}->{pushurl} = $2;
2198 } elsif (m!^(.+)\.ignore-refs=\s*(.*)\s*$!) {
2199 $r->{$1}->{ignore_refs_regex} = $2;
2200 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
2201 my ($remote, $t, $local_ref, $remote_ref) =
2202 ($1, $2, $3, $4);
2203 die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
2204 . "must start with 'refs/'\n")
2205 unless $remote_ref =~ m{^refs/};
2206 $local_ref = uri_decode($local_ref);
2207 my $rs = {
2208 t => $t,
2209 remote => $remote,
2210 path => Git::SVN::GlobSpec->new($local_ref, 1),
2211 ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
2212 if (length($rs->{ref}->{right}) != 0) {
2213 die "The '*' glob character must be the last ",
2214 "character of '$remote_ref'\n";
2215 }
2216 push @{ $r->{$remote}->{$t} }, $rs;
2217 }
2218 }
2220 map {
2221 if (defined $r->{$_}->{svm}) {
2222 my $svm;
2223 eval {
2224 my $section = "svn-remote.$_";
2225 $svm = {
2226 source => tmp_config('--get',
2227 "$section.svm-source"),
2228 replace => tmp_config('--get',
2229 "$section.svm-replace"),
2230 }
2231 };
2232 $r->{$_}->{svm} = $svm;
2233 }
2234 } keys %$r;
2236 foreach my $remote (keys %$r) {
2237 foreach ( grep { defined $_ }
2238 map { $r->{$remote}->{$_} } qw(branches tags) ) {
2239 foreach my $rs ( @$_ ) {
2240 $rs->{ignore_refs_regex} =
2241 $r->{$remote}->{ignore_refs_regex};
2242 }
2243 }
2244 }
2246 $r;
2247 }
2249 sub init_vars {
2250 $_gc_nr = $_gc_period = 1000;
2251 if (defined $_repack || defined $_repack_flags) {
2252 warn "Repack options are obsolete; they have no effect.\n";
2253 }
2254 }
2256 sub verify_remotes_sanity {
2257 return unless -d $ENV{GIT_DIR};
2258 my %seen;
2259 foreach (command(qw/config -l/)) {
2260 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
2261 if ($seen{$1}) {
2262 die "Remote ref refs/remote/$1 is tracked by",
2263 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
2264 "Please resolve this ambiguity in ",
2265 "your git configuration file before ",
2266 "continuing\n";
2267 }
2268 $seen{$1} = $_;
2269 }
2270 }
2271 }
2273 sub find_existing_remote {
2274 my ($url, $remotes) = @_;
2275 return undef if $no_reuse_existing;
2276 my $existing;
2277 foreach my $repo_id (keys %$remotes) {
2278 my $u = $remotes->{$repo_id}->{url} or next;
2279 next if $u ne $url;
2280 $existing = $repo_id;
2281 last;
2282 }
2283 $existing;
2284 }
2286 sub init_remote_config {
2287 my ($self, $url, $no_write) = @_;
2288 $url =~ s!/+$!!; # strip trailing slash
2289 my $r = read_all_remotes();
2290 my $existing = find_existing_remote($url, $r);
2291 if ($existing) {
2292 unless ($no_write) {
2293 print STDERR "Using existing ",
2294 "[svn-remote \"$existing\"]\n";
2295 }
2296 $self->{repo_id} = $existing;
2297 } elsif ($_minimize_url) {
2298 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
2299 $existing = find_existing_remote($min_url, $r);
2300 if ($existing) {
2301 unless ($no_write) {
2302 print STDERR "Using existing ",
2303 "[svn-remote \"$existing\"]\n";
2304 }
2305 $self->{repo_id} = $existing;
2306 }
2307 if ($min_url ne $url) {
2308 unless ($no_write) {
2309 print STDERR "Using higher level of URL: ",
2310 "$url => $min_url\n";
2311 }
2312 my $old_path = $self->{path};
2313 $self->{path} = $url;
2314 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
2315 if (length $old_path) {
2316 $self->{path} .= "/$old_path";
2317 }
2318 $url = $min_url;
2319 }
2320 }
2321 my $orig_url;
2322 if (!$existing) {
2323 # verify that we aren't overwriting anything:
2324 $orig_url = eval {
2325 command_oneline('config', '--get',
2326 "svn-remote.$self->{repo_id}.url")
2327 };
2328 if ($orig_url && ($orig_url ne $url)) {
2329 die "svn-remote.$self->{repo_id}.url already set: ",
2330 "$orig_url\nwanted to set to: $url\n";
2331 }
2332 }
2333 my ($xrepo_id, $xpath) = find_ref($self->refname);
2334 if (!$no_write && defined $xpath) {
2335 die "svn-remote.$xrepo_id.fetch already set to track ",
2336 "$xpath:", $self->refname, "\n";
2337 }
2338 unless ($no_write) {
2339 command_noisy('config',
2340 "svn-remote.$self->{repo_id}.url", $url);
2341 $self->{path} =~ s{^/}{};
2342 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
2343 command_noisy('config', '--add',
2344 "svn-remote.$self->{repo_id}.fetch",
2345 "$self->{path}:".$self->refname);
2346 }
2347 $self->{url} = $url;
2348 }
2350 sub find_by_url { # repos_root and, path are optional
2351 my ($class, $full_url, $repos_root, $path) = @_;
2353 return undef unless defined $full_url;
2354 remove_username($full_url);
2355 remove_username($repos_root) if defined $repos_root;
2356 my $remotes = read_all_remotes();
2357 if (defined $full_url && defined $repos_root && !defined $path) {
2358 $path = $full_url;
2359 $path =~ s#^\Q$repos_root\E(?:/|$)##;
2360 }
2361 foreach my $repo_id (keys %$remotes) {
2362 my $u = $remotes->{$repo_id}->{url} or next;
2363 remove_username($u);
2364 next if defined $repos_root && $repos_root ne $u;
2366 my $fetch = $remotes->{$repo_id}->{fetch} || {};
2367 foreach my $t (qw/branches tags/) {
2368 foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
2369 resolve_local_globs($u, $fetch, $globspec);
2370 }
2371 }
2372 my $p = $path;
2373 my $rwr = rewrite_root({repo_id => $repo_id});
2374 my $svm = $remotes->{$repo_id}->{svm}
2375 if defined $remotes->{$repo_id}->{svm};
2376 unless (defined $p) {
2377 $p = $full_url;
2378 my $z = $u;
2379 my $prefix = '';
2380 if ($rwr) {
2381 $z = $rwr;
2382 remove_username($z);
2383 } elsif (defined $svm) {
2384 $z = $svm->{source};
2385 $prefix = $svm->{replace};
2386 $prefix =~ s#^\Q$u\E(?:/|$)##;
2387 $prefix =~ s#/$##;
2388 }
2389 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2390 }
2391 foreach my $f (keys %$fetch) {
2392 next if $f ne $p;
2393 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2394 }
2395 }
2396 undef;
2397 }
2399 sub init {
2400 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2401 my $self = _new($class, $repo_id, $ref_id, $path);
2402 if (defined $url) {
2403 $self->init_remote_config($url, $no_write);
2404 }
2405 $self;
2406 }
2408 sub find_ref {
2409 my ($ref_id) = @_;
2410 foreach (command(qw/config -l/)) {
2411 next unless m!^svn-remote\.(.+)\.fetch=
2412 \s*(.*?)\s*:\s*(.+?)\s*$!x;
2413 my ($repo_id, $path, $ref) = ($1, $2, $3);
2414 if ($ref eq $ref_id) {
2415 $path = '' if ($path =~ m#^\./?#);
2416 return ($repo_id, $path);
2417 }
2418 }
2419 (undef, undef, undef);
2420 }
2422 sub new {
2423 my ($class, $ref_id, $repo_id, $path) = @_;
2424 if (defined $ref_id && !defined $repo_id && !defined $path) {
2425 ($repo_id, $path) = find_ref($ref_id);
2426 if (!defined $repo_id) {
2427 die "Could not find a \"svn-remote.*.fetch\" key ",
2428 "in the repository configuration matching: ",
2429 "$ref_id\n";
2430 }
2431 }
2432 my $self = _new($class, $repo_id, $ref_id, $path);
2433 if (!defined $self->{path} || !length $self->{path}) {
2434 my $fetch = command_oneline('config', '--get',
2435 "svn-remote.$repo_id.fetch",
2436 ":$ref_id\$") or
2437 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2438 "\":$ref_id\$\" in config\n";
2439 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2440 }
2441 $self->{path} =~ s{/+}{/}g;
2442 $self->{path} =~ s{\A/}{};
2443 $self->{path} =~ s{/\z}{};
2444 $self->{url} = command_oneline('config', '--get',
2445 "svn-remote.$repo_id.url") or
2446 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2447 $self->{pushurl} = eval { command_oneline('config', '--get',
2448 "svn-remote.$repo_id.pushurl") };
2449 $self->rebuild;
2450 $self;
2451 }
2453 sub refname {
2454 my ($refname) = $_[0]->{ref_id} ;
2456 # It cannot end with a slash /, we'll throw up on this because
2457 # SVN can't have directories with a slash in their name, either:
2458 if ($refname =~ m{/$}) {
2459 die "ref: '$refname' ends with a trailing slash, this is ",
2460 "not permitted by git nor Subversion\n";
2461 }
2463 # It cannot have ASCII control character space, tilde ~, caret ^,
2464 # colon :, question-mark ?, asterisk *, space, or open bracket [
2465 # anywhere.
2466 #
2467 # Additionally, % must be escaped because it is used for escaping
2468 # and we want our escaped refname to be reversible
2469 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2471 # no slash-separated component can begin with a dot .
2472 # /.* becomes /%2E*
2473 $refname =~ s{/\.}{/%2E}g;
2475 # It cannot have two consecutive dots .. anywhere
2476 # .. becomes %2E%2E
2477 $refname =~ s{\.\.}{%2E%2E}g;
2479 # trailing dots and .lock are not allowed
2480 # .$ becomes %2E and .lock becomes %2Elock
2481 $refname =~ s{\.(?=$|lock$)}{%2E};
2483 # the sequence @{ is used to access the reflog
2484 # @{ becomes %40{
2485 $refname =~ s{\@\{}{%40\{}g;
2487 return $refname;
2488 }
2490 sub desanitize_refname {
2491 my ($refname) = @_;
2492 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2493 return $refname;
2494 }
2496 sub svm_uuid {
2497 my ($self) = @_;
2498 return $self->{svm}->{uuid} if $self->svm;
2499 $self->ra;
2500 unless ($self->{svm}) {
2501 die "SVM UUID not cached, and reading remotely failed\n";
2502 }
2503 $self->{svm}->{uuid};
2504 }
2506 sub svm {
2507 my ($self) = @_;
2508 return $self->{svm} if $self->{svm};
2509 my $svm;
2510 # see if we have it in our config, first:
2511 eval {
2512 my $section = "svn-remote.$self->{repo_id}";
2513 $svm = {
2514 source => tmp_config('--get', "$section.svm-source"),
2515 uuid => tmp_config('--get', "$section.svm-uuid"),
2516 replace => tmp_config('--get', "$section.svm-replace"),
2517 }
2518 };
2519 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2520 $self->{svm} = $svm;
2521 }
2522 $self->{svm};
2523 }
2525 sub _set_svm_vars {
2526 my ($self, $ra) = @_;
2527 return $ra if $self->svm;
2529 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2530 "(svm:source, svm:uuid) ",
2531 "from the following URLs:\n" );
2532 sub read_svm_props {
2533 my ($self, $ra, $path, $r) = @_;
2534 my $props = ($ra->get_dir($path, $r))[2];
2535 my $src = $props->{'svm:source'};
2536 my $uuid = $props->{'svm:uuid'};
2537 return undef if (!$src || !$uuid);
2539 chomp($src, $uuid);
2541 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2542 or die "doesn't look right - svm:uuid is '$uuid'\n";
2544 # the '!' is used to mark the repos_root!/relative/path
2545 $src =~ s{/?!/?}{/};
2546 $src =~ s{/+$}{}; # no trailing slashes please
2547 # username is of no interest
2548 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2550 my $replace = $ra->{url};
2551 $replace .= "/$path" if length $path;
2553 my $section = "svn-remote.$self->{repo_id}";
2554 tmp_config("$section.svm-source", $src);
2555 tmp_config("$section.svm-replace", $replace);
2556 tmp_config("$section.svm-uuid", $uuid);
2557 $self->{svm} = {
2558 source => $src,
2559 uuid => $uuid,
2560 replace => $replace
2561 };
2562 }
2564 my $r = $ra->get_latest_revnum;
2565 my $path = $self->{path};
2566 my %tried;
2567 while (length $path) {
2568 unless ($tried{"$self->{url}/$path"}) {
2569 return $ra if $self->read_svm_props($ra, $path, $r);
2570 $tried{"$self->{url}/$path"} = 1;
2571 }
2572 $path =~ s#/?[^/]+$##;
2573 }
2574 die "Path: '$path' should be ''\n" if $path ne '';
2575 return $ra if $self->read_svm_props($ra, $path, $r);
2576 $tried{"$self->{url}/$path"} = 1;
2578 if ($ra->{repos_root} eq $self->{url}) {
2579 die @err, (map { " $_\n" } keys %tried), "\n";
2580 }
2582 # nope, make sure we're connected to the repository root:
2583 my $ok;
2584 my @tried_b;
2585 $path = $ra->{svn_path};
2586 $ra = Git::SVN::Ra->new($ra->{repos_root});
2587 while (length $path) {
2588 unless ($tried{"$ra->{url}/$path"}) {
2589 $ok = $self->read_svm_props($ra, $path, $r);
2590 last if $ok;
2591 $tried{"$ra->{url}/$path"} = 1;
2592 }
2593 $path =~ s#/?[^/]+$##;
2594 }
2595 die "Path: '$path' should be ''\n" if $path ne '';
2596 $ok ||= $self->read_svm_props($ra, $path, $r);
2597 $tried{"$ra->{url}/$path"} = 1;
2598 if (!$ok) {
2599 die @err, (map { " $_\n" } keys %tried), "\n";
2600 }
2601 Git::SVN::Ra->new($self->{url});
2602 }
2604 sub svnsync {
2605 my ($self) = @_;
2606 return $self->{svnsync} if $self->{svnsync};
2608 if ($self->no_metadata) {
2609 die "Can't have both 'noMetadata' and ",
2610 "'useSvnsyncProps' options set!\n";
2611 }
2612 if ($self->rewrite_root) {
2613 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2614 "options set!\n";
2615 }
2616 if ($self->rewrite_uuid) {
2617 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2618 "options set!\n";
2619 }
2621 my $svnsync;
2622 # see if we have it in our config, first:
2623 eval {
2624 my $section = "svn-remote.$self->{repo_id}";
2626 my $url = tmp_config('--get', "$section.svnsync-url");
2627 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2628 die "doesn't look right - svn:sync-from-url is '$url'\n";
2630 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2631 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2632 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2634 $svnsync = { url => $url, uuid => $uuid }
2635 };
2636 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2637 return $self->{svnsync} = $svnsync;
2638 }
2640 my $err = "useSvnsyncProps set, but failed to read " .
2641 "svnsync property: svn:sync-from-";
2642 my $rp = $self->ra->rev_proplist(0);
2644 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2645 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2646 die "doesn't look right - svn:sync-from-url is '$url'\n";
2648 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2649 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2650 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2652 my $section = "svn-remote.$self->{repo_id}";
2653 tmp_config('--add', "$section.svnsync-uuid", $uuid);
2654 tmp_config('--add', "$section.svnsync-url", $url);
2655 return $self->{svnsync} = { url => $url, uuid => $uuid };
2656 }
2658 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2659 # remote lookup (useful for 'git svn log').
2660 sub ra_uuid {
2661 my ($self) = @_;
2662 unless ($self->{ra_uuid}) {
2663 my $key = "svn-remote.$self->{repo_id}.uuid";
2664 my $uuid = eval { tmp_config('--get', $key) };
2665 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2666 $self->{ra_uuid} = $uuid;
2667 } else {
2668 die "ra_uuid called without URL\n" unless $self->{url};
2669 $self->{ra_uuid} = $self->ra->get_uuid;
2670 tmp_config('--add', $key, $self->{ra_uuid});
2671 }
2672 }
2673 $self->{ra_uuid};
2674 }
2676 sub _set_repos_root {
2677 my ($self, $repos_root) = @_;
2678 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2679 $repos_root ||= $self->ra->{repos_root};
2680 tmp_config($k, $repos_root);
2681 $repos_root;
2682 }
2684 sub repos_root {
2685 my ($self) = @_;
2686 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2687 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2688 }
2690 sub ra {
2691 my ($self) = shift;
2692 my $ra = Git::SVN::Ra->new($self->{url});
2693 $self->_set_repos_root($ra->{repos_root});
2694 if ($self->use_svm_props && !$self->{svm}) {
2695 if ($self->no_metadata) {
2696 die "Can't have both 'noMetadata' and ",
2697 "'useSvmProps' options set!\n";
2698 } elsif ($self->use_svnsync_props) {
2699 die "Can't have both 'useSvnsyncProps' and ",
2700 "'useSvmProps' options set!\n";
2701 }
2702 $ra = $self->_set_svm_vars($ra);
2703 $self->{-want_revprops} = 1;
2704 }
2705 $ra;
2706 }
2708 # prop_walk(PATH, REV, SUB)
2709 # -------------------------
2710 # Recursively traverse PATH at revision REV and invoke SUB for each
2711 # directory that contains a SVN property. SUB will be invoked as
2712 # follows: &SUB(gs, path, props); where `gs' is this instance of
2713 # Git::SVN, `path' the path to the directory where the properties
2714 # `props' were found. The `path' will be relative to point of checkout,
2715 # that is, if url://repo/trunk is the current Git branch, and that
2716 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2717 # as `path' (note the trailing `/').
2718 sub prop_walk {
2719 my ($self, $path, $rev, $sub) = @_;
2721 $path =~ s#^/##;
2722 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2723 $path =~ s#^/*#/#g;
2724 my $p = $path;
2725 # Strip the irrelevant part of the path.
2726 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2727 # Ensure the path is terminated by a `/'.
2728 $p =~ s#/*$#/#;
2730 # The properties contain all the internal SVN stuff nobody
2731 # (usually) cares about.
2732 my $interesting_props = 0;
2733 foreach (keys %{$props}) {
2734 # If it doesn't start with `svn:', it must be a
2735 # user-defined property.
2736 ++$interesting_props and next if $_ !~ /^svn:/;
2737 # FIXME: Fragile, if SVN adds new public properties,
2738 # this needs to be updated.
2739 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2740 |eol-style|mime-type
2741 |externals|needs-lock)$/x;
2742 }
2743 &$sub($self, $p, $props) if $interesting_props;
2745 foreach (sort keys %$dirent) {
2746 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2747 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2748 }
2749 }
2751 sub last_rev { ($_[0]->last_rev_commit)[0] }
2752 sub last_commit { ($_[0]->last_rev_commit)[1] }
2754 # returns the newest SVN revision number and newest commit SHA1
2755 sub last_rev_commit {
2756 my ($self) = @_;
2757 if (defined $self->{last_rev} && defined $self->{last_commit}) {
2758 return ($self->{last_rev}, $self->{last_commit});
2759 }
2760 my $c = ::verify_ref($self->refname.'^0');
2761 if ($c && !$self->use_svm_props && !$self->no_metadata) {
2762 my $rev = (::cmt_metadata($c))[1];
2763 if (defined $rev) {
2764 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2765 return ($rev, $c);
2766 }
2767 }
2768 my $map_path = $self->map_path;
2769 unless (-e $map_path) {
2770 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2771 return (undef, undef);
2772 }
2773 my ($rev, $commit) = $self->rev_map_max(1);
2774 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2775 return ($rev, $commit);
2776 }
2778 sub get_fetch_range {
2779 my ($self, $min, $max) = @_;
2780 $max ||= $self->ra->get_latest_revnum;
2781 $min ||= $self->rev_map_max;
2782 (++$min, $max);
2783 }
2785 sub tmp_config {
2786 my (@args) = @_;
2787 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2788 my $config = "$ENV{GIT_DIR}/svn/.metadata";
2789 if (! -f $config && -f $old_def_config) {
2790 rename $old_def_config, $config or
2791 die "Failed rename $old_def_config => $config: $!\n";
2792 }
2793 my $old_config = $ENV{GIT_CONFIG};
2794 $ENV{GIT_CONFIG} = $config;
2795 $@ = undef;
2796 my @ret = eval {
2797 unless (-f $config) {
2798 mkfile($config);
2799 open my $fh, '>', $config or
2800 die "Can't open $config: $!\n";
2801 print $fh "; This file is used internally by ",
2802 "git-svn\n" or die
2803 "Couldn't write to $config: $!\n";
2804 print $fh "; You should not have to edit it\n" or
2805 die "Couldn't write to $config: $!\n";
2806 close $fh or die "Couldn't close $config: $!\n";
2807 }
2808 command('config', @args);
2809 };
2810 my $err = $@;
2811 if (defined $old_config) {
2812 $ENV{GIT_CONFIG} = $old_config;
2813 } else {
2814 delete $ENV{GIT_CONFIG};
2815 }
2816 die $err if $err;
2817 wantarray ? @ret : $ret[0];
2818 }
2820 sub tmp_index_do {
2821 my ($self, $sub) = @_;
2822 my $old_index = $ENV{GIT_INDEX_FILE};
2823 $ENV{GIT_INDEX_FILE} = $self->{index};
2824 $@ = undef;
2825 my @ret = eval {
2826 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2827 mkpath([$dir]) unless -d $dir;
2828 &$sub;
2829 };
2830 my $err = $@;
2831 if (defined $old_index) {
2832 $ENV{GIT_INDEX_FILE} = $old_index;
2833 } else {
2834 delete $ENV{GIT_INDEX_FILE};
2835 }
2836 die $err if $err;
2837 wantarray ? @ret : $ret[0];
2838 }
2840 sub assert_index_clean {
2841 my ($self, $treeish) = @_;
2843 $self->tmp_index_do(sub {
2844 command_noisy('read-tree', $treeish) unless -e $self->{index};
2845 my $x = command_oneline('write-tree');
2846 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2847 /^tree ($::sha1)/mo);
2848 return if $y eq $x;
2850 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2851 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2852 command_noisy('read-tree', $treeish);
2853 $x = command_oneline('write-tree');
2854 if ($y ne $x) {
2855 ::fatal "trees ($treeish) $y != $x\n",
2856 "Something is seriously wrong...";
2857 }
2858 });
2859 }
2861 sub get_commit_parents {
2862 my ($self, $log_entry) = @_;
2863 my (%seen, @ret, @tmp);
2864 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2865 if (my $ip = $self->{inject_parents}) {
2866 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2867 push @tmp, $commit;
2868 }
2869 }
2870 if (my $cur = ::verify_ref($self->refname.'^0')) {
2871 push @tmp, $cur;
2872 }
2873 if (my $ipd = $self->{inject_parents_dcommit}) {
2874 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2875 push @tmp, @$commit;
2876 }
2877 }
2878 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2879 while (my $p = shift @tmp) {
2880 next if $seen{$p};
2881 $seen{$p} = 1;
2882 push @ret, $p;
2883 }
2884 @ret;
2885 }
2887 sub rewrite_root {
2888 my ($self) = @_;
2889 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2890 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2891 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2892 if ($rwr) {
2893 $rwr =~ s#/+$##;
2894 if ($rwr !~ m#^[a-z\+]+://#) {
2895 die "$rwr is not a valid URL (key: $k)\n";
2896 }
2897 }
2898 $self->{-rewrite_root} = $rwr;
2899 }
2901 sub rewrite_uuid {
2902 my ($self) = @_;
2903 return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2904 my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2905 my $rwid = eval { command_oneline(qw/config --get/, $k) };
2906 if ($rwid) {
2907 $rwid =~ s#/+$##;
2908 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2909 die "$rwid is not a valid UUID (key: $k)\n";
2910 }
2911 }
2912 $self->{-rewrite_uuid} = $rwid;
2913 }
2915 sub metadata_url {
2916 my ($self) = @_;
2917 ($self->rewrite_root || $self->{url}) .
2918 (length $self->{path} ? '/' . $self->{path} : '');
2919 }
2921 sub full_url {
2922 my ($self) = @_;
2923 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2924 }
2926 sub full_pushurl {
2927 my ($self) = @_;
2928 if ($self->{pushurl}) {
2929 return $self->{pushurl} . (length $self->{path} ? '/' .
2930 $self->{path} : '');
2931 } else {
2932 return $self->full_url;
2933 }
2934 }
2936 sub set_commit_header_env {
2937 my ($log_entry) = @_;
2938 my %env;
2939 foreach my $ned (qw/NAME EMAIL DATE/) {
2940 foreach my $ac (qw/AUTHOR COMMITTER/) {
2941 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2942 }
2943 }
2945 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2946 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2947 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2949 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2950 ? $log_entry->{commit_name}
2951 : $log_entry->{name};
2952 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2953 ? $log_entry->{commit_email}
2954 : $log_entry->{email};
2955 \%env;
2956 }
2958 sub restore_commit_header_env {
2959 my ($env) = @_;
2960 foreach my $ned (qw/NAME EMAIL DATE/) {
2961 foreach my $ac (qw/AUTHOR COMMITTER/) {
2962 my $k = "GIT_${ac}_${ned}";
2963 if (defined $env->{$k}) {
2964 $ENV{$k} = $env->{$k};
2965 } else {
2966 delete $ENV{$k};
2967 }
2968 }
2969 }
2970 }
2972 sub gc {
2973 command_noisy('gc', '--auto');
2974 };
2976 sub do_git_commit {
2977 my ($self, $log_entry) = @_;
2978 my $lr = $self->last_rev;
2979 if (defined $lr && $lr >= $log_entry->{revision}) {
2980 die "Last fetched revision of ", $self->refname,
2981 " was r$lr, but we are about to fetch: ",
2982 "r$log_entry->{revision}!\n";
2983 }
2984 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2985 croak "$log_entry->{revision} = $c already exists! ",
2986 "Why are we refetching it?\n";
2987 }
2988 my $old_env = set_commit_header_env($log_entry);
2989 my $tree = $log_entry->{tree};
2990 if (!defined $tree) {
2991 $tree = $self->tmp_index_do(sub {
2992 command_oneline('write-tree') });
2993 }
2994 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2996 my @exec = ('git', 'commit-tree', $tree);
2997 foreach ($self->get_commit_parents($log_entry)) {
2998 push @exec, '-p', $_;
2999 }
3000 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
3001 or croak $!;
3002 binmode $msg_fh;
3004 # we always get UTF-8 from SVN, but we may want our commits in
3005 # a different encoding.
3006 if (my $enc = Git::config('i18n.commitencoding')) {
3007 require Encode;
3008 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
3009 }
3010 print $msg_fh $log_entry->{log} or croak $!;
3011 restore_commit_header_env($old_env);
3012 unless ($self->no_metadata) {
3013 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
3014 or croak $!;
3015 }
3016 $msg_fh->flush == 0 or croak $!;
3017 close $msg_fh or croak $!;
3018 chomp(my $commit = do { local $/; <$out_fh> });
3019 close $out_fh or croak $!;
3020 waitpid $pid, 0;
3021 croak $? if $?;
3022 if ($commit !~ /^$::sha1$/o) {
3023 die "Failed to commit, invalid sha1: $commit\n";
3024 }
3026 $self->rev_map_set($log_entry->{revision}, $commit, 1);
3028 $self->{last_rev} = $log_entry->{revision};
3029 $self->{last_commit} = $commit;
3030 print "r$log_entry->{revision}" unless $::_q > 1;
3031 if (defined $log_entry->{svm_revision}) {
3032 print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
3033 $self->rev_map_set($log_entry->{svm_revision}, $commit,
3034 0, $self->svm_uuid);
3035 }
3036 print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
3037 if (--$_gc_nr == 0) {
3038 $_gc_nr = $_gc_period;
3039 gc();
3040 }
3041 return $commit;
3042 }
3044 sub match_paths {
3045 my ($self, $paths, $r) = @_;
3046 return 1 if $self->{path} eq '';
3047 if (my $path = $paths->{"/$self->{path}"}) {
3048 return ($path->{action} eq 'D') ? 0 : 1;
3049 }
3050 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
3051 if (grep /$self->{path_regex}/, keys %$paths) {
3052 return 1;
3053 }
3054 my $c = '';
3055 foreach (split m#/#, $self->{path}) {
3056 $c .= "/$_";
3057 next unless ($paths->{$c} &&
3058 ($paths->{$c}->{action} =~ /^[AR]$/));
3059 if ($self->ra->check_path($self->{path}, $r) ==
3060 $SVN::Node::dir) {
3061 return 1;
3062 }
3063 }
3064 return 0;
3065 }
3067 sub find_parent_branch {
3068 my ($self, $paths, $rev) = @_;
3069 return undef unless $self->follow_parent;
3070 unless (defined $paths) {
3071 my $err_handler = $SVN::Error::handler;
3072 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
3073 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
3074 sub { $paths = $_[0] });
3075 $SVN::Error::handler = $err_handler;
3076 }
3077 return undef unless defined $paths;
3079 # look for a parent from another branch:
3080 my @b_path_components = split m#/#, $self->{path};
3081 my @a_path_components;
3082 my $i;
3083 while (@b_path_components) {
3084 $i = $paths->{'/'.join('/', @b_path_components)};
3085 last if $i && defined $i->{copyfrom_path};
3086 unshift(@a_path_components, pop(@b_path_components));
3087 }
3088 return undef unless defined $i && defined $i->{copyfrom_path};
3089 my $branch_from = $i->{copyfrom_path};
3090 if (@a_path_components) {
3091 print STDERR "branch_from: $branch_from => ";
3092 $branch_from .= '/'.join('/', @a_path_components);
3093 print STDERR $branch_from, "\n";
3094 }
3095 my $r = $i->{copyfrom_rev};
3096 my $repos_root = $self->ra->{repos_root};
3097 my $url = $self->ra->{url};
3098 my $new_url = $url . $branch_from;
3099 print STDERR "Found possible branch point: ",
3100 "$new_url => ", $self->full_url, ", $r\n"
3101 unless $::_q > 1;
3102 $branch_from =~ s#^/##;
3103 my $gs = $self->other_gs($new_url, $url,
3104 $branch_from, $r, $self->{ref_id});
3105 my ($r0, $parent) = $gs->find_rev_before($r, 1);
3106 {
3107 my ($base, $head);
3108 if (!defined $r0 || !defined $parent) {
3109 ($base, $head) = parse_revision_argument(0, $r);
3110 } else {
3111 if ($r0 < $r) {
3112 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
3113 0, 1, sub { $base = $_[1] - 1 });
3114 }
3115 }
3116 if (defined $base && $base <= $r) {
3117 $gs->fetch($base, $r);
3118 }
3119 ($r0, $parent) = $gs->find_rev_before($r, 1);
3120 }
3121 if (defined $r0 && defined $parent) {
3122 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
3123 unless $::_q > 1;
3124 my $ed;
3125 if ($self->ra->can_do_switch) {
3126 $self->assert_index_clean($parent);
3127 print STDERR "Following parent with do_switch\n"
3128 unless $::_q > 1;
3129 # do_switch works with svn/trunk >= r22312, but that
3130 # is not included with SVN 1.4.3 (the latest version
3131 # at the moment), so we can't rely on it
3132 $self->{last_rev} = $r0;
3133 $self->{last_commit} = $parent;
3134 $ed = SVN::Git::Fetcher->new($self, $gs->{path});
3135 $gs->ra->gs_do_switch($r0, $rev, $gs,
3136 $self->full_url, $ed)
3137 or die "SVN connection failed somewhere...\n";
3138 } elsif ($self->ra->trees_match($new_url, $r0,
3139 $self->full_url, $rev)) {
3140 print STDERR "Trees match:\n",
3141 " $new_url\@$r0\n",
3142 " ${\$self->full_url}\@$rev\n",
3143 "Following parent with no changes\n"
3144 unless $::_q > 1;
3145 $self->tmp_index_do(sub {
3146 command_noisy('read-tree', $parent);
3147 });
3148 $self->{last_commit} = $parent;
3149 } else {
3150 print STDERR "Following parent with do_update\n"
3151 unless $::_q > 1;
3152 $ed = SVN::Git::Fetcher->new($self);
3153 $self->ra->gs_do_update($rev, $rev, $self, $ed)
3154 or die "SVN connection failed somewhere...\n";
3155 }
3156 print STDERR "Successfully followed parent\n" unless $::_q > 1;
3157 return $self->make_log_entry($rev, [$parent], $ed);
3158 }
3159 return undef;
3160 }
3162 sub do_fetch {
3163 my ($self, $paths, $rev) = @_;
3164 my $ed;
3165 my ($last_rev, @parents);
3166 if (my $lc = $self->last_commit) {
3167 # we can have a branch that was deleted, then re-added
3168 # under the same name but copied from another path, in
3169 # which case we'll have multiple parents (we don't
3170 # want to break the original ref, nor lose copypath info):
3171 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
3172 push @{$log_entry->{parents}}, $lc;
3173 return $log_entry;
3174 }
3175 $ed = SVN::Git::Fetcher->new($self);
3176 $last_rev = $self->{last_rev};
3177 $ed->{c} = $lc;
3178 @parents = ($lc);
3179 } else {
3180 $last_rev = $rev;
3181 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
3182 return $log_entry;
3183 }
3184 $ed = SVN::Git::Fetcher->new($self);
3185 }
3186 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
3187 die "SVN connection failed somewhere...\n";
3188 }
3189 $self->make_log_entry($rev, \@parents, $ed);
3190 }
3192 sub mkemptydirs {
3193 my ($self, $r) = @_;
3195 sub scan {
3196 my ($r, $empty_dirs, $line) = @_;
3197 if (defined $r && $line =~ /^r(\d+)$/) {
3198 return 0 if $1 > $r;
3199 } elsif ($line =~ /^ \+empty_dir: (.+)$/) {
3200 $empty_dirs->{$1} = 1;
3201 } elsif ($line =~ /^ \-empty_dir: (.+)$/) {
3202 my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
3203 delete @$empty_dirs{@d};
3204 }
3205 1; # continue
3206 };
3208 my %empty_dirs = ();
3209 my $gz_file = "$self->{dir}/unhandled.log.gz";
3210 if (-f $gz_file) {
3211 if (!$can_compress) {
3212 warn "Compress::Zlib could not be found; ",
3213 "empty directories in $gz_file will not be read\n";
3214 } else {
3215 my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
3216 die "Unable to open $gz_file: $!\n";
3217 my $line;
3218 while ($gz->gzreadline($line) > 0) {
3219 scan($r, \%empty_dirs, $line) or last;
3220 }
3221 $gz->gzclose;
3222 }
3223 }
3225 if (open my $fh, '<', "$self->{dir}/unhandled.log") {
3226 binmode $fh or croak "binmode: $!";
3227 while (<$fh>) {
3228 scan($r, \%empty_dirs, $_) or last;
3229 }
3230 close $fh;
3231 }
3233 my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
3234 foreach my $d (sort keys %empty_dirs) {
3235 $d = uri_decode($d);
3236 $d =~ s/$strip//;
3237 next unless length($d);
3238 next if -d $d;
3239 if (-e $d) {
3240 warn "$d exists but is not a directory\n";
3241 } else {
3242 print "creating empty directory: $d\n";
3243 mkpath([$d]);
3244 }
3245 }
3246 }
3248 sub get_untracked {
3249 my ($self, $ed) = @_;
3250 my @out;
3251 my $h = $ed->{empty};
3252 foreach (sort keys %$h) {
3253 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
3254 push @out, " $act: " . uri_encode($_);
3255 warn "W: $act: $_\n";
3256 }
3257 foreach my $t (qw/dir_prop file_prop/) {
3258 $h = $ed->{$t} or next;
3259 foreach my $path (sort keys %$h) {
3260 my $ppath = $path eq '' ? '.' : $path;
3261 foreach my $prop (sort keys %{$h->{$path}}) {
3262 next if $SKIP_PROP{$prop};
3263 my $v = $h->{$path}->{$prop};
3264 my $t_ppath_prop = "$t: " .
3265 uri_encode($ppath) . ' ' .
3266 uri_encode($prop);
3267 if (defined $v) {
3268 push @out, " +$t_ppath_prop " .
3269 uri_encode($v);
3270 } else {
3271 push @out, " -$t_ppath_prop";
3272 }
3273 }
3274 }
3275 }
3276 foreach my $t (qw/absent_file absent_directory/) {
3277 $h = $ed->{$t} or next;
3278 foreach my $parent (sort keys %$h) {
3279 foreach my $path (sort @{$h->{$parent}}) {
3280 push @out, " $t: " .
3281 uri_encode("$parent/$path");
3282 warn "W: $t: $parent/$path ",
3283 "Insufficient permissions?\n";
3284 }
3285 }
3286 }
3287 \@out;
3288 }
3290 # parse_svn_date(DATE)
3291 # --------------------
3292 # Given a date (in UTC) from Subversion, return a string in the format
3293 # "<TZ Offset> <local date/time>" that Git will use.
3294 #
3295 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
3296 # is true we'll convert it to the local timezone instead.
3297 sub parse_svn_date {
3298 my $date = shift || return '+0000 1970-01-01 00:00:00';
3299 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
3300 (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
3301 croak "Unable to parse date: $date\n";
3302 my $parsed_date; # Set next.
3304 if ($Git::SVN::_localtime) {
3305 # Translate the Subversion datetime to an epoch time.
3306 # Begin by switching ourselves to $date's timezone, UTC.
3307 my $old_env_TZ = $ENV{TZ};
3308 $ENV{TZ} = 'UTC';
3310 my $epoch_in_UTC =
3311 POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
3313 # Determine our local timezone (including DST) at the
3314 # time of $epoch_in_UTC. $Git::SVN::Log::TZ stored the
3315 # value of TZ, if any, at the time we were run.
3316 if (defined $Git::SVN::Log::TZ) {
3317 $ENV{TZ} = $Git::SVN::Log::TZ;
3318 } else {
3319 delete $ENV{TZ};
3320 }
3322 my $our_TZ =
3323 POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
3325 # This converts $epoch_in_UTC into our local timezone.
3326 my ($sec, $min, $hour, $mday, $mon, $year,
3327 $wday, $yday, $isdst) = localtime($epoch_in_UTC);
3329 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
3330 $our_TZ, $year + 1900, $mon + 1,
3331 $mday, $hour, $min, $sec);
3333 # Reset us to the timezone in effect when we entered
3334 # this routine.
3335 if (defined $old_env_TZ) {
3336 $ENV{TZ} = $old_env_TZ;
3337 } else {
3338 delete $ENV{TZ};
3339 }
3340 } else {
3341 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
3342 }
3344 return $parsed_date;
3345 }
3347 sub other_gs {
3348 my ($self, $new_url, $url,
3349 $branch_from, $r, $old_ref_id) = @_;
3350 my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
3351 unless ($gs) {
3352 my $ref_id = $old_ref_id;
3353 $ref_id =~ s/\@\d+-*$//;
3354 $ref_id .= "\@$r";
3355 # just grow a tail if we're not unique enough :x
3356 $ref_id .= '-' while find_ref($ref_id);
3357 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
3358 if ($u =~ s#^\Q$url\E(/|$)##) {
3359 $p = $u;
3360 $u = $url;
3361 $repo_id = $self->{repo_id};
3362 }
3363 while (1) {
3364 # It is possible to tag two different subdirectories at
3365 # the same revision. If the url for an existing ref
3366 # does not match, we must either find a ref with a
3367 # matching url or create a new ref by growing a tail.
3368 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
3369 my (undef, $max_commit) = $gs->rev_map_max(1);
3370 last if (!$max_commit);
3371 my ($url) = ::cmt_metadata($max_commit);
3372 last if ($url eq $gs->metadata_url);
3373 $ref_id .= '-';
3374 }
3375 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
3376 }
3377 $gs
3378 }
3380 sub call_authors_prog {
3381 my ($orig_author) = @_;
3382 $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
3383 my $author = `$::_authors_prog $orig_author`;
3384 if ($? != 0) {
3385 die "$::_authors_prog failed with exit code $?\n"
3386 }
3387 if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
3388 my ($name, $email) = ($1, $2);
3389 $email = undef if length $2 == 0;
3390 return [$name, $email];
3391 } else {
3392 die "Author: $orig_author: $::_authors_prog returned "
3393 . "invalid author format: $author\n";
3394 }
3395 }
3397 sub check_author {
3398 my ($author) = @_;
3399 if (!defined $author || length $author == 0) {
3400 $author = '(no author)';
3401 }
3402 if (!defined $::users{$author}) {
3403 if (defined $::_authors_prog) {
3404 $::users{$author} = call_authors_prog($author);
3405 } elsif (defined $::_authors) {
3406 die "Author: $author not defined in $::_authors file\n";
3407 }
3408 }
3409 $author;
3410 }
3412 sub find_extra_svk_parents {
3413 my ($self, $ed, $tickets, $parents) = @_;
3414 # aha! svk:merge property changed...
3415 my @tickets = split "\n", $tickets;
3416 my @known_parents;
3417 for my $ticket ( @tickets ) {
3418 my ($uuid, $path, $rev) = split /:/, $ticket;
3419 if ( $uuid eq $self->ra_uuid ) {
3420 my $url = $self->{url};
3421 my $repos_root = $url;
3422 my $branch_from = $path;
3423 $branch_from =~ s{^/}{};
3424 my $gs = $self->other_gs($repos_root."/".$branch_from,
3425 $url,
3426 $branch_from,
3427 $rev,
3428 $self->{ref_id});
3429 if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3430 # wahey! we found it, but it might be
3431 # an old one (!)
3432 push @known_parents, [ $rev, $commit ];
3433 }
3434 }
3435 }
3436 # Ordering matters; highest-numbered commit merge tickets
3437 # first, as they may account for later merge ticket additions
3438 # or changes.
3439 @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3440 for my $parent ( @known_parents ) {
3441 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3442 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3443 my $new;
3444 while ( <$msg_fh> ) {
3445 $new=1;last;
3446 }
3447 command_close_pipe($msg_fh, $ctx);
3448 if ( $new ) {
3449 print STDERR
3450 "Found merge parent (svk:merge ticket): $parent\n";
3451 push @$parents, $parent;
3452 }
3453 }
3454 }
3456 sub lookup_svn_merge {
3457 my $uuid = shift;
3458 my $url = shift;
3459 my $merge = shift;
3461 my ($source, $revs) = split ":", $merge;
3462 my $path = $source;
3463 $path =~ s{^/}{};
3464 my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3465 if ( !$gs ) {
3466 warn "Couldn't find revmap for $url$source\n";
3467 return;
3468 }
3469 my @ranges = split ",", $revs;
3470 my ($tip, $tip_commit);
3471 my @merged_commit_ranges;
3472 # find the tip
3473 for my $range ( @ranges ) {
3474 my ($bottom, $top) = split "-", $range;
3475 $top ||= $bottom;
3476 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3477 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3479 unless ($top_commit and $bottom_commit) {
3480 warn "W:unknown path/rev in svn:mergeinfo "
3481 ."dirprop: $source:$range\n";
3482 next;
3483 }
3485 if (scalar(command('rev-parse', "$bottom_commit^@"))) {
3486 push @merged_commit_ranges,
3487 "$bottom_commit^..$top_commit";
3488 } else {
3489 push @merged_commit_ranges, "$top_commit";
3490 }
3492 if ( !defined $tip or $top > $tip ) {
3493 $tip = $top;
3494 $tip_commit = $top_commit;
3495 }
3496 }
3497 return ($tip_commit, @merged_commit_ranges);
3498 }
3500 sub _rev_list {
3501 my ($msg_fh, $ctx) = command_output_pipe(
3502 "rev-list", @_,
3503 );
3504 my @rv;
3505 while ( <$msg_fh> ) {
3506 chomp;
3507 push @rv, $_;
3508 }
3509 command_close_pipe($msg_fh, $ctx);
3510 @rv;
3511 }
3513 sub check_cherry_pick {
3514 my $base = shift;
3515 my $tip = shift;
3516 my $parents = shift;
3517 my @ranges = @_;
3518 my %commits = map { $_ => 1 }
3519 _rev_list("--no-merges", $tip, "--not", $base, @$parents, "--");
3520 for my $range ( @ranges ) {
3521 delete @commits{_rev_list($range, "--")};
3522 }
3523 for my $commit (keys %commits) {
3524 if (has_no_changes($commit)) {
3525 delete $commits{$commit};
3526 }
3527 }
3528 return (keys %commits);
3529 }
3531 sub has_no_changes {
3532 my $commit = shift;
3534 my @revs = split / /, command_oneline(
3535 qw(rev-list --parents -1 -m), $commit);
3537 # Commits with no parents, e.g. the start of a partial branch,
3538 # have changes by definition.
3539 return 1 if (@revs < 2);
3541 # Commits with multiple parents, e.g a merge, have no changes
3542 # by definition.
3543 return 0 if (@revs > 2);
3545 return (command_oneline("rev-parse", "$commit^{tree}") eq
3546 command_oneline("rev-parse", "$commit~1^{tree}"));
3547 }
3549 # The GIT_DIR environment variable is not always set until after the command
3550 # line arguments are processed, so we can't memoize in a BEGIN block.
3551 {
3552 my $memoized = 0;
3554 sub memoize_svn_mergeinfo_functions {
3555 return if $memoized;
3556 $memoized = 1;
3558 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3559 mkpath([$cache_path]) unless -d $cache_path;
3561 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3562 "$cache_path/lookup_svn_merge.db", 'nstore';
3563 memoize 'lookup_svn_merge',
3564 SCALAR_CACHE => 'FAULT',
3565 LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3566 ;
3568 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3569 "$cache_path/check_cherry_pick.db", 'nstore';
3570 memoize 'check_cherry_pick',
3571 SCALAR_CACHE => 'FAULT',
3572 LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3573 ;
3575 tie my %has_no_changes_cache => 'Memoize::Storable',
3576 "$cache_path/has_no_changes.db", 'nstore';
3577 memoize 'has_no_changes',
3578 SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3579 LIST_CACHE => 'FAULT',
3580 ;
3581 }
3583 sub unmemoize_svn_mergeinfo_functions {
3584 return if not $memoized;
3585 $memoized = 0;
3587 Memoize::unmemoize 'lookup_svn_merge';
3588 Memoize::unmemoize 'check_cherry_pick';
3589 Memoize::unmemoize 'has_no_changes';
3590 }
3592 Memoize::memoize 'Git::SVN::repos_root';
3593 }
3595 END {
3596 # Force cache writeout explicitly instead of waiting for
3597 # global destruction to avoid segfault in Storable:
3598 # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3599 unmemoize_svn_mergeinfo_functions();
3600 }
3602 sub parents_exclude {
3603 my $parents = shift;
3604 my @commits = @_;
3605 return unless @commits;
3607 my @excluded;
3608 my $excluded;
3609 do {
3610 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3611 $excluded = command_oneline(@cmd);
3612 if ( $excluded ) {
3613 my @new;
3614 my $found;
3615 for my $commit ( @commits ) {
3616 if ( $commit eq $excluded ) {
3617 push @excluded, $commit;
3618 $found++;
3619 last;
3620 }
3621 else {
3622 push @new, $commit;
3623 }
3624 }
3625 die "saw commit '$excluded' in rev-list output, "
3626 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3627 unless $found;
3628 @commits = @new;
3629 }
3630 }
3631 while ($excluded and @commits);
3633 return @excluded;
3634 }
3637 # note: this function should only be called if the various dirprops
3638 # have actually changed
3639 sub find_extra_svn_parents {
3640 my ($self, $ed, $mergeinfo, $parents) = @_;
3641 # aha! svk:merge property changed...
3643 memoize_svn_mergeinfo_functions();
3645 # We first search for merged tips which are not in our
3646 # history. Then, we figure out which git revisions are in
3647 # that tip, but not this revision. If all of those revisions
3648 # are now marked as merge, we can add the tip as a parent.
3649 my @merges = split "\n", $mergeinfo;
3650 my @merge_tips;
3651 my $url = $self->{url};
3652 my $uuid = $self->ra_uuid;
3653 my %ranges;
3654 for my $merge ( @merges ) {
3655 my ($tip_commit, @ranges) =
3656 lookup_svn_merge( $uuid, $url, $merge );
3657 unless (!$tip_commit or
3658 grep { $_ eq $tip_commit } @$parents ) {
3659 push @merge_tips, $tip_commit;
3660 $ranges{$tip_commit} = \@ranges;
3661 } else {
3662 push @merge_tips, undef;
3663 }
3664 }
3666 my %excluded = map { $_ => 1 }
3667 parents_exclude($parents, grep { defined } @merge_tips);
3669 # check merge tips for new parents
3670 my @new_parents;
3671 for my $merge_tip ( @merge_tips ) {
3672 my $spec = shift @merges;
3673 next unless $merge_tip and $excluded{$merge_tip};
3675 my $ranges = $ranges{$merge_tip};
3677 # check out 'new' tips
3678 my $merge_base;
3679 eval {
3680 $merge_base = command_oneline(
3681 "merge-base",
3682 @$parents, $merge_tip,
3683 );
3684 };
3685 if ($@) {
3686 die "An error occurred during merge-base"
3687 unless $@->isa("Git::Error::Command");
3689 warn "W: Cannot find common ancestor between ".
3690 "@$parents and $merge_tip. Ignoring merge info.\n";
3691 next;
3692 }
3694 # double check that there are no missing non-merge commits
3695 my (@incomplete) = check_cherry_pick(
3696 $merge_base, $merge_tip,
3697 $parents,
3698 @$ranges,
3699 );
3701 if ( @incomplete ) {
3702 warn "W:svn cherry-pick ignored ($spec) - missing "
3703 .@incomplete." commit(s) (eg $incomplete[0])\n";
3704 } else {
3705 warn
3706 "Found merge parent (svn:mergeinfo prop): ",
3707 $merge_tip, "\n";
3708 push @new_parents, $merge_tip;
3709 }
3710 }
3712 # cater for merges which merge commits from multiple branches
3713 if ( @new_parents > 1 ) {
3714 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3715 for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3716 next if $i == $j;
3717 next unless $new_parents[$i];
3718 next unless $new_parents[$j];
3719 my $revs = command_oneline(
3720 "rev-list", "-1",
3721 "$new_parents[$i]..$new_parents[$j]",
3722 );
3723 if ( !$revs ) {
3724 undef($new_parents[$j]);
3725 }
3726 }
3727 }
3728 }
3729 push @$parents, grep { defined } @new_parents;
3730 }
3732 sub make_log_entry {
3733 my ($self, $rev, $parents, $ed) = @_;
3734 my $untracked = $self->get_untracked($ed);
3736 my @parents = @$parents;
3737 my $ps = $ed->{path_strip} || "";
3738 for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3739 my $props = $ed->{dir_prop}{$path};
3740 if ( $props->{"svk:merge"} ) {
3741 $self->find_extra_svk_parents
3742 ($ed, $props->{"svk:merge"}, \@parents);
3743 }
3744 if ( $props->{"svn:mergeinfo"} ) {
3745 $self->find_extra_svn_parents
3746 ($ed,
3747 $props->{"svn:mergeinfo"},
3748 \@parents);
3749 }
3750 }
3752 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3753 print $un "r$rev\n" or croak $!;
3754 print $un $_, "\n" foreach @$untracked;
3755 my %log_entry = ( parents => \@parents, revision => $rev,
3756 log => '');
3758 my $headrev;
3759 my $logged = delete $self->{logged_rev_props};
3760 if (!$logged || $self->{-want_revprops}) {
3761 my $rp = $self->ra->rev_proplist($rev);
3762 foreach (sort keys %$rp) {
3763 my $v = $rp->{$_};
3764 if (/^svn:(author|date|log)$/) {
3765 $log_entry{$1} = $v;
3766 } elsif ($_ eq 'svm:headrev') {
3767 $headrev = $v;
3768 } else {
3769 print $un " rev_prop: ", uri_encode($_), ' ',
3770 uri_encode($v), "\n";
3771 }
3772 }
3773 } else {
3774 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3775 }
3776 close $un or croak $!;
3778 $log_entry{date} = parse_svn_date($log_entry{date});
3779 $log_entry{log} .= "\n";
3780 my $author = $log_entry{author} = check_author($log_entry{author});
3781 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3782 : ($author, undef);
3784 my ($commit_name, $commit_email) = ($name, $email);
3785 if ($_use_log_author) {
3786 my $name_field;
3787 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3788 $name_field = $1;
3789 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3790 $name_field = $1;
3791 }
3792 if (!defined $name_field) {
3793 if (!defined $email) {
3794 $email = $name;
3795 }
3796 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3797 ($name, $email) = ($1, $2);
3798 } elsif ($name_field =~ /(.*)@/) {
3799 ($name, $email) = ($1, $name_field);
3800 } else {
3801 ($name, $email) = ($name_field, $name_field);
3802 }
3803 }
3804 if (defined $headrev && $self->use_svm_props) {
3805 if ($self->rewrite_root) {
3806 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3807 "options set!\n";
3808 }
3809 if ($self->rewrite_uuid) {
3810 die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3811 "options set!\n";
3812 }
3813 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3814 # we don't want "SVM: initializing mirror for junk" ...
3815 return undef if $r == 0;
3816 my $svm = $self->svm;
3817 if ($uuid ne $svm->{uuid}) {
3818 die "UUID mismatch on SVM path:\n",
3819 "expected: $svm->{uuid}\n",
3820 " got: $uuid\n";
3821 }
3822 my $full_url = $self->full_url;
3823 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3824 die "Failed to replace '$svm->{replace}' with ",
3825 "'$svm->{source}' in $full_url\n";
3826 # throw away username for storing in records
3827 remove_username($full_url);
3828 $log_entry{metadata} = "$full_url\@$r $uuid";
3829 $log_entry{svm_revision} = $r;
3830 $email ||= "$author\@$uuid";
3831 $commit_email ||= "$author\@$uuid";
3832 } elsif ($self->use_svnsync_props) {
3833 my $full_url = $self->svnsync->{url};
3834 $full_url .= "/$self->{path}" if length $self->{path};
3835 remove_username($full_url);
3836 my $uuid = $self->svnsync->{uuid};
3837 $log_entry{metadata} = "$full_url\@$rev $uuid";
3838 $email ||= "$author\@$uuid";
3839 $commit_email ||= "$author\@$uuid";
3840 } else {
3841 my $url = $self->metadata_url;
3842 remove_username($url);
3843 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3844 $log_entry{metadata} = "$url\@$rev " . $uuid;
3845 $email ||= "$author\@" . $uuid;
3846 $commit_email ||= "$author\@" . $uuid;
3847 }
3848 $log_entry{name} = $name;
3849 $log_entry{email} = $email;
3850 $log_entry{commit_name} = $commit_name;
3851 $log_entry{commit_email} = $commit_email;
3852 \%log_entry;
3853 }
3855 sub fetch {
3856 my ($self, $min_rev, $max_rev, @parents) = @_;
3857 my ($last_rev, $last_commit) = $self->last_rev_commit;
3858 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3859 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3860 }
3862 sub set_tree_cb {
3863 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3864 $self->{inject_parents} = { $rev => $tree };
3865 $self->fetch(undef, undef);
3866 }
3868 sub set_tree {
3869 my ($self, $tree) = (shift, shift);
3870 my $log_entry = ::get_commit_entry($tree);
3871 unless ($self->{last_rev}) {
3872 ::fatal("Must have an existing revision to commit");
3873 }
3874 my %ed_opts = ( r => $self->{last_rev},
3875 log => $log_entry->{log},
3876 ra => $self->ra,
3877 tree_a => $self->{last_commit},
3878 tree_b => $tree,
3879 editor_cb => sub {
3880 $self->set_tree_cb($log_entry, $tree, @_) },
3881 svn_path => $self->{path} );
3882 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3883 print "No changes\nr$self->{last_rev} = $tree\n";
3884 }
3885 }
3887 sub rebuild_from_rev_db {
3888 my ($self, $path) = @_;
3889 my $r = -1;
3890 open my $fh, '<', $path or croak "open: $!";
3891 binmode $fh or croak "binmode: $!";
3892 while (<$fh>) {
3893 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3894 chomp($_);
3895 ++$r;
3896 next if $_ eq ('0' x 40);
3897 $self->rev_map_set($r, $_);
3898 print "r$r = $_\n";
3899 }
3900 close $fh or croak "close: $!";
3901 unlink $path or croak "unlink: $!";
3902 }
3904 sub rebuild {
3905 my ($self) = @_;
3906 my $map_path = $self->map_path;
3907 my $partial = (-e $map_path && ! -z $map_path);
3908 return unless ::verify_ref($self->refname.'^0');
3909 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3910 my $rev_db = $self->rev_db_path;
3911 $self->rebuild_from_rev_db($rev_db);
3912 if ($self->use_svm_props) {
3913 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3914 $self->rebuild_from_rev_db($svm_rev_db);
3915 }
3916 $self->unlink_rev_db_symlink;
3917 return;
3918 }
3919 print "Rebuilding $map_path ...\n" if (!$partial);
3920 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3921 (undef, undef));
3922 my ($log, $ctx) =
3923 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3924 ($head ? "$head.." : "") . $self->refname,
3925 '--');
3926 my $metadata_url = $self->metadata_url;
3927 remove_username($metadata_url);
3928 my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3929 my $c;
3930 while (<$log>) {
3931 if ( m{^commit ($::sha1)$} ) {
3932 $c = $1;
3933 next;
3934 }
3935 next unless s{^\s*(git-svn-id:)}{$1};
3936 my ($url, $rev, $uuid) = ::extract_metadata($_);
3937 remove_username($url);
3939 # ignore merges (from set-tree)
3940 next if (!defined $rev || !$uuid);
3942 # if we merged or otherwise started elsewhere, this is
3943 # how we break out of it
3944 if (($uuid ne $svn_uuid) ||
3945 ($metadata_url && $url && ($url ne $metadata_url))) {
3946 next;
3947 }
3948 if ($partial && $head) {
3949 print "Partial-rebuilding $map_path ...\n";
3950 print "Currently at $base_rev = $head\n";
3951 $head = undef;
3952 }
3954 $self->rev_map_set($rev, $c);
3955 print "r$rev = $c\n";
3956 }
3957 command_close_pipe($log, $ctx);
3958 print "Done rebuilding $map_path\n" if (!$partial || !$head);
3959 my $rev_db_path = $self->rev_db_path;
3960 if (-f $self->rev_db_path) {
3961 unlink $self->rev_db_path or croak "unlink: $!";
3962 }
3963 $self->unlink_rev_db_symlink;
3964 }
3966 # rev_map:
3967 # Tie::File seems to be prone to offset errors if revisions get sparse,
3968 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
3969 # one of my favorite modules is out :< Next up would be one of the DBM
3970 # modules, but I'm not sure which is most portable...
3971 #
3972 # This is the replacement for the rev_db format, which was too big
3973 # and inefficient for large repositories with a lot of sparse history
3974 # (mainly tags)
3975 #
3976 # The format is this:
3977 # - 24 bytes for every record,
3978 # * 4 bytes for the integer representing an SVN revision number
3979 # * 20 bytes representing the sha1 of a git commit
3980 # - No empty padding records like the old format
3981 # (except the last record, which can be overwritten)
3982 # - new records are written append-only since SVN revision numbers
3983 # increase monotonically
3984 # - lookups on SVN revision number are done via a binary search
3985 # - Piping the file to xxd -c24 is a good way of dumping it for
3986 # viewing or editing (piped back through xxd -r), should the need
3987 # ever arise.
3988 # - The last record can be padding revision with an all-zero sha1
3989 # This is used to optimize fetch performance when using multiple
3990 # "fetch" directives in .git/config
3991 #
3992 # These files are disposable unless noMetadata or useSvmProps is set
3994 sub _rev_map_set {
3995 my ($fh, $rev, $commit) = @_;
3997 binmode $fh or croak "binmode: $!";
3998 my $size = (stat($fh))[7];
3999 ($size % 24) == 0 or croak "inconsistent size: $size";
4001 my $wr_offset = 0;
4002 if ($size > 0) {
4003 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
4004 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
4005 $read == 24 or croak "read only $read bytes (!= 24)";
4006 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
4007 if ($last_commit eq ('0' x40)) {
4008 if ($size >= 48) {
4009 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
4010 $read = sysread($fh, $buf, 24) or
4011 croak "read: $!";
4012 $read == 24 or
4013 croak "read only $read bytes (!= 24)";
4014 ($last_rev, $last_commit) =
4015 unpack(rev_map_fmt, $buf);
4016 if ($last_commit eq ('0' x40)) {
4017 croak "inconsistent .rev_map\n";
4018 }
4019 }
4020 if ($last_rev >= $rev) {
4021 croak "last_rev is higher!: $last_rev >= $rev";
4022 }
4023 $wr_offset = -24;
4024 }
4025 }
4026 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
4027 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
4028 croak "write: $!";
4029 }
4031 sub _rev_map_reset {
4032 my ($fh, $rev, $commit) = @_;
4033 my $c = _rev_map_get($fh, $rev);
4034 $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
4035 my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
4036 truncate $fh, $offset or croak "truncate: $!";
4037 }
4039 sub mkfile {
4040 my ($path) = @_;
4041 unless (-e $path) {
4042 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
4043 mkpath([$dir]) unless -d $dir;
4044 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
4045 close $fh or die "Couldn't close (create) $path: $!\n";
4046 }
4047 }
4049 sub rev_map_set {
4050 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
4051 defined $commit or die "missing arg3\n";
4052 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
4053 my $db = $self->map_path($uuid);
4054 my $db_lock = "$db.lock";
4055 my $sig;
4056 $update_ref ||= 0;
4057 if ($update_ref) {
4058 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
4059 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
4060 }
4061 mkfile($db);
4063 $LOCKFILES{$db_lock} = 1;
4064 my $sync;
4065 # both of these options make our .rev_db file very, very important
4066 # and we can't afford to lose it because rebuild() won't work
4067 if ($self->use_svm_props || $self->no_metadata) {
4068 $sync = 1;
4069 copy($db, $db_lock) or die "rev_map_set(@_): ",
4070 "Failed to copy: ",
4071 "$db => $db_lock ($!)\n";
4072 } else {
4073 rename $db, $db_lock or die "rev_map_set(@_): ",
4074 "Failed to rename: ",
4075 "$db => $db_lock ($!)\n";
4076 }
4078 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
4079 or croak "Couldn't open $db_lock: $!\n";
4080 $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
4081 _rev_map_set($fh, $rev, $commit);
4082 if ($sync) {
4083 $fh->flush or die "Couldn't flush $db_lock: $!\n";
4084 $fh->sync or die "Couldn't sync $db_lock: $!\n";
4085 }
4086 close $fh or croak $!;
4087 if ($update_ref) {
4088 $_head = $self;
4089 my $note = "";
4090 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
4091 command_noisy('update-ref', '-m', "r$rev$note",
4092 $self->refname, $commit);
4093 }
4094 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
4095 "$db_lock => $db ($!)\n";
4096 delete $LOCKFILES{$db_lock};
4097 if ($update_ref) {
4098 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
4099 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
4100 kill $sig, $$ if defined $sig;
4101 }
4102 }
4104 # If want_commit, this will return an array of (rev, commit) where
4105 # commit _must_ be a valid commit in the archive.
4106 # Otherwise, it'll return the max revision (whether or not the
4107 # commit is valid or just a 0x40 placeholder).
4108 sub rev_map_max {
4109 my ($self, $want_commit) = @_;
4110 $self->rebuild;
4111 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
4112 $want_commit ? ($r, $c) : $r;
4113 }
4115 sub rev_map_max_norebuild {
4116 my ($self, $want_commit) = @_;
4117 my $map_path = $self->map_path;
4118 stat $map_path or return $want_commit ? (0, undef) : 0;
4119 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
4120 binmode $fh or croak "binmode: $!";
4121 my $size = (stat($fh))[7];
4122 ($size % 24) == 0 or croak "inconsistent size: $size";
4124 if ($size == 0) {
4125 close $fh or croak "close: $!";
4126 return $want_commit ? (0, undef) : 0;
4127 }
4129 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
4130 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
4131 my ($r, $c) = unpack(rev_map_fmt, $buf);
4132 if ($want_commit && $c eq ('0' x40)) {
4133 if ($size < 48) {
4134 return $want_commit ? (0, undef) : 0;
4135 }
4136 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
4137 sysread($fh, $buf, 24) == 24 or croak "read: $!";
4138 ($r, $c) = unpack(rev_map_fmt, $buf);
4139 if ($c eq ('0'x40)) {
4140 croak "Penultimate record is all-zeroes in $map_path";
4141 }
4142 }
4143 close $fh or croak "close: $!";
4144 $want_commit ? ($r, $c) : $r;
4145 }
4147 sub rev_map_get {
4148 my ($self, $rev, $uuid) = @_;
4149 my $map_path = $self->map_path($uuid);
4150 return undef unless -e $map_path;
4152 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
4153 my $c = _rev_map_get($fh, $rev);
4154 close($fh) or croak "close: $!";
4155 $c
4156 }
4158 sub _rev_map_get {
4159 my ($fh, $rev) = @_;
4161 binmode $fh or croak "binmode: $!";
4162 my $size = (stat($fh))[7];
4163 ($size % 24) == 0 or croak "inconsistent size: $size";
4165 if ($size == 0) {
4166 return undef;
4167 }
4169 my ($l, $u) = (0, $size - 24);
4170 my ($r, $c, $buf);
4172 while ($l <= $u) {
4173 my $i = int(($l/24 + $u/24) / 2) * 24;
4174 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
4175 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
4176 my ($r, $c) = unpack(rev_map_fmt, $buf);
4178 if ($r < $rev) {
4179 $l = $i + 24;
4180 } elsif ($r > $rev) {
4181 $u = $i - 24;
4182 } else { # $r == $rev
4183 return $c eq ('0' x 40) ? undef : $c;
4184 }
4185 }
4186 undef;
4187 }
4189 # Finds the first svn revision that exists on (if $eq_ok is true) or
4190 # before $rev for the current branch. It will not search any lower
4191 # than $min_rev. Returns the git commit hash and svn revision number
4192 # if found, else (undef, undef).
4193 sub find_rev_before {
4194 my ($self, $rev, $eq_ok, $min_rev) = @_;
4195 --$rev unless $eq_ok;
4196 $min_rev ||= 1;
4197 my $max_rev = $self->rev_map_max;
4198 $rev = $max_rev if ($rev > $max_rev);
4199 while ($rev >= $min_rev) {
4200 if (my $c = $self->rev_map_get($rev)) {
4201 return ($rev, $c);
4202 }
4203 --$rev;
4204 }
4205 return (undef, undef);
4206 }
4208 # Finds the first svn revision that exists on (if $eq_ok is true) or
4209 # after $rev for the current branch. It will not search any higher
4210 # than $max_rev. Returns the git commit hash and svn revision number
4211 # if found, else (undef, undef).
4212 sub find_rev_after {
4213 my ($self, $rev, $eq_ok, $max_rev) = @_;
4214 ++$rev unless $eq_ok;
4215 $max_rev ||= $self->rev_map_max;
4216 while ($rev <= $max_rev) {
4217 if (my $c = $self->rev_map_get($rev)) {
4218 return ($rev, $c);
4219 }
4220 ++$rev;
4221 }
4222 return (undef, undef);
4223 }
4225 sub _new {
4226 my ($class, $repo_id, $ref_id, $path) = @_;
4227 unless (defined $repo_id && length $repo_id) {
4228 $repo_id = $Git::SVN::default_repo_id;
4229 }
4230 unless (defined $ref_id && length $ref_id) {
4231 $_prefix = '' unless defined($_prefix);
4232 $_[2] = $ref_id =
4233 "refs/remotes/$_prefix$Git::SVN::default_ref_id";
4234 }
4235 $_[1] = $repo_id;
4236 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
4238 # Older repos imported by us used $GIT_DIR/svn/foo instead of
4239 # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
4240 if ($ref_id =~ m{^refs/remotes/(.*)}) {
4241 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
4242 if (-d $old_dir && ! -d $dir) {
4243 $dir = $old_dir;
4244 }
4245 }
4247 $_[3] = $path = '' unless (defined $path);
4248 mkpath([$dir]);
4249 bless {
4250 ref_id => $ref_id, dir => $dir, index => "$dir/index",
4251 path => $path, config => "$ENV{GIT_DIR}/svn/config",
4252 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
4253 }
4255 # for read-only access of old .rev_db formats
4256 sub unlink_rev_db_symlink {
4257 my ($self) = @_;
4258 my $link = $self->rev_db_path;
4259 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
4260 if (-l $link) {
4261 unlink $link or croak "unlink: $link failed!";
4262 }
4263 }
4265 sub rev_db_path {
4266 my ($self, $uuid) = @_;
4267 my $db_path = $self->map_path($uuid);
4268 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
4269 or croak "map_path: $db_path does not contain '/.rev_map.' !";
4270 $db_path;
4271 }
4273 # the new replacement for .rev_db
4274 sub map_path {
4275 my ($self, $uuid) = @_;
4276 $uuid ||= $self->ra_uuid;
4277 "$self->{map_root}.$uuid";
4278 }
4280 sub uri_encode {
4281 my ($f) = @_;
4282 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
4283 $f
4284 }
4286 sub uri_decode {
4287 my ($f) = @_;
4288 $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
4289 $f
4290 }
4292 sub remove_username {
4293 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
4294 }
4296 package Git::SVN::Prompt;
4297 use strict;
4298 use warnings;
4299 require SVN::Core;
4300 use vars qw/$_no_auth_cache $_username/;
4302 sub simple {
4303 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
4304 $may_save = undef if $_no_auth_cache;
4305 $default_username = $_username if defined $_username;
4306 if (defined $default_username && length $default_username) {
4307 if (defined $realm && length $realm) {
4308 print STDERR "Authentication realm: $realm\n";
4309 STDERR->flush;
4310 }
4311 $cred->username($default_username);
4312 } else {
4313 username($cred, $realm, $may_save, $pool);
4314 }
4315 $cred->password(_read_password("Password for '" .
4316 $cred->username . "': ", $realm));
4317 $cred->may_save($may_save);
4318 $SVN::_Core::SVN_NO_ERROR;
4319 }
4321 sub ssl_server_trust {
4322 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
4323 $may_save = undef if $_no_auth_cache;
4324 print STDERR "Error validating server certificate for '$realm':\n";
4325 {
4326 no warnings 'once';
4327 # All variables SVN::Auth::SSL::* are used only once,
4328 # so we're shutting up Perl warnings about this.
4329 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
4330 print STDERR " - The certificate is not issued ",
4331 "by a trusted authority. Use the\n",
4332 " fingerprint to validate ",
4333 "the certificate manually!\n";
4334 }
4335 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
4336 print STDERR " - The certificate hostname ",
4337 "does not match.\n";
4338 }
4339 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
4340 print STDERR " - The certificate is not yet valid.\n";
4341 }
4342 if ($failures & $SVN::Auth::SSL::EXPIRED) {
4343 print STDERR " - The certificate has expired.\n";
4344 }
4345 if ($failures & $SVN::Auth::SSL::OTHER) {
4346 print STDERR " - The certificate has ",
4347 "an unknown error.\n";
4348 }
4349 } # no warnings 'once'
4350 printf STDERR
4351 "Certificate information:\n".
4352 " - Hostname: %s\n".
4353 " - Valid: from %s until %s\n".
4354 " - Issuer: %s\n".
4355 " - Fingerprint: %s\n",
4356 map $cert_info->$_, qw(hostname valid_from valid_until
4357 issuer_dname fingerprint);
4358 my $choice;
4359 prompt:
4360 print STDERR $may_save ?
4361 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
4362 "(R)eject or accept (t)emporarily? ";
4363 STDERR->flush;
4364 $choice = lc(substr(<STDIN> || 'R', 0, 1));
4365 if ($choice =~ /^t$/i) {
4366 $cred->may_save(undef);
4367 } elsif ($choice =~ /^r$/i) {
4368 return -1;
4369 } elsif ($may_save && $choice =~ /^p$/i) {
4370 $cred->may_save($may_save);
4371 } else {
4372 goto prompt;
4373 }
4374 $cred->accepted_failures($failures);
4375 $SVN::_Core::SVN_NO_ERROR;
4376 }
4378 sub ssl_client_cert {
4379 my ($cred, $realm, $may_save, $pool) = @_;
4380 $may_save = undef if $_no_auth_cache;
4381 print STDERR "Client certificate filename: ";
4382 STDERR->flush;
4383 chomp(my $filename = <STDIN>);
4384 $cred->cert_file($filename);
4385 $cred->may_save($may_save);
4386 $SVN::_Core::SVN_NO_ERROR;
4387 }
4389 sub ssl_client_cert_pw {
4390 my ($cred, $realm, $may_save, $pool) = @_;
4391 $may_save = undef if $_no_auth_cache;
4392 $cred->password(_read_password("Password: ", $realm));
4393 $cred->may_save($may_save);
4394 $SVN::_Core::SVN_NO_ERROR;
4395 }
4397 sub username {
4398 my ($cred, $realm, $may_save, $pool) = @_;
4399 $may_save = undef if $_no_auth_cache;
4400 if (defined $realm && length $realm) {
4401 print STDERR "Authentication realm: $realm\n";
4402 }
4403 my $username;
4404 if (defined $_username) {
4405 $username = $_username;
4406 } else {
4407 print STDERR "Username: ";
4408 STDERR->flush;
4409 chomp($username = <STDIN>);
4410 }
4411 $cred->username($username);
4412 $cred->may_save($may_save);
4413 $SVN::_Core::SVN_NO_ERROR;
4414 }
4416 sub _read_password {
4417 my ($prompt, $realm) = @_;
4418 my $password = '';
4419 if (exists $ENV{GIT_ASKPASS}) {
4420 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4421 $password = <PH>;
4422 $password =~ s/[\012\015]//; # \n\r
4423 close(PH);
4424 } else {
4425 print STDERR $prompt;
4426 STDERR->flush;
4427 require Term::ReadKey;
4428 Term::ReadKey::ReadMode('noecho');
4429 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4430 last if $key =~ /[\012\015]/; # \n\r
4431 $password .= $key;
4432 }
4433 Term::ReadKey::ReadMode('restore');
4434 print STDERR "\n";
4435 STDERR->flush;
4436 }
4437 $password;
4438 }
4440 package SVN::Git::Fetcher;
4441 use vars qw/@ISA $_ignore_regex $_preserve_empty_dirs $_placeholder_filename
4442 @deleted_gpath %added_placeholder $repo_id/;
4443 use strict;
4444 use warnings;
4445 use Carp qw/croak/;
4446 use File::Basename qw/dirname/;
4447 use IO::File qw//;
4449 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4450 sub new {
4451 my ($class, $git_svn, $switch_path) = @_;
4452 my $self = SVN::Delta::Editor->new;
4453 bless $self, $class;
4454 if (exists $git_svn->{last_commit}) {
4455 $self->{c} = $git_svn->{last_commit};
4456 $self->{empty_symlinks} =
4457 _mark_empty_symlinks($git_svn, $switch_path);
4458 }
4460 # some options are read globally, but can be overridden locally
4461 # per [svn-remote "..."] section. Command-line options will *NOT*
4462 # override options set in an [svn-remote "..."] section
4463 $repo_id = $git_svn->{repo_id};
4464 my $k = "svn-remote.$repo_id.ignore-paths";
4465 my $v = eval { command_oneline('config', '--get', $k) };
4466 $self->{ignore_regex} = $v;
4468 $k = "svn-remote.$repo_id.preserve-empty-dirs";
4469 $v = eval { command_oneline('config', '--get', '--bool', $k) };
4470 if ($v && $v eq 'true') {
4471 $_preserve_empty_dirs = 1;
4472 $k = "svn-remote.$repo_id.placeholder-filename";
4473 $v = eval { command_oneline('config', '--get', $k) };
4474 $_placeholder_filename = $v;
4475 }
4477 # Load the list of placeholder files added during previous invocations.
4478 $k = "svn-remote.$repo_id.added-placeholder";
4479 $v = eval { command_oneline('config', '--get-all', $k) };
4480 if ($_preserve_empty_dirs && $v) {
4481 # command() prints errors to stderr, so we only call it if
4482 # command_oneline() succeeded.
4483 my @v = command('config', '--get-all', $k);
4484 $added_placeholder{ dirname($_) } = $_ foreach @v;
4485 }
4487 $self->{empty} = {};
4488 $self->{dir_prop} = {};
4489 $self->{file_prop} = {};
4490 $self->{absent_dir} = {};
4491 $self->{absent_file} = {};
4492 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4493 $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4494 $self;
4495 }
4497 # this uses the Ra object, so it must be called before do_{switch,update},
4498 # not inside them (when the Git::SVN::Fetcher object is passed) to
4499 # do_{switch,update}
4500 sub _mark_empty_symlinks {
4501 my ($git_svn, $switch_path) = @_;
4502 my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4503 return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4505 my %ret;
4506 my ($rev, $cmt) = $git_svn->last_rev_commit;
4507 return {} unless ($rev && $cmt);
4509 # allow the warning to be printed for each revision we fetch to
4510 # ensure the user sees it. The user can also disable the workaround
4511 # on the repository even while git svn is running and the next
4512 # revision fetched will skip this expensive function.
4513 my $printed_warning;
4514 chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4515 my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4516 local $/ = "\0";
4517 my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4518 $pfx .= '/' if length($pfx);
4519 while (<$ls>) {
4520 chomp;
4521 s/\A100644 blob $empty_blob\t//o or next;
4522 unless ($printed_warning) {
4523 print STDERR "Scanning for empty symlinks, ",
4524 "this may take a while if you have ",
4525 "many empty files\n",
4526 "You may disable this with `",
4527 "git config svn.brokenSymlinkWorkaround ",
4528 "false'.\n",
4529 "This may be done in a different ",
4530 "terminal without restarting ",
4531 "git svn\n";
4532 $printed_warning = 1;
4533 }
4534 my $path = $_;
4535 my (undef, $props) =
4536 $git_svn->ra->get_file($pfx.$path, $rev, undef);
4537 if ($props->{'svn:special'}) {
4538 $ret{$path} = 1;
4539 }
4540 }
4541 command_close_pipe($ls, $ctx);
4542 \%ret;
4543 }
4545 # returns true if a given path is inside a ".git" directory
4546 sub in_dot_git {
4547 $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4548 }
4550 # return value: 0 -- don't ignore, 1 -- ignore
4551 sub is_path_ignored {
4552 my ($self, $path) = @_;
4553 return 1 if in_dot_git($path);
4554 return 1 if defined($self->{ignore_regex}) &&
4555 $path =~ m!$self->{ignore_regex}!;
4556 return 0 unless defined($_ignore_regex);
4557 return 1 if $path =~ m!$_ignore_regex!o;
4558 return 0;
4559 }
4561 sub set_path_strip {
4562 my ($self, $path) = @_;
4563 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4564 }
4566 sub open_root {
4567 { path => '' };
4568 }
4570 sub open_directory {
4571 my ($self, $path, $pb, $rev) = @_;
4572 { path => $path };
4573 }
4575 sub git_path {
4576 my ($self, $path) = @_;
4577 if (my $enc = $self->{pathnameencoding}) {
4578 require Encode;
4579 Encode::from_to($path, 'UTF-8', $enc);
4580 }
4581 if ($self->{path_strip}) {
4582 $path =~ s!$self->{path_strip}!! or
4583 die "Failed to strip path '$path' ($self->{path_strip})\n";
4584 }
4585 $path;
4586 }
4588 sub delete_entry {
4589 my ($self, $path, $rev, $pb) = @_;
4590 return undef if $self->is_path_ignored($path);
4592 my $gpath = $self->git_path($path);
4593 return undef if ($gpath eq '');
4595 # remove entire directories.
4596 my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4597 =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4598 if ($tree) {
4599 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4600 -r --name-only -z/,
4601 $tree);
4602 local $/ = "\0";
4603 while (<$ls>) {
4604 chomp;
4605 my $rmpath = "$gpath/$_";
4606 $self->{gii}->remove($rmpath);
4607 print "\tD\t$rmpath\n" unless $::_q;
4608 }
4609 print "\tD\t$gpath/\n" unless $::_q;
4610 command_close_pipe($ls, $ctx);
4611 } else {
4612 $self->{gii}->remove($gpath);
4613 print "\tD\t$gpath\n" unless $::_q;
4614 }
4615 # Don't add to @deleted_gpath if we're deleting a placeholder file.
4616 push @deleted_gpath, $gpath unless $added_placeholder{dirname($path)};
4617 $self->{empty}->{$path} = 0;
4618 undef;
4619 }
4621 sub open_file {
4622 my ($self, $path, $pb, $rev) = @_;
4623 my ($mode, $blob);
4625 goto out if $self->is_path_ignored($path);
4627 my $gpath = $self->git_path($path);
4628 ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4629 =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4630 unless (defined $mode && defined $blob) {
4631 die "$path was not found in commit $self->{c} (r$rev)\n";
4632 }
4633 if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4634 $mode = '120000';
4635 }
4636 out:
4637 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4638 pool => SVN::Pool->new, action => 'M' };
4639 }
4641 sub add_file {
4642 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4643 my $mode;
4645 if (!$self->is_path_ignored($path)) {
4646 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4647 delete $self->{empty}->{$dir};
4648 $mode = '100644';
4650 if ($added_placeholder{$dir}) {
4651 # Remove our placeholder file, if we created one.
4652 delete_entry($self, $added_placeholder{$dir})
4653 unless $path eq $added_placeholder{$dir};
4654 delete $added_placeholder{$dir}
4655 }
4656 }
4658 { path => $path, mode_a => $mode, mode_b => $mode,
4659 pool => SVN::Pool->new, action => 'A' };
4660 }
4662 sub add_directory {
4663 my ($self, $path, $cp_path, $cp_rev) = @_;
4664 goto out if $self->is_path_ignored($path);
4665 my $gpath = $self->git_path($path);
4666 if ($gpath eq '') {
4667 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4668 -r --name-only -z/,
4669 $self->{c});
4670 local $/ = "\0";
4671 while (<$ls>) {
4672 chomp;
4673 $self->{gii}->remove($_);
4674 print "\tD\t$_\n" unless $::_q;
4675 push @deleted_gpath, $gpath;
4676 }
4677 command_close_pipe($ls, $ctx);
4678 $self->{empty}->{$path} = 0;
4679 }
4680 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4681 delete $self->{empty}->{$dir};
4682 $self->{empty}->{$path} = 1;
4684 if ($added_placeholder{$dir}) {
4685 # Remove our placeholder file, if we created one.
4686 delete_entry($self, $added_placeholder{$dir});
4687 delete $added_placeholder{$dir}
4688 }
4690 out:
4691 { path => $path };
4692 }
4694 sub change_dir_prop {
4695 my ($self, $db, $prop, $value) = @_;
4696 return undef if $self->is_path_ignored($db->{path});
4697 $self->{dir_prop}->{$db->{path}} ||= {};
4698 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4699 undef;
4700 }
4702 sub absent_directory {
4703 my ($self, $path, $pb) = @_;
4704 return undef if $self->is_path_ignored($path);
4705 $self->{absent_dir}->{$pb->{path}} ||= [];
4706 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4707 undef;
4708 }
4710 sub absent_file {
4711 my ($self, $path, $pb) = @_;
4712 return undef if $self->is_path_ignored($path);
4713 $self->{absent_file}->{$pb->{path}} ||= [];
4714 push @{$self->{absent_file}->{$pb->{path}}}, $path;
4715 undef;
4716 }
4718 sub change_file_prop {
4719 my ($self, $fb, $prop, $value) = @_;
4720 return undef if $self->is_path_ignored($fb->{path});
4721 if ($prop eq 'svn:executable') {
4722 if ($fb->{mode_b} != 120000) {
4723 $fb->{mode_b} = defined $value ? 100755 : 100644;
4724 }
4725 } elsif ($prop eq 'svn:special') {
4726 $fb->{mode_b} = defined $value ? 120000 : 100644;
4727 } else {
4728 $self->{file_prop}->{$fb->{path}} ||= {};
4729 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4730 }
4731 undef;
4732 }
4734 sub apply_textdelta {
4735 my ($self, $fb, $exp) = @_;
4736 return undef if $self->is_path_ignored($fb->{path});
4737 my $fh = $::_repository->temp_acquire('svn_delta');
4738 # $fh gets auto-closed() by SVN::TxDelta::apply(),
4739 # (but $base does not,) so dup() it for reading in close_file
4740 open my $dup, '<&', $fh or croak $!;
4741 my $base = $::_repository->temp_acquire('git_blob');
4743 if ($fb->{blob}) {
4744 my ($base_is_link, $size);
4746 if ($fb->{mode_a} eq '120000' &&
4747 ! $self->{empty_symlinks}->{$fb->{path}}) {
4748 print $base 'link ' or die "print $!\n";
4749 $base_is_link = 1;
4750 }
4751 retry:
4752 $size = $::_repository->cat_blob($fb->{blob}, $base);
4753 die "Failed to read object $fb->{blob}" if ($size < 0);
4755 if (defined $exp) {
4756 seek $base, 0, 0 or croak $!;
4757 my $got = ::md5sum($base);
4758 if ($got ne $exp) {
4759 my $err = "Checksum mismatch: ".
4760 "$fb->{path} $fb->{blob}\n" .
4761 "expected: $exp\n" .
4762 " got: $got\n";
4763 if ($base_is_link) {
4764 warn $err,
4765 "Retrying... (possibly ",
4766 "a bad symlink from SVN)\n";
4767 $::_repository->temp_reset($base);
4768 $base_is_link = 0;
4769 goto retry;
4770 }
4771 die $err;
4772 }
4773 }
4774 }
4775 seek $base, 0, 0 or croak $!;
4776 $fb->{fh} = $fh;
4777 $fb->{base} = $base;
4778 [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4779 }
4781 sub close_file {
4782 my ($self, $fb, $exp) = @_;
4783 return undef if $self->is_path_ignored($fb->{path});
4785 my $hash;
4786 my $path = $self->git_path($fb->{path});
4787 if (my $fh = $fb->{fh}) {
4788 if (defined $exp) {
4789 seek($fh, 0, 0) or croak $!;
4790 my $got = ::md5sum($fh);
4791 if ($got ne $exp) {
4792 die "Checksum mismatch: $path\n",
4793 "expected: $exp\n got: $got\n";
4794 }
4795 }
4796 if ($fb->{mode_b} == 120000) {
4797 sysseek($fh, 0, 0) or croak $!;
4798 my $rd = sysread($fh, my $buf, 5);
4800 if (!defined $rd) {
4801 croak "sysread: $!\n";
4802 } elsif ($rd == 0) {
4803 warn "$path has mode 120000",
4804 " but it points to nothing\n",
4805 "converting to an empty file with mode",
4806 " 100644\n";
4807 $fb->{mode_b} = '100644';
4808 } elsif ($buf ne 'link ') {
4809 warn "$path has mode 120000",
4810 " but is not a link\n";
4811 } else {
4812 my $tmp_fh = $::_repository->temp_acquire(
4813 'svn_hash');
4814 my $res;
4815 while ($res = sysread($fh, my $str, 1024)) {
4816 my $out = syswrite($tmp_fh, $str, $res);
4817 defined($out) && $out == $res
4818 or croak("write ",
4819 Git::temp_path($tmp_fh),
4820 ": $!\n");
4821 }
4822 defined $res or croak $!;
4824 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4825 Git::temp_release($tmp_fh, 1);
4826 }
4827 }
4829 $hash = $::_repository->hash_and_insert_object(
4830 Git::temp_path($fh));
4831 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4833 Git::temp_release($fb->{base}, 1);
4834 Git::temp_release($fh, 1);
4835 } else {
4836 $hash = $fb->{blob} or die "no blob information\n";
4837 }
4838 $fb->{pool}->clear;
4839 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4840 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4841 undef;
4842 }
4844 sub abort_edit {
4845 my $self = shift;
4846 $self->{nr} = $self->{gii}->{nr};
4847 delete $self->{gii};
4848 $self->SUPER::abort_edit(@_);
4849 }
4851 sub close_edit {
4852 my $self = shift;
4854 if ($_preserve_empty_dirs) {
4855 my @empty_dirs;
4857 # Any entry flagged as empty that also has an associated
4858 # dir_prop represents a newly created empty directory.
4859 foreach my $i (keys %{$self->{empty}}) {
4860 push @empty_dirs, $i if exists $self->{dir_prop}->{$i};
4861 }
4863 # Search for directories that have become empty due subsequent
4864 # file deletes.
4865 push @empty_dirs, $self->find_empty_directories();
4867 # Finally, add a placeholder file to each empty directory.
4868 $self->add_placeholder_file($_) foreach (@empty_dirs);
4870 $self->stash_placeholder_list();
4871 }
4873 $self->{git_commit_ok} = 1;
4874 $self->{nr} = $self->{gii}->{nr};
4875 delete $self->{gii};
4876 $self->SUPER::close_edit(@_);
4877 }
4879 sub find_empty_directories {
4880 my ($self) = @_;
4881 my @empty_dirs;
4882 my %dirs = map { dirname($_) => 1 } @deleted_gpath;
4884 foreach my $dir (sort keys %dirs) {
4885 next if $dir eq ".";
4887 # If there have been any additions to this directory, there is
4888 # no reason to check if it is empty.
4889 my $skip_added = 0;
4890 foreach my $t (qw/dir_prop file_prop/) {
4891 foreach my $path (keys %{ $self->{$t} }) {
4892 if (exists $self->{$t}->{dirname($path)}) {
4893 $skip_added = 1;
4894 last;
4895 }
4896 }
4897 last if $skip_added;
4898 }
4899 next if $skip_added;
4901 # Use `git ls-tree` to get the filenames of this directory
4902 # that existed prior to this particular commit.
4903 my $ls = command('ls-tree', '-z', '--name-only',
4904 $self->{c}, "$dir/");
4905 my %files = map { $_ => 1 } split(/\0/, $ls);
4907 # Remove the filenames that were deleted during this commit.
4908 delete $files{$_} foreach (@deleted_gpath);
4910 # Report the directory if there are no filenames left.
4911 push @empty_dirs, $dir unless (scalar %files);
4912 }
4913 @empty_dirs;
4914 }
4916 sub add_placeholder_file {
4917 my ($self, $dir) = @_;
4918 my $path = "$dir/$_placeholder_filename";
4919 my $gpath = $self->git_path($path);
4921 my $fh = $::_repository->temp_acquire($gpath);
4922 my $hash = $::_repository->hash_and_insert_object(Git::temp_path($fh));
4923 Git::temp_release($fh, 1);
4924 $self->{gii}->update('100644', $hash, $gpath) or croak $!;
4926 # The directory should no longer be considered empty.
4927 delete $self->{empty}->{$dir} if exists $self->{empty}->{$dir};
4929 # Keep track of any placeholder files we create.
4930 $added_placeholder{$dir} = $path;
4931 }
4933 sub stash_placeholder_list {
4934 my ($self) = @_;
4935 my $k = "svn-remote.$repo_id.added-placeholder";
4936 my $v = eval { command_oneline('config', '--get-all', $k) };
4937 command_noisy('config', '--unset-all', $k) if $v;
4938 foreach (values %added_placeholder) {
4939 command_noisy('config', '--add', $k, $_);
4940 }
4941 }
4943 package SVN::Git::Editor;
4944 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4945 use strict;
4946 use warnings;
4947 use Carp qw/croak/;
4948 use IO::File;
4950 sub new {
4951 my ($class, $opts) = @_;
4952 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4953 die "$_ required!\n" unless (defined $opts->{$_});
4954 }
4956 my $pool = SVN::Pool->new;
4957 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4958 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4959 $opts->{r}, $mods);
4961 # $opts->{ra} functions should not be used after this:
4962 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
4963 $opts->{editor_cb}, $pool);
4964 my $self = SVN::Delta::Editor->new(@ce, $pool);
4965 bless $self, $class;
4966 foreach (qw/svn_path r tree_a tree_b/) {
4967 $self->{$_} = $opts->{$_};
4968 }
4969 $self->{url} = $opts->{ra}->{url};
4970 $self->{mods} = $mods;
4971 $self->{types} = $types;
4972 $self->{pool} = $pool;
4973 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4974 $self->{rm} = { };
4975 $self->{path_prefix} = length $self->{svn_path} ?
4976 "$self->{svn_path}/" : '';
4977 $self->{config} = $opts->{config};
4978 $self->{mergeinfo} = $opts->{mergeinfo};
4979 return $self;
4980 }
4982 sub generate_diff {
4983 my ($tree_a, $tree_b) = @_;
4984 my @diff_tree = qw(diff-tree -z -r);
4985 if ($_cp_similarity) {
4986 push @diff_tree, "-C$_cp_similarity";
4987 } else {
4988 push @diff_tree, '-C';
4989 }
4990 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4991 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4992 push @diff_tree, $tree_a, $tree_b;
4993 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4994 local $/ = "\0";
4995 my $state = 'meta';
4996 my @mods;
4997 while (<$diff_fh>) {
4998 chomp $_; # this gets rid of the trailing "\0"
4999 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
5000 ($::sha1)\s($::sha1)\s
5001 ([MTCRAD])\d*$/xo) {
5002 push @mods, { mode_a => $1, mode_b => $2,
5003 sha1_a => $3, sha1_b => $4,
5004 chg => $5 };
5005 if ($5 =~ /^(?:C|R)$/) {
5006 $state = 'file_a';
5007 } else {
5008 $state = 'file_b';
5009 }
5010 } elsif ($state eq 'file_a') {
5011 my $x = $mods[$#mods] or croak "Empty array\n";
5012 if ($x->{chg} !~ /^(?:C|R)$/) {
5013 croak "Error parsing $_, $x->{chg}\n";
5014 }
5015 $x->{file_a} = $_;
5016 $state = 'file_b';
5017 } elsif ($state eq 'file_b') {
5018 my $x = $mods[$#mods] or croak "Empty array\n";
5019 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
5020 croak "Error parsing $_, $x->{chg}\n";
5021 }
5022 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
5023 croak "Error parsing $_, $x->{chg}\n";
5024 }
5025 $x->{file_b} = $_;
5026 $state = 'meta';
5027 } else {
5028 croak "Error parsing $_\n";
5029 }
5030 }
5031 command_close_pipe($diff_fh, $ctx);
5032 \@mods;
5033 }
5035 sub check_diff_paths {
5036 my ($ra, $pfx, $rev, $mods) = @_;
5037 my %types;
5038 $pfx .= '/' if length $pfx;
5040 sub type_diff_paths {
5041 my ($ra, $types, $path, $rev) = @_;
5042 my @p = split m#/+#, $path;
5043 my $c = shift @p;
5044 unless (defined $types->{$c}) {
5045 $types->{$c} = $ra->check_path($c, $rev);
5046 }
5047 while (@p) {
5048 $c .= '/' . shift @p;
5049 next if defined $types->{$c};
5050 $types->{$c} = $ra->check_path($c, $rev);
5051 }
5052 }
5054 foreach my $m (@$mods) {
5055 foreach my $f (qw/file_a file_b/) {
5056 next unless defined $m->{$f};
5057 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
5058 if (length $pfx.$dir && ! defined $types{$dir}) {
5059 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
5060 }
5061 }
5062 }
5063 \%types;
5064 }
5066 sub split_path {
5067 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
5068 }
5070 sub repo_path {
5071 my ($self, $path) = @_;
5072 if (my $enc = $self->{pathnameencoding}) {
5073 require Encode;
5074 Encode::from_to($path, $enc, 'UTF-8');
5075 }
5076 $self->{path_prefix}.(defined $path ? $path : '');
5077 }
5079 sub url_path {
5080 my ($self, $path) = @_;
5081 if ($self->{url} =~ m#^https?://#) {
5082 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
5083 }
5084 $self->{url} . '/' . $self->repo_path($path);
5085 }
5087 sub rmdirs {
5088 my ($self) = @_;
5089 my $rm = $self->{rm};
5090 delete $rm->{''}; # we never delete the url we're tracking
5091 return unless %$rm;
5093 foreach (keys %$rm) {
5094 my @d = split m#/#, $_;
5095 my $c = shift @d;
5096 $rm->{$c} = 1;
5097 while (@d) {
5098 $c .= '/' . shift @d;
5099 $rm->{$c} = 1;
5100 }
5101 }
5102 delete $rm->{$self->{svn_path}};
5103 delete $rm->{''}; # we never delete the url we're tracking
5104 return unless %$rm;
5106 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
5107 $self->{tree_b});
5108 local $/ = "\0";
5109 while (<$fh>) {
5110 chomp;
5111 my @dn = split m#/#, $_;
5112 while (pop @dn) {
5113 delete $rm->{join '/', @dn};
5114 }
5115 unless (%$rm) {
5116 close $fh;
5117 return;
5118 }
5119 }
5120 command_close_pipe($fh, $ctx);
5122 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
5123 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
5124 $self->close_directory($bat->{$d}, $p);
5125 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
5126 print "\tD+\t$d/\n" unless $::_q;
5127 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
5128 delete $bat->{$d};
5129 }
5130 }
5132 sub open_or_add_dir {
5133 my ($self, $full_path, $baton) = @_;
5134 my $t = $self->{types}->{$full_path};
5135 if (!defined $t) {
5136 die "$full_path not known in r$self->{r} or we have a bug!\n";
5137 }
5138 {
5139 no warnings 'once';
5140 # SVN::Node::none and SVN::Node::file are used only once,
5141 # so we're shutting up Perl's warnings about them.
5142 if ($t == $SVN::Node::none) {
5143 return $self->add_directory($full_path, $baton,
5144 undef, -1, $self->{pool});
5145 } elsif ($t == $SVN::Node::dir) {
5146 return $self->open_directory($full_path, $baton,
5147 $self->{r}, $self->{pool});
5148 } # no warnings 'once'
5149 print STDERR "$full_path already exists in repository at ",
5150 "r$self->{r} and it is not a directory (",
5151 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
5152 } # no warnings 'once'
5153 exit 1;
5154 }
5156 sub ensure_path {
5157 my ($self, $path) = @_;
5158 my $bat = $self->{bat};
5159 my $repo_path = $self->repo_path($path);
5160 return $bat->{''} unless (length $repo_path);
5161 my @p = split m#/+#, $repo_path;
5162 my $c = shift @p;
5163 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
5164 while (@p) {
5165 my $c0 = $c;
5166 $c .= '/' . shift @p;
5167 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
5168 }
5169 return $bat->{$c};
5170 }
5172 # Subroutine to convert a globbing pattern to a regular expression.
5173 # From perl cookbook.
5174 sub glob2pat {
5175 my $globstr = shift;
5176 my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
5177 $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
5178 return '^' . $globstr . '$';
5179 }
5181 sub check_autoprop {
5182 my ($self, $pattern, $properties, $file, $fbat) = @_;
5183 # Convert the globbing pattern to a regular expression.
5184 my $regex = glob2pat($pattern);
5185 # Check if the pattern matches the file name.
5186 if($file =~ m/($regex)/) {
5187 # Parse the list of properties to set.
5188 my @props = split(/;/, $properties);
5189 foreach my $prop (@props) {
5190 # Parse 'name=value' syntax and set the property.
5191 if ($prop =~ /([^=]+)=(.*)/) {
5192 my ($n,$v) = ($1,$2);
5193 for ($n, $v) {
5194 s/^\s+//; s/\s+$//;
5195 }
5196 $self->change_file_prop($fbat, $n, $v);
5197 }
5198 }
5199 }
5200 }
5202 sub apply_autoprops {
5203 my ($self, $file, $fbat) = @_;
5204 my $conf_t = ${$self->{config}}{'config'};
5205 no warnings 'once';
5206 # Check [miscellany]/enable-auto-props in svn configuration.
5207 if (SVN::_Core::svn_config_get_bool(
5208 $conf_t,
5209 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
5210 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
5211 0)) {
5212 # Auto-props are enabled. Enumerate them to look for matches.
5213 my $callback = sub {
5214 $self->check_autoprop($_[0], $_[1], $file, $fbat);
5215 };
5216 SVN::_Core::svn_config_enumerate(
5217 $conf_t,
5218 $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
5219 $callback);
5220 }
5221 }
5223 sub A {
5224 my ($self, $m) = @_;
5225 my ($dir, $file) = split_path($m->{file_b});
5226 my $pbat = $self->ensure_path($dir);
5227 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
5228 undef, -1);
5229 print "\tA\t$m->{file_b}\n" unless $::_q;
5230 $self->apply_autoprops($file, $fbat);
5231 $self->chg_file($fbat, $m);
5232 $self->close_file($fbat,undef,$self->{pool});
5233 }
5235 sub C {
5236 my ($self, $m) = @_;
5237 my ($dir, $file) = split_path($m->{file_b});
5238 my $pbat = $self->ensure_path($dir);
5239 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
5240 $self->url_path($m->{file_a}), $self->{r});
5241 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
5242 $self->chg_file($fbat, $m);
5243 $self->close_file($fbat,undef,$self->{pool});
5244 }
5246 sub delete_entry {
5247 my ($self, $path, $pbat) = @_;
5248 my $rpath = $self->repo_path($path);
5249 my ($dir, $file) = split_path($rpath);
5250 $self->{rm}->{$dir} = 1;
5251 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
5252 }
5254 sub R {
5255 my ($self, $m) = @_;
5256 my ($dir, $file) = split_path($m->{file_b});
5257 my $pbat = $self->ensure_path($dir);
5258 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
5259 $self->url_path($m->{file_a}), $self->{r});
5260 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
5261 $self->apply_autoprops($file, $fbat);
5262 $self->chg_file($fbat, $m);
5263 $self->close_file($fbat,undef,$self->{pool});
5265 ($dir, $file) = split_path($m->{file_a});
5266 $pbat = $self->ensure_path($dir);
5267 $self->delete_entry($m->{file_a}, $pbat);
5268 }
5270 sub M {
5271 my ($self, $m) = @_;
5272 my ($dir, $file) = split_path($m->{file_b});
5273 my $pbat = $self->ensure_path($dir);
5274 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
5275 $pbat,$self->{r},$self->{pool});
5276 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
5277 $self->chg_file($fbat, $m);
5278 $self->close_file($fbat,undef,$self->{pool});
5279 }
5281 sub T { shift->M(@_) }
5283 sub change_file_prop {
5284 my ($self, $fbat, $pname, $pval) = @_;
5285 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
5286 }
5288 sub change_dir_prop {
5289 my ($self, $pbat, $pname, $pval) = @_;
5290 $self->SUPER::change_dir_prop($pbat, $pname, $pval, $self->{pool});
5291 }
5293 sub _chg_file_get_blob ($$$$) {
5294 my ($self, $fbat, $m, $which) = @_;
5295 my $fh = $::_repository->temp_acquire("git_blob_$which");
5296 if ($m->{"mode_$which"} =~ /^120/) {
5297 print $fh 'link ' or croak $!;
5298 $self->change_file_prop($fbat,'svn:special','*');
5299 } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
5300 $self->change_file_prop($fbat,'svn:special',undef);
5301 }
5302 my $blob = $m->{"sha1_$which"};
5303 return ($fh,) if ($blob =~ /^0{40}$/);
5304 my $size = $::_repository->cat_blob($blob, $fh);
5305 croak "Failed to read object $blob" if ($size < 0);
5306 $fh->flush == 0 or croak $!;
5307 seek $fh, 0, 0 or croak $!;
5309 my $exp = ::md5sum($fh);
5310 seek $fh, 0, 0 or croak $!;
5311 return ($fh, $exp);
5312 }
5314 sub chg_file {
5315 my ($self, $fbat, $m) = @_;
5316 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
5317 $self->change_file_prop($fbat,'svn:executable','*');
5318 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
5319 $self->change_file_prop($fbat,'svn:executable',undef);
5320 }
5321 my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
5322 my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
5323 my $pool = SVN::Pool->new;
5324 my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
5325 if (-s $fh_a) {
5326 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
5327 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
5328 if (defined $res) {
5329 die "Unexpected result from send_txstream: $res\n",
5330 "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
5331 }
5332 } else {
5333 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
5334 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
5335 if ($got ne $exp_b);
5336 }
5337 Git::temp_release($fh_b, 1);
5338 Git::temp_release($fh_a, 1);
5339 $pool->clear;
5340 }
5342 sub D {
5343 my ($self, $m) = @_;
5344 my ($dir, $file) = split_path($m->{file_b});
5345 my $pbat = $self->ensure_path($dir);
5346 print "\tD\t$m->{file_b}\n" unless $::_q;
5347 $self->delete_entry($m->{file_b}, $pbat);
5348 }
5350 sub close_edit {
5351 my ($self) = @_;
5352 my ($p,$bat) = ($self->{pool}, $self->{bat});
5353 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
5354 next if $_ eq '';
5355 $self->close_directory($bat->{$_}, $p);
5356 }
5357 $self->close_directory($bat->{''}, $p);
5358 $self->SUPER::close_edit($p);
5359 $p->clear;
5360 }
5362 sub abort_edit {
5363 my ($self) = @_;
5364 $self->SUPER::abort_edit($self->{pool});
5365 }
5367 sub DESTROY {
5368 my $self = shift;
5369 $self->SUPER::DESTROY(@_);
5370 $self->{pool}->clear;
5371 }
5373 # this drives the editor
5374 sub apply_diff {
5375 my ($self) = @_;
5376 my $mods = $self->{mods};
5377 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
5378 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
5379 my $f = $m->{chg};
5380 if (defined $o{$f}) {
5381 $self->$f($m);
5382 } else {
5383 fatal("Invalid change type: $f");
5384 }
5385 }
5387 if (defined($self->{mergeinfo})) {
5388 $self->change_dir_prop($self->{bat}{''}, "svn:mergeinfo",
5389 $self->{mergeinfo});
5390 }
5391 $self->rmdirs if $_rmdir;
5392 if (@$mods == 0) {
5393 $self->abort_edit;
5394 } else {
5395 $self->close_edit;
5396 }
5397 return scalar @$mods;
5398 }
5400 package Git::SVN::Ra;
5401 use vars qw/@ISA $config_dir $_ignore_refs_regex $_log_window_size/;
5402 use strict;
5403 use warnings;
5404 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
5406 BEGIN {
5407 # enforce temporary pool usage for some simple functions
5408 no strict 'refs';
5409 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
5410 get_file/) {
5411 my $SUPER = "SUPER::$f";
5412 *$f = sub {
5413 my $self = shift;
5414 my $pool = SVN::Pool->new;
5415 my @ret = $self->$SUPER(@_,$pool);
5416 $pool->clear;
5417 wantarray ? @ret : $ret[0];
5418 };
5419 }
5420 }
5422 sub _auth_providers () {
5423 [
5424 SVN::Client::get_simple_provider(),
5425 SVN::Client::get_ssl_server_trust_file_provider(),
5426 SVN::Client::get_simple_prompt_provider(
5427 \&Git::SVN::Prompt::simple, 2),
5428 SVN::Client::get_ssl_client_cert_file_provider(),
5429 SVN::Client::get_ssl_client_cert_prompt_provider(
5430 \&Git::SVN::Prompt::ssl_client_cert, 2),
5431 SVN::Client::get_ssl_client_cert_pw_file_provider(),
5432 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
5433 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
5434 SVN::Client::get_username_provider(),
5435 SVN::Client::get_ssl_server_trust_prompt_provider(
5436 \&Git::SVN::Prompt::ssl_server_trust),
5437 SVN::Client::get_username_prompt_provider(
5438 \&Git::SVN::Prompt::username, 2)
5439 ]
5440 }
5442 sub escape_uri_only {
5443 my ($uri) = @_;
5444 my @tmp;
5445 foreach (split m{/}, $uri) {
5446 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
5447 push @tmp, $_;
5448 }
5449 join('/', @tmp);
5450 }
5452 sub escape_url {
5453 my ($url) = @_;
5454 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
5455 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
5456 $url = "$scheme://$domain$uri";
5457 }
5458 $url;
5459 }
5461 sub new {
5462 my ($class, $url) = @_;
5463 $url =~ s!/+$!!;
5464 return $RA if ($RA && $RA->{url} eq $url);
5466 ::_req_svn();
5468 SVN::_Core::svn_config_ensure($config_dir, undef);
5469 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
5470 my $config = SVN::Core::config_get_config($config_dir);
5471 $RA = undef;
5472 my $dont_store_passwords = 1;
5473 my $conf_t = ${$config}{'config'};
5474 {
5475 no warnings 'once';
5476 # The usage of $SVN::_Core::SVN_CONFIG_* variables
5477 # produces warnings that variables are used only once.
5478 # I had not found the better way to shut them up, so
5479 # the warnings of type 'once' are disabled in this block.
5480 if (SVN::_Core::svn_config_get_bool($conf_t,
5481 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
5482 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
5483 1) == 0) {
5484 SVN::_Core::svn_auth_set_parameter($baton,
5485 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
5486 bless (\$dont_store_passwords, "_p_void"));
5487 }
5488 if (SVN::_Core::svn_config_get_bool($conf_t,
5489 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
5490 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
5491 1) == 0) {
5492 $Git::SVN::Prompt::_no_auth_cache = 1;
5493 }
5494 } # no warnings 'once'
5495 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
5496 config => $config,
5497 pool => SVN::Pool->new,
5498 auth_provider_callbacks => $callbacks);
5499 $self->{url} = $url;
5500 $self->{svn_path} = $url;
5501 $self->{repos_root} = $self->get_repos_root;
5502 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
5503 $self->{cache} = { check_path => { r => 0, data => {} },
5504 get_dir => { r => 0, data => {} } };
5505 $RA = bless $self, $class;
5506 }
5508 sub check_path {
5509 my ($self, $path, $r) = @_;
5510 my $cache = $self->{cache}->{check_path};
5511 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
5512 return $cache->{data}->{$path};
5513 }
5514 my $pool = SVN::Pool->new;
5515 my $t = $self->SUPER::check_path($path, $r, $pool);
5516 $pool->clear;
5517 if ($r != $cache->{r}) {
5518 %{$cache->{data}} = ();
5519 $cache->{r} = $r;
5520 }
5521 $cache->{data}->{$path} = $t;
5522 }
5524 sub get_dir {
5525 my ($self, $dir, $r) = @_;
5526 my $cache = $self->{cache}->{get_dir};
5527 if ($r == $cache->{r}) {
5528 if (my $x = $cache->{data}->{$dir}) {
5529 return wantarray ? @$x : $x->[0];
5530 }
5531 }
5532 my $pool = SVN::Pool->new;
5533 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
5534 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
5535 $pool->clear;
5536 if ($r != $cache->{r}) {
5537 %{$cache->{data}} = ();
5538 $cache->{r} = $r;
5539 }
5540 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5541 wantarray ? (\%dirents, $r, $props) : \%dirents;
5542 }
5544 sub DESTROY {
5545 # do not call the real DESTROY since we store ourselves in $RA
5546 }
5548 # get_log(paths, start, end, limit,
5549 # discover_changed_paths, strict_node_history, receiver)
5550 sub get_log {
5551 my ($self, @args) = @_;
5552 my $pool = SVN::Pool->new;
5554 # svn_log_changed_path_t objects passed to get_log are likely to be
5555 # overwritten even if only the refs are copied to an external variable,
5556 # so we should dup the structures in their entirety. Using an
5557 # externally passed pool (instead of our temporary and quickly cleared
5558 # pool in Git::SVN::Ra) does not help matters at all...
5559 my $receiver = pop @args;
5560 my $prefix = "/".$self->{svn_path};
5561 $prefix =~ s#/+($)##;
5562 my $prefix_regex = qr#^\Q$prefix\E#;
5563 push(@args, sub {
5564 my ($paths) = $_[0];
5565 return &$receiver(@_) unless $paths;
5566 $_[0] = ();
5567 foreach my $p (keys %$paths) {
5568 my $i = $paths->{$p};
5569 # Make path relative to our url, not repos_root
5570 $p =~ s/$prefix_regex//;
5571 my %s = map { $_ => $i->$_; }
5572 qw/copyfrom_path copyfrom_rev action/;
5573 if ($s{'copyfrom_path'}) {
5574 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5575 }
5576 $_[0]{$p} = \%s;
5577 }
5578 &$receiver(@_);
5579 });
5582 # the limit parameter was not supported in SVN 1.1.x, so we
5583 # drop it. Therefore, the receiver callback passed to it
5584 # is made aware of this limitation by being wrapped if
5585 # the limit passed to is being wrapped.
5586 if ($SVN::Core::VERSION le '1.2.0') {
5587 my $limit = splice(@args, 3, 1);
5588 if ($limit > 0) {
5589 my $receiver = pop @args;
5590 push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5591 }
5592 }
5593 my $ret = $self->SUPER::get_log(@args, $pool);
5594 $pool->clear;
5595 $ret;
5596 }
5598 sub trees_match {
5599 my ($self, $url1, $rev1, $url2, $rev2) = @_;
5600 my $ctx = SVN::Client->new(auth => _auth_providers);
5601 my $out = IO::File->new_tmpfile;
5603 # older SVN (1.1.x) doesn't take $pool as the last parameter for
5604 # $ctx->diff(), so we'll create a default one
5605 my $pool = SVN::Pool->new_default_sub;
5607 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5608 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5609 $out->flush;
5610 my $ret = (($out->stat)[7] == 0);
5611 close $out or croak $!;
5613 $ret;
5614 }
5616 sub get_commit_editor {
5617 my ($self, $log, $cb, $pool) = @_;
5618 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5619 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5620 }
5622 sub gs_do_update {
5623 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5624 my $new = ($rev_a == $rev_b);
5625 my $path = $gs->{path};
5627 if ($new && -e $gs->{index}) {
5628 unlink $gs->{index} or die
5629 "Couldn't unlink index: $gs->{index}: $!\n";
5630 }
5631 my $pool = SVN::Pool->new;
5632 $editor->set_path_strip($path);
5633 my (@pc) = split m#/#, $path;
5634 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5635 1, $editor, $pool);
5636 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5638 # Since we can't rely on svn_ra_reparent being available, we'll
5639 # just have to do some magic with set_path to make it so
5640 # we only want a partial path.
5641 my $sp = '';
5642 my $final = join('/', @pc);
5643 while (@pc) {
5644 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5645 $sp .= '/' if length $sp;
5646 $sp .= shift @pc;
5647 }
5648 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5650 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5652 $reporter->finish_report($pool);
5653 $pool->clear;
5654 $editor->{git_commit_ok};
5655 }
5657 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5658 # svn_ra_reparent didn't work before 1.4)
5659 sub gs_do_switch {
5660 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5661 my $path = $gs->{path};
5662 my $pool = SVN::Pool->new;
5664 my $full_url = $self->{url};
5665 my $old_url = $full_url;
5666 $full_url .= '/' . $path if length $path;
5667 my ($ra, $reparented);
5669 if ($old_url =~ m#^svn(\+ssh)?://# ||
5670 ($full_url =~ m#^https?://# &&
5671 escape_url($full_url) ne $full_url)) {
5672 $_[0] = undef;
5673 $self = undef;
5674 $RA = undef;
5675 $ra = Git::SVN::Ra->new($full_url);
5676 $ra_invalid = 1;
5677 } elsif ($old_url ne $full_url) {
5678 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5679 $self->{url} = $full_url;
5680 $reparented = 1;
5681 }
5683 $ra ||= $self;
5684 $url_b = escape_url($url_b);
5685 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5686 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5687 $reporter->set_path('', $rev_a, 0, @lock, $pool);
5688 $reporter->finish_report($pool);
5690 if ($reparented) {
5691 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5692 $self->{url} = $old_url;
5693 }
5695 $pool->clear;
5696 $editor->{git_commit_ok};
5697 }
5699 sub longest_common_path {
5700 my ($gsv, $globs) = @_;
5701 my %common;
5702 my $common_max = scalar @$gsv;
5704 foreach my $gs (@$gsv) {
5705 my @tmp = split m#/#, $gs->{path};
5706 my $p = '';
5707 foreach (@tmp) {
5708 $p .= length($p) ? "/$_" : $_;
5709 $common{$p} ||= 0;
5710 $common{$p}++;
5711 }
5712 }
5713 $globs ||= [];
5714 $common_max += scalar @$globs;
5715 foreach my $glob (@$globs) {
5716 my @tmp = split m#/#, $glob->{path}->{left};
5717 my $p = '';
5718 foreach (@tmp) {
5719 $p .= length($p) ? "/$_" : $_;
5720 $common{$p} ||= 0;
5721 $common{$p}++;
5722 }
5723 }
5725 my $longest_path = '';
5726 foreach (sort {length $b <=> length $a} keys %common) {
5727 if ($common{$_} == $common_max) {
5728 $longest_path = $_;
5729 last;
5730 }
5731 }
5732 $longest_path;
5733 }
5735 sub gs_fetch_loop_common {
5736 my ($self, $base, $head, $gsv, $globs) = @_;
5737 return if ($base > $head);
5738 my $inc = $_log_window_size;
5739 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5740 my $longest_path = longest_common_path($gsv, $globs);
5741 my $ra_url = $self->{url};
5742 my $find_trailing_edge;
5743 while (1) {
5744 my %revs;
5745 my $err;
5746 my $err_handler = $SVN::Error::handler;
5747 $SVN::Error::handler = sub {
5748 ($err) = @_;
5749 skip_unknown_revs($err);
5750 };
5751 sub _cb {
5752 my ($paths, $r, $author, $date, $log) = @_;
5753 [ $paths,
5754 { author => $author, date => $date, log => $log } ];
5755 }
5756 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5757 sub { $revs{$_[1]} = _cb(@_) });
5758 if ($err) {
5759 print "Checked through r$max\r";
5760 } else {
5761 $find_trailing_edge = 1;
5762 }
5763 if ($err and $find_trailing_edge) {
5764 print STDERR "Path '$longest_path' ",
5765 "was probably deleted:\n",
5766 $err->expanded_message,
5767 "\nWill attempt to follow ",
5768 "revisions r$min .. r$max ",
5769 "committed before the deletion\n";
5770 my $hi = $max;
5771 while (--$hi >= $min) {
5772 my $ok;
5773 $self->get_log([$longest_path], $min, $hi,
5774 0, 1, 1, sub {
5775 $ok = $_[1];
5776 $revs{$_[1]} = _cb(@_) });
5777 if ($ok) {
5778 print STDERR "r$min .. r$ok OK\n";
5779 last;
5780 }
5781 }
5782 $find_trailing_edge = 0;
5783 }
5784 $SVN::Error::handler = $err_handler;
5786 my %exists = map { $_->{path} => $_ } @$gsv;
5787 foreach my $r (sort {$a <=> $b} keys %revs) {
5788 my ($paths, $logged) = @{$revs{$r}};
5790 foreach my $gs ($self->match_globs(\%exists, $paths,
5791 $globs, $r)) {
5792 if ($gs->rev_map_max >= $r) {
5793 next;
5794 }
5795 next unless $gs->match_paths($paths, $r);
5796 $gs->{logged_rev_props} = $logged;
5797 if (my $last_commit = $gs->last_commit) {
5798 $gs->assert_index_clean($last_commit);
5799 }
5800 my $log_entry = $gs->do_fetch($paths, $r);
5801 if ($log_entry) {
5802 $gs->do_git_commit($log_entry);
5803 }
5804 $INDEX_FILES{$gs->{index}} = 1;
5805 }
5806 foreach my $g (@$globs) {
5807 my $k = "svn-remote.$g->{remote}." .
5808 "$g->{t}-maxRev";
5809 Git::SVN::tmp_config($k, $r);
5810 }
5811 if ($ra_invalid) {
5812 $_[0] = undef;
5813 $self = undef;
5814 $RA = undef;
5815 $self = Git::SVN::Ra->new($ra_url);
5816 $ra_invalid = undef;
5817 }
5818 }
5819 # pre-fill the .rev_db since it'll eventually get filled in
5820 # with '0' x40 if something new gets committed
5821 foreach my $gs (@$gsv) {
5822 next if $gs->rev_map_max >= $max;
5823 next if defined $gs->rev_map_get($max);
5824 $gs->rev_map_set($max, 0 x40);
5825 }
5826 foreach my $g (@$globs) {
5827 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5828 Git::SVN::tmp_config($k, $max);
5829 }
5830 last if $max >= $head;
5831 $min = $max + 1;
5832 $max += $inc;
5833 $max = $head if ($max > $head);
5834 }
5835 Git::SVN::gc();
5836 }
5838 sub get_dir_globbed {
5839 my ($self, $left, $depth, $r) = @_;
5841 my @x = eval { $self->get_dir($left, $r) };
5842 return unless scalar @x == 3;
5843 my $dirents = $x[0];
5844 my @finalents;
5845 foreach my $de (keys %$dirents) {
5846 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5847 if ($depth > 1) {
5848 my @args = ("$left/$de", $depth - 1, $r);
5849 foreach my $dir ($self->get_dir_globbed(@args)) {
5850 push @finalents, "$de/$dir";
5851 }
5852 } else {
5853 push @finalents, $de;
5854 }
5855 }
5856 @finalents;
5857 }
5859 # return value: 0 -- don't ignore, 1 -- ignore
5860 sub is_ref_ignored {
5861 my ($g, $p) = @_;
5862 my $refname = $g->{ref}->full_path($p);
5863 return 1 if defined($g->{ignore_refs_regex}) &&
5864 $refname =~ m!$g->{ignore_refs_regex}!;
5865 return 0 unless defined($_ignore_refs_regex);
5866 return 1 if $refname =~ m!$_ignore_refs_regex!o;
5867 return 0;
5868 }
5870 sub match_globs {
5871 my ($self, $exists, $paths, $globs, $r) = @_;
5873 sub get_dir_check {
5874 my ($self, $exists, $g, $r) = @_;
5876 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5877 $g->{path}->{depth},
5878 $r);
5880 foreach my $de (@dirs) {
5881 my $p = $g->{path}->full_path($de);
5882 next if $exists->{$p};
5883 next if (length $g->{path}->{right} &&
5884 ($self->check_path($p, $r) !=
5885 $SVN::Node::dir));
5886 next unless $p =~ /$g->{path}->{regex}/;
5887 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5888 $g->{ref}->full_path($de), 1);
5889 }
5890 }
5891 foreach my $g (@$globs) {
5892 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5893 if ($path->{action} =~ /^[AR]$/) {
5894 get_dir_check($self, $exists, $g, $r);
5895 }
5896 }
5897 foreach (keys %$paths) {
5898 if (/$g->{path}->{left_regex}/ &&
5899 !/$g->{path}->{regex}/) {
5900 next if $paths->{$_}->{action} !~ /^[AR]$/;
5901 get_dir_check($self, $exists, $g, $r);
5902 }
5903 next unless /$g->{path}->{regex}/;
5904 my $p = $1;
5905 my $pathname = $g->{path}->full_path($p);
5906 next if is_ref_ignored($g, $p);
5907 next if $exists->{$pathname};
5908 next if ($self->check_path($pathname, $r) !=
5909 $SVN::Node::dir);
5910 $exists->{$pathname} = Git::SVN->init(
5911 $self->{url}, $pathname, undef,
5912 $g->{ref}->full_path($p), 1);
5913 }
5914 my $c = '';
5915 foreach (split m#/#, $g->{path}->{left}) {
5916 $c .= "/$_";
5917 next unless ($paths->{$c} &&
5918 ($paths->{$c}->{action} =~ /^[AR]$/));
5919 get_dir_check($self, $exists, $g, $r);
5920 }
5921 }
5922 values %$exists;
5923 }
5925 sub minimize_url {
5926 my ($self) = @_;
5927 return $self->{url} if ($self->{url} eq $self->{repos_root});
5928 my $url = $self->{repos_root};
5929 my @components = split(m!/!, $self->{svn_path});
5930 my $c = '';
5931 do {
5932 $url .= "/$c" if length $c;
5933 eval {
5934 my $ra = (ref $self)->new($url);
5935 my $latest = $ra->get_latest_revnum;
5936 $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5937 };
5938 } while ($@ && ($c = shift @components));
5939 $url;
5940 }
5942 sub can_do_switch {
5943 my $self = shift;
5944 unless (defined $can_do_switch) {
5945 my $pool = SVN::Pool->new;
5946 my $rep = eval {
5947 $self->do_switch(1, '', 0, $self->{url},
5948 SVN::Delta::Editor->new, $pool);
5949 };
5950 if ($@) {
5951 $can_do_switch = 0;
5952 } else {
5953 $rep->abort_report($pool);
5954 $can_do_switch = 1;
5955 }
5956 $pool->clear;
5957 }
5958 $can_do_switch;
5959 }
5961 sub skip_unknown_revs {
5962 my ($err) = @_;
5963 my $errno = $err->apr_err();
5964 # Maybe the branch we're tracking didn't
5965 # exist when the repo started, so it's
5966 # not an error if it doesn't, just continue
5967 #
5968 # Wonderfully consistent library, eh?
5969 # 160013 - svn:// and file://
5970 # 175002 - http(s)://
5971 # 175007 - http(s):// (this repo required authorization, too...)
5972 # More codes may be discovered later...
5973 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5974 my $err_key = $err->expanded_message;
5975 # revision numbers change every time, filter them out
5976 $err_key =~ s/\d+/\0/g;
5977 $err_key = "$errno\0$err_key";
5978 unless ($ignored_err{$err_key}) {
5979 warn "W: Ignoring error from SVN, path probably ",
5980 "does not exist: ($errno): ",
5981 $err->expanded_message,"\n";
5982 warn "W: Do not be alarmed at the above message ",
5983 "git-svn is just searching aggressively for ",
5984 "old history.\n",
5985 "This may take a while on large repositories\n";
5986 $ignored_err{$err_key} = 1;
5987 }
5988 return;
5989 }
5990 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5991 }
5993 package Git::SVN::Log;
5994 use strict;
5995 use warnings;
5996 use POSIX qw/strftime/;
5997 use Time::Local;
5998 use constant commit_log_separator => ('-' x 72) . "\n";
5999 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
6000 %rusers $show_commit $incremental/;
6001 my $l_fmt;
6003 sub cmt_showable {
6004 my ($c) = @_;
6005 return 1 if defined $c->{r};
6007 # big commit message got truncated by the 16k pretty buffer in rev-list
6008 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
6009 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
6010 @{$c->{l}} = ();
6011 my @log = command(qw/cat-file commit/, $c->{c});
6013 # shift off the headers
6014 shift @log while ($log[0] ne '');
6015 shift @log;
6017 # TODO: make $c->{l} not have a trailing newline in the future
6018 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
6020 (undef, $c->{r}, undef) = ::extract_metadata(
6021 (grep(/^git-svn-id: /, @log))[-1]);
6022 }
6023 return defined $c->{r};
6024 }
6026 sub log_use_color {
6027 return $color || Git->repository->get_colorbool('color.diff');
6028 }
6030 sub git_svn_log_cmd {
6031 my ($r_min, $r_max, @args) = @_;
6032 my $head = 'HEAD';
6033 my (@files, @log_opts);
6034 foreach my $x (@args) {
6035 if ($x eq '--' || @files) {
6036 push @files, $x;
6037 } else {
6038 if (::verify_ref("$x^0")) {
6039 $head = $x;
6040 } else {
6041 push @log_opts, $x;
6042 }
6043 }
6044 }
6046 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
6047 $gs ||= Git::SVN->_new;
6048 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
6049 $gs->refname);
6050 push @cmd, '-r' unless $non_recursive;
6051 push @cmd, qw/--raw --name-status/ if $verbose;
6052 push @cmd, '--color' if log_use_color();
6053 push @cmd, @log_opts;
6054 if (defined $r_max && $r_max == $r_min) {
6055 push @cmd, '--max-count=1';
6056 if (my $c = $gs->rev_map_get($r_max)) {
6057 push @cmd, $c;
6058 }
6059 } elsif (defined $r_max) {
6060 if ($r_max < $r_min) {
6061 ($r_min, $r_max) = ($r_max, $r_min);
6062 }
6063 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
6064 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
6065 # If there are no commits in the range, both $c_max and $c_min
6066 # will be undefined. If there is at least 1 commit in the
6067 # range, both will be defined.
6068 return () if !defined $c_min || !defined $c_max;
6069 if ($c_min eq $c_max) {
6070 push @cmd, '--max-count=1', $c_min;
6071 } else {
6072 push @cmd, '--boundary', "$c_min..$c_max";
6073 }
6074 }
6075 return (@cmd, @files);
6076 }
6078 # adapted from pager.c
6079 sub config_pager {
6080 if (! -t *STDOUT) {
6081 $ENV{GIT_PAGER_IN_USE} = 'false';
6082 $pager = undef;
6083 return;
6084 }
6085 chomp($pager = command_oneline(qw(var GIT_PAGER)));
6086 if ($pager eq 'cat') {
6087 $pager = undef;
6088 }
6089 $ENV{GIT_PAGER_IN_USE} = defined($pager);
6090 }
6092 sub run_pager {
6093 return unless defined $pager;
6094 pipe my ($rfd, $wfd) or return;
6095 defined(my $pid = fork) or ::fatal "Can't fork: $!";
6096 if (!$pid) {
6097 open STDOUT, '>&', $wfd or
6098 ::fatal "Can't redirect to stdout: $!";
6099 return;
6100 }
6101 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
6102 $ENV{LESS} ||= 'FRSX';
6103 exec $pager or ::fatal "Can't run pager: $! ($pager)";
6104 }
6106 sub format_svn_date {
6107 # some systmes don't handle or mishandle %z, so be creative.
6108 my $t = shift || time;
6109 my $gm = timelocal(gmtime($t));
6110 my $sign = qw( + + - )[ $t <=> $gm ];
6111 my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
6112 return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
6113 }
6115 sub parse_git_date {
6116 my ($t, $tz) = @_;
6117 # Date::Parse isn't in the standard Perl distro :(
6118 if ($tz =~ s/^\+//) {
6119 $t += tz_to_s_offset($tz);
6120 } elsif ($tz =~ s/^\-//) {
6121 $t -= tz_to_s_offset($tz);
6122 }
6123 return $t;
6124 }
6126 sub set_local_timezone {
6127 if (defined $TZ) {
6128 $ENV{TZ} = $TZ;
6129 } else {
6130 delete $ENV{TZ};
6131 }
6132 }
6134 sub tz_to_s_offset {
6135 my ($tz) = @_;
6136 $tz =~ s/(\d\d)$//;
6137 return ($1 * 60) + ($tz * 3600);
6138 }
6140 sub get_author_info {
6141 my ($dest, $author, $t, $tz) = @_;
6142 $author =~ s/(?:^\s*|\s*$)//g;
6143 $dest->{a_raw} = $author;
6144 my $au;
6145 if ($::_authors) {
6146 $au = $rusers{$author} || undef;
6147 }
6148 if (!$au) {
6149 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
6150 }
6151 $dest->{t} = $t;
6152 $dest->{tz} = $tz;
6153 $dest->{a} = $au;
6154 $dest->{t_utc} = parse_git_date($t, $tz);
6155 }
6157 sub process_commit {
6158 my ($c, $r_min, $r_max, $defer) = @_;
6159 if (defined $r_min && defined $r_max) {
6160 if ($r_min == $c->{r} && $r_min == $r_max) {
6161 show_commit($c);
6162 return 0;
6163 }
6164 return 1 if $r_min == $r_max;
6165 if ($r_min < $r_max) {
6166 # we need to reverse the print order
6167 return 0 if (defined $limit && --$limit < 0);
6168 push @$defer, $c;
6169 return 1;
6170 }
6171 if ($r_min != $r_max) {
6172 return 1 if ($r_min < $c->{r});
6173 return 1 if ($r_max > $c->{r});
6174 }
6175 }
6176 return 0 if (defined $limit && --$limit < 0);
6177 show_commit($c);
6178 return 1;
6179 }
6181 sub show_commit {
6182 my $c = shift;
6183 if ($oneline) {
6184 my $x = "\n";
6185 if (my $l = $c->{l}) {
6186 while ($l->[0] =~ /^\s*$/) { shift @$l }
6187 $x = $l->[0];
6188 }
6189 $l_fmt ||= 'A' . length($c->{r});
6190 print 'r',pack($l_fmt, $c->{r}),' | ';
6191 print "$c->{c} | " if $show_commit;
6192 print $x;
6193 } else {
6194 show_commit_normal($c);
6195 }
6196 }
6198 sub show_commit_changed_paths {
6199 my ($c) = @_;
6200 return unless $c->{changed};
6201 print "Changed paths:\n", @{$c->{changed}};
6202 }
6204 sub show_commit_normal {
6205 my ($c) = @_;
6206 print commit_log_separator, "r$c->{r} | ";
6207 print "$c->{c} | " if $show_commit;
6208 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
6209 my $nr_line = 0;
6211 if (my $l = $c->{l}) {
6212 while ($l->[$#$l] eq "\n" && $#$l > 0
6213 && $l->[($#$l - 1)] eq "\n") {
6214 pop @$l;
6215 }
6216 $nr_line = scalar @$l;
6217 if (!$nr_line) {
6218 print "1 line\n\n\n";
6219 } else {
6220 if ($nr_line == 1) {
6221 $nr_line = '1 line';
6222 } else {
6223 $nr_line .= ' lines';
6224 }
6225 print $nr_line, "\n";
6226 show_commit_changed_paths($c);
6227 print "\n";
6228 print $_ foreach @$l;
6229 }
6230 } else {
6231 print "1 line\n";
6232 show_commit_changed_paths($c);
6233 print "\n";
6235 }
6236 foreach my $x (qw/raw stat diff/) {
6237 if ($c->{$x}) {
6238 print "\n";
6239 print $_ foreach @{$c->{$x}}
6240 }
6241 }
6242 }
6244 sub cmd_show_log {
6245 my (@args) = @_;
6246 my ($r_min, $r_max);
6247 my $r_last = -1; # prevent dupes
6248 set_local_timezone();
6249 if (defined $::_revision) {
6250 if ($::_revision =~ /^(\d+):(\d+)$/) {
6251 ($r_min, $r_max) = ($1, $2);
6252 } elsif ($::_revision =~ /^\d+$/) {
6253 $r_min = $r_max = $::_revision;
6254 } else {
6255 ::fatal "-r$::_revision is not supported, use ",
6256 "standard 'git log' arguments instead";
6257 }
6258 }
6260 config_pager();
6261 @args = git_svn_log_cmd($r_min, $r_max, @args);
6262 if (!@args) {
6263 print commit_log_separator unless $incremental || $oneline;
6264 return;
6265 }
6266 my $log = command_output_pipe(@args);
6267 run_pager();
6268 my (@k, $c, $d, $stat);
6269 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
6270 while (<$log>) {
6271 if (/^${esc_color}commit (?:- )?($::sha1_short)/o) {
6272 my $cmt = $1;
6273 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
6274 $r_last = $c->{r};
6275 process_commit($c, $r_min, $r_max, \@k) or
6276 goto out;
6277 }
6278 $d = undef;
6279 $c = { c => $cmt };
6280 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
6281 get_author_info($c, $1, $2, $3);
6282 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
6283 # ignore
6284 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
6285 push @{$c->{raw}}, $_;
6286 } elsif (/^${esc_color}[ACRMDT]\t/) {
6287 # we could add $SVN->{svn_path} here, but that requires
6288 # remote access at the moment (repo_path_split)...
6289 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
6290 push @{$c->{changed}}, $_;
6291 } elsif (/^${esc_color}diff /o) {
6292 $d = 1;
6293 push @{$c->{diff}}, $_;
6294 } elsif ($d) {
6295 push @{$c->{diff}}, $_;
6296 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
6297 $esc_color*[\+\-]*$esc_color$/x) {
6298 $stat = 1;
6299 push @{$c->{stat}}, $_;
6300 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
6301 push @{$c->{stat}}, $_;
6302 $stat = undef;
6303 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
6304 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
6305 } elsif (s/^${esc_color} //o) {
6306 push @{$c->{l}}, $_;
6307 }
6308 }
6309 if ($c && defined $c->{r} && $c->{r} != $r_last) {
6310 $r_last = $c->{r};
6311 process_commit($c, $r_min, $r_max, \@k);
6312 }
6313 if (@k) {
6314 ($r_min, $r_max) = ($r_max, $r_min);
6315 process_commit($_, $r_min, $r_max) foreach reverse @k;
6316 }
6317 out:
6318 close $log;
6319 print commit_log_separator unless $incremental || $oneline;
6320 }
6322 sub cmd_blame {
6323 my $path = pop;
6325 config_pager();
6326 run_pager();
6328 my ($fh, $ctx, $rev);
6330 if ($_git_format) {
6331 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
6332 while (my $line = <$fh>) {
6333 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
6334 # Uncommitted edits show up as a rev ID of
6335 # all zeros, which we can't look up with
6336 # cmt_metadata
6337 if ($1 !~ /^0+$/) {
6338 (undef, $rev, undef) =
6339 ::cmt_metadata($1);
6340 $rev = '0' if (!$rev);
6341 } else {
6342 $rev = '0';
6343 }
6344 $rev = sprintf('%-10s', $rev);
6345 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
6346 }
6347 print $line;
6348 }
6349 } else {
6350 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
6351 '--', $path);
6352 my ($sha1);
6353 my %authors;
6354 my @buffer;
6355 my %dsha; #distinct sha keys
6357 while (my $line = <$fh>) {
6358 push @buffer, $line;
6359 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
6360 $dsha{$1} = 1;
6361 }
6362 }
6364 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
6366 foreach my $line (@buffer) {
6367 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
6368 $rev = $s2r->{$1};
6369 $rev = '0' if (!$rev)
6370 }
6371 elsif ($line =~ /^author (.*)/) {
6372 $authors{$rev} = $1;
6373 $authors{$rev} =~ s/\s/_/g;
6374 }
6375 elsif ($line =~ /^\t(.*)$/) {
6376 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
6377 }
6378 }
6379 }
6380 command_close_pipe($fh, $ctx);
6381 }
6383 package Git::SVN::Migration;
6384 # these version numbers do NOT correspond to actual version numbers
6385 # of git nor git-svn. They are just relative.
6386 #
6387 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
6388 #
6389 # v1 layout: .git/$id/info/url, refs/remotes/$id
6390 #
6391 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
6392 #
6393 # v3 layout: .git/svn/$id, refs/remotes/$id
6394 # - info/url may remain for backwards compatibility
6395 # - this is what we migrate up to this layout automatically,
6396 # - this will be used by git svn init on single branches
6397 # v3.1 layout (auto migrated):
6398 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
6399 # for backwards compatibility
6400 #
6401 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
6402 # - this is only created for newly multi-init-ed
6403 # repositories. Similar in spirit to the
6404 # --use-separate-remotes option in git-clone (now default)
6405 # - we do not automatically migrate to this (following
6406 # the example set by core git)
6407 #
6408 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
6409 # - newer, more-efficient format that uses 24-bytes per record
6410 # with no filler space.
6411 # - use xxd -c24 < .rev_map.$UUID to view and debug
6412 # - This is a one-way migration, repositories updated to the
6413 # new format will not be able to use old git-svn without
6414 # rebuilding the .rev_db. Rebuilding the rev_db is not
6415 # possible if noMetadata or useSvmProps are set; but should
6416 # be no problem for users that use the (sensible) defaults.
6417 use strict;
6418 use warnings;
6419 use Carp qw/croak/;
6420 use File::Path qw/mkpath/;
6421 use File::Basename qw/dirname basename/;
6422 use vars qw/$_minimize/;
6424 sub migrate_from_v0 {
6425 my $git_dir = $ENV{GIT_DIR};
6426 return undef unless -d $git_dir;
6427 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
6428 my $migrated = 0;
6429 while (<$fh>) {
6430 chomp;
6431 my ($id, $orig_ref) = ($_, $_);
6432 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
6433 next unless -f "$git_dir/$id/info/url";
6434 my $new_ref = "refs/remotes/$id";
6435 if (::verify_ref("$new_ref^0")) {
6436 print STDERR "W: $orig_ref is probably an old ",
6437 "branch used by an ancient version of ",
6438 "git-svn.\n",
6439 "However, $new_ref also exists.\n",
6440 "We will not be able ",
6441 "to use this branch until this ",
6442 "ambiguity is resolved.\n";
6443 next;
6444 }
6445 print STDERR "Migrating from v0 layout...\n" if !$migrated;
6446 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
6447 command_noisy('update-ref', $new_ref, $orig_ref);
6448 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
6449 $migrated++;
6450 }
6451 command_close_pipe($fh, $ctx);
6452 print STDERR "Done migrating from v0 layout...\n" if $migrated;
6453 $migrated;
6454 }
6456 sub migrate_from_v1 {
6457 my $git_dir = $ENV{GIT_DIR};
6458 my $migrated = 0;
6459 return $migrated unless -d $git_dir;
6460 my $svn_dir = "$git_dir/svn";
6462 # just in case somebody used 'svn' as their $id at some point...
6463 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
6465 print STDERR "Migrating from a git-svn v1 layout...\n";
6466 mkpath([$svn_dir]);
6467 print STDERR "Data from a previous version of git-svn exists, but\n\t",
6468 "$svn_dir\n\t(required for this version ",
6469 "($::VERSION) of git-svn) does not exist.\n";
6470 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
6471 while (<$fh>) {
6472 my $x = $_;
6473 next unless $x =~ s#^refs/remotes/##;
6474 chomp $x;
6475 next unless -f "$git_dir/$x/info/url";
6476 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
6477 next unless $u;
6478 my $dn = dirname("$git_dir/svn/$x");
6479 mkpath([$dn]) unless -d $dn;
6480 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
6481 mkpath(["$git_dir/svn/svn"]);
6482 print STDERR " - $git_dir/$x/info => ",
6483 "$git_dir/svn/$x/info\n";
6484 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
6485 croak "$!: $x";
6486 # don't worry too much about these, they probably
6487 # don't exist with repos this old (save for index,
6488 # and we can easily regenerate that)
6489 foreach my $f (qw/unhandled.log index .rev_db/) {
6490 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
6491 }
6492 } else {
6493 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
6494 rename "$git_dir/$x", "$git_dir/svn/$x" or
6495 croak "$!: $x";
6496 }
6497 $migrated++;
6498 }
6499 command_close_pipe($fh, $ctx);
6500 print STDERR "Done migrating from a git-svn v1 layout\n";
6501 $migrated;
6502 }
6504 sub read_old_urls {
6505 my ($l_map, $pfx, $path) = @_;
6506 my @dir;
6507 foreach (<$path/*>) {
6508 if (-r "$_/info/url") {
6509 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
6510 my $ref_id = $pfx . basename $_;
6511 my $url = ::file_to_s("$_/info/url");
6512 $l_map->{$ref_id} = $url;
6513 } elsif (-d $_) {
6514 push @dir, $_;
6515 }
6516 }
6517 foreach (@dir) {
6518 my $x = $_;
6519 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
6520 read_old_urls($l_map, $x, $_);
6521 }
6522 }
6524 sub migrate_from_v2 {
6525 my @cfg = command(qw/config -l/);
6526 return if grep /^svn-remote\..+\.url=/, @cfg;
6527 my %l_map;
6528 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
6529 my $migrated = 0;
6531 foreach my $ref_id (sort keys %l_map) {
6532 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
6533 if ($@) {
6534 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
6535 }
6536 $migrated++;
6537 }
6538 $migrated;
6539 }
6541 sub minimize_connections {
6542 my $r = Git::SVN::read_all_remotes();
6543 my $new_urls = {};
6544 my $root_repos = {};
6545 foreach my $repo_id (keys %$r) {
6546 my $url = $r->{$repo_id}->{url} or next;
6547 my $fetch = $r->{$repo_id}->{fetch} or next;
6548 my $ra = Git::SVN::Ra->new($url);
6550 # skip existing cases where we already connect to the root
6551 if (($ra->{url} eq $ra->{repos_root}) ||
6552 ($ra->{repos_root} eq $repo_id)) {
6553 $root_repos->{$ra->{url}} = $repo_id;
6554 next;
6555 }
6557 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6558 my $root_path = $ra->{url};
6559 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6560 foreach my $path (keys %$fetch) {
6561 my $ref_id = $fetch->{$path};
6562 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6564 # make sure we can read when connecting to
6565 # a higher level of a repository
6566 my ($last_rev, undef) = $gs->last_rev_commit;
6567 if (!defined $last_rev) {
6568 $last_rev = eval {
6569 $root_ra->get_latest_revnum;
6570 };
6571 next if $@;
6572 }
6573 my $new = $root_path;
6574 $new .= length $path ? "/$path" : '';
6575 eval {
6576 $root_ra->get_log([$new], $last_rev, $last_rev,
6577 0, 0, 1, sub { });
6578 };
6579 next if $@;
6580 $new_urls->{$ra->{repos_root}}->{$new} =
6581 { ref_id => $ref_id,
6582 old_repo_id => $repo_id,
6583 old_path => $path };
6584 }
6585 }
6587 my @emptied;
6588 foreach my $url (keys %$new_urls) {
6589 # see if we can re-use an existing [svn-remote "repo_id"]
6590 # instead of creating a(n ugly) new section:
6591 my $repo_id = $root_repos->{$url} || $url;
6593 my $fetch = $new_urls->{$url};
6594 foreach my $path (keys %$fetch) {
6595 my $x = $fetch->{$path};
6596 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6597 my $pfx = "svn-remote.$x->{old_repo_id}";
6599 my $old_fetch = quotemeta("$x->{old_path}:".
6600 "$x->{ref_id}");
6601 command_noisy(qw/config --unset/,
6602 "$pfx.fetch", '^'. $old_fetch . '$');
6603 delete $r->{$x->{old_repo_id}}->
6604 {fetch}->{$x->{old_path}};
6605 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6606 command_noisy(qw/config --unset/,
6607 "$pfx.url");
6608 push @emptied, $x->{old_repo_id}
6609 }
6610 }
6611 }
6612 if (@emptied) {
6613 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6614 print STDERR <<EOF;
6615 The following [svn-remote] sections in your config file ($file) are empty
6616 and can be safely removed:
6617 EOF
6618 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6619 }
6620 }
6622 sub migration_check {
6623 migrate_from_v0();
6624 migrate_from_v1();
6625 migrate_from_v2();
6626 minimize_connections() if $_minimize;
6627 }
6629 package Git::IndexInfo;
6630 use strict;
6631 use warnings;
6632 use Git qw/command_input_pipe command_close_pipe/;
6634 sub new {
6635 my ($class) = @_;
6636 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6637 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6638 }
6640 sub remove {
6641 my ($self, $path) = @_;
6642 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6643 return ++$self->{nr};
6644 }
6645 undef;
6646 }
6648 sub update {
6649 my ($self, $mode, $hash, $path) = @_;
6650 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6651 return ++$self->{nr};
6652 }
6653 undef;
6654 }
6656 sub DESTROY {
6657 my ($self) = @_;
6658 command_close_pipe($self->{gui}, $self->{ctx});
6659 }
6661 package Git::SVN::GlobSpec;
6662 use strict;
6663 use warnings;
6665 sub new {
6666 my ($class, $glob, $pattern_ok) = @_;
6667 my $re = $glob;
6668 $re =~ s!/+$!!g; # no need for trailing slashes
6669 my (@left, @right, @patterns);
6670 my $state = "left";
6671 my $die_msg = "Only one set of wildcard directories " .
6672 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6673 for my $part (split(m|/|, $glob)) {
6674 if ($part =~ /\*/ && $part ne "*") {
6675 die "Invalid pattern in '$glob': $part\n";
6676 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6677 $part !~ /^\{[^{}]+\}/) {
6678 die "Invalid pattern in '$glob': $part\n";
6679 }
6680 if ($part eq "*") {
6681 die $die_msg if $state eq "right";
6682 $state = "pattern";
6683 push(@patterns, "[^/]*");
6684 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6685 die $die_msg if $state eq "right";
6686 $state = "pattern";
6687 my $p = quotemeta($1);
6688 $p =~ s/\\,/|/g;
6689 push(@patterns, "(?:$p)");
6690 } else {
6691 if ($state eq "left") {
6692 push(@left, $part);
6693 } else {
6694 push(@right, $part);
6695 $state = "right";
6696 }
6697 }
6698 }
6699 my $depth = @patterns;
6700 if ($depth == 0) {
6701 die "One '*' is needed in glob: '$glob'\n";
6702 }
6703 my $left = join('/', @left);
6704 my $right = join('/', @right);
6705 $re = join('/', @patterns);
6706 $re = join('\/',
6707 grep(length, quotemeta($left), "($re)", quotemeta($right)));
6708 my $left_re = qr/^\/\Q$left\E(\/|$)/;
6709 bless { left => $left, right => $right, left_regex => $left_re,
6710 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6711 }
6713 sub full_path {
6714 my ($self, $path) = @_;
6715 return (length $self->{left} ? "$self->{left}/" : '') .
6716 $path . (length $self->{right} ? "/$self->{right}" : '');
6717 }
6719 __END__
6721 Data structures:
6724 $remotes = { # returned by read_all_remotes()
6725 'svn' => {
6726 # svn-remote.svn.url=https://svn.musicpd.org
6727 url => 'https://svn.musicpd.org',
6728 # svn-remote.svn.fetch=mpd/trunk:trunk
6729 fetch => {
6730 'mpd/trunk' => 'trunk',
6731 },
6732 # svn-remote.svn.tags=mpd/tags/*:tags/*
6733 tags => {
6734 path => {
6735 left => 'mpd/tags',
6736 right => '',
6737 regex => qr!mpd/tags/([^/]+)$!,
6738 glob => 'tags/*',
6739 },
6740 ref => {
6741 left => 'tags',
6742 right => '',
6743 regex => qr!tags/([^/]+)$!,
6744 glob => 'tags/*',
6745 },
6746 }
6747 }
6748 };
6750 $log_entry hashref as returned by libsvn_log_entry()
6751 {
6752 log => 'whitespace-formatted log entry
6753 ', # trailing newline is preserved
6754 revision => '8', # integer
6755 date => '2004-02-24T17:01:44.108345Z', # commit date
6756 author => 'committer name'
6757 };
6760 # this is generated by generate_diff();
6761 @mods = array of diff-index line hashes, each element represents one line
6762 of diff-index output
6764 diff-index line ($m hash)
6765 {
6766 mode_a => first column of diff-index output, no leading ':',
6767 mode_b => second column of diff-index output,
6768 sha1_b => sha1sum of the final blob,
6769 chg => change type [MCRADT],
6770 file_a => original file name of a file (iff chg is 'C' or 'R')
6771 file_b => new/current file name of a file (any chg)
6772 }
6773 ;
6775 # retval of read_url_paths{,_all}();
6776 $l_map = {
6777 # repository root url
6778 'https://svn.musicpd.org' => {
6779 # repository path # GIT_SVN_ID
6780 'mpd/trunk' => 'trunk',
6781 'mpd/tags/0.11.5' => 'tags/0.11.5',
6782 },
6783 }
6785 Notes:
6786 I don't trust the each() function on unless I created %hash myself
6787 because the internal iterator may not have started at base.