1 /*
2 * SysDB - src/frontend/grammar.y
3 * Copyright (C) 2013 Sebastian 'tokkee' Harl <sh@tokkee.org>
4 * All rights reserved.
5 *
6 * Redistribution and use in source and binary forms, with or without
7 * modification, are permitted provided that the following conditions
8 * are met:
9 * 1. Redistributions of source code must retain the above copyright
10 * notice, this list of conditions and the following disclaimer.
11 * 2. Redistributions in binary form must reproduce the above copyright
12 * notice, this list of conditions and the following disclaimer in the
13 * documentation and/or other materials provided with the distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
17 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
18 * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19 * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
20 * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
21 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
22 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
23 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
24 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
25 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
26 */
28 %{
30 #include "frontend/connection-private.h"
31 #include "frontend/parser.h"
32 #include "frontend/grammar.h"
34 #include "core/store.h"
35 #include "core/store-private.h"
36 #include "core/time.h"
38 #include "utils/error.h"
39 #include "utils/llist.h"
41 #include <stdio.h>
42 #include <string.h>
44 int
45 sdb_fe_yylex(YYSTYPE *yylval, YYLTYPE *yylloc, sdb_fe_yyscan_t yyscanner);
47 sdb_fe_yyextra_t *
48 sdb_fe_yyget_extra(sdb_fe_yyscan_t scanner);
50 void
51 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg);
53 /* quick access to the current parse tree */
54 #define pt sdb_fe_yyget_extra(scanner)->parsetree
56 /* quick access to the parser mode */
57 #define parser_mode sdb_fe_yyget_extra(scanner)->mode
59 %}
61 %pure-parser
62 %lex-param {sdb_fe_yyscan_t scanner}
63 %parse-param {sdb_fe_yyscan_t scanner}
64 %locations
65 %error-verbose
66 %expect 0
67 %name-prefix "sdb_fe_yy"
69 %union {
70 const char *sstr; /* static string */
71 char *str;
73 sdb_data_t data;
74 sdb_time_t datetime;
76 sdb_llist_t *list;
77 sdb_conn_node_t *node;
79 sdb_store_matcher_t *m;
80 sdb_store_expr_t *expr;
81 }
83 %start statements
85 %token SCANNER_ERROR
87 %token AND OR IS NOT MATCHING FILTER
88 %token CMP_EQUAL CMP_NEQUAL CMP_REGEX CMP_NREGEX
89 %token CMP_LT CMP_LE CMP_GE CMP_GT
90 %token CONCAT
92 %token START END
94 /* NULL token */
95 %token NULL_T
97 %token FETCH LIST LOOKUP TIMESERIES
99 %token <str> IDENTIFIER STRING
101 %token <data> INTEGER FLOAT
103 %token <datetime> DATE TIME
105 /* Precedence (lowest first): */
106 %left OR
107 %left AND
108 %right NOT
109 %left CMP_EQUAL CMP_NEQUAL
110 %left CMP_LT CMP_LE CMP_GE CMP_GT
111 %nonassoc CMP_REGEX CMP_NREGEX
112 %left CONCAT
113 %nonassoc IS
114 %left '+' '-'
115 %left '*' '/' '%'
116 %left '[' ']'
117 %left '(' ')'
118 %left '.'
120 %type <list> statements
121 %type <node> statement
122 fetch_statement
123 list_statement
124 lookup_statement
125 timeseries_statement
126 matching_clause
127 filter_clause
128 condition
130 %type <m> matcher
131 compare_matcher
133 %type <expr> expression
135 %type <sstr> cmp
137 %type <data> data
138 interval interval_elem
140 %type <datetime> datetime
141 start_clause end_clause
143 %destructor { free($$); } <str>
144 %destructor { sdb_object_deref(SDB_OBJ($$)); } <node> <m> <expr>
146 %%
148 statements:
149 statements ';' statement
150 {
151 /* only accept this in default parse mode */
152 if (parser_mode != SDB_PARSE_DEFAULT) {
153 sdb_fe_yyerror(&yylloc, scanner,
154 YY_("syntax error, unexpected statement, "
155 "expecting condition"));
156 sdb_object_deref(SDB_OBJ($3));
157 YYABORT;
158 }
160 if ($3) {
161 sdb_llist_append(pt, SDB_OBJ($3));
162 sdb_object_deref(SDB_OBJ($3));
163 }
164 }
165 |
166 statement
167 {
168 /* only accept this in default parse mode */
169 if (parser_mode != SDB_PARSE_DEFAULT) {
170 sdb_fe_yyerror(&yylloc, scanner,
171 YY_("syntax error, unexpected statement, "
172 "expecting condition"));
173 sdb_object_deref(SDB_OBJ($1));
174 YYABORT;
175 }
177 if ($1) {
178 sdb_llist_append(pt, SDB_OBJ($1));
179 sdb_object_deref(SDB_OBJ($1));
180 }
181 }
182 |
183 condition
184 {
185 /* only accept this in condition parse mode */
186 if (! (parser_mode & SDB_PARSE_COND)) {
187 sdb_fe_yyerror(&yylloc, scanner,
188 YY_("syntax error, unexpected condition, "
189 "expecting statement"));
190 sdb_object_deref(SDB_OBJ($1));
191 YYABORT;
192 }
194 if ($1) {
195 sdb_llist_append(pt, SDB_OBJ($1));
196 sdb_object_deref(SDB_OBJ($1));
197 }
198 }
199 ;
201 statement:
202 fetch_statement
203 |
204 list_statement
205 |
206 lookup_statement
207 |
208 timeseries_statement
209 |
210 /* empty */
211 {
212 $$ = NULL;
213 }
214 ;
216 /*
217 * FETCH <type> <hostname> [FILTER <condition>];
218 *
219 * Retrieve detailed information about a single host.
220 */
221 fetch_statement:
222 FETCH IDENTIFIER STRING filter_clause
223 {
224 /* TODO: support other types as well */
225 if (strcasecmp($2, "host")) {
226 char errmsg[strlen($2) + 32];
227 snprintf(errmsg, sizeof(errmsg),
228 YY_("unknown data-source %s"), $2);
229 sdb_fe_yyerror(&yylloc, scanner, errmsg);
230 free($2); $2 = NULL;
231 free($3); $3 = NULL;
232 sdb_object_deref(SDB_OBJ($4));
233 YYABORT;
234 }
236 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
237 conn_fetch_t, conn_fetch_destroy));
238 CONN_FETCH($$)->type = SDB_HOST;
239 CONN_FETCH($$)->name = $3;
240 CONN_FETCH($$)->filter = CONN_MATCHER($4);
241 $$->cmd = CONNECTION_FETCH;
242 free($2); $2 = NULL;
243 }
244 ;
246 /*
247 * LIST <type> [FILTER <condition>];
248 *
249 * Returns a list of all hosts in the store.
250 */
251 list_statement:
252 LIST IDENTIFIER filter_clause
253 {
254 int type = sdb_store_parse_object_type_plural($2);
255 if (type < 0) {
256 char errmsg[strlen($2) + 32];
257 snprintf(errmsg, sizeof(errmsg),
258 YY_("unknown data-source %s"), $2);
259 sdb_fe_yyerror(&yylloc, scanner, errmsg);
260 free($2); $2 = NULL;
261 sdb_object_deref(SDB_OBJ($3));
262 YYABORT;
263 }
265 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
266 conn_list_t, conn_list_destroy));
267 CONN_LIST($$)->type = type;
268 CONN_LIST($$)->filter = CONN_MATCHER($3);
269 $$->cmd = CONNECTION_LIST;
270 free($2); $2 = NULL;
271 }
272 ;
274 /*
275 * LOOKUP <type> MATCHING <condition> [FILTER <condition>];
276 *
277 * Returns detailed information about <type> matching condition.
278 */
279 lookup_statement:
280 LOOKUP IDENTIFIER matching_clause filter_clause
281 {
282 /* TODO: support other types as well */
283 if (strcasecmp($2, "hosts")) {
284 char errmsg[strlen($2) + 32];
285 snprintf(errmsg, sizeof(errmsg),
286 YY_("unknown data-source %s"), $2);
287 sdb_fe_yyerror(&yylloc, scanner, errmsg);
288 free($2); $2 = NULL;
289 sdb_object_deref(SDB_OBJ($3));
290 sdb_object_deref(SDB_OBJ($4));
291 YYABORT;
292 }
294 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
295 conn_lookup_t, conn_lookup_destroy));
296 CONN_LOOKUP($$)->type = SDB_HOST;
297 CONN_LOOKUP($$)->matcher = CONN_MATCHER($3);
298 CONN_LOOKUP($$)->filter = CONN_MATCHER($4);
299 $$->cmd = CONNECTION_LOOKUP;
300 free($2); $2 = NULL;
301 }
302 ;
304 matching_clause:
305 MATCHING condition { $$ = $2; }
306 |
307 /* empty */ { $$ = NULL; }
309 filter_clause:
310 FILTER condition { $$ = $2; }
311 |
312 /* empty */ { $$ = NULL; }
314 /*
315 * TIMESERIES <host>.<metric> [START <datetime>] [END <datetime>];
316 *
317 * Returns a time-series for the specified host's metric.
318 */
319 timeseries_statement:
320 TIMESERIES STRING '.' STRING start_clause end_clause
321 {
322 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
323 conn_ts_t, conn_ts_destroy));
324 CONN_TS($$)->hostname = $2;
325 CONN_TS($$)->metric = $4;
326 CONN_TS($$)->opts.start = $5;
327 CONN_TS($$)->opts.end = $6;
328 $$->cmd = CONNECTION_TIMESERIES;
329 }
330 ;
332 start_clause:
333 START datetime { $$ = $2; }
334 |
335 /* empty */ { $$ = sdb_gettime() - SDB_INTERVAL_HOUR; }
337 end_clause:
338 END datetime { $$ = $2; }
339 |
340 /* empty */ { $$ = sdb_gettime(); }
342 /*
343 * Basic expressions.
344 */
346 condition:
347 matcher
348 {
349 if (! $1) {
350 /* TODO: improve error reporting */
351 sdb_fe_yyerror(&yylloc, scanner,
352 YY_("syntax error, invalid condition"));
353 YYABORT;
354 }
356 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
357 conn_matcher_t, conn_matcher_destroy));
358 $$->cmd = CONNECTION_MATCHER;
359 CONN_MATCHER($$)->matcher = $1;
360 }
361 ;
363 matcher:
364 '(' matcher ')'
365 {
366 $$ = $2;
367 }
368 |
369 matcher AND matcher
370 {
371 $$ = sdb_store_con_matcher($1, $3);
372 sdb_object_deref(SDB_OBJ($1));
373 sdb_object_deref(SDB_OBJ($3));
374 }
375 |
376 matcher OR matcher
377 {
378 $$ = sdb_store_dis_matcher($1, $3);
379 sdb_object_deref(SDB_OBJ($1));
380 sdb_object_deref(SDB_OBJ($3));
381 }
382 |
383 NOT matcher
384 {
385 $$ = sdb_store_inv_matcher($2);
386 sdb_object_deref(SDB_OBJ($2));
387 }
388 |
389 compare_matcher
390 {
391 $$ = $1;
392 }
393 ;
395 /*
396 * <object_type>.<object_attr> <cmp> <value>
397 *
398 * Parse matchers comparing object attributes with a value.
399 */
400 compare_matcher:
401 '.' IDENTIFIER cmp expression
402 {
403 $$ = sdb_store_matcher_parse_field_cmp($2, $3, $4);
404 free($2); $2 = NULL;
405 sdb_object_deref(SDB_OBJ($4));
406 }
407 |
408 IDENTIFIER cmp expression
409 {
410 $$ = sdb_store_matcher_parse_cmp($1, NULL, $2, $3);
411 free($1); $1 = NULL;
412 sdb_object_deref(SDB_OBJ($3));
413 }
414 |
415 IDENTIFIER '[' IDENTIFIER ']' cmp expression
416 {
417 $$ = sdb_store_matcher_parse_cmp($1, $3, $5, $6);
418 free($1); $1 = NULL;
419 free($3); $3 = NULL;
420 sdb_object_deref(SDB_OBJ($6));
421 }
422 |
423 IDENTIFIER '[' IDENTIFIER ']' IS NULL_T
424 {
425 $$ = sdb_store_matcher_parse_cmp($1, $3, "IS", NULL);
426 free($1); $1 = NULL;
427 free($3); $3 = NULL;
428 }
429 |
430 IDENTIFIER '[' IDENTIFIER ']' IS NOT NULL_T
431 {
432 sdb_store_matcher_t *m;
433 m = sdb_store_matcher_parse_cmp($1, $3, "IS", NULL);
434 free($1); $1 = NULL;
435 free($3); $3 = NULL;
437 /* sdb_store_inv_matcher return NULL if m==NULL */
438 $$ = sdb_store_inv_matcher(m);
439 sdb_object_deref(SDB_OBJ(m));
440 }
441 ;
443 expression:
444 '(' expression ')'
445 {
446 $$ = $2;
447 }
448 |
449 expression '+' expression
450 {
451 $$ = sdb_store_expr_create(SDB_DATA_ADD, $1, $3);
452 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
453 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
454 }
455 |
456 expression '-' expression
457 {
458 $$ = sdb_store_expr_create(SDB_DATA_SUB, $1, $3);
459 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
460 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
461 }
462 |
463 expression '*' expression
464 {
465 $$ = sdb_store_expr_create(SDB_DATA_MUL, $1, $3);
466 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
467 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
468 }
469 |
470 expression '/' expression
471 {
472 $$ = sdb_store_expr_create(SDB_DATA_DIV, $1, $3);
473 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
474 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
475 }
476 |
477 expression '%' expression
478 {
479 $$ = sdb_store_expr_create(SDB_DATA_MOD, $1, $3);
480 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
481 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
482 }
483 |
484 expression CONCAT expression
485 {
486 $$ = sdb_store_expr_create(SDB_DATA_CONCAT, $1, $3);
487 sdb_object_deref(SDB_OBJ($1)); $1 = NULL;
488 sdb_object_deref(SDB_OBJ($3)); $3 = NULL;
489 }
490 |
491 '.' IDENTIFIER
492 {
493 int field = sdb_store_parse_field_name($2);
494 free($2); $2 = NULL;
495 $$ = sdb_store_expr_fieldvalue(field);
496 }
497 |
498 IDENTIFIER '[' IDENTIFIER ']'
499 {
500 $$ = sdb_store_expr_attrvalue($3);
501 free($1); $1 = NULL;
502 free($3); $3 = NULL;
503 }
504 |
505 data
506 {
507 $$ = sdb_store_expr_constvalue(&$1);
508 sdb_data_free_datum(&$1);
509 }
510 ;
512 cmp:
513 CMP_EQUAL { $$ = "="; }
514 |
515 CMP_NEQUAL { $$ = "!="; }
516 |
517 CMP_REGEX { $$ = "=~"; }
518 |
519 CMP_NREGEX { $$ = "!~"; }
520 |
521 CMP_LT { $$ = "<"; }
522 |
523 CMP_LE { $$ = "<="; }
524 |
525 CMP_GE { $$ = ">="; }
526 |
527 CMP_GT { $$ = ">"; }
528 ;
530 data:
531 STRING { $$.type = SDB_TYPE_STRING; $$.data.string = $1; }
532 |
533 INTEGER { $$ = $1; }
534 |
535 FLOAT { $$ = $1; }
536 |
537 datetime { $$.type = SDB_TYPE_DATETIME; $$.data.datetime = $1; }
538 |
539 interval { $$ = $1; }
540 ;
542 datetime:
543 DATE TIME { $$ = $1 + $2; }
544 |
545 DATE { $$ = $1; }
546 |
547 TIME { $$ = $1; }
548 ;
550 interval:
551 interval interval_elem
552 {
553 $$.data.datetime = $1.data.datetime + $2.data.datetime;
554 }
555 |
556 interval_elem { $$ = $1; }
557 ;
559 interval_elem:
560 INTEGER IDENTIFIER
561 {
562 sdb_time_t unit = 1;
564 unit = sdb_strpunit($2);
565 if (! unit) {
566 char errmsg[strlen($2) + 32];
567 snprintf(errmsg, sizeof(errmsg),
568 YY_("invalid time unit %s"), $2);
569 sdb_fe_yyerror(&yylloc, scanner, errmsg);
570 free($2); $2 = NULL;
571 YYABORT;
572 }
573 free($2); $2 = NULL;
575 $$.type = SDB_TYPE_DATETIME;
576 $$.data.datetime = (sdb_time_t)$1.data.integer * unit;
578 if ($1.data.integer < 0) {
579 sdb_fe_yyerror(&yylloc, scanner,
580 YY_("syntax error, negative intervals not supported"));
581 YYABORT;
582 }
583 }
584 ;
586 %%
588 void
589 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg)
590 {
591 sdb_log(SDB_LOG_ERR, "frontend: parse error: %s", msg);
592 } /* sdb_fe_yyerror */
594 /* vim: set tw=78 sw=4 ts=4 noexpandtab : */