1 /*
2 * SysDB - src/frontend/grammar.y
3 * Copyright (C) 2013 Sebastian 'tokkee' Harl <sh@tokkee.org>
4 * All rights reserved.
5 *
6 * Redistribution and use in source and binary forms, with or without
7 * modification, are permitted provided that the following conditions
8 * are met:
9 * 1. Redistributions of source code must retain the above copyright
10 * notice, this list of conditions and the following disclaimer.
11 * 2. Redistributions in binary form must reproduce the above copyright
12 * notice, this list of conditions and the following disclaimer in the
13 * documentation and/or other materials provided with the distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
17 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
18 * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19 * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
20 * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
21 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
22 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
23 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
24 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
25 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
26 */
28 %{
30 #include "frontend/connection-private.h"
31 #include "frontend/parser.h"
32 #include "frontend/grammar.h"
34 #include "core/store.h"
35 #include "core/store-private.h"
37 #include "utils/error.h"
38 #include "utils/llist.h"
40 #include <stdio.h>
41 #include <string.h>
43 int
44 sdb_fe_yylex(YYSTYPE *yylval, YYLTYPE *yylloc, sdb_fe_yyscan_t yyscanner);
46 sdb_fe_yyextra_t *
47 sdb_fe_yyget_extra(sdb_fe_yyscan_t scanner);
49 void
50 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg);
52 /* quick access to the current parse tree */
53 #define pt sdb_fe_yyget_extra(scanner)->parsetree
55 /* quick access to the parser mode */
56 #define parser_mode sdb_fe_yyget_extra(scanner)->mode
58 %}
60 %pure-parser
61 %lex-param {sdb_fe_yyscan_t scanner}
62 %parse-param {sdb_fe_yyscan_t scanner}
63 %locations
64 %error-verbose
65 %expect 0
66 %name-prefix="sdb_fe_yy"
68 %union {
69 char *str;
71 sdb_llist_t *list;
72 sdb_conn_node_t *node;
74 sdb_store_matcher_t *m;
75 }
77 %start statements
79 %token SCANNER_ERROR
81 %token AND OR NOT WHERE
83 %token CMP_EQUAL CMP_NEQUAL CMP_REGEX CMP_NREGEX
85 %token <str> IDENTIFIER STRING
86 %token <node> FETCH LIST LOOKUP
88 /* Precedence (lowest first): */
89 %left OR
90 %left AND
91 %left NOT
92 %left CMP_EQUAL CMP_NEQUAL
93 %left CMP_REGEX CMP_NREGEX
94 %left '(' ')'
95 %left '.'
97 %type <list> statements
98 %type <node> statement
99 fetch_statement
100 list_statement
101 lookup_statement
102 expression
104 %type <m> matcher
105 compare_matcher
107 %%
109 statements:
110 statements ';' statement
111 {
112 /* only accept this in default parse mode */
113 if (parser_mode != SDB_PARSE_DEFAULT) {
114 sdb_fe_yyerror(&yylloc, scanner,
115 YY_("syntax error, unexpected statement, "
116 "expecting expression"));
117 sdb_object_deref(SDB_OBJ($3));
118 YYABORT;
119 }
121 if ($3) {
122 sdb_llist_append(pt, SDB_OBJ($3));
123 sdb_object_deref(SDB_OBJ($3));
124 }
125 }
126 |
127 statement
128 {
129 /* only accept this in default parse mode */
130 if (parser_mode != SDB_PARSE_DEFAULT) {
131 sdb_fe_yyerror(&yylloc, scanner,
132 YY_("syntax error, unexpected statement, "
133 "expecting expression"));
134 sdb_object_deref(SDB_OBJ($1));
135 YYABORT;
136 }
138 if ($1) {
139 sdb_llist_append(pt, SDB_OBJ($1));
140 sdb_object_deref(SDB_OBJ($1));
141 }
142 }
143 |
144 expression
145 {
146 /* only accept this in expression parse mode */
147 if (! (parser_mode & SDB_PARSE_EXPR)) {
148 sdb_fe_yyerror(&yylloc, scanner,
149 YY_("syntax error, unexpected expression, "
150 "expecting statement"));
151 sdb_object_deref(SDB_OBJ($1));
152 YYABORT;
153 }
155 if ($1) {
156 sdb_llist_append(pt, SDB_OBJ($1));
157 sdb_object_deref(SDB_OBJ($1));
158 }
159 }
160 ;
162 statement:
163 fetch_statement
164 |
165 list_statement
166 |
167 lookup_statement
168 |
169 /* empty */
170 {
171 $$ = NULL;
172 }
173 ;
175 /*
176 * FETCH <hostname>;
177 *
178 * Retrieve detailed information about a single host.
179 */
180 fetch_statement:
181 FETCH STRING
182 {
183 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
184 conn_fetch_t, conn_fetch_destroy));
185 CONN_FETCH($$)->name = strdup($2);
186 $$->cmd = CONNECTION_FETCH;
187 free($2); $2 = NULL;
188 }
189 ;
191 /*
192 * LIST;
193 *
194 * Returns a list of all hosts in the store.
195 */
196 list_statement:
197 LIST
198 {
199 $$ = SDB_CONN_NODE(sdb_object_create_T(/* name = */ NULL,
200 sdb_conn_node_t));
201 $$->cmd = CONNECTION_LIST;
202 }
203 ;
205 /*
206 * LOOKUP <type> WHERE <expression>;
207 *
208 * Returns detailed information about <type> matching expression.
209 */
210 lookup_statement:
211 LOOKUP IDENTIFIER WHERE expression
212 {
213 /* TODO: support other types as well */
214 if (strcasecmp($2, "hosts")) {
215 char errmsg[strlen($2) + 32];
216 snprintf(errmsg, sizeof(errmsg),
217 YY_("unknown table %s"), $2);
218 sdb_fe_yyerror(&yylloc, scanner, errmsg);
219 free($2); $2 = NULL;
220 sdb_object_deref(SDB_OBJ($4));
221 YYABORT;
222 }
224 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
225 conn_lookup_t, conn_lookup_destroy));
226 CONN_LOOKUP($$)->matcher = CONN_MATCHER($4);
227 $$->cmd = CONNECTION_LOOKUP;
228 free($2); $2 = NULL;
229 }
230 ;
232 expression:
233 matcher
234 {
235 sdb_store_matcher_t *m = $1;
236 if (! m) {
237 /* TODO: improve error reporting */
238 sdb_fe_yyerror(&yylloc, scanner,
239 YY_("syntax error, invalid expression"));
240 YYABORT;
241 }
243 $$ = SDB_CONN_NODE(sdb_object_create_dT(/* name = */ NULL,
244 conn_node_matcher_t, conn_matcher_destroy));
245 $$->cmd = CONNECTION_EXPR;
247 if ((M(m)->type == MATCHER_HOST)
248 || (M(m)->type == MATCHER_AND)
249 || (M(m)->type == MATCHER_OR)
250 || (M(m)->type == MATCHER_NOT))
251 CONN_MATCHER($$)->matcher = m;
252 else if (M(m)->type == MATCHER_SERVICE)
253 CONN_MATCHER($$)->matcher = sdb_store_host_matcher(NULL,
254 /* name_re = */ NULL, /* service = */ m,
255 /* attr = */ NULL);
256 else if (M(m)->type == MATCHER_ATTR)
257 CONN_MATCHER($$)->matcher = sdb_store_host_matcher(NULL,
258 /* name_re = */ NULL, /* service = */ NULL,
259 /* attr = */ m);
260 else {
261 char errbuf[1024];
262 snprintf(errbuf, sizeof(errbuf),
263 YY_("syntax error, unexpected matcher type %d"),
264 M(m)->type);
265 sdb_object_deref(SDB_OBJ($$));
266 sdb_fe_yyerror(&yylloc, scanner, errbuf);
267 YYABORT;
268 }
269 }
270 ;
272 matcher:
273 '(' matcher ')'
274 {
275 $$ = $2;
276 }
277 |
278 matcher AND matcher
279 {
280 $$ = sdb_store_con_matcher($1, $3);
281 }
282 |
283 matcher OR matcher
284 {
285 $$ = sdb_store_dis_matcher($1, $3);
286 }
287 |
288 NOT matcher
289 {
290 $$ = sdb_store_inv_matcher($2);
291 }
292 |
293 compare_matcher
294 {
295 $$ = $1;
296 }
297 ;
299 /*
300 * <object_type>.<object_attr> <op> <value>
301 *
302 * Parse matchers comparing object attributes with a value.
303 */
304 compare_matcher:
305 IDENTIFIER '.' IDENTIFIER CMP_EQUAL STRING
306 {
307 $$ = sdb_store_matcher_parse_cmp($1, $3, "=", $5);
308 /* TODO: simplify memory management in the parser */
309 free($1); $1 = NULL;
310 free($3); $3 = NULL;
311 free($5); $5 = NULL;
312 }
313 |
314 IDENTIFIER '.' IDENTIFIER CMP_NEQUAL STRING
315 {
316 $$ = sdb_store_matcher_parse_cmp($1, $3, "!=", $5);
317 /* TODO: simplify memory management in the parser */
318 free($1); $1 = NULL;
319 free($3); $3 = NULL;
320 free($5); $5 = NULL;
321 }
322 |
323 IDENTIFIER '.' IDENTIFIER CMP_REGEX STRING
324 {
325 $$ = sdb_store_matcher_parse_cmp($1, $3, "=~", $5);
326 free($1); $1 = NULL;
327 free($3); $3 = NULL;
328 free($5); $5 = NULL;
329 }
330 |
331 IDENTIFIER '.' IDENTIFIER CMP_NREGEX STRING
332 {
333 $$ = sdb_store_matcher_parse_cmp($1, $3, "!~", $5);
334 free($1); $1 = NULL;
335 free($3); $3 = NULL;
336 free($5); $5 = NULL;
337 }
338 ;
340 %%
342 void
343 sdb_fe_yyerror(YYLTYPE *lval, sdb_fe_yyscan_t scanner, const char *msg)
344 {
345 sdb_log(SDB_LOG_ERR, "frontend: parse error: %s", msg);
346 } /* sdb_fe_yyerror */
348 /* vim: set tw=78 sw=4 ts=4 noexpandtab : */