m4/progtest.m4

   1 # progtest.m4 serial 2 (gettext-0.10.40)
   2 dnl Copyright (C) 1996-2002 Free Software Foundation, Inc.
   3 dnl This file is free software, distributed under the terms of the GNU
   4 dnl General Public License.  As a special exception to the GNU General
   5 dnl Public License, this file may be distributed as part of a program
   6 dnl that contains a configuration script generated by Autoconf, under
   7 dnl the same distribution terms as the rest of that program.
   8 dnl
   9 dnl This file can can be used in projects which are not available under
  10 dnl the GNU General Public License or the GNU Library General Public
  11 dnl License but which still want to provide support for the GNU gettext
  12 dnl functionality.
  13 dnl Please note that the actual code of the GNU gettext library is covered
  14 dnl by the GNU Library General Public License, and the rest of the GNU
  15 dnl gettext package package is covered by the GNU General Public License.
  16 dnl They are *not* in the public domain.
  17
  18 dnl Authors:
  19 dnl   Ulrich Drepper <drepper@cygnus.com>, 1996.
  20
  21 # Search path for a program which passes the given test.
  22
  23 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
  24 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
  25 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
  26 [# Extract the first word of "$2", so it can be a program name with args.
  27 set dummy $2; ac_word=[$]2
  28 AC_MSG_CHECKING([for $ac_word])
  29 AC_CACHE_VAL(ac_cv_path_$1,
  30 [case "[$]$1" in
  31   /*)
  32   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
  33   ;;
  34   *)
  35   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
  36   for ac_dir in ifelse([$5], , $PATH, [$5]); do
  37     test -z "$ac_dir" && ac_dir=.
  38     if test -f $ac_dir/$ac_word; then
  39       if [$3]; then
  40         ac_cv_path_$1="$ac_dir/$ac_word"
  41         break
  42       fi
  43     fi
  44   done
  45   IFS="$ac_save_ifs"
  46 dnl If no 4th arg is given, leave the cache variable unset,
  47 dnl so AC_PATH_PROGS will keep looking.
  48 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
  49 ])dnl
  50   ;;
  51 esac])dnl
  52 $1="$ac_cv_path_$1"
  53 if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
  54   AC_MSG_RESULT([$]$1)
  55 else
  56   AC_MSG_RESULT(no)
  57 fi
  58 AC_SUBST($1)dnl
  59 ])