m4/ax_openmp.m4

   1 # ===========================================================================
   2 #               http://autoconf-archive.cryp.to/ax_openmp.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_OPENMP([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro tries to find out how to compile programs that use OpenMP a
  12 #   standard API and set of compiler directives for parallel programming
  13 #   (see http://www-unix.mcs/)
  14 #
  15 #   On success, it sets the OPENMP_CFLAGS/OPENMP_CXXFLAGS/OPENMP_F77FLAGS
  16 #   output variable to the flag (e.g. -omp) used both to compile *and* link
  17 #   OpenMP programs in the current language.
  18 #
  19 #   NOTE: You are assumed to not only compile your program with these flags,
  20 #   but also link it with them as well.
  21 #
  22 #   If you want to compile everything with OpenMP, you should set:
  23 #
  24 #       CFLAGS="$CFLAGS $OPENMP_CFLAGS"
  25 #       #OR#  CXXFLAGS="$CXXFLAGS $OPENMP_CXXFLAGS"
  26 #       #OR#  FFLAGS="$FFLAGS $OPENMP_FFLAGS"
  27 #
  28 #   (depending on the selected language).
  29 #
  30 #   The user can override the default choice by setting the corresponding
  31 #   environment variable (e.g. OPENMP_CFLAGS).
  32 #
  33 #   ACTION-IF-FOUND is a list of shell commands to run if an OpenMP flag is
  34 #   found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it is
  35 #   not found. If ACTION-IF-FOUND is not specified, the default action will
  36 #   define HAVE_OPENMP.
  37 #
  38 # LAST MODIFICATION
  39 #
  40 #   2008-04-12
  41 #
  42 # COPYLEFT
  43 #
  44 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  45 #
  46 #   This program is free software: you can redistribute it and/or modify it
  47 #   under the terms of the GNU General Public License as published by the
  48 #   Free Software Foundation, either version 3 of the License, or (at your
  49 #   option) any later version.
  50 #
  51 #   This program is distributed in the hope that it will be useful, but
  52 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  53 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  54 #   Public License for more details.
  55 #
  56 #   You should have received a copy of the GNU General Public License along
  57 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  58 #
  59 #   As a special exception, the respective Autoconf Macro's copyright owner
  60 #   gives unlimited permission to copy, distribute and modify the configure
  61 #   scripts that are the output of Autoconf when processing the Macro. You
  62 #   need not follow the terms of the GNU General Public License when using
  63 #   or distributing such scripts, even though portions of the text of the
  64 #   Macro appear in them. The GNU General Public License (GPL) does govern
  65 #   all other use of the material that constitutes the Autoconf Macro.
  66 #
  67 #   This special exception to the GPL applies to versions of the Autoconf
  68 #   Macro released by the Autoconf Macro Archive. When you make and
  69 #   distribute a modified version of the Autoconf Macro, you may extend this
  70 #   special exception to the GPL to apply to your modified version as well.
  71
  72 AC_DEFUN([AX_OPENMP], [
  73 AC_PREREQ(2.59) dnl for _AC_LANG_PREFIX
  74
  75 AC_CACHE_CHECK([for OpenMP flag of _AC_LANG compiler], ax_cv_[]_AC_LANG_ABBREV[]_openmp, [save[]_AC_LANG_PREFIX[]FLAGS=$[]_AC_LANG_PREFIX[]FLAGS
  76 ax_cv_[]_AC_LANG_ABBREV[]_openmp=unknown
  77 # Flags to try:  -fopenmp (gcc), -openmp (icc), -mp (SGI & PGI),
  78 #                -xopenmp (Sun), -omp (Tru64), -qsmp=omp (AIX), none
  79 ax_openmp_flags="-fopenmp -openmp -mp -xopenmp -omp -qsmp=omp none"
  80 if test "x$OPENMP_[]_AC_LANG_PREFIX[]FLAGS" != x; then
  81   ax_openmp_flags="$OPENMP_[]_AC_LANG_PREFIX[]FLAGS $ax_openmp_flags"
  82 fi
  83 for ax_openmp_flag in $ax_openmp_flags; do
  84   case $ax_openmp_flag in
  85     none) []_AC_LANG_PREFIX[]FLAGS=$save[]_AC_LANG_PREFIX[] ;;
  86     *) []_AC_LANG_PREFIX[]FLAGS="$save[]_AC_LANG_PREFIX[]FLAGS $ax_openmp_flag" ;;
  87   esac
  88   AC_TRY_LINK_FUNC(omp_set_num_threads,
  89         [ax_cv_[]_AC_LANG_ABBREV[]_openmp=$ax_openmp_flag; break])
  90 done
  91 []_AC_LANG_PREFIX[]FLAGS=$save[]_AC_LANG_PREFIX[]FLAGS
  92 ])
  93 if test "x$ax_cv_[]_AC_LANG_ABBREV[]_openmp" = "xunknown"; then
  94   m4_default([$2],:)
  95 else
  96   if test "x$ax_cv_[]_AC_LANG_ABBREV[]_openmp" != "xnone"; then
  97     OPENMP_[]_AC_LANG_PREFIX[]FLAGS=$ax_cv_[]_AC_LANG_ABBREV[]_openmp
  98   fi
  99   m4_default([$1], [AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])])
 100 fi
 101 ])dnl AX_OPENMP