1 # netdb_h.m4 serial 5
2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
7 AC_DEFUN([gl_HEADER_NETDB],
8 [
9 AC_REQUIRE([gl_NETDB_H_DEFAULTS])
10 gl_CHECK_NEXT_HEADERS([netdb.h])
11 if test $ac_cv_header_netdb_h = yes; then
12 AC_COMPILE_IFELSE(
13 [AC_LANG_PROGRAM([[
14 #include <netdb.h>
15 struct addrinfo a;
16 int b = EAI_OVERFLOW;
17 int c = AI_NUMERICSERV;
18 ]])],
19 [NETDB_H=''], [NETDB_H='netdb.h'])
20 HAVE_NETDB_H=1
21 else
22 NETDB_H='netdb.h'
23 HAVE_NETDB_H=0
24 fi
25 AC_SUBST([HAVE_NETDB_H])
26 AC_SUBST([NETDB_H])
27 ])
29 AC_DEFUN([gl_NETDB_MODULE_INDICATOR],
30 [
31 dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
32 AC_REQUIRE([gl_NETDB_H_DEFAULTS])
33 GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
34 ])
36 AC_DEFUN([gl_NETDB_H_DEFAULTS],
37 [
38 GNULIB_GETADDRINFO=0; AC_SUBST([GNULIB_GETADDRINFO])
39 dnl Assume proper GNU behavior unless another module says otherwise.
40 HAVE_STRUCT_ADDRINFO=1; AC_SUBST([HAVE_STRUCT_ADDRINFO])
41 HAVE_DECL_FREEADDRINFO=1; AC_SUBST([HAVE_DECL_FREEADDRINFO])
42 HAVE_DECL_GAI_STRERROR=1; AC_SUBST([HAVE_DECL_GAI_STRERROR])
43 HAVE_DECL_GETADDRINFO=1; AC_SUBST([HAVE_DECL_GETADDRINFO])
44 HAVE_DECL_GETNAMEINFO=1; AC_SUBST([HAVE_DECL_GETNAMEINFO])
45 ])