gl/m4/dup2.m4

   1 #serial 10
   2 dnl Copyright (C) 2002, 2005, 2007, 2009-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_DUP2],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11   AC_CHECK_FUNCS_ONCE([dup2])
  12   if test $ac_cv_func_dup2 = no; then
  13     HAVE_DUP2=0
  14     AC_LIBOBJ([dup2])
  15   else
  16     AC_CACHE_CHECK([whether dup2 works], [gl_cv_func_dup2_works],
  17       [AC_RUN_IFELSE([
  18          AC_LANG_PROGRAM([[#include <unistd.h>
  19 #include <errno.h>]],
  20            [if (dup2 (1, 1) == 0)
  21               return 1;
  22             close (0);
  23             if (dup2 (0, 0) != -1)
  24               return 2;
  25             /* Many gnulib modules require POSIX conformance of EBADF.  */
  26             if (dup2 (1, 1000000) == -1 && errno != EBADF)
  27               return 3;
  28             return 0;
  29            ])
  30         ],
  31         [gl_cv_func_dup2_works=yes], [gl_cv_func_dup2_works=no],
  32         [case "$host_os" in
  33            mingw*) # on this platform, dup2 always returns 0 for success
  34              gl_cv_func_dup2_works=no;;
  35            cygwin*) # on cygwin 1.5.x, dup2(1,1) returns 0
  36              gl_cv_func_dup2_works=no;;
  37            linux*) # On linux between 2008-07-27 and 2009-05-11, dup2 of a
  38                    # closed fd may yield -EBADF instead of -1 / errno=EBADF.
  39              gl_cv_func_dup2_works=no;;
  40            freebsd*) # on FreeBSD 6.1, dup2(1,1000000) gives EMFILE, not EBADF.
  41              gl_cv_func_dup2_works=no;;
  42            *) gl_cv_func_dup2_works=yes;;
  43          esac])
  44       ])
  45     if test "$gl_cv_func_dup2_works" = no; then
  46       gl_REPLACE_DUP2
  47     fi
  48   fi
  49 ])
  50
  51 AC_DEFUN([gl_REPLACE_DUP2],
  52 [
  53   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  54   if test $ac_cv_func_dup2 = yes; then
  55     REPLACE_DUP2=1
  56   fi
  57   AC_LIBOBJ([dup2])
  58 ])