doc/keys-html.xsl

   1 <?xml version="1.0" encoding="utf-8"?>
   2
   3 <xsl:stylesheet
   4    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
   5    xmlns="http://www.w3.org/1999/xhtml"
   6    xmlns:k="http://www.inkscape.org/namespaces/keys"
   7    xmlns:inkscape="http://www.inkscape.org/namespaces/inkscape"
   8    xmlns:sodipodi="http://sodipodi.sourceforge.net/DTD/sodipodi-0.dtd"
   9    xmlns:xlink="http://www.w3.org/1999/xlink"
  10    exclude-result-prefixes="k #default inkscape sodipodi xlink"
  11 >
  12 <xsl:output method="html" encoding="utf-8" indent="no" doctype-public="-//W3C//DTD HTML 4.0 Transitional//EN"/>
  13
  14 <xsl:template match="k:root">
  15 <xsl:comment>
  16 Do not edit this file.
  17 It is generated automatically from doc/keys.xml by doc/keys-html.xsl.
  18 </xsl:comment>
  19 <html>
  20 <head>
  21 <title>Inkscape keys and mouse reference</title>
  22 <style type="text/css">
  23 .key {font-weight: bold}
  24 .action {}
  25 .note {padding-left: 50px; font-size: 70%}
  26 .contents {padding: 1em; background-color: #eeeeee; font-size: small;}
  27 .contents strong {font-size: large;}
  28 body {margin: 1em; background-color: #ffffff;}
  29 h1 {margin-top: 0.5em; padding-left: 50px; padding-bottom: 0em; margin-bottom: 0em; letter-spacing: -0.02em}
  30 h4 {font-weight: bold; font-style: italic; margin-top: 1em; padding-left: 50px; padding-bottom: 0em; margin-bottom: 0em}
  31 </style>
  32 </head>
  33 <body>
  34 <xsl:apply-templates select="k:p"/>
  35
  36 <p class="contents"><strong>Contents:</strong><xsl:text>  </xsl:text>
  37 <xsl:for-each select="//k:section">
  38 <a href="#{./@title}"><xsl:value-of select="./@title"/></a>
  39 <xsl:if test="following::k:section"><xsl:text> | </xsl:text></xsl:if>
  40 </xsl:for-each>
  41 </p>
  42
  43 <center>
  44 <table border="0" cellspacing="0" cellpadding="4" width="100%">
  45 <xsl:apply-templates select="k:column"/>
  46 </table>
  47 </center>
  48
  49     <p>
  50       <a href="http://validator.w3.org/check/referer"><img border="0"
  51           src="http://www.w3.org/Icons/valid-html40"
  52           alt="Valid HTML 4.0!" height="31" width="88" /></a>
  53     </p>
  54
  55 </body>
  56 </html>
  57 </xsl:template>
  58
  59 <xsl:template match="k:p">
  60 <p><xsl:apply-templates/></p>
  61 </xsl:template>
  62
  63 <xsl:template match="k:a">
  64 <a href="{@href}"><xsl:apply-templates/></a>
  65 </xsl:template>
  66
  67 <xsl:template match="k:root/text() | k:column/text()"/>
  68
  69 <xsl:template match="k:column">
  70 <xsl:apply-templates/>
  71 </xsl:template>
  72
  73 <xsl:template match="k:section">
  74 <tr><td colspan="3"><a name="{@title}"/><h1><xsl:value-of select="@title"/></h1></td></tr>
  75 <xsl:apply-templates/>
  76 </xsl:template>
  77
  78 <xsl:template match="k:title">
  79 <tr bgcolor="{ancestor::k:section/@color}"><td colspan="3"><h4><xsl:value-of select="text()"/></h4></td></tr>
  80 </xsl:template>
  81
  82 <xsl:template match="k:note">
  83 <tr bgcolor="{ancestor::k:section/@color}"><td colspan="3"><span class="note"><xsl:value-of select="text()"/></span></td></tr>
  84 </xsl:template>
  85
  86 <xsl:template match="k:keys | k:mouse">
  87 <tr bgcolor="{ancestor::k:section/@color}">
  88 <td align="right">
  89 <xsl:choose>
  90 <xsl:when test="count(k:key) = 2">
  91 <span class="key"><xsl:apply-templates select="k:key[1]"/></span>,
  92 <span class="key"><xsl:apply-templates select="k:key[2]"/></span>
  93 </xsl:when>
  94 <xsl:otherwise>
  95 <span class="key"><xsl:apply-templates select="k:key[1]"/></span>
  96 </xsl:otherwise>
  97 </xsl:choose>
  98 </td>
  99 <td>
 100 <span class="action">
 101 <xsl:apply-templates select="k:action"/>
 102 </span>
 103 </td>
 104 </tr>
 105 </xsl:template>
 106
 107 <xsl:template match="k:action">
 108 <xsl:apply-templates/>
 109 </xsl:template>
 110
 111 <xsl:template match="k:key">
 112 <xsl:apply-templates/>
 113 </xsl:template>
 114
 115 <xsl:template match="k:shift">
 116 <xsl:text>Shift+</xsl:text>
 117 </xsl:template>
 118
 119 <xsl:template match="k:ctrl">
 120 <xsl:text>Ctrl+</xsl:text>
 121 </xsl:template>
 122
 123 <xsl:template match="k:alt">
 124 <xsl:text>Alt+</xsl:text>
 125 </xsl:template>
 126
 127 <xsl:template match="k:left">
 128 <xsl:text>Left </xsl:text>
 129 </xsl:template>
 130
 131 <xsl:template match="k:right">
 132 <xsl:text>Right </xsl:text>
 133 </xsl:template>
 134
 135 <xsl:template match="k:keyf | k:misc | k:misc-wide">
 136 <xsl:value-of select="@f"/>
 137 </xsl:template>
 138
 139 <xsl:template match="k:arrows">
 140 <xsl:text>arrows</xsl:text>
 141 </xsl:template>
 142
 143 <xsl:template match="k:up">
 144 <xsl:text>Up arrow</xsl:text>
 145 </xsl:template>
 146
 147 <xsl:template match="k:down">
 148 <xsl:text>Down arrow</xsl:text>
 149 </xsl:template>
 150
 151 <xsl:template match="k:left-arrow">
 152 <xsl:text>Left arrow</xsl:text>
 153 </xsl:template>
 154
 155 <xsl:template match="k:right-arrow">
 156 <xsl:text>Right arrow</xsl:text>
 157 </xsl:template>
 158
 159 <xsl:template match="k:up-arrow">
 160 <xsl:text>Up arrow</xsl:text>
 161 </xsl:template>
 162
 163 <xsl:template match="k:down-arrow">
 164 <xsl:text>Down arrow</xsl:text>
 165 </xsl:template>
 166
 167 <xsl:template match="k:wheel">
 168 <xsl:text>mouse wheel</xsl:text>
 169 </xsl:template>
 170
 171 <xsl:template match="k:left-drag">
 172 <xsl:text>mouse drag</xsl:text>
 173 </xsl:template>
 174
 175 <xsl:template match="k:left-click">
 176 <xsl:text>click</xsl:text>
 177 </xsl:template>
 178
 179 <xsl:template match="k:mid-drag">
 180 <xsl:text>middle button drag</xsl:text>
 181 </xsl:template>
 182
 183 <xsl:template match="k:mid-click">
 184 <xsl:text>middle click</xsl:text>
 185 </xsl:template>
 186
 187 <xsl:template match="k:right-drag">
 188 <xsl:text>right button drag</xsl:text>
 189 </xsl:template>
 190
 191 <xsl:template match="k:right-click">
 192 <xsl:text>right click</xsl:text>
 193 </xsl:template>
 194
 195 </xsl:stylesheet>