configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.50)
   4 AC_INIT(inkscape, 0.45+devel)
   5 dnl N.B. After 0.40, please change to `0.40+cvs' instead of `0.41cvs'.
   6 dnl Rationale: (i) placate simple version comparison software such as
   7 dnl `dpkg --compare-versions'.  (ii) We don't always know what the next
   8 dnl version is going to be called until about the time we release it
   9 dnl (whereas we always know what the previous version was called).
  10 AC_CANONICAL_HOST
  11 AC_CONFIG_SRCDIR(src/main.cpp)
  12 AM_INIT_AUTOMAKE
  13
  14 AC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [
  15   prefix=/opt/inkscape
  16   PATH="/opt/lsb/bin:$PATH"
  17   CC=lsbcc
  18   CXX=lsbc++
  19   export CC CXX
  20 ])
  21
  22 AM_CONFIG_HEADER(config.h)
  23
  24 AC_PROG_INTLTOOL(0.22)
  25
  26 AC_LANG(C++)
  27 AC_ISC_POSIX
  28 AC_PROG_CXX
  29 AM_PROG_CC_STDC
  30 AM_PROG_AS
  31 AC_HEADER_STDC
  32
  33 dnl These next few lines are needed only while libcroco is in our source tree.
  34 AC_PROG_CC
  35 AM_PROG_CC_C_O
  36 AC_MSG_NOTICE([Testing -Wno-pointer-sign])
  37 if test "$GCC" = "yes"; then
  38   # Enable some warnings from gcc.
  39
  40   AC_LANG_PUSH(C)
  41   # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted
  42   # by gcc 2.95.
  43   ink_svd_CFLAGS="$CFLAGS"
  44   CFLAGS="-Wno-pointer-sign $CFLAGS"
  45   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), AC_MSG_NOTICE([ compiler supports -Wno-pointer-sign]), CFLAGS="$ink_svd_CFLAGS")
  46   CFLAGS="-Wall -Wformat-security -W -D_FORTIFY_SOURCE=2 $CFLAGS"
  47   AC_LANG_POP
  48 fi
  49
  50 dnl Honor aclocal flags
  51 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  52
  53 AC_PROG_RANLIB
  54
  55 dnl Verify our GCC version
  56 if test "x$GXX" = "xyes"; then
  57         AC_MSG_CHECKING([GNU compiler version])
  58
  59         # Don't pass CXXFLAGS to the following CXX command as some
  60         # of them can't be specified along with '-v'.
  61         cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\
  62                 sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]
  63
  64         AC_MSG_RESULT([$cc_version])
  65
  66         # Some version numbers
  67         cc_vers_major=`echo $cc_version | cut -f1 -d.`
  68         cc_vers_minor=`echo $cc_version | cut -f2 -d.`
  69         cc_vers_patch=`echo $cc_version | cut -f3 -d.`
  70         test -n "$cc_vers_major" || cc_vers_major=0
  71         test -n "$cc_vers_minor" || cc_vers_minor=0
  72         test -n "$cc_vers_patch" || cc_vers_patch=0
  73         cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`
  74
  75         if test $cc_vers_major -lt 3; then
  76                 AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])
  77         fi
  78 fi
  79
  80 dnl ******************************
  81 dnl Gettext stuff
  82 dnl ******************************
  83 GETTEXT_PACKAGE="AC_PACKAGE_NAME"
  84 AC_SUBST(GETTEXT_PACKAGE)
  85 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])
  86 dnl Add the languages which your application supports here.
  87 ALL_LINGUAS="am az be bg bn ca cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fi fr ga gl he hr hu id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@Latn sr sv th tr uk vi zh_CN zh_TW"
  88 AM_GLIB_GNU_GETTEXT
  89
  90 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  91 if test "x$PKG_CONFIG" = "xno"; then
  92         AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)
  93 fi
  94
  95 dnl Find msgfmt.  Without this, po/Makefile fails to set MSGFMT on some platforms.
  96 AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)
  97 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
  98
  99 dnl ******************************
 100 dnl Check for libpng
 101 dnl ******************************
 102 AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=no)], png_ok=no, -lz -lm)
 103 if test "x$png_ok" != "xyes"; then
 104         AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])
 105 fi
 106
 107 dnl Handle possible dlopen requirement for libgc
 108 dnl Isn't this internal to something in autoconf?  Couldn't find it...
 109 AC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],
 110           [lt_cv_dlopen="dlopen"],
 111       [AC_CHECK_LIB([dl], [dlopen],
 112             [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
 113         [AC_CHECK_LIB([svld], [dlopen],
 114               [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
 115           [AC_CHECK_LIB([dld], [dld_link],
 116                 [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
 117           ])
 118         ])
 119       ])
 120     ])
 121
 122 AC_CHECK_HEADERS([gc.h gc/gc.h],
 123                  [
 124                     # To test for the different required libs, I have to
 125                     # overcome autoconf's caching system, so I change the
 126                     # desired function name.  They're all in libgc.
 127                     # The "break" will exit from the top level
 128                     # AC_CHECK_HEADERS.
 129                     gc_libs=""
 130                     AC_CHECK_LIB(gc, GC_init,
 131                                  [gc_ok=yes;
 132                                   LIBS="-lgc $gc_libs $LIBS";
 133                                   break], [gc_ok=no], [$gc_libs])
 134                     gc_libs="-lpthread"
 135                     AC_CHECK_LIB(gc, GC_malloc,
 136                                  [gc_ok=yes;
 137                                   LIBS="-lgc $gc_libs $LIBS";
 138                                   break], [gc_ok=no], [$gc_libs])
 139                     gc_libs="$lt_cv_dlopen_libs"
 140                     AC_CHECK_LIB(gc, GC_realloc,
 141                                  [gc_ok=yes;
 142                                   LIBS="-lgc $gc_libs $LIBS";
 143                                   break], [gc_ok=no], [$gc_libs])
 144                     gc_libs="-lpthread $lt_cv_dlopen_libs"
 145                     AC_CHECK_LIB(gc, GC_free,
 146                                  [gc_ok=yes;
 147                                   LIBS="-lgc $gc_libs $LIBS";
 148                                   break], [gc_ok=no], [$gc_libs])
 149                     break],
 150                  [gc_ok=no])
 151 if test "x$gc_ok" = "xyes"; then
 152         AC_MSG_CHECKING([libgc version 6.4+])
 153         AC_RUN_IFELSE(
 154                 [AC_LANG_SOURCE([[
 155                         #ifdef HAVE_GC_GC_H
 156                         # include <gc/gc.h>
 157                         #else
 158                         # include <gc.h>
 159                         #endif
 160                         #include <stdio.h>
 161                         extern unsigned GC_version;
 162                         int main(void){
 163                                 unsigned min = ((6 << 16) | (4 << 8) | 0);
 164                                 printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);
 165                                 if (GC_version>=min) return 0;
 166                                 return 1;
 167                         }]])],
 168                 [gc_ok=yes],
 169                 [gc_ok=no]
 170         )
 171         AC_MSG_RESULT([$gc_ok])
 172 fi
 173 if test "x$gc_ok" != "xyes"; then
 174         AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])
 175 fi
 176
 177 dnl This check is to get a FIONREAD definition on Solaris 8
 178 AC_CHECK_HEADERS([sys/filio.h])
 179
 180
 181 AC_CHECK_HEADERS([malloc.h])
 182 AC_CHECK_FUNCS([mallinfo], [
 183         AC_CHECK_MEMBERS([struct mallinfo.usmblks,
 184                           struct mallinfo.fsmblks,
 185                           struct mallinfo.uordblks,
 186                           struct mallinfo.fordblks,
 187                           struct mallinfo.hblkhd],,,
 188                          [#include <malloc.h>])
 189 ])
 190
 191 AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 192 if test "x$FREETYPE_CONFIG" = "xno"; then
 193         AC_MSG_ERROR([Cannot find freetype-config])
 194 fi
 195 FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
 196 FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
 197 AC_SUBST(FREETYPE_CFLAGS)
 198 AC_SUBST(FREETYPE_LIBS)
 199
 200 dnl ******************************
 201 dnl Win32
 202 dnl ******************************
 203 AC_MSG_CHECKING([for Win32 platform])
 204 case "$host" in
 205   *-*-mingw*)
 206     platform_win32=yes
 207     INKSCAPE_CFLAGS="$INKSCAPE_CFLAGS -mms-bitfields -DLIBXML_STATIC"
 208     ;;
 209   *)
 210     platform_win32=no
 211     ;;
 212 esac
 213 AC_MSG_RESULT([$platform_win32])
 214 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 215
 216 AC_MSG_CHECKING([for Solaris 2.8 platform])
 217 case "$host" in
 218   *-solaris2.8)
 219     platform_solaris_2_8=yes
 220     CFLAGS="$CFLAGS -DSOLARIS_2_8"
 221     CXXFLAGS="$CXXFLAGS -DSOLARIS_2_8"
 222     ;;
 223   *)
 224     platform_solaris_2_8=no
 225     ;;
 226 esac
 227 AC_MSG_RESULT([$platform_solaris_2_8])
 228 AM_CONDITIONAL(PLATFORM_SOLARIS_2_8, test "$platform_solaris_2_8" = "yes")
 229
 230 dnl ******************************
 231 dnl Xft checking
 232 dnl ******************************
 233
 234 AC_ARG_WITH(xft,
 235             AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),
 236             [with_xft=$withval], [with_xft=auto])
 237
 238 if test "x$with_xft" != "xno" ; then
 239         dnl Test fontconfig package
 240         PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)
 241         if test "x$xft_ok" != "xyes"; then
 242                 dnl test xft package
 243                 PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)
 244                 if test "x$xft_ok" != "xyes"; then
 245                         dnl Have to test xft presence
 246                         AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)
 247                         if test "x$xft_ok" != "xyes"; then
 248                                 dnl No xft found
 249                                 if test "x$with_xft" = "xyes"; then
 250                                         dnl Xft was explicitly asked, so stop
 251                                         AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])
 252                                 fi
 253                         else
 254                                 dnl Working Xft1
 255                                 XFT_LIBS="-L/usr/X11R6/lib -lXft "
 256                         fi
 257                 fi
 258         fi
 259 else
 260         dnl Asked to ignore xft
 261         xft_ok=no
 262 fi
 263
 264 AC_SUBST(XFT_CFLAGS)
 265 AC_SUBST(XFT_LIBS)
 266
 267 AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")
 268 if test "x$xft_ok" = "xyes"; then
 269         AC_DEFINE(WITH_XFT, 1, [Use Xft font database])
 270 fi
 271
 272 dnl ******************************
 273 dnl pangoft2 for xft
 274 dnl ******************************
 275
 276 if test "x$xft_ok" = "xyes"; then
 277         PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)
 278         if test "x$pango_ok" = "xyes"; then
 279                 XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"
 280         fi
 281 fi
 282
 283 dnl ******************************
 284 dnl GnomePrint checking
 285 dnl ******************************
 286
 287 AC_ARG_WITH(gnome-print,
 288             AC_HELP_STRING([--with-gnome-print], [use gnome print font database and spooler frontend]),
 289             [with_gp=$withval], [with_gp=auto])
 290
 291 if test "x$with_gp" = "xyes"; then
 292         dnl Have to test gnome-print presence
 293         PKG_CHECK_MODULES(GNOME_PRINT, libgnomeprint-2.2 >= 1.116.0  libgnomeprintui-2.2 >= 1.116.0, gp=yes, gp=no)
 294         if test "x$gp" != "xyes"; then
 295                 dnl No gnome-print found
 296                 if test "x$with_gp" = "xyes"; then
 297                         dnl Gnome-print was explicitly asked, so stop
 298                         AC_MSG_ERROR([--with-gnome-print was specified, but appropriate libgnomeprint development packages could not be found])
 299                 else
 300                         # gp is no, tell us for the log file
 301                         AC_MSG_RESULT($gp)
 302                 fi
 303         fi
 304 else
 305         dnl Asked to ignore gnome-print
 306         gp=no
 307 fi
 308
 309 AC_SUBST(GNOME_PRINT_CFLAGS)
 310 AC_SUBST(GNOME_PRINT_LIBS)
 311
 312 AM_CONDITIONAL(USE_GNOME_PRINT, test "x$gp" = "xyes")
 313 if test "x$gp" = "xyes"; then
 314         AC_DEFINE(WITH_GNOME_PRINT, 1, [Use gnome print font database and spooler frontend])
 315 fi
 316
 317 dnl ******************************
 318 dnl gnome vfs checking
 319 dnl ******************************
 320
 321 AC_ARG_WITH(gnome-vfs,
 322         AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),
 323         [with_gnome_vfs=$withval], [with_gnome_vfs=auto])
 324
 325 if test "x$with_gnome_vfs" = "xno"; then
 326         dnl Asked to ignore gnome-vfs
 327         gnome_vfs=no
 328 else
 329         dnl Have to test gnome-vfs presence
 330         PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)
 331         if test "x$gnome_vfs" != "xyes"; then
 332                 dnl No gnome-vfs found
 333                 if test "x$with_gnome_vfs" = "xyes"; then
 334                         dnl Gnome-VFS was explicitly asked for, so stop
 335                         AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])
 336                 else
 337                         # gnome-vfs is no, tell us for the log file
 338                         AC_MSG_RESULT($gnome_vfs)
 339                 fi
 340         fi
 341 fi
 342
 343 AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")
 344 if test "x$gnome_vfs" = "xyes"; then
 345         AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])
 346 fi
 347
 348 AC_SUBST(GNOME_VFS_CFLAGS)
 349 AC_SUBST(GNOME_VFS_LIBS)
 350
 351 dnl ******************************
 352 dnl libinkjar checking
 353 dnl ******************************
 354
 355 AC_ARG_WITH(inkjar,
 356         AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])
 357
 358 if test "x$with_ij" = "xyes"; then
 359         AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])
 360         AC_C_BIGENDIAN
 361         AC_CHECK_HEADERS(zlib.h)
 362         ij=yes
 363 else
 364         ij=no
 365 fi
 366 AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")
 367
 368 ink_spell_pkg=
 369 if pkg-config --exists gtkspell-2.0; then
 370         ink_spell_pkg=gtkspell-2.0
 371         AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])
 372 fi
 373
 374 dnl ******************************
 375 dnl PERL checking
 376 dnl ******************************
 377
 378 AC_MSG_CHECKING(for Perl development environment)
 379 AC_ARG_WITH(perl,
 380             AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),
 381             [with_perl=$withval], [with_perl=skipped])
 382
 383 if test "x$with_perl" = "xyes"; then
 384     checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`
 385     if test "$?" -gt "0"; then
 386         with_perl="no"
 387     else
 388         checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`
 389         if test "$?" -gt "0"; then
 390             with_perl="no"
 391         else
 392             with_perl="yes"
 393         fi
 394     fi
 395 fi
 396 AC_MSG_RESULT([$with_perl])
 397 if test "x$with_perl" = "xyes"; then
 398     # Test that we actually have the perl libraries installed
 399     oldCFLAGS="$CFLAGS"
 400     oldLIBS="$LIBS"
 401     CFLAGS="$CFLAGS $checkPERL_CFLAGS"
 402     LIBS="$LIBS $checkPERL_LIBS"
 403     AC_CHECK_FUNC([perl_parse],[
 404         PERL_CFLAGS="$checkPERL_CFLAGS"
 405         PERL_LIBS="$checkPERL_LIBS"
 406         AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])
 407         ],[
 408         with_perl="no"
 409         ])
 410     CFLAGS="$oldCFLAGS"
 411     LIBS="$oldLIBS"
 412 fi
 413 AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")
 414 AC_SUBST(PERL_CFLAGS)
 415 AC_SUBST(PERL_LIBS)
 416
 417 dnl ******************************
 418 dnl Python checking
 419 dnl ******************************
 420
 421 AC_MSG_CHECKING(for Python development environment)
 422 AC_ARG_WITH(python,
 423             AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),
 424             [with_python=$withval], [with_python=skipped])
 425
 426 if test "x$with_python" = "xyes"; then
 427     checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`
 428     if test "$?" -gt "0"; then
 429         with_python="no"
 430     else
 431         checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`
 432         if test "$?" -gt "0"; then
 433             with_python="no"
 434         else
 435             with_python="yes"
 436         fi
 437     fi
 438 fi
 439 AC_MSG_RESULT([$with_python])
 440 if test "x$with_python" = "xyes"; then
 441     # Test that we actually have the python libraries installed
 442     oldCFLAGS="$CFLAGS"
 443     oldLIBS="$LIBS"
 444     CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"
 445     LIBS="$LIBS $checkPYTHON_LIBS"
 446     AC_CHECK_FUNC([Py_Initialize],[
 447         PYTHON_CFLAGS="$checkPYTHON_CFLAGS"
 448         PYTHON_LIBS="$checkPYTHON_LIBS"
 449         AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])
 450         ],[
 451         with_python="no"
 452         ])
 453     CFLAGS="$oldCFLAGS"
 454     LIBS="$oldLIBS"
 455 fi
 456 AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")
 457 AC_SUBST(PYTHON_CFLAGS)
 458 AC_SUBST(PYTHON_LIBS)
 459
 460 dnl ******************************
 461 dnl LittleCms checking
 462 dnl ******************************
 463
 464 AC_ARG_ENABLE(lcms,
 465         AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),
 466         [enable_lcms=$enableval], [enable_lcms=yes])
 467
 468 if test "x$enable_lcms" = "xno"; then
 469         dnl Asked to ignore LittleCms
 470         lcms=no
 471 else
 472         dnl Have to test LittleCms presence
 473         PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)
 474         if test "x$lcms" != "xyes"; then
 475                 dnl No lcms found
 476                 if test "x$enable_lcms" = "xyes"; then
 477                         dnl LittleCms was explicitly asked for, so stop
 478                         AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])
 479                 else
 480                         # lcms is no, tell us for the log file
 481                         AC_MSG_RESULT($lcms)
 482                 fi
 483         else
 484                 dnl Working lcms
 485                 LCMS_LIBS="-llcms "
 486         fi
 487 fi
 488
 489 if test "x$lcms" = "xyes"; then
 490         LIBS="$LIBS $LCMS_LIBS"
 491         AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])
 492 fi
 493 AM_CONDITIONAL(USE_LCMS, test "x$lcms" = "xyes")
 494 AC_SUBST(LCMS_CFLAGS)
 495 AC_SUBST(LCMS_LIBS)
 496
 497 dnl ******************************
 498 dnl Libpoppler checking
 499 dnl ******************************
 500
 501 POPPLER_CFLAGS=""
 502 PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.5, poppler=yes, poppler=no)
 503
 504 if test "x$poppler" = "xyes"; then
 505         dnl Working libpoppler
 506         POPPLER_LIBS="-lpoppler "
 507         dnl Have to test libpoppler-glib presence
 508         PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.5, poppler_glib=yes, poppler_glib=no)
 509         if test "x$poppler_glib" = "xyes"; then
 510                 dnl Working libpoppler-glib found
 511                 dnl Check whether the Cairo SVG backend is available
 512                 PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)
 513                 if test "x$cairo_svg" = "xyes"; then
 514                         POPPLER_LIBS="$POPPLER_LIBS -lpoppler-glib "
 515                 fi
 516         fi
 517 fi
 518
 519 if test "x$poppler" = "xyes"; then
 520         LIBS="$LIBS $POPPLER_LIBS"
 521         AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])
 522 fi
 523 if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then
 524         AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])
 525 fi
 526 AC_SUBST(POPPLER_CFLAGS)
 527 AC_SUBST(POPPLER_LIBS)
 528
 529 dnl ******************************
 530 dnl Inkboard dependency checking
 531 dnl ******************************
 532
 533 with_inkboard="no"
 534 with_inkboard_ssl="no"
 535
 536 INKBOARD_CFLAGS=""
 537
 538 AC_ARG_ENABLE(inkboard,
 539                 AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),
 540        with_inkboard=$enableval,with_inkboard=no)
 541
 542 if test "x$with_inkboard" = "xyes"; then
 543                 with_inkboard="yes"
 544                 AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])
 545
 546                 dnl Test for OpenSSL
 547                 PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)
 548                 if test "x$with_inkboard_ssl" = "xyes"; then
 549                         dnl OpenSSL found; enable SSL support in Pedro
 550                         INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"
 551                         RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
 552                         RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
 553                         AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])
 554                 fi
 555 else
 556         with_inkboard="no"
 557 fi
 558
 559 AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")
 560 AC_SUBST(INKBOARD_LIBS)
 561 AC_SUBST(INKBOARD_CFLAGS)
 562
 563 dnl ******************************
 564 dnl Check for ImageMagick Magick++
 565 dnl ******************************
 566
 567 AC_CHECK_LIB(Magick++, InitializeMagick, [AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)], magick_ok=no, -llcms -lfreetype -ljpeg -lfontconfig -lXext -lSM -lICE -lX11 -lz -lpthread -lm -lpthread)
 568
 569 if test "x$magick_ok" = "xyes"; then
 570         AC_CHECK_PROG(MAGICKPP_CONFIG, Magick++-config, yes, no)
 571         if test "x$MAGICKPP_CONFIG" = "xyes"; then
 572                 IMAGEMAGICK_LIBS=`Magick++-config --libs`
 573                 AC_SUBST(IMAGEMAGICK_LIBS)
 574                 AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])
 575         fi
 576 fi
 577
 578 AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")
 579
 580 dnl ******************************
 581 dnl   Unconditional dependencies
 582 dnl ******************************
 583
 584 dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10
 585 if test $cc_vers_major -gt 3; then
 586   min_sigc_version=2.0.12
 587 else
 588   min_sigc_version=2.0.11
 589 fi
 590 PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4  glibmm-2.4  gtkmm-2.4  gtk+-2.0 >= 2.8.0  libxml-2.0 >= 2.6.11  libxslt >= 1.0.15  cairo  sigc++-2.0 >= $min_sigc_version  $ink_spell_pkg  gthread-2.0 >= 2.0 libpng >= 1.2)
 591
 592 # Check for some boost header files
 593 AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))
 594
 595 PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)
 596 if test "x$cairo_pdf" = "xyes"; then
 597   AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])
 598 fi
 599
 600 PKG_CHECK_MODULES(GTK_UNIX_PRINT, gtk+-unix-print-2.0, gtk_unix_print=yes, gtk_unix_print=no)
 601 if test "x$gtk_unix_print" = "xyes"; then
 602   AC_DEFINE(HAVE_GTK_UNIX_PRINT, 1, [Whether the GTK Unix printing backend is available])
 603 fi
 604
 605 dnl Shouldn't we test for libpng and libz?
 606 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz"
 607
 608 AC_CHECK_HEADER(popt.h,
 609                 [INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],
 610                 AC_MSG_ERROR([libpopt is required]))
 611
 612 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 613 sp_save_LIBS=$LIBS
 614 LIBS="$LIBS $INKSCAPE_LIBS"
 615 AC_CHECK_FUNCS(bind_textdomain_codeset)
 616 dnl Check for gtk_window_fullscreen in gtk (>= 2.2)
 617 AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)
 618 AC_CHECK_FUNCS(gtk_window_fullscreen)
 619 LIBS=$sp_save_LIBS
 620
 621
 622 dnl Check for binary relocation support
 623 dnl Hongli Lai <h.lai@chello.nl>
 624
 625 AC_ARG_ENABLE(binreloc,
 626        [  --enable-binreloc       compile with binary relocation support],
 627        enable_binreloc=$enableval,enable_binreloc=no)
 628
 629 AC_MSG_CHECKING(whether binary relocation support should be enabled)
 630 if test "$enable_binreloc" = "yes"; then
 631        AC_MSG_RESULT(yes)
 632        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
 633        if test -e /proc/self/maps; then
 634                AC_MSG_RESULT(yes)
 635        else
 636                AC_MSG_RESULT(no)
 637                AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
 638                enable_binreloc="no"
 639        fi
 640
 641 elif test "$enable_binreloc" = "auto"; then
 642        AC_MSG_RESULT(yes when available)
 643        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
 644        if test -e /proc/self/maps; then
 645                AC_MSG_RESULT(yes)
 646                enable_binreloc=yes
 647
 648                AC_MSG_CHECKING(whether everything is installed to the same prefix)
 649                if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
 650                        "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
 651                        "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
 652                then
 653                        AC_MSG_RESULT(yes)
 654                else
 655                        AC_MSG_RESULT(no)
 656                        AC_MSG_NOTICE(Binary relocation support will be disabled.)
 657                        enable_binreloc=no
 658                fi
 659
 660        else
 661                AC_MSG_RESULT(no)
 662                enable_binreloc=no
 663        fi
 664
 665 elif test "$enable_binreloc" = "no"; then
 666        AC_MSG_RESULT(no)
 667 else
 668        AC_MSG_RESULT(no (unknown value "$enable_binreloc"))
 669        enable_binreloc=no
 670 fi
 671 AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])
 672 if test "$enable_binreloc" = "yes"; then
 673    AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
 674 fi
 675
 676 AC_ARG_ENABLE(osxapp,
 677        [  --enable-osxapp         compile with OSX .app data dir paths],
 678        enable_osxapp=$enableval,enable_osxapp=no)
 679 if test "$enable_osxapp" = "yes"; then
 680    AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])
 681 fi
 682
 683 dnl ******************************
 684 dnl   Reported by autoscan
 685 dnl ******************************
 686 AC_CHECK_FUNCS(pow)
 687 # if we did not find pow(), see if it's in libm.
 688 if test x"$ac_cv_func_pow" = x"no" ; then
 689         AC_CHECK_LIB(m,pow)
 690 fi
 691 AC_CHECK_FUNCS(sqrt)
 692 AC_CHECK_FUNCS(floor)
 693 AC_CHECK_FUNCS(gettimeofday)
 694 AC_CHECK_FUNCS(memmove)
 695 AC_CHECK_FUNCS(memset)
 696 AC_CHECK_FUNCS(mkdir)
 697 AC_CHECK_FUNCS(strncasecmp)
 698 AC_CHECK_FUNCS(strpbrk)
 699 AC_CHECK_FUNCS(strrchr)
 700 AC_CHECK_FUNCS(strspn)
 701 AC_CHECK_FUNCS(strstr)
 702 AC_CHECK_FUNCS(strtoul)
 703 AC_CHECK_FUNCS(fpsetmask)
 704 AC_CHECK_FUNCS(ecvt)
 705 AC_CHECK_HEADERS(ieeefp.h)
 706 AC_CHECK_HEADERS(fcntl.h)
 707 AC_CHECK_HEADERS(libintl.h)
 708 AC_CHECK_HEADERS(stddef.h)
 709 AC_CHECK_HEADERS(sys/time.h)
 710 AC_FUNC_STAT
 711 AC_FUNC_STRFTIME
 712 AC_FUNC_STRTOD
 713 AC_HEADER_STAT
 714 AC_HEADER_TIME
 715 AC_STRUCT_TM
 716 AC_TYPE_MODE_T
 717 AC_TYPE_SIGNAL
 718
 719 dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't
 720 dnl set correctly because the gettext function isn't noticed.
 721 if test "$ac_cv_header_libintl_h" = "yes" &&
 722    test "$ac_cv_func_bind_textdomain_codeset" = "yes"  &&
 723    test "$gt_cv_func_have_gettext" != "yes"; then
 724     AC_DEFINE(ENABLE_NLS)
 725 fi
 726
 727 dnl ******************************
 728 dnl   Compilation warnings
 729 dnl ******************************
 730 if test "$GXX" = "yes"; then
 731   # Enable some warnings from g++.
 732
 733   # Rationale: a number of bugs in inkscape have been fixed by enabling g++
 734   # warnings and addressing the produced warnings.  Usually the committing
 735   # developer is the best person to address the warnings.
 736
 737   ink_svd_CXXFLAGS="$CXXFLAGS"
 738   CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"
 739   # -Wno-unused-parameter isn't accepted by gcc 2.95.
 740   AC_COMPILE_IFELSE([int dummy;
 741 ], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)
 742   # Note: At least one bug has been caught from unused parameter warnings,
 743   # so it might be worth trying not to disable it.
 744   # One way of selectively disabling the warnings (i.e. only where the
 745   # programmer deliberately isn't using the parameter, e.g. for a callback)
 746   # is to remove the parameter name (leaving just its type), as is done
 747   # in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the
 748   # programmer deliberately has an unused parameter (e.g. because it's used
 749   # as a callback or similar function pointer use).
 750
 751   CXXFLAGS="-Wall -Wformat-security -W -Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch -D_FORTIFY_SOURCE=2 $CXXFLAGS"
 752
 753   dnl Test for arch-specific situations.
 754   case "$host_cpu" in
 755     mips|mipsel)
 756       dnl Symbol tables can get too large: this uses alternate tables
 757       dnl See http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=283476
 758       CXXFLAGS="$CXXFLAGS -Wa,-xgot"
 759       CFLAGS="$CFLAGS -Wa,-xgot"
 760       ;;
 761   esac
 762 fi
 763
 764 AC_DEFINE(WITH_MODULES, 1, [Use experimental module support])
 765
 766 dnl ******************************
 767 dnl   libinkscape
 768 dnl ******************************
 769 dnl
 770 dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])
 771 dnl
 772 dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")
 773 dnl
 774
 775 AC_SUBST(INKSCAPE_CFLAGS)
 776 AC_SUBST(INKSCAPE_LIBS)
 777
 778 #
 779 # Checks to see if we should compile in MMX support (there will be
 780 # a runtime test when the code is actually run to see if it should
 781 # be used - this just checks if we can compile it.)
 782 #
 783 # This code is partially taken from Mesa
 784 #
 785 dnl Let people disable the MMX optimization
 786 AC_ARG_ENABLE(mmx, [  --disable-mmx     Don't use MMX optimization [default=auto]], enable_mmx="$enableval", enable_mmx=auto)
 787
 788 AC_MSG_CHECKING(for x86 platform)
 789 case $host_cpu in
 790   i386|i486|i586|i686|i786|k6|k7)
 791     use_x86_asm=yes
 792     ;;
 793   *)
 794     use_x86_asm=no
 795 esac
 796 AC_MSG_RESULT($use_x86_asm)
 797
 798 dnl Are we going to use MMX extensions
 799 use_mmx_asm=no
 800
 801 AC_MSG_CHECKING(compiler support for MMX)
 802
 803 if test x$enable_mmx = xauto ; then
 804   if test $use_x86_asm = yes; then
 805     save_ac_ext=$ac_ext
 806     ac_ext=S
 807
 808     cp $srcdir/src/libnr/nr_mmx_R8G8B8A8_P_R8G8B8A8_P_A8_RGBAP.S conftest.S
 809     if AC_TRY_EVAL(ac_compile); then
 810         use_mmx_asm=yes
 811     fi
 812     dnl rm -f conftest.[oS]
 813
 814     ac_ext=$save_ac_ext
 815   fi
 816
 817 dnl Enforce usage of MMX extensions
 818 elif test x$enable_mmx = xyes ; then
 819     use_mmx_asm=yes
 820 else
 821     use_mmx_asm=no
 822 fi
 823
 824 if test $use_mmx_asm = yes; then
 825         AC_DEFINE(WITH_MMX, 1, [Use MMX optimizations, if CPU supports it])
 826         AC_MSG_RESULT(yes)
 827 else
 828         AC_MSG_RESULT(no)
 829 fi
 830
 831 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 832
 833 dnl Figure out where the datadir actually is
 834 dnl http://autoconf-archive.cryp.to/ac_define_dir.html
 835 prefix_NONE=
 836 exec_prefix_NONE=
 837 test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
 838 test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
 839 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
 840 dnl refers to ${prefix}.  Thus we have to use `eval' twice.
 841 eval runtime_datadir="${datadir}"
 842 eval runtime_datadir="${runtime_datadir}"
 843 test "$prefix_NONE" && prefix=NONE
 844 test "$exec_prefix_NONE" && exec_prefix=NONE
 845
 846 inkscape_sharedir="${runtime_datadir}/${PACKAGE_NAME}"
 847
 848 dnl Define our data paths for config.h
 849 AC_SUBST(INKSCAPE_DATADIR)
 850 AC_DEFINE_UNQUOTED([INKSCAPE_DATADIR], "${runtime_datadir}",
 851                                         [Base data directory -- only path-prefix.h should use it!])
 852 AC_SUBST(PACKAGE_LOCALE_DIR)
 853 AC_DEFINE_UNQUOTED([PACKAGE_LOCALE_DIR], "${runtime_datadir}/locale",
 854                                         [Localization directory])
 855 AC_SUBST(INKSCAPE_LIBDIR)
 856 AC_DEFINE_UNQUOTED([INKSCAPE_LIBDIR], "${prefix}/lib",
 857                                         [Base library directory -- only path-prefix.h should use it!])
 858
 859 dnl Have to add module makefiles (lauris)
 860
 861 AC_CONFIG_FILES([
 862 Makefile
 863 src/Makefile
 864 src/check-header-compile
 865 src/algorithms/makefile
 866 src/application/makefile
 867 src/debug/makefile
 868 src/dialogs/makefile
 869 src/display/makefile
 870 src/dom/makefile
 871 src/extension/implementation/makefile
 872 src/extension/internal/makefile
 873 src/extension/makefile
 874 src/extension/script/makefile
 875 src/helper/makefile
 876 src/inkjar/makefile
 877 src/io/makefile
 878 src/libcroco/makefile
 879 src/libnr/makefile
 880 src/libnrtype/makefile
 881 src/libavoid/makefile
 882 src/livarot/makefile
 883 src/live_effects/makefile
 884 src/live_effects/parameter/makefile
 885 src/pedro/makefile
 886 src/jabber_whiteboard/makefile
 887 src/removeoverlap/makefile
 888 src/svg/makefile
 889 src/trace/makefile
 890 src/traits/makefile
 891 src/ui/cache/makefile
 892 src/ui/dialog/makefile
 893 src/ui/makefile
 894 src/ui/view/makefile
 895 src/ui/widget/makefile
 896 src/utest/makefile
 897 src/util/makefile
 898 src/widgets/makefile
 899 src/xml/makefile
 900 src/2geom/makefile
 901 doc/Makefile
 902 po/Makefile.in
 903 share/Makefile
 904 share/clipart/Makefile
 905 share/examples/Makefile
 906 share/extensions/Makefile
 907 share/extensions/Barcode/Makefile
 908 share/fonts/Makefile
 909 share/gradients/Makefile
 910 share/icons/Makefile
 911 share/keys/Makefile
 912 share/markers/Makefile
 913 share/palettes/Makefile
 914 share/patterns/Makefile
 915 share/screens/Makefile
 916 share/templates/Makefile
 917 share/tutorials/Makefile
 918 share/ui/Makefile
 919 packaging/autopackage/default.apspec
 920 inkscape.spec
 921 Info.plist
 922 inkview.1
 923 ])
 924
 925 AH_BOTTOM([
 926
 927
 928 ])
 929
 930 AC_OUTPUT
 931
 932 echo "
 933 Configuration:
 934
 935         Source code location:     ${srcdir}
 936         Destination path prefix:  ${prefix}
 937         Compiler:                 ${CXX}
 938         CPPFLAGS:                 ${CPPFLAGS}
 939         CXXFLAGS:                 ${CXXFLAGS}
 940         CFLAGS:                   ${CFLAGS}
 941         LDFLAGS:                  ${LDFLAGS}
 942
 943         Use Xft font database:    ${xft_ok}
 944         Use gnome-vfs:            ${gnome_vfs}
 945         Use openoffice files:     ${ij}
 946         Use MMX optimizations:    ${use_mmx_asm}
 947         Use relocation support:   ${enable_binreloc}
 948         Internal Python:          ${with_python}
 949         Internal Perl:            ${with_perl}
 950         Enable LittleCms:         ${enable_lcms}
 951         Enable Inkboard:          ${with_inkboard}
 952         Enable SSL in Inkboard:   ${with_inkboard_ssl}
 953         ImageMagick Magick++:     ${magick_ok}
 954 "