1 dnl Process this file with autoconf to produce a configure script.
3 AC_PREREQ(2.53)
5 # Always use 0.xx+devel instead of 0.xxdevel for the version, e.g. 0.46+devel.
6 # Rationale: (i) placate simple version comparison software such as
7 # `dpkg --compare-versions'. (ii) We don't always know what the next
8 # version is going to be called until about the time we release it
9 # (whereas we always know what the previous version was called).
10 AC_INIT(inkscape, 0.47+devel)
12 AC_CANONICAL_HOST
13 AC_CONFIG_SRCDIR([src/main.cpp])
14 AM_INIT_AUTOMAKE([dist-zip dist-bzip2 tar-pax])
16 AC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [
17 prefix=/opt/inkscape
18 PATH="/opt/lsb/bin:$PATH"
19 CC=lsbcc
20 CXX=lsbc++
21 export CC CXX
22 ])
24 AM_CONFIG_HEADER(config.h)
26 AC_LANG(C++)
27 AC_ISC_POSIX
28 AC_PROG_CXX
29 AM_PROG_CC_STDC
30 AM_PROG_AS
31 AC_PROG_RANLIB
32 AC_PROG_INTLTOOL(0.22)
33 AC_HEADER_STDC
34 INK_BZR_SNAPSHOT_BUILD
36 dnl If automake 1.11 shave the output to look nice
37 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
39 dnl These next few lines are needed only while libcroco is in our source tree.
40 AC_PROG_CC
41 AM_PROG_CC_C_O
42 if test "$GCC" = "yes"; then
43 # Enable some warnings from gcc.
44 AC_LANG_PUSH(C)
46 ####
47 # Generic cpp flags...
49 # What is just plain "-W" ?
50 # Fortify source requires -O2 or higher, which is handled with newer autoconf
51 CPPFLAGS="-W -D_FORTIFY_SOURCE=2 $CPPFLAGS"
52 # Enable format and format security warnings
53 CPPFLAGS="-Wformat -Wformat-security $CPPFLAGS"
54 # Enable all default warnings
55 CPPFLAGS="-Wall $CPPFLAGS"
57 # Test for -Werror=... (introduced some time post-4.0)
58 # If we hit a format error -- it should be fatal.
59 AC_MSG_CHECKING([compiler support for -Werror=format-security])
60 ink_svd_CPPFLAGS="$CPPFLAGS"
61 CPPFLAGS="-Werror=format-security $CPPFLAGS"
62 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
63 AC_MSG_RESULT([$ink_opt_ok])
64 if test "x$ink_opt_ok" != "xyes"; then
65 CPPFLAGS="$ink_svd_CPPFLAGS"
66 fi
68 ####
69 # C-specific flags...
71 # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted
72 # by gcc 2.95.
73 AC_MSG_CHECKING([compiler support for -Wno-pointer-sign])
74 ink_svd_CFLAGS="$CFLAGS"
75 CFLAGS="-Wno-pointer-sign $CFLAGS"
76 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
77 AC_MSG_RESULT([$ink_opt_ok])
78 if test "x$ink_opt_ok" != "xyes"; then
79 CFLAGS="$ink_svd_CFLAGS"
80 fi
82 ####
83 # Linker flags...
85 # Have linker produce read-only relocations, if it knows how
86 AC_MSG_CHECKING([linker tolerates -z relro])
87 ink_svd_LDFLAGS="$LDFLAGS"
88 LDFLAGS="-Wl,-z,relro $LDFLAGS"
89 AC_LINK_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
90 AC_MSG_RESULT([$ink_opt_ok])
91 if test "x$ink_opt_ok" != "xyes"; then
92 LDFLAGS="$ink_svd_LDFLAGS"
93 fi
95 AC_LANG_POP
97 # C++-specific flags are defined further below. Look for CXXFLAGS...
98 fi
100 dnl Honor aclocal flags
101 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
103 dnl Verify our GCC version
104 if test "x$GXX" = "xyes"; then
105 AC_MSG_CHECKING([GNU compiler version])
107 # Don't pass CXXFLAGS to the following CXX command as some
108 # of them can't be specified along with '-v'.
109 cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\
110 sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]
112 AC_MSG_RESULT([$cc_version])
114 # Some version numbers
115 cc_vers_major=`echo $cc_version | cut -f1 -d.`
116 cc_vers_minor=`echo $cc_version | cut -f2 -d.`
117 cc_vers_patch=`echo $cc_version | cut -f3 -d.`
118 test -n "$cc_vers_major" || cc_vers_major=0
119 test -n "$cc_vers_minor" || cc_vers_minor=0
120 test -n "$cc_vers_patch" || cc_vers_patch=0
121 cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`
123 if test $cc_vers_major -lt 3; then
124 AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])
125 fi
126 fi
128 # Test for broken unordered_set on GCC 4.0.0, shipped with Apple XCode tools
129 # This is a system header so we check it as soon as possible
130 AC_MSG_CHECKING([TR1 unordered_set usability])
131 AC_COMPILE_IFELSE([
132 #include <tr1/unordered_set>
133 int main() {
134 std::tr1::unordered_set<int> i, j;
135 i = j;
136 return 0;
137 }
138 ], [unordered_set_broken=no], [unordered_set_broken=yes])
139 if test "x$unordered_set_broken" = "xyes"; then
140 AC_MSG_RESULT([broken])
141 AC_MSG_ERROR([
142 You have a broken version of the <tr1/unordered_set> header. See
143 http://wiki.inkscape.org/wiki/index.php/HashtableFixOSX
144 for information on how to fix this problem.])
145 else
146 AC_MSG_RESULT([ok])
147 fi
149 # Test whether GCC emits a spurious warning when using boost::optional
150 # If yes, turn off strict aliasing warnings to reduce noise
151 # and allow the legitimate warnings to stand out
152 AC_MSG_CHECKING([for overzealous strict aliasing warnings])
153 ignore_strict_aliasing=no
154 CXXFLAGS_SAVE=$CXXFLAGS
155 CXXFLAGS="$CXXFLAGS -Werror=strict-aliasing"
156 AC_COMPILE_IFELSE([
157 #include <boost/optional.hpp>
158 boost::optional<int> x;
159 int func() {
160 return *x;
161 }
162 ], [ignore_strict_aliasing=no], [ignore_strict_aliasing=yes])
163 AC_MSG_RESULT($ignore_strict_aliasing)
164 CXXFLAGS=$CXXFLAGS_SAVE
165 if test "x$ignore_strict_aliasing" = "xyes"; then
166 CXXFLAGS="$CXXFLAGS -Wno-strict-aliasing"
167 fi
169 dnl ******************************
170 dnl Gettext stuff
171 dnl ******************************
172 GETTEXT_PACKAGE="AC_PACKAGE_NAME"
173 AC_SUBST(GETTEXT_PACKAGE)
174 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])
175 dnl Add the languages which your application supports here.
176 ALL_LINGUAS="am ar az be bg bn br ca ca@valencia cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fa fi fr ga gl he hr hu hy id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@latin sr sv th tr uk vi zh_CN zh_TW"
177 AM_GLIB_GNU_GETTEXT
179 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
180 if test "x$PKG_CONFIG" = "xno"; then
181 AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)
182 fi
184 dnl Find msgfmt. Without this, po/Makefile fails to set MSGFMT on some platforms.
185 AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)
186 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
188 dnl ******************************
189 dnl Check for OpenMP
190 dnl Replace this with AC_OPENMP once Autoconf 2.62 is widespread
191 dnl ******************************
192 AX_OPENMP([openmp_ok=yes],[openmp_ok=no])
193 if test "x$openmp_ok" = "xyes"; then
194 dnl We have it, now set up the flags
195 CXXFLAGS="$CXXFLAGS $OPENMP_CXXFLAGS"
196 AC_CHECK_HEADER(omp.h)
197 fi
199 dnl ******************************
200 dnl Check for libpng
201 dnl ******************************
202 AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=yes)], png_ok=no, -lz -lm)
203 if test "x$png_ok" != "xyes"; then
204 AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])
205 fi
207 dnl Handle possible dlopen requirement for libgc
208 dnl Isn't this internal to something in autoconf? Couldn't find it...
209 AC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],
210 [lt_cv_dlopen="dlopen"],
211 [AC_CHECK_LIB([dl], [dlopen],
212 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
213 [AC_CHECK_LIB([svld], [dlopen],
214 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
215 [AC_CHECK_LIB([dld], [dld_link],
216 [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
217 ])
218 ])
219 ])
220 ])
222 AC_CHECK_HEADERS([gc.h gc/gc.h],
223 [
224 # To test for the different required libs, I have to
225 # overcome autoconf's caching system, so I change the
226 # desired function name. They're all in libgc.
227 # The "break" will exit from the top level
228 # AC_CHECK_HEADERS.
229 gc_libs=""
230 AC_CHECK_LIB(gc, GC_init,
231 [gc_ok=yes;
232 LIBS="-lgc $gc_libs $LIBS";
233 break], [gc_ok=no], [$gc_libs])
234 gc_libs="-lpthread"
235 AC_CHECK_LIB(gc, GC_malloc,
236 [gc_ok=yes;
237 LIBS="-lgc $gc_libs $LIBS";
238 break], [gc_ok=no], [$gc_libs])
239 gc_libs="$lt_cv_dlopen_libs"
240 AC_CHECK_LIB(gc, GC_realloc,
241 [gc_ok=yes;
242 LIBS="-lgc $gc_libs $LIBS";
243 break], [gc_ok=no], [$gc_libs])
244 gc_libs="-lpthread $lt_cv_dlopen_libs"
245 AC_CHECK_LIB(gc, GC_free,
246 [gc_ok=yes;
247 LIBS="-lgc $gc_libs $LIBS";
248 break], [gc_ok=no], [$gc_libs])
249 break],
250 [gc_ok=no])
251 if test "x$gc_ok" = "xyes" && test "x$cross_compiling" = "xno" ; then
252 AC_MSG_CHECKING([libgc version 6.4+])
253 AC_RUN_IFELSE(
254 [AC_LANG_SOURCE([[
255 #ifdef HAVE_GC_GC_H
256 # include <gc/gc.h>
257 #else
258 # include <gc.h>
259 #endif
260 #include <stdio.h>
261 extern unsigned GC_version;
262 int main(void){
263 unsigned min = ((6 << 16) | (4 << 8) | 0);
264 printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);
265 if (GC_version>=min) return 0;
266 return 1;
267 }]])],
268 [gc_ok=yes],
269 [gc_ok=no]
270 )
271 AC_MSG_RESULT([$gc_ok])
272 fi
273 if test "x$gc_ok" != "xyes"; then
274 AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])
275 fi
277 dnl This check is to get a FIONREAD definition on Solaris 8
278 AC_CHECK_HEADERS([sys/filio.h])
281 AC_CHECK_HEADERS([malloc.h])
282 AC_CHECK_FUNCS([mallinfo], [
283 AC_CHECK_MEMBERS([struct mallinfo.usmblks,
284 struct mallinfo.fsmblks,
285 struct mallinfo.uordblks,
286 struct mallinfo.fordblks,
287 struct mallinfo.hblkhd],,,
288 [#include <malloc.h>])
289 ])
291 AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
292 if test "x$FREETYPE_CONFIG" = "xno"; then
293 AC_MSG_ERROR([Cannot find freetype-config])
294 fi
295 FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
296 FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
297 AC_SUBST(FREETYPE_CFLAGS)
298 AC_SUBST(FREETYPE_LIBS)
300 dnl ******************************
301 dnl Win32
302 dnl ******************************
303 AC_MSG_CHECKING([for Win32 platform])
304 case "$host" in
305 *-*-mingw*)
306 platform_win32=yes
307 WIN32_CFLAGS="-mms-bitfields -DLIBXML_STATIC"
308 ;;
309 *)
310 platform_win32=no
311 ;;
312 esac
313 AC_MSG_RESULT([$platform_win32])
314 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
315 AC_SUBST(WIN32_CFLAGS)
317 AC_MSG_CHECKING([for Solaris platform])
318 case "$host" in
319 *-solaris2.*)
320 platform_solaris=yes
321 solaris_version=`echo $host|sed -e 's/^.*-solaris2\.//' -e s'/\..*$//'`
322 CFLAGS="$CFLAGS -DSOLARIS=$solaris_version"
323 CXXFLAGS="$CXXFLAGS -DSOLARIS=$solaris_version"
324 ;;
325 *)
326 platform_solaris=no
327 ;;
328 esac
329 AC_MSG_RESULT([$platform_solaris])
330 AM_CONDITIONAL(PLATFORM_SOLARIS, test "$platform_solaris" = "yes")
332 dnl ******************************
333 dnl Xft checking
334 dnl ******************************
336 AC_ARG_WITH(xft,
337 AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),
338 [with_xft=$withval], [with_xft=auto])
340 if test "x$with_xft" != "xno" ; then
341 dnl Test fontconfig package
342 PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)
343 if test "x$xft_ok" != "xyes"; then
344 dnl test xft package
345 PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)
346 if test "x$xft_ok" != "xyes"; then
347 dnl Have to test xft presence
348 AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)
349 if test "x$xft_ok" != "xyes"; then
350 dnl No xft found
351 if test "x$with_xft" = "xyes"; then
352 dnl Xft was explicitly asked, so stop
353 AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])
354 fi
355 else
356 dnl Working Xft1
357 XFT_LIBS="-L/usr/X11R6/lib -lXft "
358 fi
359 fi
360 fi
361 else
362 dnl Asked to ignore xft
363 xft_ok=no
364 fi
366 AC_SUBST(XFT_CFLAGS)
367 AC_SUBST(XFT_LIBS)
369 AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")
370 if test "x$xft_ok" = "xyes"; then
371 AC_DEFINE(WITH_XFT, 1, [Use Xft font database])
372 fi
374 dnl ******************************
375 dnl pangoft2 for xft
376 dnl ******************************
378 if test "x$xft_ok" = "xyes"; then
379 PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)
380 if test "x$pango_ok" = "xyes"; then
381 XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"
382 fi
383 fi
386 dnl ******************************
387 dnl gnome vfs checking
388 dnl ******************************
390 AC_ARG_WITH(gnome-vfs,
391 AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),
392 [with_gnome_vfs=$withval], [with_gnome_vfs=auto])
394 if test "x$with_gnome_vfs" = "xno"; then
395 dnl Asked to ignore gnome-vfs
396 gnome_vfs=no
397 else
398 dnl Have to test gnome-vfs presence
399 PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)
400 if test "x$gnome_vfs" != "xyes"; then
401 dnl No gnome-vfs found
402 if test "x$with_gnome_vfs" = "xyes"; then
403 dnl Gnome-VFS was explicitly asked for, so stop
404 AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])
405 else
406 # gnome-vfs is no, tell us for the log file
407 AC_MSG_RESULT($gnome_vfs)
408 fi
409 fi
410 fi
412 AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")
413 if test "x$gnome_vfs" = "xyes"; then
414 AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])
415 fi
417 AC_SUBST(GNOME_VFS_CFLAGS)
418 AC_SUBST(GNOME_VFS_LIBS)
420 dnl ******************************
421 dnl libinkjar checking
422 dnl ******************************
424 AC_ARG_WITH(inkjar,
425 AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])
427 if test "x$with_ij" = "xyes"; then
428 AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])
429 AC_C_BIGENDIAN
430 AC_CHECK_HEADERS(zlib.h)
431 ij=yes
432 else
433 ij=no
434 fi
435 AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")
437 ink_spell_pkg=
438 if pkg-config --exists gtkspell-2.0; then
439 ink_spell_pkg=gtkspell-2.0
440 AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])
441 fi
443 dnl ******************************
444 dnl PERL checking
445 dnl ******************************
447 AC_MSG_CHECKING(for Perl development environment)
448 AC_ARG_WITH(perl,
449 AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),
450 [with_perl=$withval], [with_perl=skipped])
452 if test "x$with_perl" = "xyes"; then
453 checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`
454 if test "$?" -gt "0"; then
455 with_perl="no"
456 else
457 checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`
458 if test "$?" -gt "0"; then
459 with_perl="no"
460 else
461 with_perl="yes"
462 fi
463 fi
464 fi
465 AC_MSG_RESULT([$with_perl])
466 if test "x$with_perl" = "xyes"; then
467 # Test that we actually have the perl libraries installed
468 oldCFLAGS="$CFLAGS"
469 oldLIBS="$LIBS"
470 CFLAGS="$CFLAGS $checkPERL_CFLAGS"
471 LIBS="$LIBS $checkPERL_LIBS"
472 AC_CHECK_FUNC([perl_parse],[
473 PERL_CFLAGS="$checkPERL_CFLAGS"
474 PERL_LIBS="$checkPERL_LIBS"
475 AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])
476 ],[
477 with_perl="no"
478 ])
479 CFLAGS="$oldCFLAGS"
480 LIBS="$oldLIBS"
481 fi
482 AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")
483 AC_SUBST(PERL_CFLAGS)
484 AC_SUBST(PERL_LIBS)
486 dnl ******************************
487 dnl Python checking
488 dnl ******************************
490 AC_MSG_CHECKING(for Python development environment)
491 AC_ARG_WITH(python,
492 AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),
493 [with_python=$withval], [with_python=skipped])
495 if test "x$with_python" = "xyes"; then
496 checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`
497 if test "$?" -gt "0"; then
498 with_python="no"
499 else
500 checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`
501 if test "$?" -gt "0"; then
502 with_python="no"
503 else
504 with_python="yes"
505 fi
506 fi
507 fi
508 AC_MSG_RESULT([$with_python])
509 if test "x$with_python" = "xyes"; then
510 # Test that we actually have the python libraries installed
511 oldCFLAGS="$CFLAGS"
512 oldLIBS="$LIBS"
513 CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"
514 LIBS="$LIBS $checkPYTHON_LIBS"
515 AC_CHECK_FUNC([Py_Initialize],[
516 PYTHON_CFLAGS="$checkPYTHON_CFLAGS"
517 PYTHON_LIBS="$checkPYTHON_LIBS"
518 AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])
519 ],[
520 with_python="no"
521 ])
522 CFLAGS="$oldCFLAGS"
523 LIBS="$oldLIBS"
524 fi
525 AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")
526 AC_SUBST(PYTHON_CFLAGS)
527 AC_SUBST(PYTHON_LIBS)
529 dnl ******************************
530 dnl LittleCms checking
531 dnl ******************************
533 AC_ARG_ENABLE(lcms,
534 AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),
535 [enable_lcms=$enableval], [enable_lcms=yes])
537 if test "x$enable_lcms" = "xno"; then
538 dnl Asked to ignore LittleCms
539 lcms=no
540 else
541 dnl Have to test LittleCms presence
542 PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)
543 if test "x$lcms" != "xyes"; then
544 dnl No lcms found
545 if test "x$enable_lcms" = "xyes"; then
546 dnl LittleCms was explicitly asked for, so stop
547 AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])
548 else
549 # lcms is no, tell us for the log file
550 AC_MSG_RESULT($lcms)
551 fi
552 else
553 dnl Working lcms
554 LIBS="$LIBS $LCMS_LIBS"
555 AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])
556 fi
557 fi
559 AC_SUBST(LCMS_CFLAGS)
560 AC_SUBST(LCMS_LIBS)
562 dnl ******************************
563 dnl Libpoppler checking
564 dnl ******************************
566 AC_ARG_ENABLE(poppler-cairo,
567 AC_HELP_STRING([--enable-poppler-cairo], [Enable libpoppler-cairo for rendering PDF preview]),
568 [enable_poppler_cairo=$enableval], [enable_poppler_cairo=yes])
570 POPPLER_CFLAGS=""
571 PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.9, poppler=yes, poppler=no)
573 if test "x$poppler" = "xyes"; then
574 dnl Working libpoppler
575 POPPLER_LIBS="-lpoppler "
576 dnl Have to test libpoppler-glib presence
577 PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.9, poppler_glib=yes, poppler_glib=no)
578 if test "x$poppler_glib" = "xyes"; then
579 dnl Working libpoppler-glib found
580 dnl Check whether the Cairo SVG backend is available
581 PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)
582 if test "x$cairo_svg" = "xyes"; then
583 POPPLER_LIBS="$POPPLER_LIBS -lpoppler-glib "
584 fi
585 fi
586 if test "x$enable_poppler_cairo" = "xyes"; then
587 dnl Have to test libpoppler-cairo presence for PDF preview
588 dnl AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)
589 PKG_CHECK_MODULES(POPPLER_CAIRO, poppler-cairo >= 0.5.9, poppler_cairo=yes, poppler_cairo=no)
590 if test "x$poppler_glib" = "xyes" -a "x$poppler_cairo" = "xyes" -a \
591 "x$cairo_svg" = "xno"
592 then
593 POPPLER_LIBS="$POPPLER_LIBS -lpoppler-glib "
594 fi
595 fi
596 fi
598 if test "x$poppler" = "xyes"; then
599 LIBS="$LIBS $POPPLER_LIBS"
600 AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])
601 fi
602 if test "x$poppler_cairo" = "xyes" -a "x$poppler_glib" = "xyes"; then
603 AC_DEFINE(HAVE_POPPLER_CAIRO, 1, [Use libpoppler-cairo for rendering PDF preview])
604 fi
605 if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then
606 AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])
607 fi
608 AC_SUBST(POPPLER_CFLAGS)
609 AC_SUBST(POPPLER_LIBS)
611 PKG_CHECK_MODULES(POPPLERNEW, poppler >= 0.8.3, popplernew=yes, popplernew=no)
612 if test "x$popplernew" = "xyes"; then
613 AC_DEFINE(POPPLER_NEW_GFXFONT, 1, [Poppler version of GfxFont to use (0.8.3 or higher versions of Poppler)])
614 fi
616 dnl ******************************
617 dnl Inkboard dependency checking
618 dnl ******************************
620 dnl with_inkboard="no"
621 dnl with_inkboard_ssl="no"
623 dnl INKBOARD_CFLAGS=""
625 dnl AC_ARG_ENABLE(inkboard,
626 dnl AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),
627 dnl with_inkboard=$enableval,with_inkboard=no)
629 dnl if test "x$with_inkboard" = "xyes"; then
630 dnl with_inkboard="yes"
631 dnl AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])
633 dnl Test for OpenSSL
634 dnl PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)
635 dnl if test "x$with_inkboard_ssl" = "xyes"; then
636 dnl OpenSSL found; enable SSL support in Pedro
637 dnl INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"
638 dnl RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
639 dnl RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
640 dnl AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])
641 dnl fi
642 dnl else
643 dnl with_inkboard="no"
644 dnl fi
646 dnl AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")
648 INKBOARD_CFLAGS=""
649 INKBOARD_LIBS=""
650 AC_SUBST(INKBOARD_LIBS)
651 AC_SUBST(INKBOARD_CFLAGS)
653 dnl ******************************
654 dnl Check for libwpg for extension
655 dnl ******************************
657 PKG_CHECK_MODULES(LIBWPG, libwpg-0.1 libwpg-stream-0.1, with_libwpg=yes, with_libwpg=no)
658 if test "x$with_libwpg" = "xyes"; then
659 AC_DEFINE(WITH_LIBWPG,1,[Build in libwpg])
660 fi
661 AM_CONDITIONAL(WITH_LIBWPG, test "x$with_libwpg" = "xyes")
663 AC_SUBST(LIBWPG_LIBS)
664 AC_SUBST(LIBWPG_CFLAGS)
666 dnl ******************************
667 dnl Check for ImageMagick Magick++
668 dnl ******************************
670 PKG_CHECK_MODULES(IMAGEMAGICK, ImageMagick++, magick_ok=yes, magick_ok=no)
671 if test "x$magick_ok" = "xyes"; then
672 AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])
673 fi
674 AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")
676 AC_SUBST(IMAGEMAGICK_LIBS)
677 AC_SUBST(IMAGEMAGICK_CFLAGS)
679 dnl ***********************************************************************************************************
680 dnl Check for a Cairo version that implements user-fonts feature (with a stable API, that is cairo > 1.7.6),
681 dnl so that we conditionally add SVGFonts support
682 dnl ***********************************************************************************************************
684 PKG_CHECK_MODULES(CAIRO_USER_FONTS, cairo > 1.7.6, cairouserfonts=yes, cairouserfonts=no)
685 if test "x$cairouserfonts" = "xyes"; then
686 AC_DEFINE(ENABLE_SVG_FONTS, 1, [SVG Fonts should be used])
687 fi
689 dnl ******************************
690 dnl Unconditional dependencies
691 dnl ******************************
693 dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10
694 if test $cc_vers_major -gt 3; then
695 min_sigc_version=2.0.12
696 else
697 min_sigc_version=2.0.11
698 fi
699 PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4 glibmm-2.4 giomm-2.4 gtkmm-2.4 >= 2.10.0 gtk+-2.0 libxml-2.0 >= 2.6.11 libxslt >= 1.0.15 cairo sigc++-2.0 >= $min_sigc_version $ink_spell_pkg gthread-2.0 >= 2.0 libpng >= 1.2 gsl)
701 # Check for Apple Mac OS X Carbon framework
702 carbon_ok=no
703 AC_MSG_CHECKING([for Mac OS X Carbon support])
704 AC_COMPILE_IFELSE([
705 #include <Carbon/Carbon.h>
706 #include <CoreServices/CoreServices.h>
707 ], [carbon_ok=yes])
708 AC_MSG_RESULT($carbon_ok)
709 if test "x$carbon_ok" = "xyes"; then
710 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
711 CARBON_LDFLAGS="-framework Carbon"
712 AC_SUBST(CARBON_LDFLAGS)
713 fi
714 AM_CONDITIONAL(HAVE_CARBON, test "x$carbon_ok" = "xyes")
716 # Check for some boost header files
717 AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))
719 PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)
720 if test "x$cairo_pdf" = "xyes"; then
721 AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])
722 fi
724 dnl Shouldn't we test for libpng and libz?
725 if test "x$openmp_ok" = "xyes"; then
726 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz -lgomp"
727 else
728 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz"
729 fi
731 AC_CHECK_HEADER(popt.h,
732 [INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],
733 AC_MSG_ERROR([libpopt is required]))
735 dnl **************************
736 dnl Check for aspell
737 dnl ******************************
738 AC_CHECK_LIB(aspell, new_aspell_config, [AC_CHECK_HEADER(aspell.h, aspell_ok=yes, aspell_ok=no)], aspell_ok=no, -lz -lm)
739 if test "x$aspell_ok" = "xyes"; then
740 AC_DEFINE(HAVE_ASPELL, 1, [Use aspell for built-in spellchecker])
741 INKSCAPE_LIBS="$INKSCAPE_LIBS -laspell"
742 else
743 AC_MSG_CHECKING([Aspell not found, spell checker will be disabled])
744 fi
746 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
747 sp_save_LIBS=$LIBS
748 LIBS="$LIBS $INKSCAPE_LIBS"
749 AC_CHECK_FUNCS(bind_textdomain_codeset)
750 dnl Check for gtk_window_fullscreen in gtk (>= 2.2)
751 AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)
752 AC_CHECK_FUNCS(gtk_window_fullscreen)
753 LIBS=$sp_save_LIBS
756 dnl Check for binary relocation support
757 dnl Hongli Lai <h.lai@chello.nl>
759 AC_ARG_ENABLE(binreloc,
760 [ --enable-binreloc compile with binary relocation support],
761 enable_binreloc=$enableval,enable_binreloc=no)
763 AC_MSG_CHECKING(whether binary relocation support should be enabled)
764 if test "$enable_binreloc" = "yes"; then
765 AC_MSG_RESULT(yes)
766 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
767 if test -e /proc/self/maps; then
768 AC_MSG_RESULT(yes)
769 else
770 AC_MSG_RESULT(no)
771 AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
772 enable_binreloc="no"
773 fi
775 elif test "$enable_binreloc" = "auto"; then
776 AC_MSG_RESULT(yes when available)
777 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
778 if test -e /proc/self/maps; then
779 AC_MSG_RESULT(yes)
780 enable_binreloc=yes
782 AC_MSG_CHECKING(whether everything is installed to the same prefix)
783 if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
784 "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
785 "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
786 then
787 AC_MSG_RESULT(yes)
788 else
789 AC_MSG_RESULT(no)
790 AC_MSG_NOTICE(Binary relocation support will be disabled.)
791 enable_binreloc=no
792 fi
794 else
795 AC_MSG_RESULT(no)
796 enable_binreloc=no
797 fi
799 elif test "$enable_binreloc" = "no"; then
800 AC_MSG_RESULT(no)
801 else
802 AC_MSG_RESULT([no (unknown value "$enable_binreloc")])
803 enable_binreloc=no
804 fi
805 AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])
806 if test "$enable_binreloc" = "yes"; then
807 AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
808 fi
810 AC_ARG_ENABLE(osxapp,
811 [ --enable-osxapp compile with OSX .app data dir paths],
812 enable_osxapp=$enableval,enable_osxapp=no)
813 if test "$enable_osxapp" = "yes"; then
814 AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])
815 fi
817 dnl ******************************
818 dnl Reported by autoscan
819 dnl ******************************
820 AC_CHECK_FUNCS(pow)
821 # if we did not find pow(), see if it's in libm.
822 if test x"$ac_cv_func_pow" = x"no" ; then
823 AC_CHECK_LIB(m,pow)
824 fi
825 AC_CHECK_FUNCS(sqrt)
826 AC_CHECK_FUNCS(floor)
827 AC_CHECK_FUNCS(gettimeofday)
828 AC_CHECK_FUNCS(memmove)
829 AC_CHECK_FUNCS(memset)
830 AC_CHECK_FUNCS(mkdir)
831 AC_CHECK_FUNCS(strncasecmp)
832 AC_CHECK_FUNCS(strpbrk)
833 AC_CHECK_FUNCS(strrchr)
834 AC_CHECK_FUNCS(strspn)
835 AC_CHECK_FUNCS(strstr)
836 AC_CHECK_FUNCS(strtoul)
837 AC_CHECK_FUNCS(fpsetmask)
838 AC_CHECK_FUNCS(ecvt)
839 AC_CHECK_HEADERS(ieeefp.h)
840 AC_CHECK_HEADERS(fcntl.h)
841 AC_CHECK_HEADERS(libintl.h)
842 AC_CHECK_HEADERS(stddef.h)
843 AC_CHECK_HEADERS(sys/time.h)
844 AC_FUNC_STAT
845 AC_FUNC_STRFTIME
846 AC_FUNC_STRTOD
847 AC_HEADER_STAT
848 AC_HEADER_TIME
849 AC_STRUCT_TM
850 AC_TYPE_MODE_T
851 AC_TYPE_SIGNAL
853 dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't
854 dnl set correctly because the gettext function isn't noticed.
855 if test "$ac_cv_header_libintl_h" = "yes" &&
856 test "$ac_cv_func_bind_textdomain_codeset" = "yes" &&
857 test "$gt_cv_func_have_gettext" != "yes"; then
858 AC_DEFINE(ENABLE_NLS)
859 fi
861 dnl ******************************
862 dnl Compilation warnings
863 dnl ******************************
864 if test "$GXX" = "yes"; then
865 # Enable some warnings from g++.
867 # Rationale: a number of bugs in inkscape have been fixed by enabling g++
868 # warnings and addressing the produced warnings. Usually the committing
869 # developer is the best person to address the warnings.
871 ink_svd_CXXFLAGS="$CXXFLAGS"
872 CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"
873 # -Wno-unused-parameter isn't accepted by gcc 2.95.
874 AC_COMPILE_IFELSE([int dummy;
875 ], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)
876 # Note: At least one bug has been caught from unused parameter warnings,
877 # so it might be worth trying not to disable it.
878 # One way of selectively disabling the warnings (i.e. only where the
879 # programmer deliberately isn't using the parameter, e.g. for a callback)
880 # is to remove the parameter name (leaving just its type), as is done
881 # in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the
882 # programmer deliberately has an unused parameter (e.g. because it's used
883 # as a callback or similar function pointer use).
885 # Add even more stuff
886 CXXFLAGS="-Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch $CXXFLAGS"
888 fi
890 dnl ******************************
891 dnl libinkscape
892 dnl ******************************
893 dnl
894 dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])
895 dnl
896 dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")
897 dnl
899 AC_SUBST(INKSCAPE_CFLAGS)
900 AC_SUBST(INKSCAPE_LIBS)
902 #
903 # Checks to see if we should compile in MMX support (there will be
904 # a runtime test when the code is actually run to see if it should
905 # be used - this just checks if we can compile it.)
906 #
907 # This code is partially taken from Mesa
908 #
909 dnl Let people disable the MMX optimization
910 AC_ARG_ENABLE(mmx, [ --disable-mmx Don't use MMX optimization [default=auto]], enable_mmx="$enableval", enable_mmx=auto)
912 AC_MSG_CHECKING(for x86 platform)
913 case $host_cpu in
914 i386|i486|i586|i686|i786|k6|k7)
915 use_x86_asm=yes
916 ;;
917 *)
918 use_x86_asm=no
919 esac
920 AC_MSG_RESULT($use_x86_asm)
922 dnl Are we going to use MMX extensions
923 use_mmx_asm=no
925 AC_MSG_CHECKING(compiler support for MMX)
927 if test x$enable_mmx = xauto ; then
928 if test $use_x86_asm = yes; then
929 save_ac_ext=$ac_ext
930 ac_ext=S
932 cp $srcdir/src/libnr/nr_mmx_R8G8B8A8_P_R8G8B8A8_P_A8_RGBAP.S conftest.S
933 if AC_TRY_EVAL(ac_compile); then
934 use_mmx_asm=yes
935 fi
936 dnl rm -f conftest.[oS]
938 ac_ext=$save_ac_ext
939 fi
941 dnl Enforce usage of MMX extensions
942 elif test x$enable_mmx = xyes ; then
943 use_mmx_asm=yes
944 else
945 use_mmx_asm=no
946 fi
948 if test $use_mmx_asm = yes; then
949 AC_DEFINE(WITH_MMX, 1, [Use MMX optimizations, if CPU supports it])
950 AC_MSG_RESULT(yes)
951 else
952 AC_MSG_RESULT(no)
953 fi
955 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
957 dnl Define our data paths for config.h
958 AC_DEFINE_DIR([INKSCAPE_DATADIR], [datadir], [Base data directory])
959 AC_DEFINE_DIR([PACKAGE_LOCALE_DIR], [localedir], [Locatization directory])
961 AC_CONFIG_FILES([
962 Makefile
963 src/Makefile
964 src/check-header-compile
965 src/algorithms/makefile
966 src/application/makefile
967 src/bind/makefile
968 src/debug/makefile
969 src/dialogs/makefile
970 src/display/makefile
971 src/dom/makefile
972 src/extension/implementation/makefile
973 src/extension/internal/makefile
974 src/extension/makefile
975 src/extension/script/makefile
976 src/filters/makefile
977 src/helper/makefile
978 src/inkjar/makefile
979 src/io/makefile
980 src/libcroco/makefile
981 src/libgdl/makefile
982 src/libnr/makefile
983 src/libnrtype/makefile
984 src/libavoid/makefile
985 src/livarot/makefile
986 src/live_effects/makefile
987 src/live_effects/parameter/makefile
988 src/pedro/makefile
989 src/jabber_whiteboard/makefile
990 src/removeoverlap/makefile
991 src/svg/makefile
992 src/trace/makefile
993 src/traits/makefile
994 src/ui/cache/makefile
995 src/ui/dialog/makefile
996 src/ui/makefile
997 src/ui/view/makefile
998 src/ui/widget/makefile
999 src/util/makefile
1000 src/widgets/makefile
1001 src/xml/makefile
1002 src/2geom/makefile
1003 doc/Makefile
1004 po/Makefile.in
1005 share/Makefile
1006 share/clipart/Makefile
1007 share/examples/Makefile
1008 share/extensions/Makefile
1009 share/extensions/alphabet_soup/Makefile
1010 share/extensions/Barcode/Makefile
1011 share/extensions/Poly3DObjects/Makefile
1012 share/extensions/test/Makefile
1013 share/extensions/xaml2svg/Makefile
1014 share/filters/Makefile
1015 share/fonts/Makefile
1016 share/gradients/Makefile
1017 share/icons/Makefile
1018 share/icons/application/Makefile
1019 share/icons/application/16x16/Makefile
1020 share/icons/application/22x22/Makefile
1021 share/icons/application/24x24/Makefile
1022 share/icons/application/32x32/Makefile
1023 share/icons/application/48x48/Makefile
1024 share/icons/application/256x256/Makefile
1025 share/keys/Makefile
1026 share/markers/Makefile
1027 share/palettes/Makefile
1028 share/patterns/Makefile
1029 share/screens/Makefile
1030 share/templates/Makefile
1031 share/tutorials/Makefile
1032 share/ui/Makefile
1033 packaging/autopackage/default.apspec
1034 inkscape.spec
1035 Info.plist
1036 inkview.1
1037 ])
1039 AH_BOTTOM([
1042 ])
1044 AC_OUTPUT
1046 echo "
1047 Configuration:
1049 Source code location: ${srcdir}
1050 Destination path prefix: ${prefix}
1051 Compiler: ${CXX}
1052 CPPFLAGS: ${CPPFLAGS}
1053 CXXFLAGS: ${CXXFLAGS}
1054 CFLAGS: ${CFLAGS}
1055 LDFLAGS: ${LDFLAGS}
1057 Use Xft font database: ${xft_ok}
1058 Use gnome-vfs: ${gnome_vfs}
1059 Use openoffice files: ${ij}
1060 Use MMX optimizations: ${use_mmx_asm}
1061 Use relocation support: ${enable_binreloc}
1062 Internal Python: ${with_python}
1063 Internal Perl: ${with_perl}
1064 Enable LittleCms: ${enable_lcms}
1065 Enable Poppler-Cairo: ${enable_poppler_cairo}
1066 ImageMagick Magick++: ${magick_ok}
1067 Libwpg: ${with_libwpg}
1068 "