1 dnl Process this file with autoconf to produce a configure script.
3 AC_PREREQ(2.50)
4 AC_INIT(inkscape, 0.45+devel)
5 dnl N.B. After 0.40, please change to `0.40+cvs' instead of `0.41cvs'.
6 dnl Rationale: (i) placate simple version comparison software such as
7 dnl `dpkg --compare-versions'. (ii) We don't always know what the next
8 dnl version is going to be called until about the time we release it
9 dnl (whereas we always know what the previous version was called).
10 AC_CANONICAL_HOST
11 AC_CONFIG_SRCDIR(src/main.cpp)
12 AM_INIT_AUTOMAKE
14 AC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [
15 prefix=/opt/inkscape
16 PATH="/opt/lsb/bin:$PATH"
17 CC=lsbcc
18 CXX=lsbc++
19 export CC CXX
20 ])
22 AM_CONFIG_HEADER(config.h)
24 AC_PROG_INTLTOOL(0.22)
26 AC_LANG(C++)
27 AC_ISC_POSIX
28 AC_PROG_CXX
29 AM_PROG_CC_STDC
30 AM_PROG_AS
31 AC_HEADER_STDC
33 dnl These next few lines are needed only while libcroco is in our source tree.
34 AC_PROG_CC
35 AM_PROG_CC_C_O
36 AC_MSG_NOTICE([Testing -Wno-pointer-sign])
37 if test "$GCC" = "yes"; then
38 # Enable some warnings from gcc.
40 AC_LANG_PUSH(C)
41 # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted
42 # by gcc 2.95.
43 ink_svd_CFLAGS="$CFLAGS"
44 CFLAGS="-Wno-pointer-sign $CFLAGS"
45 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), AC_MSG_NOTICE([ compiler supports -Wno-pointer-sign]), CFLAGS="$ink_svd_CFLAGS")
46 CFLAGS="-Wall -Wformat-security -W -D_FORTIFY_SOURCE=2 $CFLAGS"
47 AC_LANG_POP
48 fi
50 dnl Honor aclocal flags
51 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
53 AC_PROG_RANLIB
55 dnl Verify our GCC version
56 if test "x$GXX" = "xyes"; then
57 AC_MSG_CHECKING([GNU compiler version])
59 # Don't pass CXXFLAGS to the following CXX command as some
60 # of them can't be specified along with '-v'.
61 cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\
62 sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]
64 AC_MSG_RESULT([$cc_version])
66 # Some version numbers
67 cc_vers_major=`echo $cc_version | cut -f1 -d.`
68 cc_vers_minor=`echo $cc_version | cut -f2 -d.`
69 cc_vers_patch=`echo $cc_version | cut -f3 -d.`
70 test -n "$cc_vers_major" || cc_vers_major=0
71 test -n "$cc_vers_minor" || cc_vers_minor=0
72 test -n "$cc_vers_patch" || cc_vers_patch=0
73 cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`
75 if test $cc_vers_major -lt 3; then
76 AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])
77 fi
78 fi
80 dnl ******************************
81 dnl Gettext stuff
82 dnl ******************************
83 GETTEXT_PACKAGE="AC_PACKAGE_NAME"
84 AC_SUBST(GETTEXT_PACKAGE)
85 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])
86 dnl Add the languages which your application supports here.
87 ALL_LINGUAS="am az be bg bn ca cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fi fr ga gl he hr hu id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@Latn sr sv th tr uk vi zh_CN zh_TW"
88 AM_GLIB_GNU_GETTEXT
90 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
91 if test "x$PKG_CONFIG" = "xno"; then
92 AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)
93 fi
95 dnl Find msgfmt. Without this, po/Makefile fails to set MSGFMT on some platforms.
96 AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)
97 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
99 dnl ******************************
100 dnl Check for libpng
101 dnl ******************************
102 AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=no)], png_ok=no, -lz -lm)
103 if test "x$png_ok" != "xyes"; then
104 AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])
105 fi
107 dnl Handle possible dlopen requirement for libgc
108 dnl Isn't this internal to something in autoconf? Couldn't find it...
109 AC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],
110 [lt_cv_dlopen="dlopen"],
111 [AC_CHECK_LIB([dl], [dlopen],
112 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
113 [AC_CHECK_LIB([svld], [dlopen],
114 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
115 [AC_CHECK_LIB([dld], [dld_link],
116 [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
117 ])
118 ])
119 ])
120 ])
122 AC_CHECK_HEADERS([gc.h gc/gc.h],
123 [
124 # To test for the different required libs, I have to
125 # overcome autoconf's caching system, so I change the
126 # desired function name. They're all in libgc.
127 # The "break" will exit from the top level
128 # AC_CHECK_HEADERS.
129 gc_libs=""
130 AC_CHECK_LIB(gc, GC_init,
131 [gc_ok=yes;
132 LIBS="-lgc $gc_libs $LIBS";
133 break], [gc_ok=no], [$gc_libs])
134 gc_libs="-lpthread"
135 AC_CHECK_LIB(gc, GC_malloc,
136 [gc_ok=yes;
137 LIBS="-lgc $gc_libs $LIBS";
138 break], [gc_ok=no], [$gc_libs])
139 gc_libs="$lt_cv_dlopen_libs"
140 AC_CHECK_LIB(gc, GC_realloc,
141 [gc_ok=yes;
142 LIBS="-lgc $gc_libs $LIBS";
143 break], [gc_ok=no], [$gc_libs])
144 gc_libs="-lpthread $lt_cv_dlopen_libs"
145 AC_CHECK_LIB(gc, GC_free,
146 [gc_ok=yes;
147 LIBS="-lgc $gc_libs $LIBS";
148 break], [gc_ok=no], [$gc_libs])
149 break],
150 [gc_ok=no])
151 if test "x$gc_ok" = "xyes"; then
152 AC_MSG_CHECKING([libgc version 6.4+])
153 AC_RUN_IFELSE(
154 [AC_LANG_SOURCE([[
155 #ifdef HAVE_GC_GC_H
156 # include <gc/gc.h>
157 #else
158 # include <gc.h>
159 #endif
160 #include <stdio.h>
161 extern unsigned GC_version;
162 int main(void){
163 unsigned min = ((6 << 16) | (4 << 8) | 0);
164 printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);
165 if (GC_version>=min) return 0;
166 return 1;
167 }]])],
168 [gc_ok=yes],
169 [gc_ok=no]
170 )
171 AC_MSG_RESULT([$gc_ok])
172 fi
173 if test "x$gc_ok" != "xyes"; then
174 AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])
175 fi
177 dnl This check is to get a FIONREAD definition on Solaris 8
178 AC_CHECK_HEADERS([sys/filio.h])
181 AC_CHECK_HEADERS([malloc.h])
182 AC_CHECK_FUNCS([mallinfo], [
183 AC_CHECK_MEMBERS([struct mallinfo.usmblks,
184 struct mallinfo.fsmblks,
185 struct mallinfo.uordblks,
186 struct mallinfo.fordblks,
187 struct mallinfo.hblkhd],,,
188 [#include <malloc.h>])
189 ])
191 AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
192 if test "x$FREETYPE_CONFIG" = "xno"; then
193 AC_MSG_ERROR([Cannot find freetype-config])
194 fi
195 FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
196 FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
197 AC_SUBST(FREETYPE_CFLAGS)
198 AC_SUBST(FREETYPE_LIBS)
200 dnl ******************************
201 dnl Win32
202 dnl ******************************
203 AC_MSG_CHECKING([for Win32 platform])
204 case "$host" in
205 *-*-mingw*)
206 platform_win32=yes
207 INKSCAPE_CFLAGS="$INKSCAPE_CFLAGS -mms-bitfields -DLIBXML_STATIC"
208 ;;
209 *)
210 platform_win32=no
211 ;;
212 esac
213 AC_MSG_RESULT([$platform_win32])
214 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
216 AC_MSG_CHECKING([for Solaris 2.8 platform])
217 case "$host" in
218 *-solaris2.8)
219 platform_solaris_2_8=yes
220 CFLAGS="$CFLAGS -DSOLARIS_2_8"
221 CXXFLAGS="$CXXFLAGS -DSOLARIS_2_8"
222 ;;
223 *)
224 platform_solaris_2_8=no
225 ;;
226 esac
227 AC_MSG_RESULT([$platform_solaris_2_8])
228 AM_CONDITIONAL(PLATFORM_SOLARIS_2_8, test "$platform_solaris_2_8" = "yes")
230 dnl ******************************
231 dnl Xft checking
232 dnl ******************************
234 AC_ARG_WITH(xft,
235 AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),
236 [with_xft=$withval], [with_xft=auto])
238 if test "x$with_xft" != "xno" ; then
239 dnl Test fontconfig package
240 PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)
241 if test "x$xft_ok" != "xyes"; then
242 dnl test xft package
243 PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)
244 if test "x$xft_ok" != "xyes"; then
245 dnl Have to test xft presence
246 AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)
247 if test "x$xft_ok" != "xyes"; then
248 dnl No xft found
249 if test "x$with_xft" = "xyes"; then
250 dnl Xft was explicitly asked, so stop
251 AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])
252 fi
253 else
254 dnl Working Xft1
255 XFT_LIBS="-L/usr/X11R6/lib -lXft "
256 fi
257 fi
258 fi
259 else
260 dnl Asked to ignore xft
261 xft_ok=no
262 fi
264 AC_SUBST(XFT_CFLAGS)
265 AC_SUBST(XFT_LIBS)
267 AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")
268 if test "x$xft_ok" = "xyes"; then
269 AC_DEFINE(WITH_XFT, 1, [Use Xft font database])
270 fi
272 dnl ******************************
273 dnl pangoft2 for xft
274 dnl ******************************
276 if test "x$xft_ok" = "xyes"; then
277 PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)
278 if test "x$pango_ok" = "xyes"; then
279 XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"
280 fi
281 fi
284 dnl ******************************
285 dnl gnome vfs checking
286 dnl ******************************
288 AC_ARG_WITH(gnome-vfs,
289 AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),
290 [with_gnome_vfs=$withval], [with_gnome_vfs=auto])
292 if test "x$with_gnome_vfs" = "xno"; then
293 dnl Asked to ignore gnome-vfs
294 gnome_vfs=no
295 else
296 dnl Have to test gnome-vfs presence
297 PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)
298 if test "x$gnome_vfs" != "xyes"; then
299 dnl No gnome-vfs found
300 if test "x$with_gnome_vfs" = "xyes"; then
301 dnl Gnome-VFS was explicitly asked for, so stop
302 AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])
303 else
304 # gnome-vfs is no, tell us for the log file
305 AC_MSG_RESULT($gnome_vfs)
306 fi
307 fi
308 fi
310 AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")
311 if test "x$gnome_vfs" = "xyes"; then
312 AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])
313 fi
315 AC_SUBST(GNOME_VFS_CFLAGS)
316 AC_SUBST(GNOME_VFS_LIBS)
318 dnl ******************************
319 dnl libinkjar checking
320 dnl ******************************
322 AC_ARG_WITH(inkjar,
323 AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])
325 if test "x$with_ij" = "xyes"; then
326 AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])
327 AC_C_BIGENDIAN
328 AC_CHECK_HEADERS(zlib.h)
329 ij=yes
330 else
331 ij=no
332 fi
333 AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")
335 ink_spell_pkg=
336 if pkg-config --exists gtkspell-2.0; then
337 ink_spell_pkg=gtkspell-2.0
338 AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])
339 fi
341 dnl ******************************
342 dnl PERL checking
343 dnl ******************************
345 AC_MSG_CHECKING(for Perl development environment)
346 AC_ARG_WITH(perl,
347 AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),
348 [with_perl=$withval], [with_perl=skipped])
350 if test "x$with_perl" = "xyes"; then
351 checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`
352 if test "$?" -gt "0"; then
353 with_perl="no"
354 else
355 checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`
356 if test "$?" -gt "0"; then
357 with_perl="no"
358 else
359 with_perl="yes"
360 fi
361 fi
362 fi
363 AC_MSG_RESULT([$with_perl])
364 if test "x$with_perl" = "xyes"; then
365 # Test that we actually have the perl libraries installed
366 oldCFLAGS="$CFLAGS"
367 oldLIBS="$LIBS"
368 CFLAGS="$CFLAGS $checkPERL_CFLAGS"
369 LIBS="$LIBS $checkPERL_LIBS"
370 AC_CHECK_FUNC([perl_parse],[
371 PERL_CFLAGS="$checkPERL_CFLAGS"
372 PERL_LIBS="$checkPERL_LIBS"
373 AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])
374 ],[
375 with_perl="no"
376 ])
377 CFLAGS="$oldCFLAGS"
378 LIBS="$oldLIBS"
379 fi
380 AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")
381 AC_SUBST(PERL_CFLAGS)
382 AC_SUBST(PERL_LIBS)
384 dnl ******************************
385 dnl Python checking
386 dnl ******************************
388 AC_MSG_CHECKING(for Python development environment)
389 AC_ARG_WITH(python,
390 AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),
391 [with_python=$withval], [with_python=skipped])
393 if test "x$with_python" = "xyes"; then
394 checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`
395 if test "$?" -gt "0"; then
396 with_python="no"
397 else
398 checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`
399 if test "$?" -gt "0"; then
400 with_python="no"
401 else
402 with_python="yes"
403 fi
404 fi
405 fi
406 AC_MSG_RESULT([$with_python])
407 if test "x$with_python" = "xyes"; then
408 # Test that we actually have the python libraries installed
409 oldCFLAGS="$CFLAGS"
410 oldLIBS="$LIBS"
411 CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"
412 LIBS="$LIBS $checkPYTHON_LIBS"
413 AC_CHECK_FUNC([Py_Initialize],[
414 PYTHON_CFLAGS="$checkPYTHON_CFLAGS"
415 PYTHON_LIBS="$checkPYTHON_LIBS"
416 AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])
417 ],[
418 with_python="no"
419 ])
420 CFLAGS="$oldCFLAGS"
421 LIBS="$oldLIBS"
422 fi
423 AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")
424 AC_SUBST(PYTHON_CFLAGS)
425 AC_SUBST(PYTHON_LIBS)
427 dnl ******************************
428 dnl LittleCms checking
429 dnl ******************************
431 AC_ARG_ENABLE(lcms,
432 AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),
433 [enable_lcms=$enableval], [enable_lcms=yes])
435 if test "x$enable_lcms" = "xno"; then
436 dnl Asked to ignore LittleCms
437 lcms=no
438 else
439 dnl Have to test LittleCms presence
440 PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)
441 if test "x$lcms" != "xyes"; then
442 dnl No lcms found
443 if test "x$enable_lcms" = "xyes"; then
444 dnl LittleCms was explicitly asked for, so stop
445 AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])
446 else
447 # lcms is no, tell us for the log file
448 AC_MSG_RESULT($lcms)
449 fi
450 else
451 dnl Working lcms
452 LCMS_LIBS="-llcms "
453 fi
454 fi
456 if test "x$lcms" = "xyes"; then
457 LIBS="$LIBS $LCMS_LIBS"
458 AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])
459 fi
460 AM_CONDITIONAL(USE_LCMS, test "x$lcms" = "xyes")
461 AC_SUBST(LCMS_CFLAGS)
462 AC_SUBST(LCMS_LIBS)
464 dnl ******************************
465 dnl Libpoppler checking
466 dnl ******************************
468 POPPLER_CFLAGS=""
469 PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.9, poppler=yes, poppler=no)
471 if test "x$poppler" = "xyes"; then
472 dnl Working libpoppler
473 POPPLER_LIBS="-lpoppler "
474 dnl Have to test libpoppler-glib presence
475 PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.9, poppler_glib=yes, poppler_glib=no)
476 if test "x$poppler_glib" = "xyes"; then
477 dnl Working libpoppler-glib found
478 dnl Check whether the Cairo SVG backend is available
479 PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)
480 if test "x$cairo_svg" = "xyes"; then
481 POPPLER_LIBS="$POPPLER_LIBS -lpoppler-glib "
482 fi
483 fi
484 dnl Have to test libpoppler-cairo presence for PDF preview
485 PKG_CHECK_MODULES(POPPLER_CAIRO, poppler-cairo >= 0.5.9, poppler_cairo=yes, poppler_cairo=no)
486 if test "x$poppler_cairo" = "xyes"; then
487 dnl Working libpoppler-cairo found
488 dnl Check whether the Cairo FreeType backend is available
489 PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, cairo_ft=yes, cairo_ft=no)
490 fi
491 fi
493 if test "x$poppler" = "xyes"; then
494 LIBS="$LIBS $POPPLER_LIBS"
495 AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])
496 fi
497 if test "x$cairo_ft" = "xyes"; then
498 AC_DEFINE(HAVE_POPPLER_CAIRO, 1, [Use libpoppler-cairo for rendering PDF preview])
499 fi
500 if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then
501 AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])
502 fi
503 AC_SUBST(POPPLER_CFLAGS)
504 AC_SUBST(POPPLER_LIBS)
506 dnl ******************************
507 dnl Inkboard dependency checking
508 dnl ******************************
510 with_inkboard="no"
511 with_inkboard_ssl="no"
513 INKBOARD_CFLAGS=""
515 AC_ARG_ENABLE(inkboard,
516 AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),
517 with_inkboard=$enableval,with_inkboard=no)
519 if test "x$with_inkboard" = "xyes"; then
520 with_inkboard="yes"
521 AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])
523 dnl Test for OpenSSL
524 PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)
525 if test "x$with_inkboard_ssl" = "xyes"; then
526 dnl OpenSSL found; enable SSL support in Pedro
527 INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"
528 RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
529 RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
530 AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])
531 fi
532 else
533 with_inkboard="no"
534 fi
536 AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")
537 AC_SUBST(INKBOARD_LIBS)
538 AC_SUBST(INKBOARD_CFLAGS)
540 dnl ******************************
541 dnl Check for ImageMagick Magick++
542 dnl ******************************
544 AC_CHECK_LIB(Magick++, InitializeMagick, [AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)], magick_ok=no, -llcms -lfreetype -ljpeg -lfontconfig -lXext -lSM -lICE -lX11 -lz -lpthread -lm -lpthread)
546 if test "x$magick_ok" = "xyes"; then
547 AC_CHECK_PROG(MAGICKPP_CONFIG, Magick++-config, yes, no)
548 if test "x$MAGICKPP_CONFIG" = "xyes"; then
549 IMAGEMAGICK_LIBS=`Magick++-config --libs`
550 AC_SUBST(IMAGEMAGICK_LIBS)
551 AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])
552 fi
553 fi
555 AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")
557 dnl ******************************
558 dnl Unconditional dependencies
559 dnl ******************************
561 dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10
562 if test $cc_vers_major -gt 3; then
563 min_sigc_version=2.0.12
564 else
565 min_sigc_version=2.0.11
566 fi
567 PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4 glibmm-2.4 gtkmm-2.4 gtk+-2.0 >= 2.8.0 libxml-2.0 >= 2.6.11 libxslt >= 1.0.15 cairo sigc++-2.0 >= $min_sigc_version $ink_spell_pkg gthread-2.0 >= 2.0 libpng >= 1.2)
569 # Check for some boost header files
570 AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))
572 PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)
573 if test "x$cairo_pdf" = "xyes"; then
574 AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])
575 fi
577 PKG_CHECK_MODULES(GTK_UNIX_PRINT, gtk+-unix-print-2.0, gtk_unix_print=yes, gtk_unix_print=no)
578 if test "x$gtk_unix_print" = "xyes"; then
579 AC_DEFINE(HAVE_GTK_UNIX_PRINT, 1, [Whether the GTK Unix printing backend is available])
580 fi
582 dnl Shouldn't we test for libpng and libz?
583 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz"
585 AC_CHECK_HEADER(popt.h,
586 [INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],
587 AC_MSG_ERROR([libpopt is required]))
589 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
590 sp_save_LIBS=$LIBS
591 LIBS="$LIBS $INKSCAPE_LIBS"
592 AC_CHECK_FUNCS(bind_textdomain_codeset)
593 dnl Check for gtk_window_fullscreen in gtk (>= 2.2)
594 AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)
595 AC_CHECK_FUNCS(gtk_window_fullscreen)
596 LIBS=$sp_save_LIBS
599 dnl Check for binary relocation support
600 dnl Hongli Lai <h.lai@chello.nl>
602 AC_ARG_ENABLE(binreloc,
603 [ --enable-binreloc compile with binary relocation support],
604 enable_binreloc=$enableval,enable_binreloc=no)
606 AC_MSG_CHECKING(whether binary relocation support should be enabled)
607 if test "$enable_binreloc" = "yes"; then
608 AC_MSG_RESULT(yes)
609 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
610 if test -e /proc/self/maps; then
611 AC_MSG_RESULT(yes)
612 else
613 AC_MSG_RESULT(no)
614 AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
615 enable_binreloc="no"
616 fi
618 elif test "$enable_binreloc" = "auto"; then
619 AC_MSG_RESULT(yes when available)
620 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
621 if test -e /proc/self/maps; then
622 AC_MSG_RESULT(yes)
623 enable_binreloc=yes
625 AC_MSG_CHECKING(whether everything is installed to the same prefix)
626 if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
627 "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
628 "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
629 then
630 AC_MSG_RESULT(yes)
631 else
632 AC_MSG_RESULT(no)
633 AC_MSG_NOTICE(Binary relocation support will be disabled.)
634 enable_binreloc=no
635 fi
637 else
638 AC_MSG_RESULT(no)
639 enable_binreloc=no
640 fi
642 elif test "$enable_binreloc" = "no"; then
643 AC_MSG_RESULT(no)
644 else
645 AC_MSG_RESULT(no (unknown value "$enable_binreloc"))
646 enable_binreloc=no
647 fi
648 AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])
649 if test "$enable_binreloc" = "yes"; then
650 AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
651 fi
653 AC_ARG_ENABLE(osxapp,
654 [ --enable-osxapp compile with OSX .app data dir paths],
655 enable_osxapp=$enableval,enable_osxapp=no)
656 if test "$enable_osxapp" = "yes"; then
657 AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])
658 fi
660 dnl ******************************
661 dnl Reported by autoscan
662 dnl ******************************
663 AC_CHECK_FUNCS(pow)
664 # if we did not find pow(), see if it's in libm.
665 if test x"$ac_cv_func_pow" = x"no" ; then
666 AC_CHECK_LIB(m,pow)
667 fi
668 AC_CHECK_FUNCS(sqrt)
669 AC_CHECK_FUNCS(floor)
670 AC_CHECK_FUNCS(gettimeofday)
671 AC_CHECK_FUNCS(memmove)
672 AC_CHECK_FUNCS(memset)
673 AC_CHECK_FUNCS(mkdir)
674 AC_CHECK_FUNCS(strncasecmp)
675 AC_CHECK_FUNCS(strpbrk)
676 AC_CHECK_FUNCS(strrchr)
677 AC_CHECK_FUNCS(strspn)
678 AC_CHECK_FUNCS(strstr)
679 AC_CHECK_FUNCS(strtoul)
680 AC_CHECK_FUNCS(fpsetmask)
681 AC_CHECK_FUNCS(ecvt)
682 AC_CHECK_HEADERS(ieeefp.h)
683 AC_CHECK_HEADERS(fcntl.h)
684 AC_CHECK_HEADERS(libintl.h)
685 AC_CHECK_HEADERS(stddef.h)
686 AC_CHECK_HEADERS(sys/time.h)
687 AC_FUNC_STAT
688 AC_FUNC_STRFTIME
689 AC_FUNC_STRTOD
690 AC_HEADER_STAT
691 AC_HEADER_TIME
692 AC_STRUCT_TM
693 AC_TYPE_MODE_T
694 AC_TYPE_SIGNAL
696 dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't
697 dnl set correctly because the gettext function isn't noticed.
698 if test "$ac_cv_header_libintl_h" = "yes" &&
699 test "$ac_cv_func_bind_textdomain_codeset" = "yes" &&
700 test "$gt_cv_func_have_gettext" != "yes"; then
701 AC_DEFINE(ENABLE_NLS)
702 fi
704 dnl ******************************
705 dnl Compilation warnings
706 dnl ******************************
707 if test "$GXX" = "yes"; then
708 # Enable some warnings from g++.
710 # Rationale: a number of bugs in inkscape have been fixed by enabling g++
711 # warnings and addressing the produced warnings. Usually the committing
712 # developer is the best person to address the warnings.
714 ink_svd_CXXFLAGS="$CXXFLAGS"
715 CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"
716 # -Wno-unused-parameter isn't accepted by gcc 2.95.
717 AC_COMPILE_IFELSE([int dummy;
718 ], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)
719 # Note: At least one bug has been caught from unused parameter warnings,
720 # so it might be worth trying not to disable it.
721 # One way of selectively disabling the warnings (i.e. only where the
722 # programmer deliberately isn't using the parameter, e.g. for a callback)
723 # is to remove the parameter name (leaving just its type), as is done
724 # in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the
725 # programmer deliberately has an unused parameter (e.g. because it's used
726 # as a callback or similar function pointer use).
728 CXXFLAGS="-Wall -Wformat-security -W -Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch -D_FORTIFY_SOURCE=2 $CXXFLAGS"
730 dnl Test for arch-specific situations.
731 case "$host_cpu" in
732 mips|mipsel)
733 dnl Symbol tables can get too large: this uses alternate tables
734 dnl See http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=283476
735 CXXFLAGS="$CXXFLAGS -Wa,-xgot"
736 CFLAGS="$CFLAGS -Wa,-xgot"
737 ;;
738 esac
739 fi
741 AC_DEFINE(WITH_MODULES, 1, [Use experimental module support])
743 dnl ******************************
744 dnl libinkscape
745 dnl ******************************
746 dnl
747 dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])
748 dnl
749 dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")
750 dnl
752 AC_SUBST(INKSCAPE_CFLAGS)
753 AC_SUBST(INKSCAPE_LIBS)
755 #
756 # Checks to see if we should compile in MMX support (there will be
757 # a runtime test when the code is actually run to see if it should
758 # be used - this just checks if we can compile it.)
759 #
760 # This code is partially taken from Mesa
761 #
762 dnl Let people disable the MMX optimization
763 AC_ARG_ENABLE(mmx, [ --disable-mmx Don't use MMX optimization [default=auto]], enable_mmx="$enableval", enable_mmx=auto)
765 AC_MSG_CHECKING(for x86 platform)
766 case $host_cpu in
767 i386|i486|i586|i686|i786|k6|k7)
768 use_x86_asm=yes
769 ;;
770 *)
771 use_x86_asm=no
772 esac
773 AC_MSG_RESULT($use_x86_asm)
775 dnl Are we going to use MMX extensions
776 use_mmx_asm=no
778 AC_MSG_CHECKING(compiler support for MMX)
780 if test x$enable_mmx = xauto ; then
781 if test $use_x86_asm = yes; then
782 save_ac_ext=$ac_ext
783 ac_ext=S
785 cp $srcdir/src/libnr/nr_mmx_R8G8B8A8_P_R8G8B8A8_P_A8_RGBAP.S conftest.S
786 if AC_TRY_EVAL(ac_compile); then
787 use_mmx_asm=yes
788 fi
789 dnl rm -f conftest.[oS]
791 ac_ext=$save_ac_ext
792 fi
794 dnl Enforce usage of MMX extensions
795 elif test x$enable_mmx = xyes ; then
796 use_mmx_asm=yes
797 else
798 use_mmx_asm=no
799 fi
801 if test $use_mmx_asm = yes; then
802 AC_DEFINE(WITH_MMX, 1, [Use MMX optimizations, if CPU supports it])
803 AC_MSG_RESULT(yes)
804 else
805 AC_MSG_RESULT(no)
806 fi
808 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
810 dnl Figure out where the datadir actually is
811 dnl http://autoconf-archive.cryp.to/ac_define_dir.html
812 prefix_NONE=
813 exec_prefix_NONE=
814 test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
815 test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
816 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
817 dnl refers to ${prefix}. Thus we have to use `eval' twice.
818 eval runtime_datadir="${datadir}"
819 eval runtime_datadir="${runtime_datadir}"
820 test "$prefix_NONE" && prefix=NONE
821 test "$exec_prefix_NONE" && exec_prefix=NONE
823 inkscape_sharedir="${runtime_datadir}/${PACKAGE_NAME}"
825 dnl Define our data paths for config.h
826 AC_SUBST(INKSCAPE_DATADIR)
827 AC_DEFINE_UNQUOTED([INKSCAPE_DATADIR], "${runtime_datadir}",
828 [Base data directory -- only path-prefix.h should use it!])
829 AC_SUBST(PACKAGE_LOCALE_DIR)
830 AC_DEFINE_UNQUOTED([PACKAGE_LOCALE_DIR], "${runtime_datadir}/locale",
831 [Localization directory])
832 AC_SUBST(INKSCAPE_LIBDIR)
833 AC_DEFINE_UNQUOTED([INKSCAPE_LIBDIR], "${prefix}/lib",
834 [Base library directory -- only path-prefix.h should use it!])
836 dnl Have to add module makefiles (lauris)
838 AC_CONFIG_FILES([
839 Makefile
840 src/Makefile
841 src/check-header-compile
842 src/algorithms/makefile
843 src/application/makefile
844 src/debug/makefile
845 src/dialogs/makefile
846 src/display/makefile
847 src/dom/makefile
848 src/extension/implementation/makefile
849 src/extension/internal/makefile
850 src/extension/makefile
851 src/extension/script/makefile
852 src/helper/makefile
853 src/inkjar/makefile
854 src/io/makefile
855 src/libcroco/makefile
856 src/libgdl/makefile
857 src/libnr/makefile
858 src/libnrtype/makefile
859 src/libavoid/makefile
860 src/livarot/makefile
861 src/live_effects/makefile
862 src/live_effects/parameter/makefile
863 src/pedro/makefile
864 src/jabber_whiteboard/makefile
865 src/removeoverlap/makefile
866 src/svg/makefile
867 src/trace/makefile
868 src/traits/makefile
869 src/ui/cache/makefile
870 src/ui/dialog/makefile
871 src/ui/makefile
872 src/ui/view/makefile
873 src/ui/widget/makefile
874 src/utest/makefile
875 src/util/makefile
876 src/widgets/makefile
877 src/xml/makefile
878 src/2geom/makefile
879 doc/Makefile
880 po/Makefile.in
881 share/Makefile
882 share/clipart/Makefile
883 share/examples/Makefile
884 share/extensions/Makefile
885 share/extensions/Barcode/Makefile
886 share/extensions/xaml2svg/Makefile
887 share/fonts/Makefile
888 share/gradients/Makefile
889 share/icons/Makefile
890 share/keys/Makefile
891 share/markers/Makefile
892 share/palettes/Makefile
893 share/patterns/Makefile
894 share/screens/Makefile
895 share/templates/Makefile
896 share/tutorials/Makefile
897 share/ui/Makefile
898 packaging/autopackage/default.apspec
899 inkscape.spec
900 Info.plist
901 inkview.1
902 ])
904 AH_BOTTOM([
907 ])
909 AC_OUTPUT
911 echo "
912 Configuration:
914 Source code location: ${srcdir}
915 Destination path prefix: ${prefix}
916 Compiler: ${CXX}
917 CPPFLAGS: ${CPPFLAGS}
918 CXXFLAGS: ${CXXFLAGS}
919 CFLAGS: ${CFLAGS}
920 LDFLAGS: ${LDFLAGS}
922 Use Xft font database: ${xft_ok}
923 Use gnome-vfs: ${gnome_vfs}
924 Use openoffice files: ${ij}
925 Use MMX optimizations: ${use_mmx_asm}
926 Use relocation support: ${enable_binreloc}
927 Internal Python: ${with_python}
928 Internal Perl: ${with_perl}
929 Enable LittleCms: ${enable_lcms}
930 Enable Inkboard: ${with_inkboard}
931 Enable SSL in Inkboard: ${with_inkboard_ssl}
932 ImageMagick Magick++: ${magick_ok}
933 "