1 dnl Process this file with autoconf to produce a configure script.
3 AC_PREREQ(2.53)
5 # Always use 0.xx+devel instead of 0.xxdevel for the version, e.g. 0.46+devel.
6 # Rationale: (i) placate simple version comparison software such as
7 # `dpkg --compare-versions'. (ii) We don't always know what the next
8 # version is going to be called until about the time we release it
9 # (whereas we always know what the previous version was called).
10 AC_INIT(inkscape, 0.48+devel)
12 AC_CANONICAL_HOST
13 AC_CONFIG_SRCDIR([src/main.cpp])
14 AM_INIT_AUTOMAKE([dist-zip dist-bzip2 tar-pax])
16 AC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [
17 prefix=/opt/inkscape
18 PATH="/opt/lsb/bin:$PATH"
19 CC=lsbcc
20 CXX=lsbc++
21 export CC CXX
22 ])
24 AM_CONFIG_HEADER(config.h)
26 AC_LANG(C++)
27 AC_ISC_POSIX
28 AC_PROG_CXX
29 AM_PROG_CC_STDC
30 AM_PROG_AS
31 AC_PROG_RANLIB
32 AC_PROG_INTLTOOL(0.22)
33 AC_PROG_LIBTOOL
34 AC_HEADER_STDC
35 INK_BZR_SNAPSHOT_BUILD
37 dnl If automake 1.11 shave the output to look nice
38 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
40 dnl These next few lines are needed only while libcroco is in our source tree.
41 AC_PROG_CC
42 AM_PROG_CC_C_O
43 if test "$GCC" = "yes"; then
44 # Enable some warnings from gcc.
45 AC_LANG_PUSH(C)
47 ####
48 # Generic cpp flags...
50 # What is just plain "-W" ?
51 # Fortify source requires -O2 or higher, which is handled with newer autoconf
52 CPPFLAGS="-W -D_FORTIFY_SOURCE=2 $CPPFLAGS"
53 # Enable format and format security warnings
54 CPPFLAGS="-Wformat -Wformat-security $CPPFLAGS"
55 # Enable all default warnings
56 CPPFLAGS="-Wall $CPPFLAGS"
58 # Test for -Werror=... (introduced some time post-4.0)
59 # If we hit a format error -- it should be fatal.
60 AC_MSG_CHECKING([compiler support for -Werror=format-security])
61 ink_svd_CPPFLAGS="$CPPFLAGS"
62 CPPFLAGS="-Werror=format-security $CPPFLAGS"
63 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
64 AC_MSG_RESULT([$ink_opt_ok])
65 if test "x$ink_opt_ok" != "xyes"; then
66 CPPFLAGS="$ink_svd_CPPFLAGS"
67 fi
69 ####
70 # C-specific flags...
72 # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted
73 # by gcc 2.95.
74 AC_MSG_CHECKING([compiler support for -Wno-pointer-sign])
75 ink_svd_CFLAGS="$CFLAGS"
76 CFLAGS="-Wno-pointer-sign $CFLAGS"
77 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
78 AC_MSG_RESULT([$ink_opt_ok])
79 if test "x$ink_opt_ok" != "xyes"; then
80 CFLAGS="$ink_svd_CFLAGS"
81 fi
83 ####
84 # Linker flags...
86 # Have linker produce read-only relocations, if it knows how
87 AC_MSG_CHECKING([linker tolerates -z relro])
88 ink_svd_LDFLAGS="$LDFLAGS"
89 LDFLAGS="-Wl,-z,relro $LDFLAGS"
90 AC_LINK_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
91 AC_MSG_RESULT([$ink_opt_ok])
92 if test "x$ink_opt_ok" != "xyes"; then
93 LDFLAGS="$ink_svd_LDFLAGS"
94 fi
96 AC_LANG_POP
98 # C++-specific flags are defined further below. Look for CXXFLAGS...
99 fi
101 dnl Honor aclocal flags
102 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
104 dnl Verify our GCC version
105 if test "x$GXX" = "xyes"; then
106 AC_MSG_CHECKING([GNU compiler version])
108 # Don't pass CXXFLAGS to the following CXX command as some
109 # of them can't be specified along with '-v'.
110 cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\
111 sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]
113 AC_MSG_RESULT([$cc_version])
115 # Some version numbers
116 cc_vers_major=`echo $cc_version | cut -f1 -d.`
117 cc_vers_minor=`echo $cc_version | cut -f2 -d.`
118 cc_vers_patch=`echo $cc_version | cut -f3 -d.`
119 test -n "$cc_vers_major" || cc_vers_major=0
120 test -n "$cc_vers_minor" || cc_vers_minor=0
121 test -n "$cc_vers_patch" || cc_vers_patch=0
122 cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`
124 if test $cc_vers_major -lt 3; then
125 AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])
126 fi
127 fi
129 # Detect a working version of unordered containers.
130 AC_MSG_CHECKING([TR1 unordered_set usability])
131 AC_COMPILE_IFELSE([
132 #include <tr1/unordered_set>
133 int main() {
134 std::tr1::unordered_set<int> i, j;
135 i = j;
136 return 0;
137 }
138 ], [unordered_set_works=yes], [unordered_set_works=no])
139 if test "x$unordered_set_works" = "xyes"; then
140 AC_MSG_RESULT([ok])
141 AC_DEFINE(HAVE_TR1_UNORDERED_SET, 1, [Has working standard TR1 unordered_set])
142 else
143 AC_MSG_RESULT([not working])
144 fi
145 AC_CHECK_HEADER([boost/unordered_set.hpp], [AC_DEFINE(HAVE_BOOST_UNORDERED_SET, 1, [Boost unordered_set (Boost >= 1.36)])], [])
146 AC_CHECK_HEADER([ext/hash_set], [AC_DEFINE(HAVE_EXT_HASH_SET, 1, [Legacy GNU ext/hash_set])], [])
148 # Test whether GCC emits a spurious warning when using boost::optional
149 # If yes, turn off strict aliasing warnings to reduce noise
150 # and allow the legitimate warnings to stand out
151 AC_MSG_CHECKING([for overzealous strict aliasing warnings])
152 ignore_strict_aliasing=no
153 CXXFLAGS_SAVE=$CXXFLAGS
154 CXXFLAGS="$CXXFLAGS -Werror=strict-aliasing"
155 AC_COMPILE_IFELSE([
156 #include <boost/optional.hpp>
157 boost::optional<int> x;
158 int func() {
159 return *x;
160 }
161 ], [ignore_strict_aliasing=no], [ignore_strict_aliasing=yes])
162 AC_MSG_RESULT($ignore_strict_aliasing)
163 CXXFLAGS=$CXXFLAGS_SAVE
164 if test "x$ignore_strict_aliasing" = "xyes"; then
165 CXXFLAGS="$CXXFLAGS -Wno-strict-aliasing"
166 fi
168 dnl ******************************
169 dnl Gettext stuff
170 dnl ******************************
171 GETTEXT_PACKAGE="AC_PACKAGE_NAME"
172 AC_SUBST(GETTEXT_PACKAGE)
173 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])
174 dnl Add the languages which your application supports here.
175 ALL_LINGUAS="am ar az be bg bn br ca ca@valencia cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fa fi fr ga gl he hr hu hy id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@latin sr sv te_IN th tr uk vi zh_CN zh_TW"
176 AM_GLIB_GNU_GETTEXT
178 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
179 if test "x$PKG_CONFIG" = "xno"; then
180 AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)
181 fi
183 dnl Find msgfmt. Without this, po/Makefile fails to set MSGFMT on some platforms.
184 AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)
185 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
187 dnl ******************************
188 dnl Check for OpenMP
189 dnl Replace this with AC_OPENMP once Autoconf 2.62 is widespread
190 dnl ******************************
191 AX_OPENMP([openmp_ok=yes],[openmp_ok=no])
192 if test "x$openmp_ok" = "xyes"; then
193 dnl We have it, now set up the flags
194 CXXFLAGS="$CXXFLAGS $OPENMP_CXXFLAGS"
195 AC_CHECK_HEADER(omp.h)
196 AC_DEFINE(HAVE_OPENMP, 1, [Use OpenMP])
197 fi
199 dnl ******************************
200 dnl Check for libpng
201 dnl ******************************
202 AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=yes)], png_ok=no, -lz -lm)
203 if test "x$png_ok" != "xyes"; then
204 AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])
205 fi
207 dnl Handle possible dlopen requirement for libgc
208 dnl Isn't this internal to something in autoconf? Couldn't find it...
209 AC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],
210 [lt_cv_dlopen="dlopen"],
211 [AC_CHECK_LIB([dl], [dlopen],
212 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
213 [AC_CHECK_LIB([svld], [dlopen],
214 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
215 [AC_CHECK_LIB([dld], [dld_link],
216 [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
217 ])
218 ])
219 ])
220 ])
222 AC_CHECK_HEADERS([gc.h gc/gc.h],
223 [
224 # To test for the different required libs, I have to
225 # overcome autoconf's caching system, so I change the
226 # desired function name. They're all in libgc.
227 # The "break" will exit from the top level
228 # AC_CHECK_HEADERS.
229 gc_libs=""
230 AC_CHECK_LIB(gc, GC_init,
231 [gc_ok=yes;
232 LIBS="-lgc $gc_libs $LIBS";
233 break], [gc_ok=no], [$gc_libs])
234 gc_libs="-lpthread"
235 AC_CHECK_LIB(gc, GC_malloc,
236 [gc_ok=yes;
237 LIBS="-lgc $gc_libs $LIBS";
238 break], [gc_ok=no], [$gc_libs])
239 gc_libs="$lt_cv_dlopen_libs"
240 AC_CHECK_LIB(gc, GC_realloc,
241 [gc_ok=yes;
242 LIBS="-lgc $gc_libs $LIBS";
243 break], [gc_ok=no], [$gc_libs])
244 gc_libs="-lpthread $lt_cv_dlopen_libs"
245 AC_CHECK_LIB(gc, GC_free,
246 [gc_ok=yes;
247 LIBS="-lgc $gc_libs $LIBS";
248 break], [gc_ok=no], [$gc_libs])
249 break],
250 [gc_ok=no])
251 if test "x$gc_ok" = "xyes" && test "x$cross_compiling" = "xno" ; then
252 AC_MSG_CHECKING([libgc version 6.4+])
253 AC_RUN_IFELSE(
254 [AC_LANG_SOURCE([[
255 #ifdef HAVE_GC_GC_H
256 # include <gc/gc.h>
257 #else
258 # include <gc.h>
259 #endif
260 #include <stdio.h>
261 extern unsigned GC_version;
262 int main(void){
263 unsigned min = ((6 << 16) | (4 << 8) | 0);
264 printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);
265 if (GC_version>=min) return 0;
266 return 1;
267 }]])],
268 [gc_ok=yes],
269 [gc_ok=no]
270 )
271 AC_MSG_RESULT([$gc_ok])
272 fi
273 if test "x$gc_ok" != "xyes"; then
274 AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])
275 fi
277 dnl This check is to get a FIONREAD definition on Solaris 8
278 AC_CHECK_HEADERS([sys/filio.h])
281 AC_CHECK_HEADERS([malloc.h])
282 AC_CHECK_FUNCS([mallinfo], [
283 AC_CHECK_MEMBERS([struct mallinfo.usmblks,
284 struct mallinfo.fsmblks,
285 struct mallinfo.uordblks,
286 struct mallinfo.fordblks,
287 struct mallinfo.hblkhd],,,
288 [#include <malloc.h>])
289 ])
291 AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
292 if test "x$FREETYPE_CONFIG" = "xno"; then
293 AC_MSG_ERROR([Cannot find freetype-config])
294 fi
295 FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
296 FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
297 AC_SUBST(FREETYPE_CFLAGS)
298 AC_SUBST(FREETYPE_LIBS)
300 dnl ******************************
301 dnl Win32
302 dnl ******************************
303 AC_MSG_CHECKING([for Win32 platform])
304 case "$host" in
305 *-*-mingw*)
306 platform_win32=yes
307 WIN32_CFLAGS="-mms-bitfields -DLIBXML_STATIC"
308 ;;
309 *)
310 platform_win32=no
311 ;;
312 esac
313 AC_MSG_RESULT([$platform_win32])
314 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
315 AC_SUBST(WIN32_CFLAGS)
317 AC_MSG_CHECKING([for Solaris platform])
318 case "$host" in
319 *-solaris2.*)
320 platform_solaris=yes
321 solaris_version=`echo $host|sed -e 's/^.*-solaris2\.//' -e s'/\..*$//'`
322 CFLAGS="$CFLAGS -DSOLARIS=$solaris_version"
323 CXXFLAGS="$CXXFLAGS -DSOLARIS=$solaris_version"
324 ;;
325 *)
326 platform_solaris=no
327 ;;
328 esac
329 AC_MSG_RESULT([$platform_solaris])
330 AM_CONDITIONAL(PLATFORM_SOLARIS, test "$platform_solaris" = "yes")
332 dnl ******************************
333 dnl Xft checking
334 dnl ******************************
336 AC_ARG_WITH(xft,
337 AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),
338 [with_xft=$withval], [with_xft=auto])
340 if test "x$with_xft" != "xno" ; then
341 dnl Test fontconfig package
342 PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)
343 if test "x$xft_ok" != "xyes"; then
344 dnl test xft package
345 PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)
346 if test "x$xft_ok" != "xyes"; then
347 dnl Have to test xft presence
348 AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)
349 if test "x$xft_ok" != "xyes"; then
350 dnl No xft found
351 if test "x$with_xft" = "xyes"; then
352 dnl Xft was explicitly asked, so stop
353 AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])
354 fi
355 else
356 dnl Working Xft1
357 XFT_LIBS="-L/usr/X11R6/lib -lXft "
358 fi
359 fi
360 fi
361 else
362 dnl Asked to ignore xft
363 xft_ok=no
364 fi
366 AC_SUBST(XFT_CFLAGS)
367 AC_SUBST(XFT_LIBS)
369 AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")
370 if test "x$xft_ok" = "xyes"; then
371 AC_DEFINE(WITH_XFT, 1, [Use Xft font database])
372 fi
374 dnl ******************************
375 dnl pangoft2 for xft
376 dnl ******************************
378 if test "x$xft_ok" = "xyes"; then
379 PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)
380 if test "x$pango_ok" = "xyes"; then
381 XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"
382 fi
383 fi
386 dnl ******************************
387 dnl gnome vfs checking
388 dnl ******************************
390 AC_ARG_WITH(gnome-vfs,
391 AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),
392 [with_gnome_vfs=$withval], [with_gnome_vfs=auto])
394 if test "x$with_gnome_vfs" = "xno"; then
395 dnl Asked to ignore gnome-vfs
396 gnome_vfs=no
397 else
398 dnl Have to test gnome-vfs presence
399 PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)
400 if test "x$gnome_vfs" != "xyes"; then
401 dnl No gnome-vfs found
402 if test "x$with_gnome_vfs" = "xyes"; then
403 dnl Gnome-VFS was explicitly asked for, so stop
404 AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])
405 else
406 # gnome-vfs is no, tell us for the log file
407 AC_MSG_RESULT($gnome_vfs)
408 fi
409 fi
410 fi
412 AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")
413 if test "x$gnome_vfs" = "xyes"; then
414 AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])
415 fi
417 AC_SUBST(GNOME_VFS_CFLAGS)
418 AC_SUBST(GNOME_VFS_LIBS)
420 dnl ******************************
421 dnl libinkjar checking
422 dnl ******************************
424 AC_ARG_WITH(inkjar,
425 AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])
427 if test "x$with_ij" = "xyes"; then
428 AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])
429 AC_C_BIGENDIAN
430 AC_CHECK_HEADERS(zlib.h)
431 ij=yes
432 else
433 ij=no
434 fi
435 AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")
437 ink_spell_pkg=
438 if pkg-config --exists gtkspell-2.0; then
439 ink_spell_pkg=gtkspell-2.0
440 AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])
441 fi
443 dnl ******************************
444 dnl PERL checking
445 dnl ******************************
447 AC_MSG_CHECKING(for Perl development environment)
448 AC_ARG_WITH(perl,
449 AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),
450 [with_perl=$withval], [with_perl=skipped])
452 if test "x$with_perl" = "xyes"; then
453 checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`
454 if test "$?" -gt "0"; then
455 with_perl="no"
456 else
457 checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`
458 if test "$?" -gt "0"; then
459 with_perl="no"
460 else
461 with_perl="yes"
462 fi
463 fi
464 fi
465 AC_MSG_RESULT([$with_perl])
466 if test "x$with_perl" = "xyes"; then
467 # Test that we actually have the perl libraries installed
468 oldCFLAGS="$CFLAGS"
469 oldLIBS="$LIBS"
470 CFLAGS="$CFLAGS $checkPERL_CFLAGS"
471 LIBS="$LIBS $checkPERL_LIBS"
472 AC_CHECK_FUNC([perl_parse],[
473 PERL_CFLAGS="$checkPERL_CFLAGS"
474 PERL_LIBS="$checkPERL_LIBS"
475 AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])
476 ],[
477 with_perl="no"
478 ])
479 CFLAGS="$oldCFLAGS"
480 LIBS="$oldLIBS"
481 fi
482 AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")
483 AC_SUBST(PERL_CFLAGS)
484 AC_SUBST(PERL_LIBS)
486 dnl ******************************
487 dnl Python checking
488 dnl ******************************
490 AC_MSG_CHECKING(for Python development environment)
491 AC_ARG_WITH(python,
492 AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),
493 [with_python=$withval], [with_python=skipped])
495 if test "x$with_python" = "xyes"; then
496 checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`
497 if test "$?" -gt "0"; then
498 with_python="no"
499 else
500 checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`
501 if test "$?" -gt "0"; then
502 with_python="no"
503 else
504 with_python="yes"
505 fi
506 fi
507 fi
508 AC_MSG_RESULT([$with_python])
509 if test "x$with_python" = "xyes"; then
510 # Test that we actually have the python libraries installed
511 oldCFLAGS="$CFLAGS"
512 oldLIBS="$LIBS"
513 CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"
514 LIBS="$LIBS $checkPYTHON_LIBS"
515 AC_CHECK_FUNC([Py_Initialize],[
516 PYTHON_CFLAGS="$checkPYTHON_CFLAGS"
517 PYTHON_LIBS="$checkPYTHON_LIBS"
518 AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])
519 ],[
520 with_python="no"
521 ])
522 CFLAGS="$oldCFLAGS"
523 LIBS="$oldLIBS"
524 fi
525 AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")
526 AC_SUBST(PYTHON_CFLAGS)
527 AC_SUBST(PYTHON_LIBS)
529 dnl ******************************
530 dnl LittleCms checking
531 dnl ******************************
533 AC_ARG_ENABLE(lcms,
534 AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),
535 [enable_lcms=$enableval], [enable_lcms=yes])
537 if test "x$enable_lcms" = "xno"; then
538 dnl Asked to ignore LittleCms
539 lcms=no
540 else
541 dnl Have to test LittleCms presence
542 PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)
543 if test "x$lcms" != "xyes"; then
544 dnl No lcms found
545 if test "x$enable_lcms" = "xyes"; then
546 dnl LittleCms was explicitly asked for, so stop
547 AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])
548 else
549 # lcms is no, tell us for the log file
550 AC_MSG_RESULT($lcms)
551 fi
552 else
553 dnl Working lcms
554 LIBS="$LIBS $LCMS_LIBS"
555 AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])
556 fi
557 fi
559 AC_SUBST(LCMS_CFLAGS)
560 AC_SUBST(LCMS_LIBS)
562 dnl ******************************
563 dnl Libpoppler checking
564 dnl ******************************
566 AC_ARG_ENABLE(poppler-cairo,
567 AC_HELP_STRING([--enable-poppler-cairo], [Enable libpoppler-cairo for rendering PDF preview]),
568 [enable_poppler_cairo=$enableval], [enable_poppler_cairo=yes])
570 POPPLER_CFLAGS=""
571 PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.9, poppler=yes, poppler=no)
573 if test "x$poppler" = "xyes"; then
574 dnl Working libpoppler
575 dnl Have to test libpoppler-glib presence
576 PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.9, poppler_glib=yes, poppler_glib=no)
577 if test "x$poppler_glib" = "xyes"; then
578 dnl Working libpoppler-glib found
579 dnl Check whether the Cairo SVG backend is available
580 PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)
581 if test "x$cairo_svg" = "xyes"; then
582 POPPLER_LIBS="$POPPLER_LIBS $POPPLER_GLIB_LIBS "
583 fi
584 fi
585 if test "x$enable_poppler_cairo" = "xyes"; then
586 dnl Have to test libpoppler-cairo presence for PDF preview
587 dnl AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)
588 PKG_CHECK_MODULES(POPPLER_CAIRO, poppler-cairo >= 0.5.9, poppler_cairo=yes, poppler_cairo=no)
589 if test "x$poppler_glib" = "xyes" -a "x$poppler_cairo" = "xyes" -a \
590 "x$cairo_svg" = "xno"
591 then
592 POPPLER_LIBS="$POPPLER_LIBS $POPPLER_CAIRO_LIBS "
593 fi
594 fi
595 fi
597 if test "x$poppler" = "xyes"; then
598 LIBS="$LIBS $POPPLER_LIBS"
599 AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])
600 fi
601 if test "x$poppler_cairo" = "xyes" -a "x$poppler_glib" = "xyes"; then
602 AC_DEFINE(HAVE_POPPLER_CAIRO, 1, [Use libpoppler-cairo for rendering PDF preview])
603 fi
604 if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then
605 AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])
606 fi
607 AC_SUBST(POPPLER_CFLAGS)
608 AC_SUBST(POPPLER_LIBS)
610 PKG_CHECK_MODULES(POPPLER_GFXFONT, poppler >= 0.8.3, popplernew=yes, popplernew=no)
611 if test "x$popplernew" = "xyes"; then
612 AC_DEFINE(POPPLER_NEW_GFXFONT, 1, [Use GfxFont from Poppler >= 0.8.3])
613 fi
615 ink_svd_CPPFLAGS=$CPPFLAGS
616 ink_svd_LIBS=$LIBS
617 CPPFLAGS="$CPPFLAGS $POPPLER_CFLAGS"
618 LIBS="$LIBS $POPPLER_LIBS"
620 AC_MSG_CHECKING(for new color space API in Poppler)
621 popplercolor="no"
622 AC_COMPILE_IFELSE([
623 #include <GfxState.h>
625 int main() {
626 typedef GfxColorSpace *(*parse_p)(Object *, Gfx *);
627 parse_p p;
628 p = &GfxColorSpace::parse;
629 return 0;
630 }
631 ], [popplercolor=yes])
632 if test "x$popplercolor" = "xyes"; then
633 AC_DEFINE(POPPLER_NEW_COLOR_SPACE_API, 1, [Use color space API from Poppler >= 0.12.2])
634 AC_MSG_RESULT(yes)
635 else
636 AC_MSG_RESULT(no)
637 fi
639 # Poppler's b604a008 commit changes this
640 AC_MSG_CHECKING([whether Poppler's GfxPatch no longer uses GfxColor])
641 popplergfxcolor="no"
642 AC_COMPILE_IFELSE([
643 #include <GfxState.h>
645 int main() {
646 GfxPatch::ColorValue color = {c: {0}};
647 GfxPatch patch;
648 patch.color[[0]][[0]] = color;
649 return 0;
650 }
651 ], [popplergfxcolor=yes])
652 if test "x$popplergfxcolor" = "xyes"; then
653 AC_DEFINE(POPPLER_NEW_GFXPATCH, 1, [GfxPatch no longer uses GfxColor in >= 0.15.1])
654 AC_MSG_RESULT(yes)
655 else
656 AC_MSG_RESULT(no)
657 fi
659 CPPFLAGS=$ink_svd_CPPFLAGS
660 LIBS=$ink_svd_LIBS
662 dnl ******************************
663 dnl Inkboard dependency checking
664 dnl ******************************
666 dnl with_inkboard="no"
667 dnl with_inkboard_ssl="no"
669 dnl INKBOARD_CFLAGS=""
671 dnl AC_ARG_ENABLE(inkboard,
672 dnl AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),
673 dnl with_inkboard=$enableval,with_inkboard=no)
675 dnl if test "x$with_inkboard" = "xyes"; then
676 dnl with_inkboard="yes"
677 dnl AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])
679 dnl Test for OpenSSL
680 dnl PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)
681 dnl if test "x$with_inkboard_ssl" = "xyes"; then
682 dnl OpenSSL found; enable SSL support in Pedro
683 dnl INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"
684 dnl RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
685 dnl RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
686 dnl AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])
687 dnl fi
688 dnl else
689 dnl with_inkboard="no"
690 dnl fi
692 dnl AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")
694 INKBOARD_CFLAGS=""
695 INKBOARD_LIBS=""
696 AC_SUBST(INKBOARD_LIBS)
697 AC_SUBST(INKBOARD_CFLAGS)
699 dnl ******************************
700 dnl Check for libwpg for extension
701 dnl ******************************
703 PKG_CHECK_MODULES(LIBWPG, libwpg-0.1 libwpg-stream-0.1, with_libwpg=yes, with_libwpg=no)
704 if test "x$with_libwpg" = "xyes"; then
705 AC_DEFINE(WITH_LIBWPG,1,[Build in libwpg])
706 fi
707 AM_CONDITIONAL(WITH_LIBWPG, test "x$with_libwpg" = "xyes")
709 AC_SUBST(LIBWPG_LIBS)
710 AC_SUBST(LIBWPG_CFLAGS)
712 dnl ******************************
713 dnl Support doing a local install
714 dnl (mostly for distcheck)
715 dnl ******************************
717 with_localinstall="no"
718 AC_ARG_ENABLE(localinstall, AS_HELP_STRING([--enable-localinstall], [install system files in the local path (for distcheck)]), with_localinstall=$enableval, with_localinstall=no)
720 dnl ******************************
721 dnl Check for dbus functionality
722 dnl ******************************
724 AC_ARG_ENABLE(dbusapi,
725 [ --enable-dbusapi compile with support for DBus interface],
726 enable_dbusapi=$enableval,enable_dbusapi=no)
728 with_dbus="no"
729 if test "x$enable_dbusapi" = "xyes"; then
730 PKG_CHECK_MODULES(DBUS, dbus-glib-1, with_dbus=yes, with_dbus=no)
731 if test "x$with_dbus" = "xyes"; then
732 if test "x$with_localinstall" = "xyes"; then
733 DBUSSERVICEDIR="${datadir}/dbus-1/services/"
734 else
735 DBUSSERVICEDIR=`$PKG_CONFIG --variable=session_bus_services_dir dbus-1`
736 fi
737 AC_SUBST(DBUSSERVICEDIR)
738 AC_DEFINE(WITH_DBUS,1,[Build in dbus])
739 fi
740 fi
741 AC_SUBST(DBUS_LIBS)
742 AC_SUBST(DBUS_CFLAGS)
743 AM_CONDITIONAL(WITH_DBUS, test "x$with_dbus" = "xyes")
745 dnl ******************************
746 dnl Check for ImageMagick Magick++
747 dnl ******************************
749 PKG_CHECK_MODULES(IMAGEMAGICK, ImageMagick++, magick_ok=yes, magick_ok=no)
750 if test "x$magick_ok" = "xyes"; then
751 AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])
752 fi
753 AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")
755 AC_SUBST(IMAGEMAGICK_LIBS)
756 AC_SUBST(IMAGEMAGICK_CFLAGS)
758 dnl ***********************************************************************************************************
759 dnl Check for a Cairo version that implements user-fonts feature (with a stable API, that is cairo > 1.7.6),
760 dnl so that we conditionally add SVGFonts support
761 dnl ***********************************************************************************************************
763 PKG_CHECK_MODULES(CAIRO_USER_FONTS, cairo > 1.7.6, cairouserfonts=yes, cairouserfonts=no)
764 if test "x$cairouserfonts" = "xyes"; then
765 AC_DEFINE(ENABLE_SVG_FONTS, 1, [SVG Fonts should be used])
766 fi
768 dnl ******************************
769 dnl Unconditional dependencies
770 dnl ******************************
772 dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10
773 if test $cc_vers_major -gt 3; then
774 min_sigc_version=2.0.12
775 else
776 min_sigc_version=2.0.11
777 fi
778 PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4 glibmm-2.4 giomm-2.4 gtkmm-2.4 >= 2.10.0 gtk+-2.0 libxml-2.0 >= 2.6.11 libxslt >= 1.0.15 cairo sigc++-2.0 >= $min_sigc_version $ink_spell_pkg gthread-2.0 >= 2.0 libpng >= 1.2 gsl)
780 # Check for Apple Mac OS X Carbon framework
781 carbon_ok=no
782 AC_MSG_CHECKING([for Mac OS X Carbon support])
783 AC_COMPILE_IFELSE([
784 #include <Carbon/Carbon.h>
785 #include <CoreServices/CoreServices.h>
786 ], [carbon_ok=yes])
787 AC_MSG_RESULT($carbon_ok)
788 if test "x$carbon_ok" = "xyes"; then
789 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
790 CARBON_LDFLAGS="-framework Carbon"
791 AC_SUBST(CARBON_LDFLAGS)
792 fi
793 AM_CONDITIONAL(HAVE_CARBON, test "x$carbon_ok" = "xyes")
795 # Check for some boost header files
796 AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))
798 PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)
799 if test "x$cairo_pdf" = "xyes"; then
800 AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])
801 fi
803 dnl Shouldn't we test for libpng and libz?
804 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz -lX11 -lxml2 -ldl"
805 if test "x$openmp_ok" = "xyes"; then
806 INKSCAPE_LIBS="$INKSCAPE_LIBS -lgomp"
807 fi
809 AC_CHECK_HEADER(popt.h,
810 [INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],
811 AC_MSG_ERROR([libpopt is required]))
813 dnl **************************
814 dnl Check for aspell
815 dnl ******************************
816 AC_CHECK_LIB(aspell, new_aspell_config, [AC_CHECK_HEADER(aspell.h, aspell_ok=yes, aspell_ok=no)], aspell_ok=no, -lz -lm)
817 if test "x$aspell_ok" = "xyes"; then
818 AC_DEFINE(HAVE_ASPELL, 1, [Use aspell for built-in spellchecker])
819 INKSCAPE_LIBS="$INKSCAPE_LIBS -laspell"
820 else
821 AC_MSG_CHECKING([Aspell not found, spell checker will be disabled])
822 fi
824 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
825 sp_save_LIBS=$LIBS
826 LIBS="$LIBS $INKSCAPE_LIBS"
827 AC_CHECK_FUNCS(bind_textdomain_codeset)
828 dnl Check for gtk_window_fullscreen in gtk (>= 2.2)
829 AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)
830 AC_CHECK_FUNCS(gtk_window_fullscreen)
831 LIBS=$sp_save_LIBS
834 dnl Check for binary relocation support
835 dnl Hongli Lai <h.lai@chello.nl>
837 AC_ARG_ENABLE(binreloc,
838 [ --enable-binreloc compile with binary relocation support],
839 enable_binreloc=$enableval,enable_binreloc=no)
841 AC_MSG_CHECKING(whether binary relocation support should be enabled)
842 if test "$enable_binreloc" = "yes"; then
843 AC_MSG_RESULT(yes)
844 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
845 if test -e /proc/self/maps; then
846 AC_MSG_RESULT(yes)
847 else
848 AC_MSG_RESULT(no)
849 AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
850 enable_binreloc="no"
851 fi
853 elif test "$enable_binreloc" = "auto"; then
854 AC_MSG_RESULT(yes when available)
855 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
856 if test -e /proc/self/maps; then
857 AC_MSG_RESULT(yes)
858 enable_binreloc=yes
860 AC_MSG_CHECKING(whether everything is installed to the same prefix)
861 if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
862 "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
863 "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
864 then
865 AC_MSG_RESULT(yes)
866 else
867 AC_MSG_RESULT(no)
868 AC_MSG_NOTICE(Binary relocation support will be disabled.)
869 enable_binreloc=no
870 fi
872 else
873 AC_MSG_RESULT(no)
874 enable_binreloc=no
875 fi
877 elif test "$enable_binreloc" = "no"; then
878 AC_MSG_RESULT(no)
879 else
880 AC_MSG_RESULT([no (unknown value "$enable_binreloc")])
881 enable_binreloc=no
882 fi
883 AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])
884 if test "$enable_binreloc" = "yes"; then
885 AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
886 fi
888 AC_ARG_ENABLE(osxapp,
889 [ --enable-osxapp compile with OSX .app data dir paths],
890 enable_osxapp=$enableval,enable_osxapp=no)
891 if test "$enable_osxapp" = "yes"; then
892 AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])
893 fi
895 dnl ******************************
896 dnl Reported by autoscan
897 dnl ******************************
898 AC_CHECK_FUNCS(pow)
899 # if we did not find pow(), see if it's in libm.
900 if test x"$ac_cv_func_pow" = x"no" ; then
901 AC_CHECK_LIB(m,pow)
902 fi
903 AC_CHECK_FUNCS(sqrt)
904 AC_CHECK_FUNCS(floor)
905 AC_CHECK_FUNCS(gettimeofday)
906 AC_CHECK_FUNCS(memmove)
907 AC_CHECK_FUNCS(memset)
908 AC_CHECK_FUNCS(mkdir)
909 AC_CHECK_FUNCS(strncasecmp)
910 AC_CHECK_FUNCS(strpbrk)
911 AC_CHECK_FUNCS(strrchr)
912 AC_CHECK_FUNCS(strspn)
913 AC_CHECK_FUNCS(strstr)
914 AC_CHECK_FUNCS(strtoul)
915 AC_CHECK_FUNCS(fpsetmask)
916 AC_CHECK_FUNCS(ecvt)
917 AC_CHECK_HEADERS(ieeefp.h)
918 AC_CHECK_HEADERS(fcntl.h)
919 AC_CHECK_HEADERS(libintl.h)
920 AC_CHECK_HEADERS(stddef.h)
921 AC_CHECK_HEADERS(sys/time.h)
922 AC_FUNC_STAT
923 AC_FUNC_STRFTIME
924 AC_FUNC_STRTOD
925 AC_HEADER_STAT
926 AC_HEADER_TIME
927 AC_STRUCT_TM
928 AC_TYPE_MODE_T
929 AC_TYPE_SIGNAL
931 dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't
932 dnl set correctly because the gettext function isn't noticed.
933 if test "$ac_cv_header_libintl_h" = "yes" &&
934 test "$ac_cv_func_bind_textdomain_codeset" = "yes" &&
935 test "$gt_cv_func_have_gettext" != "yes"; then
936 AC_DEFINE(ENABLE_NLS)
937 fi
939 dnl ******************************
940 dnl Compilation warnings
941 dnl ******************************
942 if test "$GXX" = "yes"; then
943 # Enable some warnings from g++.
945 # Rationale: a number of bugs in inkscape have been fixed by enabling g++
946 # warnings and addressing the produced warnings. Usually the committing
947 # developer is the best person to address the warnings.
949 ink_svd_CXXFLAGS="$CXXFLAGS"
950 CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"
951 # -Wno-unused-parameter isn't accepted by gcc 2.95.
952 AC_COMPILE_IFELSE([int dummy;
953 ], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)
954 # Note: At least one bug has been caught from unused parameter warnings,
955 # so it might be worth trying not to disable it.
956 # One way of selectively disabling the warnings (i.e. only where the
957 # programmer deliberately isn't using the parameter, e.g. for a callback)
958 # is to remove the parameter name (leaving just its type), as is done
959 # in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the
960 # programmer deliberately has an unused parameter (e.g. because it's used
961 # as a callback or similar function pointer use).
963 # Add even more stuff
964 CXXFLAGS="-Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch $CXXFLAGS"
966 fi
968 dnl ******************************
969 dnl libinkscape
970 dnl ******************************
971 dnl
972 dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])
973 dnl
974 dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")
975 dnl
977 AC_SUBST(INKSCAPE_CFLAGS)
978 AC_SUBST(INKSCAPE_LIBS)
980 dnl Define our data paths for config.h
981 AC_DEFINE_DIR([INKSCAPE_DATADIR], [datadir], [Base data directory])
982 AC_DEFINE_DIR([PACKAGE_LOCALE_DIR], [localedir], [Locatization directory])
984 AC_CONFIG_FILES([
985 Makefile
986 src/Makefile
987 src/check-header-compile
988 src/bind/makefile
989 src/debug/makefile
990 src/dialogs/makefile
991 src/display/makefile
992 src/dom/makefile
993 src/extension/implementation/makefile
994 src/extension/internal/makefile
995 src/extension/makefile
996 src/extension/script/makefile
997 src/extension/dbus/wrapper/inkdbus.pc
998 src/filters/makefile
999 src/helper/makefile
1000 src/io/makefile
1001 src/libcroco/makefile
1002 src/libgdl/makefile
1003 src/libnr/makefile
1004 src/libnrtype/makefile
1005 src/libavoid/makefile
1006 src/livarot/makefile
1007 src/live_effects/makefile
1008 src/live_effects/parameter/makefile
1009 src/pedro/makefile
1010 src/jabber_whiteboard/makefile
1011 src/svg/makefile
1012 src/trace/makefile
1013 src/ui/cache/makefile
1014 src/ui/dialog/makefile
1015 src/ui/makefile
1016 src/ui/view/makefile
1017 src/ui/widget/makefile
1018 src/util/makefile
1019 src/widgets/makefile
1020 src/xml/makefile
1021 src/2geom/makefile
1022 doc/Makefile
1023 po/Makefile.in
1024 share/Makefile
1025 share/clipart/Makefile
1026 share/examples/Makefile
1027 share/extensions/Makefile
1028 share/extensions/alphabet_soup/Makefile
1029 share/extensions/Barcode/Makefile
1030 share/extensions/Poly3DObjects/Makefile
1031 share/extensions/test/Makefile
1032 share/extensions/xaml2svg/Makefile
1033 share/filters/Makefile
1034 share/fonts/Makefile
1035 share/gradients/Makefile
1036 share/icons/Makefile
1037 share/icons/application/Makefile
1038 share/icons/application/16x16/Makefile
1039 share/icons/application/22x22/Makefile
1040 share/icons/application/24x24/Makefile
1041 share/icons/application/32x32/Makefile
1042 share/icons/application/48x48/Makefile
1043 share/icons/application/256x256/Makefile
1044 share/keys/Makefile
1045 share/markers/Makefile
1046 share/palettes/Makefile
1047 share/patterns/Makefile
1048 share/screens/Makefile
1049 share/templates/Makefile
1050 share/tutorials/Makefile
1051 share/ui/Makefile
1052 packaging/autopackage/default.apspec
1053 inkscape.spec
1054 Info.plist
1055 inkview.1
1056 ])
1058 AH_BOTTOM([
1061 ])
1063 AC_OUTPUT
1065 echo "
1066 Configuration:
1068 Source code location: ${srcdir}
1069 Destination path prefix: ${prefix}
1070 Compiler: ${CXX}
1071 CPPFLAGS: ${CPPFLAGS}
1072 CXXFLAGS: ${CXXFLAGS}
1073 CFLAGS: ${CFLAGS}
1074 LDFLAGS: ${LDFLAGS}
1076 Use Xft font database: ${xft_ok}
1077 Use gnome-vfs: ${gnome_vfs}
1078 Use openoffice files: ${ij}
1079 Use relocation support: ${enable_binreloc}
1080 Internal Python: ${with_python}
1081 Internal Perl: ${with_perl}
1082 Enable LittleCms: ${enable_lcms}
1083 Enable DBUS: ${with_dbus}
1084 Enable Poppler-Cairo: ${enable_poppler_cairo}
1085 ImageMagick Magick++: ${magick_ok}
1086 Libwpg: ${with_libwpg}
1087 Doing Local Install: ${with_localinstall}
1088 "