configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.50)
   4 AC_INIT(inkscape, 0.45+devel)
   5 dnl N.B. After 0.40, please change to `0.40+cvs' instead of `0.41cvs'.
   6 dnl Rationale: (i) placate simple version comparison software such as
   7 dnl `dpkg --compare-versions'.  (ii) We don't always know what the next
   8 dnl version is going to be called until about the time we release it
   9 dnl (whereas we always know what the previous version was called).
  10 AC_CANONICAL_HOST
  11 AC_CONFIG_SRCDIR(src/main.cpp)
  12 AM_INIT_AUTOMAKE
  13
  14 AC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [
  15   prefix=/opt/inkscape
  16   PATH="/opt/lsb/bin:$PATH"
  17   CC=lsbcc
  18   CXX=lsbc++
  19   export CC CXX
  20 ])
  21
  22 AM_CONFIG_HEADER(config.h)
  23
  24 AC_PROG_INTLTOOL(0.22)
  25
  26 AC_LANG(C++)
  27 AC_ISC_POSIX
  28 AC_PROG_CXX
  29 AM_PROG_CC_STDC
  30 AM_PROG_AS
  31 AC_HEADER_STDC
  32
  33 dnl These next few lines are needed only while libcroco is in our source tree.
  34 AC_PROG_CC
  35 AM_PROG_CC_C_O
  36 AC_MSG_NOTICE([Testing -Wno-pointer-sign])
  37 if test "$GCC" = "yes"; then
  38   # Enable some warnings from gcc.
  39
  40   AC_LANG_PUSH(C)
  41   # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted
  42   # by gcc 2.95.
  43   ink_svd_CFLAGS="$CFLAGS"
  44   CFLAGS="-Wno-pointer-sign $CFLAGS"
  45   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), AC_MSG_NOTICE([ compiler supports -Wno-pointer-sign]), CFLAGS="$ink_svd_CFLAGS")
  46   CFLAGS="-Wall -Wformat-security -W -D_FORTIFY_SOURCE=2 $CFLAGS"
  47   AC_LANG_POP
  48 fi
  49
  50 dnl Honor aclocal flags
  51 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  52
  53 AC_PROG_RANLIB
  54
  55 dnl Verify our GCC version
  56 if test "x$GXX" = "xyes"; then
  57         AC_MSG_CHECKING([GNU compiler version])
  58
  59         # Don't pass CXXFLAGS to the following CXX command as some
  60         # of them can't be specified along with '-v'.
  61         cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\
  62                 sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]
  63
  64         AC_MSG_RESULT([$cc_version])
  65
  66         # Some version numbers
  67         cc_vers_major=`echo $cc_version | cut -f1 -d.`
  68         cc_vers_minor=`echo $cc_version | cut -f2 -d.`
  69         cc_vers_patch=`echo $cc_version | cut -f3 -d.`
  70         test -n "$cc_vers_major" || cc_vers_major=0
  71         test -n "$cc_vers_minor" || cc_vers_minor=0
  72         test -n "$cc_vers_patch" || cc_vers_patch=0
  73         cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`
  74
  75         if test $cc_vers_major -lt 3; then
  76                 AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])
  77         fi
  78 fi
  79
  80 dnl ******************************
  81 dnl Gettext stuff
  82 dnl ******************************
  83 GETTEXT_PACKAGE="AC_PACKAGE_NAME"
  84 AC_SUBST(GETTEXT_PACKAGE)
  85 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])
  86 dnl Add the languages which your application supports here.
  87 ALL_LINGUAS="am az be bg bn ca cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fi fr ga gl he hr hu id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@Latn sr sv th tr uk vi zh_CN zh_TW"
  88 AM_GLIB_GNU_GETTEXT
  89
  90 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  91 if test "x$PKG_CONFIG" = "xno"; then
  92         AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)
  93 fi
  94
  95 dnl Find msgfmt.  Without this, po/Makefile fails to set MSGFMT on some platforms.
  96 AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)
  97 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
  98
  99 dnl ******************************
 100 dnl Check for libpng
 101 dnl ******************************
 102 AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=no)], png_ok=no, -lz -lm)
 103 if test "x$png_ok" != "xyes"; then
 104         AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])
 105 fi
 106
 107 dnl Handle possible dlopen requirement for libgc
 108 dnl Isn't this internal to something in autoconf?  Couldn't find it...
 109 AC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],
 110           [lt_cv_dlopen="dlopen"],
 111       [AC_CHECK_LIB([dl], [dlopen],
 112             [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
 113         [AC_CHECK_LIB([svld], [dlopen],
 114               [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
 115           [AC_CHECK_LIB([dld], [dld_link],
 116                 [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
 117           ])
 118         ])
 119       ])
 120     ])
 121
 122 AC_CHECK_HEADERS([gc.h gc/gc.h],
 123                  [
 124                     # To test for the different required libs, I have to
 125                     # overcome autoconf's caching system, so I change the
 126                     # desired function name.  They're all in libgc.
 127                     # The "break" will exit from the top level
 128                     # AC_CHECK_HEADERS.
 129                     gc_libs=""
 130                     AC_CHECK_LIB(gc, GC_init,
 131                                  [gc_ok=yes;
 132                                   LIBS="-lgc $gc_libs $LIBS";
 133                                   break], [gc_ok=no], [$gc_libs])
 134                     gc_libs="-lpthread"
 135                     AC_CHECK_LIB(gc, GC_malloc,
 136                                  [gc_ok=yes;
 137                                   LIBS="-lgc $gc_libs $LIBS";
 138                                   break], [gc_ok=no], [$gc_libs])
 139                     gc_libs="$lt_cv_dlopen_libs"
 140                     AC_CHECK_LIB(gc, GC_realloc,
 141                                  [gc_ok=yes;
 142                                   LIBS="-lgc $gc_libs $LIBS";
 143                                   break], [gc_ok=no], [$gc_libs])
 144                     gc_libs="-lpthread $lt_cv_dlopen_libs"
 145                     AC_CHECK_LIB(gc, GC_free,
 146                                  [gc_ok=yes;
 147                                   LIBS="-lgc $gc_libs $LIBS";
 148                                   break], [gc_ok=no], [$gc_libs])
 149                     break],
 150                  [gc_ok=no])
 151 if test "x$gc_ok" = "xyes"; then
 152         AC_MSG_CHECKING([libgc version 6.4+])
 153         AC_RUN_IFELSE(
 154                 [AC_LANG_SOURCE([[
 155                         #ifdef HAVE_GC_GC_H
 156                         # include <gc/gc.h>
 157                         #else
 158                         # include <gc.h>
 159                         #endif
 160                         #include <stdio.h>
 161                         extern unsigned GC_version;
 162                         int main(void){
 163                                 unsigned min = ((6 << 16) | (4 << 8) | 0);
 164                                 printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);
 165                                 if (GC_version>=min) return 0;
 166                                 return 1;
 167                         }]])],
 168                 [gc_ok=yes],
 169                 [gc_ok=no]
 170         )
 171         AC_MSG_RESULT([$gc_ok])
 172 fi
 173 if test "x$gc_ok" != "xyes"; then
 174         AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])
 175 fi
 176
 177 dnl This check is to get a FIONREAD definition on Solaris 8
 178 AC_CHECK_HEADERS([sys/filio.h])
 179
 180
 181 AC_CHECK_HEADERS([malloc.h])
 182 AC_CHECK_FUNCS([mallinfo], [
 183         AC_CHECK_MEMBERS([struct mallinfo.usmblks,
 184                           struct mallinfo.fsmblks,
 185                           struct mallinfo.uordblks,
 186                           struct mallinfo.fordblks,
 187                           struct mallinfo.hblkhd],,,
 188                          [#include <malloc.h>])
 189 ])
 190
 191 AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 192 if test "x$FREETYPE_CONFIG" = "xno"; then
 193         AC_MSG_ERROR([Cannot find freetype-config])
 194 fi
 195 FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
 196 FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
 197 AC_SUBST(FREETYPE_CFLAGS)
 198 AC_SUBST(FREETYPE_LIBS)
 199
 200 dnl ******************************
 201 dnl Win32
 202 dnl ******************************
 203 AC_MSG_CHECKING([for Win32 platform])
 204 case "$host" in
 205   *-*-mingw*)
 206     platform_win32=yes
 207     INKSCAPE_CFLAGS="$INKSCAPE_CFLAGS -mms-bitfields -DLIBXML_STATIC"
 208     ;;
 209   *)
 210     platform_win32=no
 211     ;;
 212 esac
 213 AC_MSG_RESULT([$platform_win32])
 214 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 215
 216 AC_MSG_CHECKING([for Solaris 2.8 platform])
 217 case "$host" in
 218   *-solaris2.8)
 219     platform_solaris_2_8=yes
 220     CFLAGS="$CFLAGS -DSOLARIS_2_8"
 221     CXXFLAGS="$CXXFLAGS -DSOLARIS_2_8"
 222     ;;
 223   *)
 224     platform_solaris_2_8=no
 225     ;;
 226 esac
 227 AC_MSG_RESULT([$platform_solaris_2_8])
 228 AM_CONDITIONAL(PLATFORM_SOLARIS_2_8, test "$platform_solaris_2_8" = "yes")
 229
 230 dnl ******************************
 231 dnl Xft checking
 232 dnl ******************************
 233
 234 AC_ARG_WITH(xft,
 235             AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),
 236             [with_xft=$withval], [with_xft=auto])
 237
 238 if test "x$with_xft" != "xno" ; then
 239         dnl Test fontconfig package
 240         PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)
 241         if test "x$xft_ok" != "xyes"; then
 242                 dnl test xft package
 243                 PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)
 244                 if test "x$xft_ok" != "xyes"; then
 245                         dnl Have to test xft presence
 246                         AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)
 247                         if test "x$xft_ok" != "xyes"; then
 248                                 dnl No xft found
 249                                 if test "x$with_xft" = "xyes"; then
 250                                         dnl Xft was explicitly asked, so stop
 251                                         AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])
 252                                 fi
 253                         else
 254                                 dnl Working Xft1
 255                                 XFT_LIBS="-L/usr/X11R6/lib -lXft "
 256                         fi
 257                 fi
 258         fi
 259 else
 260         dnl Asked to ignore xft
 261         xft_ok=no
 262 fi
 263
 264 AC_SUBST(XFT_CFLAGS)
 265 AC_SUBST(XFT_LIBS)
 266
 267 AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")
 268 if test "x$xft_ok" = "xyes"; then
 269         AC_DEFINE(WITH_XFT, 1, [Use Xft font database])
 270 fi
 271
 272 dnl ******************************
 273 dnl pangoft2 for xft
 274 dnl ******************************
 275
 276 if test "x$xft_ok" = "xyes"; then
 277         PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)
 278         if test "x$pango_ok" = "xyes"; then
 279                 XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"
 280         fi
 281 fi
 282
 283 dnl ******************************
 284 dnl GnomePrint checking
 285 dnl ******************************
 286
 287 AC_ARG_WITH(gnome-print,
 288             AC_HELP_STRING([--with-gnome-print], [use gnome print font database and spooler frontend]),
 289             [with_gp=$withval], [with_gp=auto])
 290
 291 if test "x$with_gp" = "xyes"; then
 292         dnl Have to test gnome-print presence
 293         PKG_CHECK_MODULES(GNOME_PRINT, libgnomeprint-2.2 >= 1.116.0  libgnomeprintui-2.2 >= 1.116.0, gp=yes, gp=no)
 294         if test "x$gp" != "xyes"; then
 295                 dnl No gnome-print found
 296                 if test "x$with_gp" = "xyes"; then
 297                         dnl Gnome-print was explicitly asked, so stop
 298                         AC_MSG_ERROR([--with-gnome-print was specified, but appropriate libgnomeprint development packages could not be found])
 299                 else
 300                         # gp is no, tell us for the log file
 301                         AC_MSG_RESULT($gp)
 302                 fi
 303         fi
 304 else
 305         dnl Asked to ignore gnome-print
 306         gp=no
 307 fi
 308
 309 AC_SUBST(GNOME_PRINT_CFLAGS)
 310 AC_SUBST(GNOME_PRINT_LIBS)
 311
 312 AM_CONDITIONAL(USE_GNOME_PRINT, test "x$gp" = "xyes")
 313 if test "x$gp" = "xyes"; then
 314         AC_DEFINE(WITH_GNOME_PRINT, 1, [Use gnome print font database and spooler frontend])
 315 fi
 316
 317 dnl ******************************
 318 dnl gnome vfs checking
 319 dnl ******************************
 320
 321 AC_ARG_WITH(gnome-vfs,
 322         AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),
 323         [with_gnome_vfs=$withval], [with_gnome_vfs=auto])
 324
 325 if test "x$with_gnome_vfs" = "xno"; then
 326         dnl Asked to ignore gnome-vfs
 327         gnome_vfs=no
 328 else
 329         dnl Have to test gnome-vfs presence
 330         PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)
 331         if test "x$gnome_vfs" != "xyes"; then
 332                 dnl No gnome-vfs found
 333                 if test "x$with_gnome_vfs" = "xyes"; then
 334                         dnl Gnome-VFS was explicitly asked for, so stop
 335                         AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])
 336                 else
 337                         # gnome-vfs is no, tell us for the log file
 338                         AC_MSG_RESULT($gnome_vfs)
 339                 fi
 340         fi
 341 fi
 342
 343 AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")
 344 if test "x$gnome_vfs" = "xyes"; then
 345         AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])
 346 fi
 347
 348 AC_SUBST(GNOME_VFS_CFLAGS)
 349 AC_SUBST(GNOME_VFS_LIBS)
 350
 351 dnl ******************************
 352 dnl libinkjar checking
 353 dnl ******************************
 354
 355 AC_ARG_WITH(inkjar,
 356         AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])
 357
 358 if test "x$with_ij" = "xyes"; then
 359         AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])
 360         AC_C_BIGENDIAN
 361         AC_CHECK_HEADERS(zlib.h)
 362         ij=yes
 363 else
 364         ij=no
 365 fi
 366 AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")
 367
 368 ink_spell_pkg=
 369 if pkg-config --exists gtkspell-2.0; then
 370         ink_spell_pkg=gtkspell-2.0
 371         AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])
 372 fi
 373
 374 dnl ******************************
 375 dnl PERL checking
 376 dnl ******************************
 377
 378 AC_MSG_CHECKING(for Perl development environment)
 379 AC_ARG_WITH(perl,
 380             AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),
 381             [with_perl=$withval], [with_perl=skipped])
 382
 383 if test "x$with_perl" = "xyes"; then
 384     checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`
 385     if test "$?" -gt "0"; then
 386         with_perl="no"
 387     else
 388         checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`
 389         if test "$?" -gt "0"; then
 390             with_perl="no"
 391         else
 392             with_perl="yes"
 393         fi
 394     fi
 395 fi
 396 AC_MSG_RESULT([$with_perl])
 397 if test "x$with_perl" = "xyes"; then
 398     # Test that we actually have the perl libraries installed
 399     oldCFLAGS="$CFLAGS"
 400     oldLIBS="$LIBS"
 401     CFLAGS="$CFLAGS $checkPERL_CFLAGS"
 402     LIBS="$LIBS $checkPERL_LIBS"
 403     AC_CHECK_FUNC([perl_parse],[
 404         PERL_CFLAGS="$checkPERL_CFLAGS"
 405         PERL_LIBS="$checkPERL_LIBS"
 406         AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])
 407         ],[
 408         with_perl="no"
 409         ])
 410     CFLAGS="$oldCFLAGS"
 411     LIBS="$oldLIBS"
 412 fi
 413 AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")
 414 AC_SUBST(PERL_CFLAGS)
 415 AC_SUBST(PERL_LIBS)
 416
 417 dnl ******************************
 418 dnl Python checking
 419 dnl ******************************
 420
 421 AC_MSG_CHECKING(for Python development environment)
 422 AC_ARG_WITH(python,
 423             AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),
 424             [with_python=$withval], [with_python=skipped])
 425
 426 if test "x$with_python" = "xyes"; then
 427     checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`
 428     if test "$?" -gt "0"; then
 429         with_python="no"
 430     else
 431         checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`
 432         if test "$?" -gt "0"; then
 433             with_python="no"
 434         else
 435             with_python="yes"
 436         fi
 437     fi
 438 fi
 439 AC_MSG_RESULT([$with_python])
 440 if test "x$with_python" = "xyes"; then
 441     # Test that we actually have the python libraries installed
 442     oldCFLAGS="$CFLAGS"
 443     oldLIBS="$LIBS"
 444     CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"
 445     LIBS="$LIBS $checkPYTHON_LIBS"
 446     AC_CHECK_FUNC([Py_Initialize],[
 447         PYTHON_CFLAGS="$checkPYTHON_CFLAGS"
 448         PYTHON_LIBS="$checkPYTHON_LIBS"
 449         AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])
 450         ],[
 451         with_python="no"
 452         ])
 453     CFLAGS="$oldCFLAGS"
 454     LIBS="$oldLIBS"
 455 fi
 456 AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")
 457 AC_SUBST(PYTHON_CFLAGS)
 458 AC_SUBST(PYTHON_LIBS)
 459
 460 dnl ******************************
 461 dnl LittleCms checking
 462 dnl ******************************
 463
 464 AC_ARG_ENABLE(lcms,
 465         AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),
 466         [enable_lcms=$enableval], [enable_lcms=yes])
 467
 468 if test "x$enable_lcms" = "xno"; then
 469         dnl Asked to ignore LittleCms
 470         lcms=no
 471 else
 472         dnl Have to test LittleCms presence
 473         PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)
 474         if test "x$lcms" != "xyes"; then
 475                 dnl No lcms found
 476                 if test "x$enable_lcms" = "xyes"; then
 477                         dnl LittleCms was explicitly asked for, so stop
 478                         AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])
 479                 else
 480                         # lcms is no, tell us for the log file
 481                         AC_MSG_RESULT($lcms)
 482                 fi
 483         else
 484                 dnl Working lcms
 485                 LCMS_LIBS="-llcms "
 486         fi
 487 fi
 488
 489 if test "x$lcms" = "xyes"; then
 490         LIBS="$LIBS $LCMS_LIBS"
 491         AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])
 492 fi
 493 AM_CONDITIONAL(USE_LCMS, test "x$lcms" = "xyes")
 494 AC_SUBST(LCMS_CFLAGS)
 495 AC_SUBST(LCMS_LIBS)
 496
 497 dnl ******************************
 498 dnl Libpoppler checking
 499 dnl ******************************
 500
 501 POPPLER_CFLAGS=""
 502 PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.9, poppler=yes, poppler=no)
 503
 504 if test "x$poppler" = "xyes"; then
 505         dnl Working libpoppler
 506         POPPLER_LIBS="-lpoppler "
 507         dnl Have to test libpoppler-glib presence
 508         PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.9, poppler_glib=yes, poppler_glib=no)
 509         if test "x$poppler_glib" = "xyes"; then
 510                 dnl Working libpoppler-glib found
 511                 dnl Check whether the Cairo SVG backend is available
 512                 PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)
 513                 if test "x$cairo_svg" = "xyes"; then
 514                         POPPLER_LIBS="$POPPLER_LIBS -lpoppler-glib "
 515                 fi
 516         fi
 517         dnl Have to test libpoppler-cairo presence for PDF preview
 518         PKG_CHECK_MODULES(POPPLER_CAIRO, poppler-cairo >= 0.5.9, poppler_cairo=yes, poppler_cairo=no)
 519         if test "x$poppler_cairo" = "xyes"; then
 520                 dnl Working libpoppler-cairo found
 521                 dnl Check whether the Cairo FreeType backend is available
 522                 PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, cairo_ft=yes, cairo_ft=no)
 523         fi
 524 fi
 525
 526 if test "x$poppler" = "xyes"; then
 527         LIBS="$LIBS $POPPLER_LIBS"
 528         AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])
 529 fi
 530 if test "x$cairo_ft" = "xyes"; then
 531         AC_DEFINE(HAVE_POPPLER_CAIRO, 1, [Use libpoppler-cairo for rendering PDF preview])
 532 fi
 533 if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then
 534         AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])
 535 fi
 536 AC_SUBST(POPPLER_CFLAGS)
 537 AC_SUBST(POPPLER_LIBS)
 538
 539 dnl ******************************
 540 dnl Inkboard dependency checking
 541 dnl ******************************
 542
 543 with_inkboard="no"
 544 with_inkboard_ssl="no"
 545
 546 INKBOARD_CFLAGS=""
 547
 548 AC_ARG_ENABLE(inkboard,
 549                 AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),
 550        with_inkboard=$enableval,with_inkboard=no)
 551
 552 if test "x$with_inkboard" = "xyes"; then
 553                 with_inkboard="yes"
 554                 AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])
 555
 556                 dnl Test for OpenSSL
 557                 PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)
 558                 if test "x$with_inkboard_ssl" = "xyes"; then
 559                         dnl OpenSSL found; enable SSL support in Pedro
 560                         INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"
 561                         RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
 562                         RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
 563                         AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])
 564                 fi
 565 else
 566         with_inkboard="no"
 567 fi
 568
 569 AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")
 570 AC_SUBST(INKBOARD_LIBS)
 571 AC_SUBST(INKBOARD_CFLAGS)
 572
 573 dnl ******************************
 574 dnl Check for ImageMagick Magick++
 575 dnl ******************************
 576
 577 AC_CHECK_LIB(Magick++, InitializeMagick, [AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)], magick_ok=no, -llcms -lfreetype -ljpeg -lfontconfig -lXext -lSM -lICE -lX11 -lz -lpthread -lm -lpthread)
 578
 579 if test "x$magick_ok" = "xyes"; then
 580         AC_CHECK_PROG(MAGICKPP_CONFIG, Magick++-config, yes, no)
 581         if test "x$MAGICKPP_CONFIG" = "xyes"; then
 582                 IMAGEMAGICK_LIBS=`Magick++-config --libs`
 583                 AC_SUBST(IMAGEMAGICK_LIBS)
 584                 AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])
 585         fi
 586 fi
 587
 588 AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")
 589
 590 dnl ******************************
 591 dnl   Unconditional dependencies
 592 dnl ******************************
 593
 594 dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10
 595 if test $cc_vers_major -gt 3; then
 596   min_sigc_version=2.0.12
 597 else
 598   min_sigc_version=2.0.11
 599 fi
 600 PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4  glibmm-2.4  gtkmm-2.4  gtk+-2.0 >= 2.8.0  libxml-2.0 >= 2.6.11  libxslt >= 1.0.15  cairo  sigc++-2.0 >= $min_sigc_version  $ink_spell_pkg  gthread-2.0 >= 2.0 libpng >= 1.2)
 601
 602 # Check for some boost header files
 603 AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))
 604
 605 PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)
 606 if test "x$cairo_pdf" = "xyes"; then
 607   AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])
 608 fi
 609
 610 PKG_CHECK_MODULES(GTK_UNIX_PRINT, gtk+-unix-print-2.0, gtk_unix_print=yes, gtk_unix_print=no)
 611 if test "x$gtk_unix_print" = "xyes"; then
 612   AC_DEFINE(HAVE_GTK_UNIX_PRINT, 1, [Whether the GTK Unix printing backend is available])
 613 fi
 614
 615 dnl Shouldn't we test for libpng and libz?
 616 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz"
 617
 618 AC_CHECK_HEADER(popt.h,
 619                 [INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],
 620                 AC_MSG_ERROR([libpopt is required]))
 621
 622 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 623 sp_save_LIBS=$LIBS
 624 LIBS="$LIBS $INKSCAPE_LIBS"
 625 AC_CHECK_FUNCS(bind_textdomain_codeset)
 626 dnl Check for gtk_window_fullscreen in gtk (>= 2.2)
 627 AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)
 628 AC_CHECK_FUNCS(gtk_window_fullscreen)
 629 LIBS=$sp_save_LIBS
 630
 631
 632 dnl Check for binary relocation support
 633 dnl Hongli Lai <h.lai@chello.nl>
 634
 635 AC_ARG_ENABLE(binreloc,
 636        [  --enable-binreloc       compile with binary relocation support],
 637        enable_binreloc=$enableval,enable_binreloc=no)
 638
 639 AC_MSG_CHECKING(whether binary relocation support should be enabled)
 640 if test "$enable_binreloc" = "yes"; then
 641        AC_MSG_RESULT(yes)
 642        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
 643        if test -e /proc/self/maps; then
 644                AC_MSG_RESULT(yes)
 645        else
 646                AC_MSG_RESULT(no)
 647                AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
 648                enable_binreloc="no"
 649        fi
 650
 651 elif test "$enable_binreloc" = "auto"; then
 652        AC_MSG_RESULT(yes when available)
 653        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
 654        if test -e /proc/self/maps; then
 655                AC_MSG_RESULT(yes)
 656                enable_binreloc=yes
 657
 658                AC_MSG_CHECKING(whether everything is installed to the same prefix)
 659                if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
 660                        "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
 661                        "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
 662                then
 663                        AC_MSG_RESULT(yes)
 664                else
 665                        AC_MSG_RESULT(no)
 666                        AC_MSG_NOTICE(Binary relocation support will be disabled.)
 667                        enable_binreloc=no
 668                fi
 669
 670        else
 671                AC_MSG_RESULT(no)
 672                enable_binreloc=no
 673        fi
 674
 675 elif test "$enable_binreloc" = "no"; then
 676        AC_MSG_RESULT(no)
 677 else
 678        AC_MSG_RESULT(no (unknown value "$enable_binreloc"))
 679        enable_binreloc=no
 680 fi
 681 AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])
 682 if test "$enable_binreloc" = "yes"; then
 683    AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
 684 fi
 685
 686 AC_ARG_ENABLE(osxapp,
 687        [  --enable-osxapp         compile with OSX .app data dir paths],
 688        enable_osxapp=$enableval,enable_osxapp=no)
 689 if test "$enable_osxapp" = "yes"; then
 690    AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])
 691 fi
 692
 693 dnl ******************************
 694 dnl   Reported by autoscan
 695 dnl ******************************
 696 AC_CHECK_FUNCS(pow)
 697 # if we did not find pow(), see if it's in libm.
 698 if test x"$ac_cv_func_pow" = x"no" ; then
 699         AC_CHECK_LIB(m,pow)
 700 fi
 701 AC_CHECK_FUNCS(sqrt)
 702 AC_CHECK_FUNCS(floor)
 703 AC_CHECK_FUNCS(gettimeofday)
 704 AC_CHECK_FUNCS(memmove)
 705 AC_CHECK_FUNCS(memset)
 706 AC_CHECK_FUNCS(mkdir)
 707 AC_CHECK_FUNCS(strncasecmp)
 708 AC_CHECK_FUNCS(strpbrk)
 709 AC_CHECK_FUNCS(strrchr)
 710 AC_CHECK_FUNCS(strspn)
 711 AC_CHECK_FUNCS(strstr)
 712 AC_CHECK_FUNCS(strtoul)
 713 AC_CHECK_FUNCS(fpsetmask)
 714 AC_CHECK_FUNCS(ecvt)
 715 AC_CHECK_HEADERS(ieeefp.h)
 716 AC_CHECK_HEADERS(fcntl.h)
 717 AC_CHECK_HEADERS(libintl.h)
 718 AC_CHECK_HEADERS(stddef.h)
 719 AC_CHECK_HEADERS(sys/time.h)
 720 AC_FUNC_STAT
 721 AC_FUNC_STRFTIME
 722 AC_FUNC_STRTOD
 723 AC_HEADER_STAT
 724 AC_HEADER_TIME
 725 AC_STRUCT_TM
 726 AC_TYPE_MODE_T
 727 AC_TYPE_SIGNAL
 728
 729 dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't
 730 dnl set correctly because the gettext function isn't noticed.
 731 if test "$ac_cv_header_libintl_h" = "yes" &&
 732    test "$ac_cv_func_bind_textdomain_codeset" = "yes"  &&
 733    test "$gt_cv_func_have_gettext" != "yes"; then
 734     AC_DEFINE(ENABLE_NLS)
 735 fi
 736
 737 dnl ******************************
 738 dnl   Compilation warnings
 739 dnl ******************************
 740 if test "$GXX" = "yes"; then
 741   # Enable some warnings from g++.
 742
 743   # Rationale: a number of bugs in inkscape have been fixed by enabling g++
 744   # warnings and addressing the produced warnings.  Usually the committing
 745   # developer is the best person to address the warnings.
 746
 747   ink_svd_CXXFLAGS="$CXXFLAGS"
 748   CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"
 749   # -Wno-unused-parameter isn't accepted by gcc 2.95.
 750   AC_COMPILE_IFELSE([int dummy;
 751 ], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)
 752   # Note: At least one bug has been caught from unused parameter warnings,
 753   # so it might be worth trying not to disable it.
 754   # One way of selectively disabling the warnings (i.e. only where the
 755   # programmer deliberately isn't using the parameter, e.g. for a callback)
 756   # is to remove the parameter name (leaving just its type), as is done
 757   # in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the
 758   # programmer deliberately has an unused parameter (e.g. because it's used
 759   # as a callback or similar function pointer use).
 760
 761   CXXFLAGS="-Wall -Wformat-security -W -Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch -D_FORTIFY_SOURCE=2 $CXXFLAGS"
 762
 763   dnl Test for arch-specific situations.
 764   case "$host_cpu" in
 765     mips|mipsel)
 766       dnl Symbol tables can get too large: this uses alternate tables
 767       dnl See http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=283476
 768       CXXFLAGS="$CXXFLAGS -Wa,-xgot"
 769       CFLAGS="$CFLAGS -Wa,-xgot"
 770       ;;
 771   esac
 772 fi
 773
 774 AC_DEFINE(WITH_MODULES, 1, [Use experimental module support])
 775
 776 dnl ******************************
 777 dnl   libinkscape
 778 dnl ******************************
 779 dnl
 780 dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])
 781 dnl
 782 dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")
 783 dnl
 784
 785 AC_SUBST(INKSCAPE_CFLAGS)
 786 AC_SUBST(INKSCAPE_LIBS)
 787
 788 #
 789 # Checks to see if we should compile in MMX support (there will be
 790 # a runtime test when the code is actually run to see if it should
 791 # be used - this just checks if we can compile it.)
 792 #
 793 # This code is partially taken from Mesa
 794 #
 795 dnl Let people disable the MMX optimization
 796 AC_ARG_ENABLE(mmx, [  --disable-mmx     Don't use MMX optimization [default=auto]], enable_mmx="$enableval", enable_mmx=auto)
 797
 798 AC_MSG_CHECKING(for x86 platform)
 799 case $host_cpu in
 800   i386|i486|i586|i686|i786|k6|k7)
 801     use_x86_asm=yes
 802     ;;
 803   *)
 804     use_x86_asm=no
 805 esac
 806 AC_MSG_RESULT($use_x86_asm)
 807
 808 dnl Are we going to use MMX extensions
 809 use_mmx_asm=no
 810
 811 AC_MSG_CHECKING(compiler support for MMX)
 812
 813 if test x$enable_mmx = xauto ; then
 814   if test $use_x86_asm = yes; then
 815     save_ac_ext=$ac_ext
 816     ac_ext=S
 817
 818     cp $srcdir/src/libnr/nr_mmx_R8G8B8A8_P_R8G8B8A8_P_A8_RGBAP.S conftest.S
 819     if AC_TRY_EVAL(ac_compile); then
 820         use_mmx_asm=yes
 821     fi
 822     dnl rm -f conftest.[oS]
 823
 824     ac_ext=$save_ac_ext
 825   fi
 826
 827 dnl Enforce usage of MMX extensions
 828 elif test x$enable_mmx = xyes ; then
 829     use_mmx_asm=yes
 830 else
 831     use_mmx_asm=no
 832 fi
 833
 834 if test $use_mmx_asm = yes; then
 835         AC_DEFINE(WITH_MMX, 1, [Use MMX optimizations, if CPU supports it])
 836         AC_MSG_RESULT(yes)
 837 else
 838         AC_MSG_RESULT(no)
 839 fi
 840
 841 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 842
 843 dnl Figure out where the datadir actually is
 844 dnl http://autoconf-archive.cryp.to/ac_define_dir.html
 845 prefix_NONE=
 846 exec_prefix_NONE=
 847 test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
 848 test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
 849 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
 850 dnl refers to ${prefix}.  Thus we have to use `eval' twice.
 851 eval runtime_datadir="${datadir}"
 852 eval runtime_datadir="${runtime_datadir}"
 853 test "$prefix_NONE" && prefix=NONE
 854 test "$exec_prefix_NONE" && exec_prefix=NONE
 855
 856 inkscape_sharedir="${runtime_datadir}/${PACKAGE_NAME}"
 857
 858 dnl Define our data paths for config.h
 859 AC_SUBST(INKSCAPE_DATADIR)
 860 AC_DEFINE_UNQUOTED([INKSCAPE_DATADIR], "${runtime_datadir}",
 861                                         [Base data directory -- only path-prefix.h should use it!])
 862 AC_SUBST(PACKAGE_LOCALE_DIR)
 863 AC_DEFINE_UNQUOTED([PACKAGE_LOCALE_DIR], "${runtime_datadir}/locale",
 864                                         [Localization directory])
 865 AC_SUBST(INKSCAPE_LIBDIR)
 866 AC_DEFINE_UNQUOTED([INKSCAPE_LIBDIR], "${prefix}/lib",
 867                                         [Base library directory -- only path-prefix.h should use it!])
 868
 869 dnl Have to add module makefiles (lauris)
 870
 871 AC_CONFIG_FILES([
 872 Makefile
 873 src/Makefile
 874 src/check-header-compile
 875 src/algorithms/makefile
 876 src/application/makefile
 877 src/debug/makefile
 878 src/dialogs/makefile
 879 src/display/makefile
 880 src/dom/makefile
 881 src/extension/implementation/makefile
 882 src/extension/internal/makefile
 883 src/extension/makefile
 884 src/extension/script/makefile
 885 src/helper/makefile
 886 src/inkjar/makefile
 887 src/io/makefile
 888 src/libcroco/makefile
 889 src/libgdl/makefile
 890 src/libnr/makefile
 891 src/libnrtype/makefile
 892 src/libavoid/makefile
 893 src/livarot/makefile
 894 src/live_effects/makefile
 895 src/live_effects/parameter/makefile
 896 src/pedro/makefile
 897 src/jabber_whiteboard/makefile
 898 src/removeoverlap/makefile
 899 src/svg/makefile
 900 src/trace/makefile
 901 src/traits/makefile
 902 src/ui/cache/makefile
 903 src/ui/dialog/makefile
 904 src/ui/makefile
 905 src/ui/view/makefile
 906 src/ui/widget/makefile
 907 src/utest/makefile
 908 src/util/makefile
 909 src/widgets/makefile
 910 src/xml/makefile
 911 src/2geom/makefile
 912 doc/Makefile
 913 po/Makefile.in
 914 share/Makefile
 915 share/clipart/Makefile
 916 share/examples/Makefile
 917 share/extensions/Makefile
 918 share/extensions/Barcode/Makefile
 919 share/fonts/Makefile
 920 share/gradients/Makefile
 921 share/icons/Makefile
 922 share/keys/Makefile
 923 share/markers/Makefile
 924 share/palettes/Makefile
 925 share/patterns/Makefile
 926 share/screens/Makefile
 927 share/templates/Makefile
 928 share/tutorials/Makefile
 929 share/ui/Makefile
 930 packaging/autopackage/default.apspec
 931 inkscape.spec
 932 Info.plist
 933 inkview.1
 934 ])
 935
 936 AH_BOTTOM([
 937
 938
 939 ])
 940
 941 AC_OUTPUT
 942
 943 echo "
 944 Configuration:
 945
 946         Source code location:     ${srcdir}
 947         Destination path prefix:  ${prefix}
 948         Compiler:                 ${CXX}
 949         CPPFLAGS:                 ${CPPFLAGS}
 950         CXXFLAGS:                 ${CXXFLAGS}
 951         CFLAGS:                   ${CFLAGS}
 952         LDFLAGS:                  ${LDFLAGS}
 953
 954         Use Xft font database:    ${xft_ok}
 955         Use gnome-vfs:            ${gnome_vfs}
 956         Use openoffice files:     ${ij}
 957         Use MMX optimizations:    ${use_mmx_asm}
 958         Use relocation support:   ${enable_binreloc}
 959         Internal Python:          ${with_python}
 960         Internal Perl:            ${with_perl}
 961         Enable LittleCms:         ${enable_lcms}
 962         Enable Inkboard:          ${with_inkboard}
 963         Enable SSL in Inkboard:   ${with_inkboard_ssl}
 964         ImageMagick Magick++:     ${magick_ok}
 965 "