1 #
2 # Net-Oping - lib/Net/Oping.pm
3 # Copyright (C) 2007 Olivier Fredj
4 # Copyright (C) 2008,2009 Florian octo Forster
5 #
6 # This program is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; only version 2 of the License is
9 # applicable.
10 #
11 # This program is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
19 #
20 # Authors:
21 # Olivier Fredj <ofredj at proxad.net>
22 # Florian octo Forster <octo at verplant.org>
23 #
25 package Net::Oping;
27 =head1 NAME
29 Net::Oping - ICMP latency measurement module using the oping library.
31 =head1 SYNOPSIS
33 use Net::Oping;
35 my $obj = Net::Oping->new ();
36 $obj->host_add (qw(one.example.org two.example.org));
38 my $ret = $obj->ping ();
39 print "Latency to `one' is " . $ret->{'one.example.org'} . "\n";
41 =head1 DESCRIPTION
43 This Perl module is a high-level interface to the
44 L<oping library|http://verplant.org/liboping/>. Its purpose it to send
45 C<ICMP ECHO_REQUEST> packets (also known as "ping") to a host and measure the
46 time that elapses until the reception of an C<ICMP ECHO_REPLY> packet (also
47 known as "pong"). If no such packet is received after a certain timeout the
48 host is considered to be unreachable.
50 The used I<oping> library supports "ping"ing multiple hosts in parallel and
51 works with IPv4 and IPv6 transparently. Other advanced features that are
52 provided by the underlying library, such as setting the data sent or
53 configuring the time of live (TTL) are not yet supported by this interface.
55 =cut
57 use 5.006;
59 use strict;
60 use warnings;
62 use Carp (qw(cluck confess));
64 our $VERSION = '1.02';
66 require XSLoader;
67 XSLoader::load ('Net::Oping', $VERSION);
68 return (1);
70 =head1 INTERFACE
72 The interface is kept simple and clean. First you need to create an object to
73 which you then add hosts. Using the C<ping> method you can request a latency
74 measurement and get the current values returned. If necessary you can remove
75 hosts from the object, too.
77 The constructor and methods are defined as follows:
79 =over 4
81 =item my I<$obj> = Net::Oping-E<gt>B<new> ();
83 Creates and returns a new object.
85 =cut
87 sub new
88 {
89 my $pkg = shift;
90 my $ping_obj = _ping_construct ();
92 my $obj = bless ({ c_obj => $ping_obj }, $pkg);
93 return ($obj);
94 }
96 sub DESTROY
97 {
98 my $obj = shift;
99 _ping_destroy ($obj->{'c_obj'});
100 }
102 =item my I<$status> = I<$obj>-E<gt>B<timeout> (I<$timeout>);
104 Sets the timeout before a host is considered unreachable to I<$timeout>
105 seconds, which may be a floating point number to specify fractional seconds.
107 =cut
109 sub timeout
110 {
111 my $obj = shift;
112 my $timeout = shift;
113 my $status;
115 $status = _ping_setopt_timeout ($obj->{'c_obj'}, $timeout);
116 if ($status != 0)
117 {
118 $obj->{'err_msg'} = "" . _ping_get_error ($obj->{'c_obj'});
119 return;
120 }
122 return (1);
123 }
125 =item my I<$status> = I<$obj>-E<gt>B<bind> (I<$ip_addr>);
127 Sets the source IP-address to use. I<$ip_addr> must be a string containing an
128 IP-address, such as "192.168.0.1" or "2001:f00::1". As a side-effect this will
129 set the address-family (IPv4 or IPv6) to a fixed, value, too, for obvious
130 reasons.
132 =cut
134 sub bind
135 {
136 my $obj = shift;
137 my $addr = shift;
138 my $status;
140 $status = _ping_setopt_source ($obj->{'c_obj'}, $addr);
141 if ($status != 0)
142 {
143 $obj->{'err_msg'} = "" . _ping_get_error ($obj->{'c_obj'});
144 return;
145 }
147 return (1);
148 }
150 =item my I<$status> = I<$obj>-E<gt>B<host_add> (I<$host>, [I<$host>, ...]);
152 Adds one or more hosts to the Net::Oping-object I<$obj>. The number of
153 successfully added hosts is returned. If this number differs from the number of
154 hosts that were passed to the method you can use B<get_error> (see below) to
155 get the error message of the last failure.
157 =cut
159 sub host_add
160 {
161 my $obj = shift;
162 my $i;
164 $i = 0;
165 for (@_)
166 {
167 my $status = _ping_host_add ($obj->{'c_obj'}, $_);
168 if ($status != 0)
169 {
170 $obj->{'err_msg'} = "" . _ping_get_error ($obj->{'c_obj'});
171 }
172 else
173 {
174 $i++;
175 }
176 }
178 return ($i);
179 }
181 =item my I<$status> = I<$obj>-E<gt>B<host_remove> (I<$host>, [I<$host>, ...]);
183 Same semantic as B<host_add> but removes hosts.
185 =cut
187 sub host_remove
188 {
189 my $obj = shift;
190 my $i;
192 $i = 0;
193 for (@_)
194 {
195 my $status = _ping_host_remove ($obj->{'c_obj'}, $_);
196 if ($status != 0)
197 {
198 $obj->{'err_msg'} = "" . _ping_get_error ($obj->{'c_obj'});
199 }
200 else
201 {
202 $i++;
203 }
204 }
205 return ($i);
206 }
208 =item my I<$latency> = I<$obj>-E<gt>B<ping> ()
210 The central method of this module sends ICMP packets to the hosts and waits for
211 replies. The time it takes for replies to arrive is measured and returned.
213 The returned scalar is a hash reference where each host associated with the
214 I<$obj> object is a key and the associated value is the corresponding latency
215 in milliseconds. An example hash reference would be:
217 $latency = { host1 => 51.143, host2 => undef, host3 => 54.697, ... };
219 If a value is C<undef>, as for "host2" in this example, the host has timed out
220 and considered unreachable.
222 =cut
224 sub ping
225 {
226 my $obj = shift;
227 my $iter;
228 my $data = {};
229 my $status;
231 $status = _ping_send ($obj->{'c_obj'});
232 if ($status < 0)
233 {
234 print "\$status = $status;\n";
235 $obj->{'err_msg'} = "" . _ping_get_error ($obj->{'c_obj'});
236 return;
237 }
239 $iter = _ping_iterator_get ($obj->{'c_obj'});
240 while ($iter)
241 {
242 my $host = _ping_iterator_get_hostname ($iter);
243 if (!$host)
244 {
245 $iter = _ping_iterator_next ($iter);
246 next;
247 }
249 my $latency = _ping_iterator_get_latency ($iter);
250 if ($latency < 0.0)
251 {
252 $latency = undef;
253 }
255 $data->{$host} = $latency;
257 $iter = _ping_iterator_next ($iter);
258 }
260 return ($data);
261 }
263 =item my I<$errmsg> = I<$obj>-E<gt>B<get_error> ();
265 Returns the last error that occurred.
267 =cut
269 sub get_error
270 {
271 my $obj = shift;
272 return ($obj->{'err_msg'} || 'Success');
273 }
275 =back
277 =head1 CAVEATS
279 The I<oping> library opens a raw socket to be able to send ICMP packets. On
280 most systems normal users are not allowed to do this. This is why on most
281 systems the L<ping(1)> utility is installed as SetUID-root. Since, when using
282 this module, no external process is spawned B<this> process needs the
283 appropriate permissions. This means that either your script has to run as
284 superuser or, under Linux, needs the C<CAP_NET_RAW> capability.
286 =head1 SEE ALSO
288 L<liboping(3)>
290 The I<liboping> homepage may be found at L<http://verplant.org/liboping/>.
291 Information about its mailing list may be found at
292 L<http://mailman.verplant.org/listinfo/liboping>.
294 =head1 AUTHOR
296 First XSE<nbsp>port by Olivier Fredj, extended XS functionality and high-level
297 Perl interface by Florian Forster.
299 =head1 COPYRIGHT AND LICENSE
301 Copyright (C) 2007 by Olivier Fredj E<lt>ofredjE<nbsp>atE<nbsp>proxad.netE<gt>
303 Copyright (C) 2008,2009 by Florian Forster
304 E<lt>octoE<nbsp>atE<nbsp>verplant.orgE<gt>
306 This library is free software; you can redistribute it and/or modify
307 it under the same terms as Perl itself, either Perl version 5.8.7 or,
308 at your option, any later version of Perl 5 you may have available.
310 Please note that I<liboping> is licensed under the GPLv2. Derived works of
311 both, I<Net::Oping> and I<liboping>, (i.E<nbsp>e. binary packages) may
312 therefore be subject to stricter licensing terms than the source code of this
313 package.
315 =cut
317 # vim: set shiftwidth=2 softtabstop=2 tabstop=8 :