src/tools/sysdb/scanner.l

   1 /*
   2  * SysDB - src/tools/sysdb/scanner.l
   3  * Copyright (C) 2013 Sebastian 'tokkee' Harl <sh@tokkee.org>
   4  * All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  *
  15  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  16  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  17  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  18  * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
  19  * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  20  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  21  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  22  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  23  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  24  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  25  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26  */
  27
  28 %{
  29
  30 /*
  31  * This is a simplified version of frontend/scanner.l. The only purpose is to
  32  * find queries (terminated by semicolon).
  33  */
  34
  35 #if HAVE_CONFIG_H
  36 #       include "config.h"
  37 #endif /* HAVE_CONFIG_H */
  38
  39 #include "tools/sysdb/input.h"
  40
  41 #include <string.h>
  42
  43 #ifdef YY_INPUT
  44 #       undef YY_INPUT
  45 #endif
  46 #define YY_INPUT(buf, result, max_size) \
  47         sdb_input_readline((buf), (size_t *)&(result), (max_size))
  48
  49 #define APPEND() \
  50         do { \
  51                 if (! isspace((int)yytext[0])) \
  52                         sysdb_input->have_input = 1; \
  53                 sysdb_input->query_len += strlen(yytext); \
  54         } while (0)
  55
  56 %}
  57
  58 %option interactive
  59 %option 8bit
  60 %option yylineno
  61 %option nodefault
  62 %option noyywrap
  63 %option verbose
  64 %option warn
  65
  66 %x CSC
  67
  68 newline                 (\n|\r\n)
  69 simple_comment  ("--"[^\n\r]*)
  70
  71 /*
  72  * C style comments
  73  */
  74 csc_start       \/\*
  75 csc_inside      ([^*/]+|[^*]\/|\*[^/])
  76 csc_end         \*\/
  77
  78 /*
  79  * Strings.
  80  */
  81 /* TODO: fully support SQL strings */
  82 string          ('([^']|'')*')
  83
  84 %%
  85
  86         /*
  87          * Here, we only care about syntax elements that may include semicolons
  88          * and escape their meaning as a query terminator.
  89          */
  90
  91 {simple_comment}        { APPEND(); }
  92
  93 {csc_start}                     { APPEND(); BEGIN(CSC); }
  94 <CSC>{csc_inside}       { APPEND(); }
  95 <CSC>{csc_end}          { APPEND(); BEGIN(INITIAL); }
  96 <CSC><<EOF>>            { return -1; }
  97
  98 {string}                        { APPEND(); }
  99
 100         /*
 101          * The following rules are specific to the command line tool.
 102          */
 103
 104 ";\n"           { APPEND(); sdb_input_exec_query(); }
 105 ";"                     { APPEND(); sdb_input_exec_query(); }
 106
 107 {newline}       {
 108                                 APPEND();
 109                                 if (! sysdb_input->have_input)
 110                                         /* give the input module a chance to do stuff on empty lines */
 111                                         sdb_input_exec_query();
 112                         }
 113
 114 .                       { APPEND(); }
 115
 116 %%
 117
 118 /* vim: set tw=78 sw=4 ts=4 noexpandtab : */
 119