configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.8])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4008
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=6:1:2
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 106
 107 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 108 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 109
 110 if test $enable_rrd_graph != no; then
 111  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 112 fi
 113
 114 dnl Check if we run on a system that has fonts
 115 AC_ARG_WITH(rrd-default-font,
 116 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 117 [RRD_DEFAULT_FONT=$withval],[
 118   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 119         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 120   else
 121         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 122   fi
 123 ])
 124
 125 dnl Use mmap in rrd_update instead of seek+write
 126 AC_ARG_ENABLE([mmap],
 127 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 128 [],
 129 [enable_mmap=yes])
 130
 131 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 132 [],[enable_pthread=yes])
 133
 134 AC_ARG_ENABLE(static-programs,
 135      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 136      [case "${enableval}" in
 137        yes) staticprogs=yes ;;
 138        no)  staticprogs=no ;;
 139        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 140      esac],[staticprogs=no])
 141 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 142
 143
 144 CONFIGURE_PART(Audit Compilation Environment)
 145
 146
 147 dnl Check for the compiler and static/shared library creation.
 148 AC_PROG_CPP
 149 AC_PROG_CC
 150 AM_PROG_CC_C_O
 151 AC_PROG_LIBTOOL
 152
 153 dnl Try to detect/use GNU features
 154 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 155
 156 dnl check for -Werror separatly
 157 dnl (quite a few autotool checks do not work with -Werror; also, the
 158 dnl check for -Werror fails after checking and adding the other flags)
 159 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 160   [AC_COMPILE_IFELSE(
 161     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 162     [rd_cv_gcc_flag__Werror="yes"],
 163     [rd_cv_gcc_flag__Werror="no"])])
 164 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 165   WERROR="-Werror"
 166 else
 167   WERROR=""
 168 fi
 169 AC_SUBST(WERROR)
 170
 171 dnl which flags does the compiler support?
 172 if test "x$GCC" = "xyes"; then
 173   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 174     oCFLAGS="$CFLAGS"
 175     CFLAGS="$CFLAGS $flag"
 176     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 177     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 178        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 179     if eval test \$$cachename = no; then
 180          CFLAGS="$oCFLAGS"
 181     fi
 182   done
 183 fi
 184
 185
 186
 187 AC_SUBST(RRD_DEFAULT_FONT)
 188
 189 CONFIGURE_PART(Checking for Header Files)
 190
 191 dnl Checks for header files.
 192 AC_HEADER_STDC
 193 AC_HEADER_DIRENT
 194 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 195
 196 dnl Checks for typedefs, structures, and compiler characteristics.
 197 AC_C_CONST
 198 AC_HEADER_TIME
 199 AC_STRUCT_TM
 200
 201 CONFIGURE_PART(Test Library Functions)
 202
 203 dnl Checks for libraries.
 204 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 205
 206
 207 dnl add pic flag in any case this makes sure all our code is relocatable
 208 eval `./libtool --config | grep pic_flag=`
 209 CFLAGS="$CFLAGS $pic_flag"
 210
 211
 212 dnl Checks for library functions.
 213 AC_FUNC_STRFTIME
 214 AC_FUNC_VPRINTF
 215
 216 AC_C_BIGENDIAN
 217
 218 dnl for each function found we get a definition in config.h
 219 dnl of the form HAVE_FUNCTION
 220
 221 AC_CHECK_FUNCS(nl_langinfo tzset round rint fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 222
 223 AC_FUNC_STRERROR_R
 224
 225 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 226
 227 dnl Could use these to know if we need to provide a prototype
 228 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 229
 230 dnl check for fdatasync. Solaris has fdatasync in the librt
 231
 232 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 233 dnl if there is no fdatasync we may get lucky with fsync
 234 AC_CHECK_FUNCS(fsync)
 235
 236 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 237
 238 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 239 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 240
 241
 242
 243 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 244 if test "x$enable_mmap" = "xyes"; then
 245   case "$host" in
 246   *cygwin*)
 247     # the normal mmap test does not work in cygwin
 248     AC_CHECK_FUNCS(mmap)
 249     if test "x$ac_cv_func_mmap" = "xyes"; then
 250       ac_cv_func_mmap_fixed_mapped=yes
 251     fi
 252   ;;
 253   *)
 254     AC_CHECK_HEADERS(sys/mman.h)
 255     AC_FUNC_MMAP
 256     AC_CHECK_FUNCS(mmap munmap msync)
 257     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 258                                      # include <sys/mman.h>
 259                                      #endif])
 260     if test "x$ac_cv_have_decl_madvise" = "xyes";
 261     then
 262       AC_CHECK_FUNCS(madvise)
 263     else
 264       AC_CHECK_FUNCS(posix_madvise)
 265       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 266         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 267       fi
 268     fi
 269   ;;
 270   esac
 271   if test "x$ac_cv_func_mmap" != "xyes";
 272   then
 273     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 274 dnl enable_mmap="no"
 275   fi
 276 fi
 277
 278 dnl can we use posix_fadvise
 279 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 280 #include <fcntl.h>])
 281 AC_CHECK_FUNCS(posix_fadvise)
 282
 283 dnl can we use posix_fallocate
 284 AC_CHECK_FUNCS(posix_fallocate)
 285
 286 CONFIGURE_PART(Libintl Processing)
 287
 288 AM_GNU_GETTEXT_VERSION(0.17)
 289 AM_GNU_GETTEXT(external)
 290
 291 CONFIGURE_PART(IEEE Math Checks)
 292
 293
 294 dnl actual code to check if this works
 295 AC_CHECK_FUNCS(fpclassify, ,
 296   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 297     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 298 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 299       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 300
 301 AC_CHECK_FUNCS(isinf, ,
 302   [AC_MSG_CHECKING(for isinf with <math.h>)
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 304 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 305       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 306
 307 dnl finite is BSD, isfinite is C99, so prefer the latter
 308 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 309 AC_TRY_RUN([
 310 #ifdef HAVE_MATH_H
 311 #include <math.h>
 312 #endif
 313 #ifdef HAVE_FLOAT_H
 314 #include <float.h>
 315 #endif
 316 int main ()
 317 {
 318 #ifdef isfinite
 319 #ifdef LDBL_MAX
 320   if (!isfinite(LDBL_MAX)) return 1;
 321 #endif
 322 #ifdef DBL_MAX
 323   if (!isfinite(DBL_MAX)) return 1;
 324 #endif
 325 #endif
 326 return 0;
 327 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 328 case "${target}" in
 329   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 330   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 331   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 332   *) ac_cv_have_broken_isfinite=no ;;
 333 esac])
 334 ])
 335
 336 dnl the test does not seem to work on solaris 2.8
 337 dnl so lets fix this by hand
 338 case "${target}" in
 339   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 340   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 341 esac
 342
 343 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 344   AC_DEFINE(HAVE_ISFINITE)
 345 else
 346   AC_CHECK_FUNCS(finite,[],
 347       [AC_CHECK_FUNCS(isfinite,[],
 348          [AC_MSG_CHECKING(for isfinite with <math.h>)
 349           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 350 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 351                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 352 fi
 353
 354 AC_FULL_IEEE
 355
 356 CONFIGURE_PART(Resolve Portability Issues)
 357
 358 GC_TIMEZONE()
 359
 360 CHECK_FOR_WORKING_MS_ASYNC
 361
 362 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 363 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 364   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 365     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 366       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 367
 368 dnl Do we need getopt_long
 369
 370 dnl even when including our own getopt implementation
 371 dnl we may want to make sure we use the external
 372 dnl defined by libc to not run into linker resolve trouble
 373
 374 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 375 [AC_TRY_LINK([#include <unistd.h>],
 376   [extern int opterr; opterr = 1;],
 377   [rd_cv_var_int_opterr=yes],
 378   [rd_cv_var_int_opterr=no])])
 379 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 380   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 381 fi
 382
 383 build_getopt=no
 384 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 385 AC_CHECK_FUNC(getopt_long,[],[
 386 RRD_GETOPT_LONG="getopt_long"
 387 build_getopt=yes
 388 ])
 389 AC_SUBST(RRD_GETOPT_LONG)
 390 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 391
 392 dnl what does realloc do if it gets called with a NULL pointer
 393
 394 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 395 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 396               int main(void){
 397               char *x = NULL;
 398               x = realloc (x,10);
 399               if (x==NULL) return 1;
 400               return 0;
 401              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 402
 403 if test x"$rd_cv_null_realloc" = xnope; then
 404 AC_DEFINE(NO_NULL_REALLOC)
 405 fi
 406
 407 AC_LANG_PUSH(C)
 408 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 409 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 410 AC_LINK_IFELSE(
 411     AC_LANG_PROGRAM(
 412            [[#include <time.h>]],
 413            [[ctime_r(NULL,NULL,0)]]
 414                    ),
 415     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 416       AC_LINK_IFELSE(
 417           AC_LANG_PROGRAM(
 418                 [[#include <time.h>]],
 419                 [[ctime_r(NULL,NULL)]]
 420                          ),
 421           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 422           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 423       )
 424     ],
 425     [ AC_LINK_IFELSE(
 426           AC_LANG_PROGRAM(
 427                 [[#include <time.h>]],
 428                 [[ctime_r(NULL,NULL)]]
 429                          ),
 430           [AC_MSG_RESULT(no)],
 431           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 432       )
 433     ]
 434 )
 435 AC_LANG_POP(C)
 436
 437 dnl Check for pthreads
 438 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 439
 440 AC_SUBST(MULTITHREAD_CFLAGS)
 441 AC_SUBST(MULTITHREAD_LDFLAGS)
 442
 443 if test $enable_pthread != no; then
 444  ACX_PTHREAD([
 445     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 446     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 447              ],
 448              [])
 449 fi
 450
 451 dnl since we use lots of *_r functions all over the code we better
 452 dnl make sure they are known
 453
 454 if test  "x$x_rflag" != "xno"; then
 455    CPPFLAGS="$CPPFLAGS $x_rflag"
 456 fi
 457
 458 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 459
 460 AC_LANG_PUSH(C)
 461 dnl see if we have to include malloc/malloc.h
 462 AC_MSG_CHECKING([do we need malloc/malloc.h])
 463 AC_LINK_IFELSE(
 464     AC_LANG_PROGRAM(
 465            [[#include <stdlib.h>]],
 466            [[malloc(1)]]
 467                    ),
 468     [ AC_MSG_RESULT([nope, works out of the box]) ],
 469     [ AC_LINK_IFELSE(
 470           AC_LANG_PROGRAM(
 471                 [[#include <stdlib.h>
 472                   #include <malloc/malloc.h>]],
 473                 [[malloc(1)]]
 474                          ),[
 475            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 476            AC_MSG_RESULT([yes we do])],
 477           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 478       )
 479     ]
 480 )
 481 AC_LANG_POP(C)
 482
 483 dnl is time_t 32 of 64 bit ?
 484 AC_CHECK_SIZEOF([time_t])
 485
 486 CONFIGURE_PART(Find 3rd-Party Libraries)
 487
 488 have_libdbi=no
 489
 490 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[],[
 491     AC_CHECK_HEADER(dbi/dbi.h, [
 492        AC_CHECK_LIB(dbi, dbi_initialize, [
 493            AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 494            LIBS="${LIBS} -ldbi -ldl"
 495            have_libdbi=yes
 496        ])
 497     ])
 498 ])
 499
 500 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 501
 502 have_libwrap=no
 503
 504 AC_ARG_ENABLE(libwrap, AS_HELP_STRING([--disable-libwrap], [do not build in support for libwrap (tcp wrapper)]),[],[
 505     AC_CHECK_HEADER(tcpd.h,[
 506         AC_CHECK_FUNCS(hosts_access, [
 507             AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 508             have_libwrap=yes
 509         ],
 510         [
 511             AC_CHECK_LIB(wrap, hosts_access, [
 512                AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 513                LIBS="${LIBS} -lwrap"
 514                have_libwrap=yes
 515             ])
 516         ])
 517     ])
 518 ])
 519
 520
 521 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 522
 523 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 524
 525
 526 CORE_LIBS="$LIBS"
 527
 528 if test $enable_rrd_graph != no; then
 529 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.5,  http://zlib.net/, "")
 530 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.4.8,  ftp://ftp.simplesystems.org/pub/libpng/png/src/, "")
 531 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.4.6,  http://download.savannah.gnu.org/releases/freetype/, /usr/include/freetype2)
 532 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.8.0,  http://www.freedesktop.org/software/fontconfig/release/, /usr/include)
 533 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.10.2,  http://cairographics.org/releases/, "")
 534 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.10.2,  http://cairographics.org/releases/, "")
 535 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.10.2,  http://cairographics.org/releases/, "")
 536 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.10.2,  http://cairographics.org/releases/, "")
 537 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.28.4,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.28, "")
 538
 539 fi
 540 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.28.7, ftp://ftp.gtk.org/pub/glib/2.28/, "")
 541 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.7.8,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 542
 543 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 544   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 545 fi
 546
 547 ALL_LIBS="$LIBS"
 548 LIBS=
 549
 550 AC_SUBST(CORE_LIBS)
 551 AC_SUBST(ALL_LIBS)
 552
 553 CONFIGURE_PART(Prep for Building Language Bindings)
 554
 555 dnl Check for Perl and friends
 556 PATH=$PATH:/usr/perl5/bin
 557 export PATH
 558 AC_PATH_PROG(PERL, perl, no)
 559 AC_PATH_PROG(POD2MAN, pod2man, no)
 560 AC_PATH_PROG(POD2HTML, pod2html, no)
 561
 562
 563 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 564 [],[enable_perl=yes])
 565
 566
 567 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 568 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 569 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 570 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 571
 572 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 573         COMP_PERL=
 574 else
 575         COMP_PERL="perl_piped perl_shared"
 576         AC_MSG_CHECKING(for the perl version you are running)
 577         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 578         AC_MSG_RESULT($PERL_VERSION)
 579         if test -z "$PERLCC"; then
 580             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 581             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 582             AC_MSG_RESULT($perlcc)
 583             if test ! -x "$perlcc"; then
 584                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 585                 if test "$PERL_CC" = "no"; then
 586                     AC_MSG_WARN([
 587 I would not find the Compiler ($perlcc) that was originally used to compile
 588 your perl binary. You should either make sure that this compiler is
 589 available on your system, pick an other compiler and set PERLCC
 590 appropriately, or use a different perl setup that was compiled locally.
 591
 592 I will disable the compilation of the RRDs perl module for now.
 593 ])
 594                     COMP_PERL="perl_piped"
 595                 fi
 596             fi
 597         fi
 598 fi
 599
 600 AC_MSG_CHECKING(Perl Modules to build)
 601 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 602
 603 # Options to pass when configuring perl module
 604 langpref=$prefix
 605 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 606 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 607
 608 PERL_MAKE_OPTIONS="PREFIX=$langpref INSTALL_BASE= LIB=$langpref/lib/perl/$PERL_VERSION"
 609
 610 dnl pass additional perl options when generating Makefile from Makefile.PL
 611 AC_ARG_ENABLE(perl-site-install,
 612 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 613 [PERL_MAKE_OPTIONS=],[])
 614
 615 if test ! -z "$PERLCC"; then
 616    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 617
 618    if test ! -z "$PERLCCFLAGS"; then
 619        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 620    fi
 621
 622    if test -z "$PERLLD"; then
 623        PERLLD=$PERLCC
 624    fi
 625    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 626
 627    if test ! -z "$PERLLDFLAGS"; then
 628        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 629    fi
 630 fi
 631
 632 AC_ARG_WITH(perl-options,
 633 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 634                           generating Makefile from Makefile.PL. If you set this
 635                           option, interesting things may happen unless you know
 636                           what you are doing!],
 637 [PERL_MAKE_OPTIONS=$withval])
 638
 639 AC_SUBST(PERL_MAKE_OPTIONS)
 640 AC_SUBST(PERL)
 641 AC_SUBST(COMP_PERL)
 642 AC_SUBST(PERL_VERSION)
 643
 644 dnl Check for Ruby.
 645 AC_PATH_PROG(RUBY, ruby, no)
 646
 647 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 648 [],[enable_ruby=yes])
 649
 650 AC_MSG_CHECKING(if ruby modules can be built)
 651
 652 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 653         COMP_RUBY=
 654         AC_MSG_RESULT(No .. Ruby not found or disabled)
 655 else
 656         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 657                 COMP_RUBY="ruby"
 658                 AC_MSG_RESULT(YES)
 659         else
 660                 COMP_RUBY=
 661                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 662         fi
 663 fi
 664
 665 dnl pass additional ruby options when generating Makefile from Makefile.PL
 666 AC_ARG_ENABLE(ruby-site-install,
 667 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 668 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 669
 670
 671 AC_ARG_WITH(ruby-options,
 672 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 673                           generating Makefile from extconf.rb. If you set this
 674                           option, interesting things may happen unless you know
 675                           what you are doing!],
 676 [RUBY_MAKE_OPTIONS=$withval])
 677
 678 AC_SUBST(RUBY_MAKE_OPTIONS)
 679 AC_SUBST(RUBY)
 680 AC_SUBST(COMP_RUBY)
 681
 682 dnl Check for Lua.
 683 AC_PATH_PROG(LUA, lua, no)
 684
 685 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 686 [],[enable_lua=yes])
 687
 688 COMP_LUA=
 689 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 690   enable_lua=no
 691 else
 692   AC_MSG_CHECKING(for lua >= 5.0)
 693   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 694     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 695 LUA_EOF
 696   if test 0$LUA_MAJOR -lt 5; then
 697     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 698   else
 699     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 700     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 701     lua_vndot=$LUA_MAJOR$LUA_MINOR
 702     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 703     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 704       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 705         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 706           [lua_headerdir=lua$lua_vndot],
 707           [])],
 708         [])],
 709       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 710         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 711           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 712             [lua_headerdir=lua$lua_vdot],
 713             [])],
 714           [])],
 715         [AC_CHECK_HEADERS(lua.h,
 716           [AC_CHECK_HEADERS(lualib.h,
 717             [AC_CHECK_HEADER(lauxlib.h,
 718               [lua_headerdir=""],
 719               [lua_headerdir="no"])],
 720             [])],
 721           [])])])
 722
 723     if test "$lua_headerdir" = "no"; then
 724       enable_lua=no
 725     else
 726       COMP_LUA=lua
 727     fi
 728
 729     if test "$COMP_LUA" != "lua"; then
 730       enable_lua=no
 731       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 732     else
 733       # OK, headers found, let's check the libraries (LIBS is not used)
 734       LIBS=
 735       lua_havelib=no
 736       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 737       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 738         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 739           [lua_havelib=LUA$lua_vndot],
 740           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 741             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 742              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 743             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 744               [lua_havelib=$lua_vndot],
 745               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 746         [COMP_LUA=], [-lm])
 747       lua_libs=$LIBS
 748       LIBS=
 749
 750       # Options to pass when configuring Lua module
 751       if test  "$lua_havelib" != "no"; then
 752         # OK, headers and libs found. Try to set lua flags
 753         # and modules installation dirs with pkg-config
 754         if test "$PKGCONFIG" != "no"; then
 755           if test "$lua_vndot" = "50"; then
 756             lua_pkg_prefix=lualib
 757           else
 758             lua_pkg_prefix=lua
 759           fi
 760           # try with dot, without dot and finally without version
 761           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 762             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 763             # same binaries?
 764             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 765                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 766                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 767                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 768                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 769                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 770                 break
 771             fi
 772           done
 773         fi
 774
 775         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 776         # if lua 5.0 can't find compat-5.1, force installation of
 777         # compat-5.1.lua together with RRDtool.
 778         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 779           lua_need_compat51=1
 780           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 781         fi
 782
 783         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 784         if test "$LUA_CFLAGS" = ""; then
 785           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 786           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 787           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 788           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 789         fi
 790
 791         dnl pass additional lua options
 792         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 793         dnl found and install together with RRDtool, under $langpref.
 794         AC_ARG_ENABLE(lua-site-install,
 795         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 796         [],
 797         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 798
 799         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 800         AC_SUBST(LUA)
 801         AC_SUBST(COMP_LUA)
 802         AC_SUBST(LUA_INSTALL_CMOD)
 803         AC_SUBST(LUA_INSTALL_LMOD)
 804         AC_SUBST(LUA_CFLAGS)
 805         AC_SUBST(LUA_LFLAGS)
 806         AC_SUBST(LUA_DEFINES)
 807       else
 808         enable_lua=no
 809         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 810       fi
 811     fi
 812   fi
 813 fi
 814 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 815 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 816 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 817       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 818 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 819 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 820 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 821 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 822
 823 enable_tcl_site=no
 824
 825 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 826 [],[enable_tcl=yes])
 827
 828 if test  "$enable_tcl" = "yes"; then
 829   dnl Check for Tcl.
 830   withval=""
 831   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 832   enable_tcl=no
 833   for dir in $withval /usr/lib /usr/lib64 /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 834     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 835     if test -f "$dir/tclConfig.sh" ; then
 836         tcl_config=$dir/tclConfig.sh
 837         enable_tcl=yes
 838         AC_MSG_RESULT(yes)
 839         break
 840     else
 841         AC_MSG_RESULT(no)
 842     fi
 843   done
 844
 845   if test "$enable_tcl" = "no"; then
 846         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 847   else
 848         . $tcl_config
 849         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 850         if test -n "$TCL_INC_DIR"; then
 851           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 852         fi
 853   fi
 854   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 855   [],[enable_tcl_site=yes])
 856
 857 fi
 858
 859 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 860 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 861
 862
 863 AC_SUBST(TCL_PREFIX)
 864 AC_SUBST(TCL_SHLIB_CFLAGS)
 865 AC_SUBST(TCL_SHLIB_LD)
 866 AC_SUBST(TCL_SHLIB_SUFFIX)
 867 AC_SUBST(TCL_PACKAGE_PATH)
 868 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 869 AC_SUBST(TCL_STUB_LIB_SPEC)
 870 AC_SUBST(TCL_VERSION)
 871 AC_SUBST(TCL_PACKAGE_DIR)
 872 AC_SUBST(TCL_INCLUDE_SPEC)
 873
 874 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 875 [],[enable_python=yes])
 876
 877 if test  "$enable_python" = "yes"; then
 878 dnl Check for python
 879 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 880 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 881 fi
 882
 883 if test  x$enable_python = xno; then
 884         COMP_PYTHON=
 885 else
 886         COMP_PYTHON="python"
 887 fi
 888
 889 AC_SUBST(COMP_PYTHON)
 890
 891 dnl Check for nroff
 892 AC_ARG_VAR(NROFF, [path to the local nroff version])
 893 AC_PATH_PROGS(NROFF, [gnroff nroff])
 894 if test x$NROFF = x; then
 895   AC_MSG_ERROR([I need a copy of *nroff to format the documentation])
 896 fi
 897 AC_ARG_VAR(TROFF, [path to the local troff version])
 898 AC_PATH_PROGS(TROFF, [groff troff])
 899 if test x$TROFF = x; then
 900   AC_MSG_ERROR([I need a copy of *troff to format the documentation])
 901 fi
 902
 903 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 904 if test -z "$RRDDOCDIR"; then
 905    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 906
 907
 908 CONFIGURE_PART(Apply Configuration Information)
 909
 910 AC_CONFIG_FILES([examples/shared-demo.pl])
 911 AC_CONFIG_FILES([examples/piped-demo.pl])
 912 AC_CONFIG_FILES([examples/stripes.pl])
 913 AC_CONFIG_FILES([examples/bigtops.pl])
 914 AC_CONFIG_FILES([examples/minmax.pl])
 915 AC_CONFIG_FILES([examples/4charts.pl])
 916 AC_CONFIG_FILES([examples/perftest.pl])
 917 AC_CONFIG_FILES([examples/Makefile])
 918 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 919 AC_CONFIG_FILES([doc/Makefile])
 920 AC_CONFIG_FILES([po/Makefile.in])
 921 AC_CONFIG_FILES([src/Makefile])
 922 AC_CONFIG_FILES([src/librrd.sym.in])
 923 AC_CONFIG_FILES([src/librrd.pc])
 924 AC_CONFIG_FILES([bindings/Makefile])
 925 AC_CONFIG_FILES([bindings/tcl/Makefile])
 926 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 927 AC_CONFIG_FILES([Makefile])
 928 AC_CONFIG_FILES([bindings/lua/Makefile])
 929
 930 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 931
 932 dnl intl requires our config to be called config.h. indulge it.
 933 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 934
 935 AC_OUTPUT
 936
 937 AC_MSG_CHECKING(in)
 938 AC_MSG_RESULT(and out again)
 939
 940 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 941 sleep 1
 942 echo $ECHO_N ".$ECHO_C" 1>&6
 943 sleep 1
 944 echo $ECHO_N ".$ECHO_C" 1>&6
 945 sleep 1
 946 echo $ECHO_N ".$ECHO_C" 1>&6
 947 sleep 1
 948 echo $ECHO_N ".$ECHO_C" 1>&6
 949 sleep 1
 950 AC_MSG_RESULT([ just kidding ;-)])
 951 echo
 952 echo "----------------------------------------------------------------"
 953 echo "Config is DONE!"
 954 echo
 955 echo "          With MMAP IO: $enable_mmap"
 956 echo "      Build rrd_getopt: $build_getopt"
 957 echo "       Build rrd_graph: $enable_rrd_graph"
 958 echo "       Static programs: $staticprogs"
 959 echo "          Perl Modules: $COMP_PERL"
 960 echo "           Perl Binary: $PERL"
 961 echo "          Perl Version: $PERL_VERSION"
 962 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 963 echo "          Ruby Modules: $COMP_RUBY"
 964 echo "           Ruby Binary: $RUBY"
 965 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 966 echo "    Build Lua Bindings: $enable_lua"
 967 if test "$enable_lua" = "yes"; then
 968 echo "            Lua Binary: $LUA"
 969 echo "           Lua Version: $lua_version"
 970 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 971 if test "$lua_need_compat51" = "1"; then
 972 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 973 fi
 974 fi
 975 echo "    Build Tcl Bindings: $enable_tcl"
 976 echo " Build Python Bindings: $enable_python"
 977 echo "          Build rrdcgi: $enable_rrdcgi"
 978 echo "       Build librrd MT: $enable_pthread"
 979 echo "           Use gettext: $USE_NLS"
 980 echo "           With libDBI: $have_libdbi"
 981 echo "          With libwrap: $have_libwrap"
 982 echo
 983 echo "             Libraries: $ALL_LIBS"
 984 echo
 985 echo "Type 'make' to compile the software and use 'make install' to "
 986 echo "install everything to: $prefix."
 987 echo
 988 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 989 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 990 echo "place an order."
 991 echo
 992 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 993 echo "----------------------------------------------------------------"