Big autotool update:

* Upgraded to the latest version of autoconf, automake and libtool

* replaced pthread detection code in configure with a more effective one

* added a test to see if special solaris defines
  are required for ctime_r to behave posixly correct.

* Fixed lots of warnings from autotools

* started adding support for pkg-config ... this will eventually
  make the whole library finding much simpler

git-svn-id: svn://svn.oetiker.ch/rrdtool/trunk@305 a5681a0c-68f1-0310-ab6d-d61299d08faa

diff --git a/program/MakeMakefile b/program/MakeMakefile
index 6397703e9f7660dd5194118247cbab2ce22d7b1f..4aba88c6fcd3d98a9290ec1c17bb0f819aba2f9e 100755 (executable)
--- a/program/MakeMakefile
+++ b/program/MakeMakefile
@@ -15,45 +15,31 @@ PERL
 
 ERROR=0
 
-if vcheck 1.5 "libtool --version"
+if vcheck 1.5.14 "libtool --version"
 then
-  echo "get a copy of GNU libtool >= 1.5"
+  echo "get a copy of GNU libtool >= 1.5.14"
   ERROR=1
 fi
 
-#if vcheck 1.8.2  "automake  --version"
-#then
-#  if vcheck 1.8.2  "automake-1.8 --version"
-#  then
-#    echo "get a copy of GNU automake >= 1.8.2"
-#    exit 1
-#  else
-#    automake=automake-1.8
-#    aclocal="aclocal-1.8  --acdir=/usr/share/aclocal-1.8 -I /usr/share/aclocal/"
-#  fi
-#else
-#    automake="automake"
-#    aclocal="aclocal  -I /usr/pack/libtool-1.5-to/share/aclocal"
-#fi
-
-if vcheck 1.7.9  "automake  --version"
+if vcheck 1.9.5  "automake  --version"
 then
-  if vcheck 1.7.9  "automake-1.7 --version"
+  if vcheck 1.9.5  "automake-1.9 --version"
   then
-    echo "get a copy of GNU automake >= 1.79"
+    echo "get a copy of GNU automake >= 1.9.5"
     ERROR=1
   else
-    automake=automake-1.7
-    aclocal="aclocal-1.7  --acdir=/usr/share/aclocal-1.7 -I /usr/share/aclocal/"
+    automake=automake-1.9
+    aclocal="aclocal-1.9  --acdir=/usr/share/aclocal-1.9 -I /usr/share/aclocal/"
   fi
 else
     automake="automake"
-    aclocal="aclocal -I /usr/pack/libtool-1.5-to/share/aclocal"
+    aclocal="aclocal"
+#    aclocal="aclocal -I /usr/pack/libtool-1.5.14-to/share/aclocal"
 fi
 
-if vcheck 2.58 "autoconf --version"
+if vcheck 2.59 "autoconf --version"
 then
-  echo "get a copy of GNU autoconf >= 2.58"
+  echo "get a copy of GNU autoconf >= 2.59"
   ERROR=1
 fi
 
@@ -62,25 +48,17 @@ then
   exit 1
 fi
 
+# cleanup
 set -x
-find . -name Makefile | xargs rm -f
+find . -name Makefile | xargs rm -f _UNKNONW_
 find . -name "*.la" | xargs rm -f
-find . -name Makefile.in | xargs rm -f
-find . -name .libs | xargs rm -r
+find . -name Makefile.in | xargs rm -f _UNKNONW_
+find . -name .libs | xargs rm -r 
 find . -name .debs | xargs rm -r
 
-
-# wget ftp://ftp.gnu.org/gnu/libtool/libtool-1.5.tar.gz
 libtoolize --copy --force
-#cp ltmain.sh config
-
-# wget ftp://sources.redhat.com/pub/automake/automake-1.7.9.tar.gz
-# If autoconf generates undefined MACRO errors, it may be unable
-# to find libtool.m4. Add the -I flag to aclocal to specify the
-# directory location of this file.
 $aclocal
 $automake --foreign --add-missing --force-missing --copy --warnings=all
-# wget ftp://ftp.gnu.org/gnu/autoconf/autoconf-2.58.tar.gz
 autoconf --warnings=all --force
 rm config.h.in
 autoheader --warnings=all --force  

diff --git a/program/acinclude.m4 b/program/acinclude.m4
index 6c50060a8846e241efa792b218fc50d150cae39a..34ec3310e7903426451dc82466523bd5cc75b897 100644 (file)
--- a/program/acinclude.m4
+++ b/program/acinclude.m4
@@ -1,28 +1,300 @@
-# 
-# INCLUDED_LIB(LIBRARY, FUNCTION, OTHER-LIBRARIES = none)
-# ---------------------------------------------
-# Contributed by Mat Zimmermann
-#
-AC_DEFUN([INCLUDED_LIB],
+dnl Helper Functions for the RRDtool configure.ac script
+dnl 
+dnl this file gets included into aclocal.m4 when runnning aclocal
+dnl
+dnl
+dnl
+dnl Check for the presence of a particular library and its header files
+dnl if this check fails set the environment variable EX_CHECK_ALL_ERR to YES
+dnl and prints out a helful message
+dnl
+dnl
+dnl EX_CHECK_ALL(library, function, header, pkgconf name, tested-version, homepage)
+dnl              $1       $2        $3      $4            $5              $6
+dnl
+dnl
+AC_DEFUN([EX_CHECK_ALL],
 [
-use_installed_lib$1=
-AC_ARG_WITH([lib$1],
-            [AC_HELP_STRING([--with-lib$1],
-                            [Use installed lib$1 (under PREFIX)])],
-            [if test -n "$withval"; then
-               if test "$withval" = yes; then
-                 withval="default path"
-               else
-                 CFLAGS="$CFLAGS -I${withval}/include"
-                 LDFLAGS="$LDFLAGS -L${withval}/lib"
-               fi
-             fi
-             AC_CHECK_LIB([$1],[$2],
-                          [AC_MSG_NOTICE([using lib$1 in ${withval}])
-                           use_installed_lib$1=yes],
-                          [AC_MSG_ERROR([lib$1 not found in ${withval}])],
-                          [$3])],
-             [AC_MSG_NOTICE([using included lib$1])])
-AM_CONDITIONAL([USE_INSTALLED_lib$1],
-               [test "$use_installed_lib$1" = yes])
-])
+ EX_CHECK_STATE=NO
+ dnl try compiling naked first
+ AC_CHECK_LIB($1,$2, [
+    AC_CHECK_HEADER($3,[LIBS="-l$1 ${LIBS}";EX_CHECK_STATE=YES],[
+       dnl now asking pkg-config for help
+       AC_PATH_PROG(PKGCONFIG,pkg-config,no)
+       if test "$PKGCONFIG" != "no"; then
+          if $PKGCONFIG --exists $4; then
+             CPPFLAGS=${CPPFLAGS}" "`$PKGCONFIG --cflags $4`
+             LDFLAGS=${LDFLAGS}" "`$PKGCONFIG --libs-only-l $4`
+             LIBS=${LIBS}" " `$PKGCONFIG --libs-only-other $4`
+             AC_CHECK_LIB($1,$2,[ AC_CHECK_HEADER($3,[LIBS="-l$1 ${LIBS};EX_CHECK_STATE=YES"],[])],[])
+          else
+             AC_MSG_WARN([
+----------------------------------------------------------------------------
+* I found a copy of pkgconfig, but there is no $4.pc file around.
+  You may want to set the PKG_CONFIG_PATH variable to point to its
+  location.
+                       ])
+           fi
+       fi
+     ])],[])
+
+
+  if test ${EX_CHECK_STATE} = NO; then
+     AC_MSG_WARN([
+----------------------------------------------------------------------------
+* I could not find a working copy of $4. Check config.log for hints on why
+  this is the case. Maybe you need to set LDFLAGS appropriately so that the
+  linker can find lib$1. If you have not installed $4, you can get it
+  either from its original home on
+
+     $6
+
+  You can find also find an archive copy on
+
+     http://people.ee.ethz.ch/~oetiker/webtools/rrdtool/pub/libs
+
+  The last tested version of $4 is $5.
+----------------------------------------------------------------------------
+                ])
+       EX_CHECK_ALL_ERR=YES
+    fi
+]
+)
+dnl
+dnl  Ptherad check from http://autoconf-archive.cryp.to/acx_pthread.m4
+dnl
+dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl This macro figures out how to build C programs using POSIX threads.
+dnl It sets the PTHREAD_LIBS output variable to the threads library and
+dnl linker flags, and the PTHREAD_CFLAGS output variable to any special
+dnl C compiler flags that are needed. (The user can also force certain
+dnl compiler flags/libs to be tested by setting these environment
+dnl variables.)
+dnl
+dnl Also sets PTHREAD_CC to any special C compiler that is needed for
+dnl multi-threaded programs (defaults to the value of CC otherwise).
+dnl (This is necessary on AIX to use the special cc_r compiler alias.)
+dnl
+dnl NOTE: You are assumed to not only compile your program with these
+dnl flags, but also link it with them as well. e.g. you should link
+dnl with $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS
+dnl $LIBS
+dnl
+dnl If you are only building threads programs, you may wish to use
+dnl these variables in your default LIBS, CFLAGS, and CC:
+dnl
+dnl        LIBS="$PTHREAD_LIBS $LIBS"
+dnl        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
+dnl        CC="$PTHREAD_CC"
+dnl
+dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
+dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
+dnl that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
+dnl
+dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
+dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands to
+dnl run it if it is not found. If ACTION-IF-FOUND is not specified, the
+dnl default action will define HAVE_PTHREAD.
+dnl
+dnl Please let the authors know if this macro fails on any platform, or
+dnl if you have any other suggestions or comments. This macro was based
+dnl on work by SGJ on autoconf scripts for FFTW (www.fftw.org) (with
+dnl help from M. Frigo), as well as ac_pthread and hb_pthread macros
+dnl posted by Alejandro Forero Cuervo to the autoconf macro repository.
+dnl We are also grateful for the helpful feedback of numerous users.
+dnl
+dnl @category InstalledPackages
+dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
+dnl @version 2005-01-14
+dnl @license GPLWithACException
+
+AC_DEFUN([ACX_PTHREAD], [
+AC_REQUIRE([AC_CANONICAL_HOST])
+AC_LANG_SAVE
+AC_LANG_C
+acx_pthread_ok=no
+
+# We used to check for pthread.h first, but this fails if pthread.h
+# requires special compiler flags (e.g. on True64 or Sequent).
+# It gets checked for in the link test anyway.
+
+# First of all, check if the user has set any of the PTHREAD_LIBS,
+# etcetera environment variables, and if threads linking works using
+# them:
+if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
+        save_CFLAGS="$CFLAGS"
+        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
+        save_LIBS="$LIBS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
+        AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
+        AC_MSG_RESULT($acx_pthread_ok)
+        if test x"$acx_pthread_ok" = xno; then
+                PTHREAD_LIBS=""
+                PTHREAD_CFLAGS=""
+        fi
+        LIBS="$save_LIBS"
+        CFLAGS="$save_CFLAGS"
+fi
+
+# We must check for the threads library under a number of different
+# names; the ordering is very important because some systems
+# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
+# libraries is broken (non-POSIX).
+
+# Create a list of thread flags to try.  Items starting with a "-" are
+# C compiler flags, and other items are library names, except for "none"
+# which indicates that we try without any flags at all, and "pthread-config"
+# which is a program returning the flags for the Pth emulation library.
+
+acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
+
+# The ordering *is* (sometimes) important.  Some notes on the
+# individual items follow:
+
+# pthreads: AIX (must check this before -lpthread)
+# none: in case threads are in libc; should be tried before -Kthread and
+#       other compiler flags to prevent continual compiler warnings
+# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
+# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
+# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
+# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
+# -pthreads: Solaris/gcc
+# -mthreads: Mingw32/gcc, Lynx/gcc
+# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
+#      doesn't hurt to check since this sometimes defines pthreads too;
+#      also defines -D_REENTRANT)
+# pthread: Linux, etcetera
+# --thread-safe: KAI C++
+# pthread-config: use pthread-config program (for GNU Pth library)
+
+case "${host_cpu}-${host_os}" in
+        *solaris*)
+
+        # On Solaris (at least, for some versions), libc contains stubbed
+        # (non-functional) versions of the pthreads routines, so link-based
+        # tests will erroneously succeed.  (We need to link with -pthread or
+        # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
+        # a function called by this macro, so we could check for that, but
+        # who knows whether they'll stub that too in a future libc.)  So,
+        # we'll just look for -pthreads and -lpthread first:
+
+        acx_pthread_flags="-pthread -pthreads pthread -mt $acx_pthread_flags"
+        ;;
+esac
+
+if test x"$acx_pthread_ok" = xno; then
+for flag in $acx_pthread_flags; do
+
+        case $flag in
+                none)
+                AC_MSG_CHECKING([whether pthreads work without any flags])
+                ;;
+
+                -*)
+                AC_MSG_CHECKING([whether pthreads work with $flag])
+                PTHREAD_CFLAGS="$flag"
+                ;;
+
+               pthread-config)
+               AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
+               if test x"$acx_pthread_config" = xno; then continue; fi
+               PTHREAD_CFLAGS="`pthread-config --cflags`"
+               PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
+               ;;
+
+                *)
+                AC_MSG_CHECKING([for the pthreads library -l$flag])
+                PTHREAD_LIBS="-l$flag"
+                ;;
+        esac
+
+        save_LIBS="$LIBS"
+        save_CFLAGS="$CFLAGS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
+
+        # Check for various functions.  We must include pthread.h,
+        # since some functions may be macros.  (On the Sequent, we
+        # need a special flag -Kthread to make this header compile.)
+        # We check for pthread_join because it is in -lpthread on IRIX
+        # while pthread_create is in libc.  We check for pthread_attr_init
+        # due to DEC craziness with -lpthreads.  We check for
+        # pthread_cleanup_push because it is one of the few pthread
+        # functions on Solaris that doesn't have a non-functional libc stub.
+        # We try pthread_create on general principles.
+        AC_TRY_LINK([#include <pthread.h>],
+                    [pthread_t th; pthread_join(th, 0);
+                     pthread_attr_init(0); pthread_cleanup_push(0, 0);
+                     pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
+                    [acx_pthread_ok=yes])
+
+        LIBS="$save_LIBS"
+        CFLAGS="$save_CFLAGS"
+
+        AC_MSG_RESULT($acx_pthread_ok)
+        if test "x$acx_pthread_ok" = xyes; then
+                break;
+        fi
+
+        PTHREAD_LIBS=""
+        PTHREAD_CFLAGS=""
+done
+fi
+
+# Various other checks:
+if test "x$acx_pthread_ok" = xyes; then
+        save_LIBS="$LIBS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        save_CFLAGS="$CFLAGS"
+        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
+
+        # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
+       AC_MSG_CHECKING([for joinable pthread attribute])
+       attr_name=unknown
+       for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
+           AC_TRY_LINK([#include <pthread.h>], [int attr=$attr;],
+                        [attr_name=$attr; break])
+       done
+        AC_MSG_RESULT($attr_name)
+        if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
+            AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
+                               [Define to necessary symbol if this constant
+                                uses a non-standard name on your system.])
+        fi
+
+        AC_MSG_CHECKING([if more special flags are required for pthreads])
+        flag=no
+        case "${host_cpu}-${host_os}" in
+            *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
+            *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
+        esac
+        AC_MSG_RESULT(${flag})
+        if test "x$flag" != xno; then
+            PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
+        fi
+
+        LIBS="$save_LIBS"
+        CFLAGS="$save_CFLAGS"
+
+        # More AIX lossage: must compile with cc_r
+        AC_CHECK_PROG(PTHREAD_CC, cc_r, cc_r, ${CC})
+else
+        PTHREAD_CC="$CC"
+fi
+
+AC_SUBST(PTHREAD_LIBS)
+AC_SUBST(PTHREAD_CFLAGS)
+AC_SUBST(PTHREAD_CC)
+
+# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
+if test x"$acx_pthread_ok" = xyes; then
+        ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
+        :
+else
+        acx_pthread_ok=no
+        $2
+fi
+AC_LANG_RESTORE
+])dnl ACX_PTHREAD

diff --git a/program/bindings/Makefile.am b/program/bindings/Makefile.am
index ffdf4a2c51d9e9cd2fb3d529b315a4f64a163c5e..f55119617a7383ec59e46ca0f5a8f124e8683262 100644 (file)
--- a/program/bindings/Makefile.am
+++ b/program/bindings/Makefile.am
@@ -1,5 +1,4 @@
 SUBDIRS = tcl
-
 # the following files are not mentioned in any other Makefile
 EXTRA_DIST = $(shell for A in perl-*; do cat $$A/MANIFEST | sed -e s,^,$$A/, ; done)
 

diff --git a/program/configure.ac b/program/configure.ac
index 902780267165b3be8096f04e80ba4f5354430498..89da80c22e3210bb28d246f670f3d6ff2812811e 100644 (file)
--- a/program/configure.ac
+++ b/program/configure.ac
@@ -3,14 +3,13 @@ dnl ---------------------------
 dnl
 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
 dnl
-dnl
+dnl Inspiration from http://autoconf-archive.cryp.to
 
 dnl tell automake the this script is for rrdtool
-AC_INIT([rrdtool],[1.1.0])
+AC_INIT([rrdtool],[1.1.9901])
 AC_CANONICAL_TARGET
 AM_INIT_AUTOMAKE
-AM_CONFIG_HEADER(config.h)
-# AC_CONFIG_AUX_DIR(config)
+AC_CONFIG_HEADERS([config.h])
 
 dnl all our local stuff like install scripts and include files
 dnl is in there
@@ -25,7 +24,7 @@ dnl where we install our stuff ...
 AC_PREFIX_DEFAULT( /usr/local/rrdtool-1.1.0 )
 
 dnl Minimum Autoconf version required.
-AC_PREREQ(2.58)
+AC_PREREQ(2.59)
 
 dnl At the TOP of the HEADER
 
@@ -158,31 +157,6 @@ AC_SUBST(PERLFLAGS)
 dnl Checks for libraries.
 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 
-AC_DEFUN([EX_CHECK_ALL],
-[ AC_CHECK_LIB($1,$2,
-  [ AC_CHECK_HEADER($3,[LIBS="-l$1 ${LIBS}"],[
-     [ $echo "#include <$3>" | $CC -E - > /dev/null ] 
-     AC_MSG_ERROR([Adjust CPPFLAGS so that the $4 header $3 AND its dependencies gets found])
-  ] ) ],
-  [ AC_MSG_ERROR([
-############################################################################
-I could not find a working copy of $4. Check config.log for hints on why
-this is the case. Maybe you need to set LDFLAGS appropriately so that the
-linker can find lib$1. If you have not installed $4, you can get it
-either from its original home on
-
-   $6
-
-Or you can find an archive copy on
-
-   http://people.ee.ethz.ch/~oetiker/webtools/rrdtool/pub/libs
-
-The last tested version of $4 is $5.
-############################################################################
-])] )
-]
-)
- 
 dnl How the vertical axis label is printed
 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE, 
  [Vertical label angle: 90.0 (default) or 270.0])
@@ -197,74 +171,62 @@ AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 if test $enable_rrdcgi != no; then
 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib)
 fi
-EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart_lgpl, 2.3.16, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/)
+EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart_lgpl, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/)
 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.1,  http://www.gzip.org/zlib/)
-EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.5,  http://prdownloads.sourceforge.net/libpng/)
-EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype,    2.1.5,  http://prdownloads.sourceforge.net/freetype/)
- 
-dnl Check for pthreads (pieces of code from Bert Driehuis)
+EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/)
+EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype,    2.1.9,  http://prdownloads.sourceforge.net/freetype/)
+
+if test "$EX_CHECK_ALL_ERR" = "YES"; then
+  AC_MSG_ERROR([Please fix the library issues listed above and try again.])
+fi
+
+dnl solaris has some odd define it need in order to propperly compile ctime_r
+AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
+AC_LINK_IFELSE(
+    AC_LANG_PROGRAM(
+           [[#include <time.h>]],
+           [[ctime_r(NULL,NULL,0)]]
+                   ),
+    [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
+      AC_LINK_IFELSE(
+          AC_LANG_PROGRAM(
+                [[#include <time.h>]],
+                [[ctime_r(NULL,NULL)]]
+                        ),
+          [AC_MSG_RESULT([yes, this seems to be solaris style])],
+          [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
+      )
+    ],  
+    [ AC_LINK_IFELSE(
+          AC_LANG_PROGRAM(
+                [[#include <time.h>]],
+                [[ctime_r(NULL,NULL)]]
+                        ),
+          [AC_MSG_RESULT(yes)],
+          [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
+      )
+    ]  
+)
+
+dnl Check for pthreads
+dnl http://autoconf-archive.cryp.to/acx_pthread.m4
  
 AC_SUBST(MULTITHREAD_CFLAGS)
 AC_SUBST(MULTITHREAD_LDFLAGS)
 
-AC_DEFUN(AC_CHECK_PTHREAD, [
-   AC_MSG_CHECKING([pthreads: trying no flags])
-   AC_CACHE_VAL(ac_cv_flag_pthread,[
-       AC_TRY_LINK([
-               #include <pthread.h>
-       ],
-       [pthread_exit(0);],
-       eval "ac_cv_flag_pthread=no",
-       [
-               AC_MSG_RESULT([didn't work])
-               AC_MSG_CHECKING([pthreads: trying to add -pthread])
-               ac_save_CFLAGS="$CFLAGS"
-               CFLAGS="$CFLAGS -pthread"
-     AC_TRY_LINK([
-       #include <pthread.h>
-       ],
-       [pthread_exit(0);],
-       eval "ac_cv_flag_pthread=yes",
-       AC_MSG_ERROR([Can't figure out pthreads])
-     )
-     CFLAGS="$ac_save_CFLAGS"
-       ])
-   ])
- 
-   if test "$ac_cv_flag_pthread" = "no"; then
-     AC_MSG_RESULT([good, -pthread flag not necessary])
-   else
-     AC_MSG_RESULT([adding -pthread flag])
-     MULTITHREAD_CFLAGS="-pthread"
-   fi
- 
-   AC_MSG_CHECKING([for libpthread])
-   AC_CACHE_VAL(ac_cv_lib_pthread,[
-     ac_save_LIBS="$LIBS"
-     LIBS="-lpthread"
-     AC_TRY_LINK([
-       #include <pthread.h>
-       ],
-       [pthread_exit(0);],
-       eval "ac_cv_lib_pthread=-lphtread",
-       eval "ac_cv_lib_pthread=no"
-     )
-     LIBS="$ac_save_LIBS"
-   ])
-   if test "$ac_cv_lib_pthread" = "no"; then
-     AC_MSG_RESULT([no -lpthread necessary])
-   else
-     AC_MSG_RESULT([adding -lpthread to LIBS])
-     MULTITHREAD_LDFLAGS="-lpthread"
-   fi
-])
  
 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 [],[enable_pthread=yes])
  
 if test $enable_pthread != no; then 
-       AC_CHECK_PTHREAD
+ ACX_PTHREAD([
+    MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
+    MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
+            ],
+            [])
 fi
+
+
  
 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
   
@@ -350,7 +312,8 @@ if test "x$GCC" = "xyes"; then
 fi
 
 dnl add pic flag in any case this makes sure all our code is relocatable
-CFLAGS="$CFLAGS "`grep pic_flag= libtool | head -1|sed -e 's/.*pic_flag=//' -e 's/"//g'`
+CFLAGS="$CFLAGS "`grep pic_flag= libtool | head -1|sed -e 's/.*pic_flag=//' -e 's/"//g'` 
+dnl" make joes highliter happy it does not grasp the quote in the line above
 
 ZLIB_CFLAGS=$CFLAGS
 dnl it seems that hpux chockes on -fPIC for some reason

diff --git a/program/src/Makefile.am b/program/src/Makefile.am
index 1f1ff3af846240b4ec2e46410e5188ff0b1d4004..68875df779550a2cbb4db6a8c48eb667213daf5a 100644 (file)
--- a/program/src/Makefile.am
+++ b/program/src/Makefile.am
@@ -10,7 +10,7 @@ fonts_DATA = VeraMono.ttf
 
 #INCLUDES = $(CGI_INCLUDES) $(FREETYPE_INCLUDES) $(ART_INCLUDES) \
 #           $(PNG_INCLUDES) $(ZLIB_INCLUDES)
-INCLUDES = -DRRD_DEFAULT_FONT=\"$(fontsdir)/$(fonts_DATA)\"
+AM_CPPFLAGS = -DRRD_DEFAULT_FONT=\"$(fontsdir)/$(fonts_DATA)\"
 
 RRD_C_FILES =          \
        getopt.c        \