1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.99907052400])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devel versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.299907052400
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([rrd_config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
29 AC_SUBST(VERSION)
31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
33 dnl Minimum Autoconf version required.
34 AC_PREREQ(2.59)
36 dnl At the TOP of the HEADER
38 AH_TOP([
40 #ifndef RRD_CONFIG_H
41 #define RRD_CONFIG_H
42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
43 #undef MUST_DISABLE_FPMASK
45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
47 #undef MUST_DISABLE_SIGFPE
49 /* realloc does not support NULL as argument */
50 #undef NO_NULL_REALLOC
52 ])
54 AH_BOTTOM([
55 /* make sure that we pickup the correct stuff from all headers */
56 #define _XOPEN_SOURCE 600
57 #if HAVE_FEATURES_H
58 # include <features.h>
59 #endif
61 #if HAVE_SYS_TYPES_H
62 # include <sys/types.h>
63 #endif
65 #if HAVE_SYS_PARAM_H
66 # include <sys/param.h>
67 #endif
68 #ifndef MAXPATH
69 # ifdef PATH_MAX
70 # define MAXPATH PATH_MAX
71 # endif
72 #endif
73 #ifndef MAXPATH
74 /* else try the BSD variant */
75 # ifdef MAXPATHLEN
76 # define MAXPATH MAXPATHLEN
77 # endif
78 #endif
80 #if HAVE_ERRNO_H
81 # include <errno.h>
82 #endif
84 #if HAVE_SYS_MMAN_H
85 # include <sys/mman.h>
86 #endif
87 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
88 /* use posix_madvise family */
89 # define madvise posix_madvise
90 # define MADV_NORMAL POSIX_MADV_NORMAL
91 # define MADV_RANDOM POSIX_MADV_RANDOM
92 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
93 # define MADV_WILLNEED POSIX_MADV_WILLNEED
94 # define MADV_DONTNEED POSIX_MADV_DONTNEED
95 #endif
96 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
97 # define USE_MADVISE 1
98 #endif
100 #if HAVE_SYS_STAT_H
101 # include <sys/stat.h>
102 #endif
104 /* enable posix_fadvise on linux */
105 #if defined(HAVE_POSIX_FADVISE) && defined(HAVE_FCNTL_H)
106 #include <fcntl.h>
107 #endif
109 #if HAVE_UNISTD_H
110 # include <unistd.h>
111 #endif
113 #if TIME_WITH_SYS_TIME
114 # include <sys/time.h>
115 # include <time.h>
116 #else
117 # if HAVE_SYS_TIME_H
118 # include <sys/time.h>
119 # else
120 # include <time.h>
121 # endif
122 #endif
124 #if HAVE_SYS_TIMES_H
125 # include <sys/times.h>
126 #endif
128 #if HAVE_SYS_RESOURCE_H
129 # include <sys/resource.h>
130 #if (defined(__svr4__) && defined(__sun__))
131 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
132 Use this instead. */
133 extern int getrusage(int, struct rusage *);
134 #endif /* __svr4__ && __sun__ */
135 #endif
138 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
139 make sure you are NOT using bcopy, index or rindex in the code */
141 #ifdef STDC_HEADERS
142 # include <string.h>
143 #else
144 # ifndef HAVE_STRCHR
145 # define strchr index
146 # define strrchr rindex
147 # endif
148 char *strchr (), *strrchr ();
149 # ifndef HAVE_MEMMOVE
150 # define memcpy(d, s, n) bcopy ((s), (d), (n))
151 # define memmove(d, s, n) bcopy ((s), (d), (n))
152 # endif
153 #endif
155 #ifdef NO_NULL_REALLOC
156 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
157 #else
158 # define rrd_realloc(a,b) realloc((a), (b))
159 #endif
161 #ifdef NEED_MALLOC_MALLOC_H
162 # include <malloc/malloc.h>
163 #endif
165 #if HAVE_STDIO_H
166 # include <stdio.h>
167 #endif
169 #if HAVE_STDLIB_H
170 # include <stdlib.h>
171 #endif
173 #if HAVE_CTYPE_H
174 # include <ctype.h>
175 #endif
177 #if HAVE_DIRENT_H
178 # include <dirent.h>
179 # define NAMLEN(dirent) strlen((dirent)->d_name)
180 #else
181 # define dirent direct
182 # define NAMLEN(dirent) (dirent)->d_namlen
183 # if HAVE_SYS_NDIR_H
184 # include <sys/ndir.h>
185 # endif
186 # if HAVE_SYS_DIR_H
187 # include <sys/dir.h>
188 # endif
189 # if HAVE_NDIR_H
190 # include <ndir.h>
191 # endif
192 #endif
194 #ifdef MUST_DISABLE_SIGFPE
195 # include <signal.h>
196 #endif
198 #ifdef MUST_DISABLE_FPMASK
199 # include <floatingpoint.h>
200 #endif
203 #ifdef HAVE_MATH_H
204 # include <math.h>
205 #endif
207 #ifdef HAVE_FLOAT_H
208 # include <float.h>
209 #endif
211 #ifdef HAVE_IEEEFP_H
212 # include <ieeefp.h>
213 #endif
215 #ifdef HAVE_FP_CLASS_H
216 # include <fp_class.h>
217 #endif
219 /* for Solaris */
220 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
221 # define HAVE_ISINF 1
222 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
223 #endif
225 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad */
226 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
227 # undef isnan
228 # define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
229 #endif
231 /* for OSF1 Digital Unix */
232 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
233 # define HAVE_ISINF 1
234 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
235 #endif
237 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
238 # define HAVE_ISINF 1
239 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
240 #endif
242 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
243 # define HAVE_ISINF 1
244 # define isinf(a) (fpclassify(a) == FP_INFINITE)
245 #endif
247 /* for AIX */
248 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
249 # define HAVE_ISINF 1
250 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
251 #endif
253 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
254 # define HAVE_FINITE 1
255 # define finite(a) isfinite(a)
256 #endif
258 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
259 # define HAVE_FINITE 1
260 # define finite(a) (! isnan(a) && ! isinf(a))
261 #endif
263 #ifndef HAVE_FINITE
264 #error "Can't compile without finite function"
265 #endif
267 #ifndef HAVE_ISINF
268 #error "Can't compile without isinf function"
269 #endif
271 #endif /* RRD_CONFIG_H */
272 ])
274 dnl Process Special Options
275 dnl -----------------------------------
277 dnl How the vertical axis label is printed
278 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
279 [Vertical label angle: 90.0 (default) or 270.0])
280 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
281 [Vertical label angle: 90.0 (default) or 270.0])
283 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
284 [],[enable_rrdcgi=yes])
286 dnl Check if we run on a system that has fonts
287 AC_ARG_WITH(rrd-default-font,
288 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
289 [RRD_DEFAULT_FONT=$withval],[
290 if test -d ${WINDIR:-nodir}/cour.ttf ; then
291 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
292 else
293 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
294 fi
295 ])
297 dnl Use mmap in rrd_update instead of seek+write
298 AC_ARG_ENABLE([mmap],
299 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
300 [],
301 [enable_mmap=yes])
304 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
305 [],[enable_pthread=yes])
309 CONFIGURE_PART(Audit Compilation Environment)
312 dnl Check for the compiler and static/shared library creation.
313 AC_PROG_CC
314 AC_PROG_CPP
315 AC_PROG_LIBTOOL
317 dnl which flags does the compiler support?
318 if test "x$GCC" = "xyes"; then
319 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
320 oCFLAGS="$CFLAGS"
321 CFLAGS="$CFLAGS $flag"
322 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
323 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
324 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
325 if eval test \$$cachename = no; then
326 CFLAGS="$oCFLAGS"
327 fi
328 done
329 fi
333 AC_SUBST(RRD_DEFAULT_FONT)
335 CONFIGURE_PART(Checking for Header Files)
337 dnl Checks for header files.
338 AC_HEADER_STDC
339 AC_HEADER_DIRENT
340 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
342 dnl Checks for typedefs, structures, and compiler characteristics.
343 AC_C_CONST
344 AC_HEADER_TIME
345 AC_STRUCT_TM
347 dnl Checks for libraries.
348 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
350 dnl add pic flag in any case this makes sure all our code is relocatable
351 eval `./libtool --config | grep pic_flag`
352 CFLAGS="$CFLAGS $pic_flag"
354 CONFIGURE_PART(Test Library Functions)
356 dnl Checks for library functions.
357 AC_FUNC_STRFTIME
358 AC_FUNC_VPRINTF
360 AC_C_BIGENDIAN
362 dnl for each function found we get a definition in config.h
363 dnl of the form HAVE_FUNCTION
365 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday posix_fadvise)
367 dnl Could use these to know if we need to provide a prototype
368 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
369 dnl AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
370 dnl #include <fcntl.h>])
372 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
373 if test "x$enable_mmap" = "xyes"; then
374 case "$host" in
375 *cygwin*)
376 # the normal mmap test does not work in cygwin
377 AC_CHECK_FUNCS(mmap)
378 if test "x$ac_cv_func_mmap" = "xyes"; then
379 ac_cv_func_mmap_fixed_mapped=yes
380 fi
381 ;;
382 *)
383 AC_CHECK_HEADERS(sys/mman.h)
384 AC_FUNC_MMAP
385 AC_CHECK_FUNCS(mmap munmap)
386 AC_CHECK_DECLS(madvise, [], [], [#if HAVE_SYS_MMAN_H
387 # include <sys/mman.h>
388 #endif])
389 if test "x$ac_cv_have_decl_madvise" = "xyes";
390 then
391 AC_CHECK_FUNCS(madvise)
392 else
393 AC_CHECK_FUNCS(posix_madvise)
394 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
395 AC_MSG_WARN([madvise() nor posix_madvise() found.])
396 fi
397 fi
398 ;;
399 esac
400 if test "x$ac_cv_func_mmap" != "xyes";
401 then
402 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
403 fi
404 fi
407 CONFIGURE_PART(IEEE Math Checks)
410 dnl actual code to check if this works
411 AC_CHECK_FUNCS(fpclassify, ,
412 [AC_MSG_CHECKING(for fpclassify with <math.h>)
413 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
414 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
415 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
417 AC_CHECK_FUNCS(isinf, ,
418 [AC_MSG_CHECKING(for isinf with <math.h>)
419 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
420 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
421 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
423 dnl finite is BSD, isfinite is C99, so prefer the latter
424 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
425 AC_TRY_RUN([
426 #ifdef HAVE_MATH_H
427 #include <math.h>
428 #endif
429 #ifdef HAVE_FLOAT_H
430 #include <float.h>
431 #endif
432 int main ()
433 {
434 #ifdef isfinite
435 #ifdef LDBL_MAX
436 if (!isfinite(LDBL_MAX)) return 1;
437 #endif
438 #ifdef DBL_MAX
439 if (!isfinite(DBL_MAX)) return 1;
440 #endif
441 #endif
442 return 0;
443 }],[
444 have_broken_isfinite=no],have_broken_isfinite=yes,[
445 case "${target}" in
446 hppa*-*-hpux*) have_broken_isfinite=yes ;;
447 *) have_broken_isfinite=no ;;
448 esac])
449 ])
450 if test "x$have_broken_isfinite" = "xno"; then
451 AC_DEFINE(HAVE_ISFINITE)
452 else
453 AC_CHECK_FUNCS(finite,[],
454 [AC_CHECK_FUNCS(isfinite,[],
455 [AC_MSG_CHECKING(for isfinite with <math.h>)
456 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
457 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
458 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
459 fi
461 AC_FULL_IEEE
463 CONFIGURE_PART(Resolve Portability Issues)
465 dnl what does realloc do if it gets called with a NULL pointer
467 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
468 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
469 int main(void){
470 char *x = NULL;
471 x = realloc (x,10);
472 if (x==NULL) return 1;
473 return 0;
474 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
476 if test x"$rd_cv_null_realloc" = xnope; then
477 AC_DEFINE(NO_NULL_REALLOC)
478 fi
480 AC_LANG_PUSH(C)
481 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
482 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
483 AC_LINK_IFELSE(
484 AC_LANG_PROGRAM(
485 [[#include <time.h>]],
486 [[ctime_r(NULL,NULL,0)]]
487 ),
488 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
489 AC_LINK_IFELSE(
490 AC_LANG_PROGRAM(
491 [[#include <time.h>]],
492 [[ctime_r(NULL,NULL)]]
493 ),
494 [AC_MSG_RESULT([yes, this seems to be solaris style])],
495 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
496 )
497 ],
498 [ AC_LINK_IFELSE(
499 AC_LANG_PROGRAM(
500 [[#include <time.h>]],
501 [[ctime_r(NULL,NULL)]]
502 ),
503 [AC_MSG_RESULT(no)],
504 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
505 )
506 ]
507 )
508 AC_LANG_POP(C)
510 dnl Check for pthreads
511 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
513 AC_SUBST(MULTITHREAD_CFLAGS)
514 AC_SUBST(MULTITHREAD_LDFLAGS)
516 if test $enable_pthread != no; then
517 ACX_PTHREAD([
518 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
519 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
520 ],
521 [])
522 fi
524 dnl since we use lots of *_r functions all over the code we better
525 dnl make sure they are known
527 if test "x$x_rflag" != "xno"; then
528 CPPFLAGS="$CPPFLAGS $x_rflag"
529 fi
531 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
533 AC_LANG_PUSH(C)
534 dnl see if we have to include malloc/malloc.h
535 AC_MSG_CHECKING([do we need malloc/malloc.h])
536 AC_LINK_IFELSE(
537 AC_LANG_PROGRAM(
538 [[#include <stdlib.h>]],
539 [[malloc(1)]]
540 ),
541 [ AC_MSG_RESULT([nope, works out of the box]) ],
542 [ AC_LINK_IFELSE(
543 AC_LANG_PROGRAM(
544 [[#include <stdlib.h>
545 #include <malloc/malloc.h>]],
546 [[malloc(1)]]
547 ),
548 [AC_DEFINE(NEED_MALLOC_MALLOC_H)
549 AC_MSG_RESULT([yes we do])],
550 [AC_MSG_ERROR([Can not figure how to compile malloc])]
551 )
552 ]
553 )
554 AC_LANG_POP(C)
556 CONFIGURE_PART(Find 3rd-Party Libraries)
559 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
561 CORE_LIBS="$LIBS"
563 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
564 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
565 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
566 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
568 if test "$EX_CHECK_ALL_ERR" = "YES"; then
569 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
570 fi
572 ALL_LIBS="$LIBS"
573 LIBS=
575 AC_SUBST(CORE_LIBS)
576 AC_SUBST(ALL_LIBS)
578 CONFIGURE_PART(Prep for Building Language Bindings)
580 dnl Check for Perl.
581 AC_PATH_PROG(PERL, perl, no)
583 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
584 [],[enable_perl=yes])
587 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
588 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
589 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
590 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
592 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
593 COMP_PERL=
594 else
595 COMP_PERL="perl_piped perl_shared"
596 AC_MSG_CHECKING(for the perl version you are running)
597 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
598 AC_MSG_RESULT($PERL_VERSION)
599 if test -z "$PERLCC"; then
600 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
601 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
602 AC_MSG_RESULT($perlcc)
603 if test ! -x "$perlcc"; then
604 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
605 if test "$PERL_CC" = "no"; then
606 AC_MSG_WARN([
607 I would not find the Compiler ($perlcc) that was originally used to compile
608 your perl binary. You should either make sure that this compiler is
609 available on your system, pick an other compiler and set PERLCC
610 appropriately, or use a different perl setup that was compiled locally.
612 I will disable the compilation of the RRDs perl module for now.
613 ])
614 COMP_PERL="perl_piped"
615 fi
616 fi
617 fi
618 fi
620 AC_MSG_CHECKING(Perl Modules to build)
621 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
623 # Options to pass when configuring perl module
624 ppref=$prefix
625 test "$ppref" = "NONE" && ppref=$ac_default_prefix
627 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
629 dnl pass additional perl options when generating Makefile from Makefile.PL
630 AC_ARG_ENABLE(perl-site-install,
631 [ --enable-perl-site-install by default the rrdtool perl modules are installed
632 together with rrdtool in $prefix/lib/perl. You have to
633 put a 'use lib qw($prefix/lib/perl)' into your scripts
634 when you want to use them. When you set this option
635 the perl modules will get installed wherever
636 your perl setup thinks it is best.],
637 [PERL_MAKE_OPTIONS=],[])
639 if test ! -z "$PERLCC"; then
640 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
642 if test ! -z "$PERLCCFLAGS"; then
643 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
644 fi
646 if test -z "$PERLLD"; then
647 PERLLD=$PERLCC
648 fi
649 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
651 if test ! -z "$PERLLDFLAGS"; then
652 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
653 fi
654 fi
656 AC_ARG_WITH(perl-options,
657 [ --with-perl-options=[OPTIONS] options to pass on command-line when
658 generating Makefile from Makefile.PL. If you set this
659 option, interesting things may happen unless you know
660 what you are doing!],
661 [PERL_MAKE_OPTIONS=$withval])
663 AC_SUBST(PERL_MAKE_OPTIONS)
664 AC_SUBST(PERL)
665 AC_SUBST(COMP_PERL)
666 AC_SUBST(PERL_VERSION)
668 dnl Check for Ruby.
669 AC_PATH_PROG(RUBY, ruby, no)
671 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
672 [],[enable_ruby=yes])
674 AC_MSG_CHECKING(if ruby modules can be built)
676 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
677 COMP_RUBY=
678 AC_MSG_RESULT(No .. Ruby not found or disabled)
679 else
680 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
681 COMP_RUBY="ruby"
682 AC_MSG_RESULT(YES)
683 else
684 COMP_RUBY=
685 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
686 fi
687 fi
690 dnl pass additional ruby options when generating Makefile from Makefile.PL
691 AC_ARG_ENABLE(ruby-site-install,
692 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
693 together with rrdtool in $prefix/lib/ruby. You have to
694 add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
695 for ruby to find the RRD.so file.],
696 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
699 AC_ARG_WITH(ruby-options,
700 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
701 generating Makefile from extconf.rb. If you set this
702 option, interesting things may happen unless you know
703 what you are doing!],
704 [RUBY_MAKE_OPTIONS=$withval])
706 AC_SUBST(RUBY_MAKE_OPTIONS)
707 AC_SUBST(RUBY)
708 AC_SUBST(COMP_RUBY)
711 enable_tcl_site=no
713 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
714 [],[enable_tcl=yes])
716 if test "$enable_tcl" = "yes"; then
717 dnl Check for Tcl.
718 withval=""
719 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
720 enable_tcl=no
721 for dir in $withval /usr/lib /usr/local/lib; do
722 AC_MSG_CHECKING(for tclConfig.sh in $dir)
723 if test -f "$dir/tclConfig.sh" ; then
724 tcl_config=$dir/tclConfig.sh
725 enable_tcl=yes
726 AC_MSG_RESULT(yes)
727 break
728 else
729 AC_MSG_RESULT(no)
730 fi
731 done
733 if test "$enable_tcl" = "no"; then
734 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
735 else
736 . $tcl_config
737 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
738 fi
739 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
740 [],[enable_tcl_site=yes])
742 fi
744 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
745 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
747 AC_SUBST(TCL_PREFIX)
748 AC_SUBST(TCL_SHLIB_CFLAGS)
749 AC_SUBST(TCL_SHLIB_LD)
750 AC_SUBST(TCL_SHLIB_SUFFIX)
751 AC_SUBST(TCL_PACKAGE_PATH)
752 AC_SUBST(TCL_LD_SEARCH_FLAGS)
753 AC_SUBST(TCL_STUB_LIB_SPEC)
754 AC_SUBST(TCL_VERSION)
755 AC_SUBST(TCL_PACKAGE_DIR)
757 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
758 [],[enable_python=yes])
760 if test "$enable_python" = "yes"; then
761 dnl Check for python
762 AM_PATH_PYTHON(2.3,[],[enable_python=no])
763 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
764 fi
766 if test x$enable_python = xno; then
767 COMP_PYTHON=
768 else
769 COMP_PYTHON="python"
770 fi
772 AC_SUBST(COMP_PYTHON)
774 dnl Check for nroff
775 AC_PATH_PROGS(NROFF, gnroff nroff)
776 AC_PATH_PROGS(TROFF, groff troff)
778 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
779 if test -z "$RRDDOCDIR"; then
780 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
783 CONFIGURE_PART(Apply Configuration Information)
785 AC_CONFIG_FILES([examples/shared-demo.pl])
786 AC_CONFIG_FILES([examples/piped-demo.pl])
787 AC_CONFIG_FILES([examples/stripes.pl])
788 AC_CONFIG_FILES([examples/bigtops.pl])
789 AC_CONFIG_FILES([examples/minmax.pl])
790 AC_CONFIG_FILES([examples/4charts.pl])
791 AC_CONFIG_FILES([examples/perftest.pl])
792 AC_CONFIG_FILES([examples/Makefile])
793 AC_CONFIG_FILES([doc/Makefile])
794 AC_CONFIG_FILES([src/Makefile])
795 AC_CONFIG_FILES([bindings/Makefile])
796 AC_CONFIG_FILES([bindings/tcl/Makefile])
797 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
798 AC_CONFIG_FILES([Makefile])
800 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
801 AC_OUTPUT
803 AC_MSG_CHECKING(in)
804 AC_MSG_RESULT(and out again)
806 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
807 sleep 1
808 echo $ECHO_N ".$ECHO_C" 1>&6
809 sleep 1
810 echo $ECHO_N ".$ECHO_C" 1>&6
811 sleep 1
812 echo $ECHO_N ".$ECHO_C" 1>&6
813 sleep 1
814 echo $ECHO_N ".$ECHO_C" 1>&6
815 sleep 1
816 AC_MSG_RESULT([ just kidding ;-)])
817 echo
818 echo "----------------------------------------------------------------"
819 echo "Config is DONE!"
820 echo
821 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
822 echo " Perl Modules: $COMP_PERL"
823 echo " Perl Binary: $PERL"
824 echo " Perl Version: $PERL_VERSION"
825 echo " Perl Options: $PERL_MAKE_OPTIONS"
826 echo " Ruby Modules: $COMP_RUBY"
827 echo " Ruby Binary: $RUBY"
828 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
829 echo " Build Tcl Bindings: $enable_tcl"
830 echo " Build Python Bindings: $enable_python"
831 echo " Build rrdcgi: $enable_rrdcgi"
832 echo " Build librrd MT: $enable_pthread"
833 echo
834 echo
835 echo "Type 'make' to compile the software and use 'make install' to "
836 echo "install everything to: $prefix."
837 echo
838 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
839 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
840 echo "place an order."
841 echo
842 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
843 echo "----------------------------------------------------------------"