1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
10 dnl the official version number is
11 dnl a.b.c
12 AC_INIT([rrdtool],[1.3.2])
14 dnl for testing a numberical version number comes handy
15 dnl the released version are
16 dnl a.bccc
17 dnl the devel versions will be something like
18 dnl a.b999yymmddhh
19 NUMVERS=1.3002
20 AC_SUBST(NUMVERS)
22 dnl for the linker to understand which versions the library are compatible with
23 dnl each other we must keep a separate library version cout of the format c:r:a.
24 dnl - if only implementation changed but all interfaces are kept, do r++
25 dnl - if only functionality was added do c++,r=0,a++
26 dnl - if any functionality was removed do c++,r=0,a=0.
27 dnl
28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
29 dnl
30 LIBVERS=4:1:0
31 AC_SUBST(LIBVERS)
33 AC_CANONICAL_TARGET
34 AM_INIT_AUTOMAKE
35 AM_MAINTAINER_MODE
37 AC_CONFIG_HEADERS([rrd_config.h])
39 dnl all our local stuff like install scripts and include files
40 dnl is in there
43 dnl determine the type of system we are running on
45 AC_SUBST(VERSION)
47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
49 dnl Minimum Autoconf version required.
50 AC_PREREQ(2.59)
52 dnl At the TOP of the HEADER
54 AH_TOP([
55 #ifndef RRD_CONFIG_H
56 #define RRD_CONFIG_H
58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
59 #undef MUST_DISABLE_FPMASK
61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
62 #undef MUST_DISABLE_SIGFPE
64 /* realloc does not support NULL as argument */
65 #undef NO_NULL_REALLOC
67 /* lets enable madvise defines in NetBSD */
68 #if defined(__NetBSD__)
69 # if !defined(_NETBSD_SOURCE)
70 # define _NETBSD_SOURCE
71 # endif
72 #endif
74 ])
76 AH_BOTTOM([
78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
79 # include <malloc/malloc.h>
80 #endif
82 #include <rrd_config_bottom.h>
84 #endif
85 ])
87 dnl Process Special Options
88 dnl -----------------------------------
90 dnl How the vertical axis label is printed
91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
92 [Vertical label angle: -90.0 (default) or 90.0])
93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
94 [Vertical label angle: -90.0 (default) or 90.0])
96 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
97 [],[enable_rrdcgi=yes])
99 dnl Check if we run on a system that has fonts
100 AC_ARG_WITH(rrd-default-font,
101 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
102 [RRD_DEFAULT_FONT=$withval],[
103 if test -d ${WINDIR:-nodir}/cour.ttf ; then
104 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
105 else
106 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
107 fi
108 ])
110 dnl Use mmap in rrd_update instead of seek+write
111 AC_ARG_ENABLE([mmap],
112 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
113 [],
114 [enable_mmap=yes])
116 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
117 [],[enable_pthread=yes])
119 AC_ARG_ENABLE(static-programs,
120 [ --enable-static-programs Build static programs],
121 [case "${enableval}" in
122 yes) staticprogs=yes ;;
123 no) staticprogs=no ;;
124 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
125 esac],[staticprogs=no])
126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
129 CONFIGURE_PART(Audit Compilation Environment)
132 dnl Check for the compiler and static/shared library creation.
133 AC_PROG_CPP
134 AC_PROG_CC
135 AM_PROG_CC_C_O
136 AC_PROG_LIBTOOL
138 dnl Try to detect/use GNU features
139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
141 dnl check for -Werror separatly
142 dnl (quite a few autotool checks don't work with -Werror; also, the
143 dnl check for -Werror fails after checking and adding the other flags)
144 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
145 [AC_COMPILE_IFELSE(
146 [AC_LANG_PROGRAM([[]], [[return 0 ]])],
147 [rd_cv_gcc_flag__Werror="yes"],
148 [rd_cv_gcc_flag__Werror="no"])])
149 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
150 WERROR="-Werror"
151 else
152 WERROR=""
153 fi
154 AC_SUBST(WERROR)
156 dnl which flags does the compiler support?
157 if test "x$GCC" = "xyes"; then
158 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
159 oCFLAGS="$CFLAGS"
160 CFLAGS="$CFLAGS $flag"
161 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
162 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
163 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
164 if eval test \$$cachename = no; then
165 CFLAGS="$oCFLAGS"
166 fi
167 done
168 fi
172 AC_SUBST(RRD_DEFAULT_FONT)
174 CONFIGURE_PART(Checking for Header Files)
176 dnl Checks for header files.
177 AC_HEADER_STDC
178 AC_HEADER_DIRENT
179 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
181 dnl Checks for typedefs, structures, and compiler characteristics.
182 AC_C_CONST
183 AC_HEADER_TIME
184 AC_STRUCT_TM
186 CONFIGURE_PART(Test Library Functions)
188 dnl Checks for libraries.
189 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
192 dnl add pic flag in any case this makes sure all our code is relocatable
193 eval `./libtool --config | grep pic_flag`
194 CFLAGS="$CFLAGS $pic_flag"
197 dnl Checks for library functions.
198 AC_FUNC_STRFTIME
199 AC_FUNC_VPRINTF
201 AC_C_BIGENDIAN
203 dnl for each function found we get a definition in config.h
204 dnl of the form HAVE_FUNCTION
206 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
208 CONFIGURE_PART(Map/Fadvis/Madvise checking)
210 dnl Could use these to know if we need to provide a prototype
211 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
213 dnl check for fdatasync. Solaris has fdatasync in the librt
215 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
216 dnl if there is no fdatasync we may get lucky with fsync
217 AC_CHECK_FUNCS(fsync)
220 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
221 if test "x$enable_mmap" = "xyes"; then
222 case "$host" in
223 *cygwin*)
224 # the normal mmap test does not work in cygwin
225 AC_CHECK_FUNCS(mmap)
226 if test "x$ac_cv_func_mmap" = "xyes"; then
227 ac_cv_func_mmap_fixed_mapped=yes
228 fi
229 ;;
230 *)
231 AC_CHECK_HEADERS(sys/mman.h)
232 AC_FUNC_MMAP
233 AC_CHECK_FUNCS(mmap munmap msync)
234 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
235 # include <sys/mman.h>
236 #endif])
237 if test "x$ac_cv_have_decl_madvise" = "xyes";
238 then
239 AC_CHECK_FUNCS(madvise)
240 else
241 AC_CHECK_FUNCS(posix_madvise)
242 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
243 AC_MSG_WARN([madvise() nor posix_madvise() found.])
244 fi
245 fi
246 ;;
247 esac
248 if test "x$ac_cv_func_mmap" != "xyes";
249 then
250 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
251 dnl enable_mmap="no"
252 fi
253 fi
255 dnl can we use posix_fadvise
256 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
257 #include <fcntl.h>])
258 AC_CHECK_FUNCS(posix_fadvise)
260 CONFIGURE_PART(Libintl Processing)
263 dnl gettext
264 GETTEXT_PACKAGE=rrdtool
265 AC_SUBST(GETTEXT_PACKAGE)
266 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
268 AM_GLIB_GNU_GETTEXT()
270 AC_ARG_ENABLE(libintl,[ --disable-libintl i18n support (libintl)],
271 [],[enable_libintl=yes])
273 if test x$enable_libintl = xyes; then
274 IT_PROG_INTLTOOL([0.35.0],[no-xml])
275 fi
277 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
278 AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
279 enable_libintl=no
280 fi
282 if test x$enable_libintl = xyes; then
283 AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
284 fi
286 if test x$enable_libintl = xyes ; then
287 dnl it seems bsd synstems need to link against libintl
288 dnl when compiling rrdupdate. lets check
289 AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
290 fi
292 dnl use for linking rrdupdate
293 AC_SUBST(LIB_LIBINTL)
295 dnl do not touch the po stuff if we are not going to build intl
296 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
298 if test x$enable_libintl = xyes; then
299 AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
300 fi
302 CONFIGURE_PART(IEEE Math Checks)
305 dnl actual code to check if this works
306 AC_CHECK_FUNCS(fpclassify, ,
307 [AC_MSG_CHECKING(for fpclassify with <math.h>)
308 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
309 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
310 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
312 AC_CHECK_FUNCS(isinf, ,
313 [AC_MSG_CHECKING(for isinf with <math.h>)
314 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
315 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
316 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
318 dnl finite is BSD, isfinite is C99, so prefer the latter
319 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
320 AC_TRY_RUN([
321 #ifdef HAVE_MATH_H
322 #include <math.h>
323 #endif
324 #ifdef HAVE_FLOAT_H
325 #include <float.h>
326 #endif
327 int main ()
328 {
329 #ifdef isfinite
330 #ifdef LDBL_MAX
331 if (!isfinite(LDBL_MAX)) return 1;
332 #endif
333 #ifdef DBL_MAX
334 if (!isfinite(DBL_MAX)) return 1;
335 #endif
336 #endif
337 return 0;
338 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
339 case "${target}" in
340 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
341 *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
342 *) ac_cv_have_broken_isfinite=no ;;
343 esac])
344 ])
346 dnl the test does not seem to work on solaris 2.8
347 dnl so lets fix this by hand
348 case "${target}" in
349 *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
350 esac
352 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
353 AC_DEFINE(HAVE_ISFINITE)
354 else
355 AC_CHECK_FUNCS(finite,[],
356 [AC_CHECK_FUNCS(isfinite,[],
357 [AC_MSG_CHECKING(for isfinite with <math.h>)
358 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
359 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
360 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
361 fi
363 AC_FULL_IEEE
365 CONFIGURE_PART(Resolve Portability Issues)
367 dnl Do we need getopt_long
369 build_getopt=no
370 RRD_GETOPT_LONG="#"
371 AC_CHECK_FUNC(getopt_long,[],[
372 RRD_GETOPT_LONG="getopt_long"
373 build_getopt=yes
374 ])
375 AC_SUBST(RRD_GETOPT_LONG)
376 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
378 dnl what does realloc do if it gets called with a NULL pointer
380 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
381 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
382 int main(void){
383 char *x = NULL;
384 x = realloc (x,10);
385 if (x==NULL) return 1;
386 return 0;
387 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
389 if test x"$rd_cv_null_realloc" = xnope; then
390 AC_DEFINE(NO_NULL_REALLOC)
391 fi
393 AC_LANG_PUSH(C)
394 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
395 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
396 AC_LINK_IFELSE(
397 AC_LANG_PROGRAM(
398 [[#include <time.h>]],
399 [[ctime_r(NULL,NULL,0)]]
400 ),
401 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
402 AC_LINK_IFELSE(
403 AC_LANG_PROGRAM(
404 [[#include <time.h>]],
405 [[ctime_r(NULL,NULL)]]
406 ),
407 [AC_MSG_RESULT([yes, this seems to be solaris style])],
408 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
409 )
410 ],
411 [ AC_LINK_IFELSE(
412 AC_LANG_PROGRAM(
413 [[#include <time.h>]],
414 [[ctime_r(NULL,NULL)]]
415 ),
416 [AC_MSG_RESULT(no)],
417 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
418 )
419 ]
420 )
421 AC_LANG_POP(C)
423 dnl Check for pthreads
424 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
426 AC_SUBST(MULTITHREAD_CFLAGS)
427 AC_SUBST(MULTITHREAD_LDFLAGS)
429 if test $enable_pthread != no; then
430 ACX_PTHREAD([
431 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
432 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
433 ],
434 [])
435 fi
437 dnl since we use lots of *_r functions all over the code we better
438 dnl make sure they are known
440 if test "x$x_rflag" != "xno"; then
441 CPPFLAGS="$CPPFLAGS $x_rflag"
442 fi
444 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
446 AC_LANG_PUSH(C)
447 dnl see if we have to include malloc/malloc.h
448 AC_MSG_CHECKING([do we need malloc/malloc.h])
449 AC_LINK_IFELSE(
450 AC_LANG_PROGRAM(
451 [[#include <stdlib.h>]],
452 [[malloc(1)]]
453 ),
454 [ AC_MSG_RESULT([nope, works out of the box]) ],
455 [ AC_LINK_IFELSE(
456 AC_LANG_PROGRAM(
457 [[#include <stdlib.h>
458 #include <malloc/malloc.h>]],
459 [[malloc(1)]]
460 ),[
461 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
462 AC_MSG_RESULT([yes we do])],
463 [AC_MSG_ERROR([Can not figure how to compile malloc])]
464 )
465 ]
466 )
467 AC_LANG_POP(C)
469 CONFIGURE_PART(Find 3rd-Party Libraries)
472 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
475 CORE_LIBS="$LIBS"
477 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
478 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
479 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
480 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
481 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
482 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
483 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
484 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
485 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
486 EX_CHECK_ALL(pango-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
487 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
489 if test "$EX_CHECK_ALL_ERR" = "YES"; then
490 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
491 fi
493 ALL_LIBS="$LIBS"
494 LIBS=
496 AC_SUBST(CORE_LIBS)
497 AC_SUBST(ALL_LIBS)
499 CONFIGURE_PART(Prep for Building Language Bindings)
501 dnl Check for Perl and friends
502 PATH=$PATH:/usr/perl5/bin
503 export PATH
504 AC_PATH_PROG(PERL, perl, no)
505 AC_PATH_PROG(POD2MAN, pod2man, no)
506 AC_PATH_PROG(POD2HTML, pod2html, no)
509 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
510 [],[enable_perl=yes])
513 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
514 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
515 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
516 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
518 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
519 COMP_PERL=
520 else
521 COMP_PERL="perl_piped perl_shared"
522 AC_MSG_CHECKING(for the perl version you are running)
523 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
524 AC_MSG_RESULT($PERL_VERSION)
525 if test -z "$PERLCC"; then
526 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
527 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
528 AC_MSG_RESULT($perlcc)
529 if test ! -x "$perlcc"; then
530 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
531 if test "$PERL_CC" = "no"; then
532 AC_MSG_WARN([
533 I would not find the Compiler ($perlcc) that was originally used to compile
534 your perl binary. You should either make sure that this compiler is
535 available on your system, pick an other compiler and set PERLCC
536 appropriately, or use a different perl setup that was compiled locally.
538 I will disable the compilation of the RRDs perl module for now.
539 ])
540 COMP_PERL="perl_piped"
541 fi
542 fi
543 fi
544 fi
546 AC_MSG_CHECKING(Perl Modules to build)
547 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
549 # Options to pass when configuring perl module
550 langpref=$prefix
551 test "$langpref" = "$(DESTDIR)NONE" && langpref='$(DESTDIR)'$ac_default_prefix
552 test "$langpref" = "NONE" && langpref=$ac_default_prefix
554 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
556 dnl pass additional perl options when generating Makefile from Makefile.PL
557 AC_ARG_ENABLE(perl-site-install,
558 [ --enable-perl-site-install by default the rrdtool perl modules are installed
559 together with rrdtool in $prefix/lib/perl. You have to
560 put a 'use lib qw($prefix/lib/perl)' into your scripts
561 when you want to use them. When you set this option
562 the perl modules will get installed wherever
563 your perl setup thinks it is best.],
564 [PERL_MAKE_OPTIONS=],[])
566 if test ! -z "$PERLCC"; then
567 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
569 if test ! -z "$PERLCCFLAGS"; then
570 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
571 fi
573 if test -z "$PERLLD"; then
574 PERLLD=$PERLCC
575 fi
576 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
578 if test ! -z "$PERLLDFLAGS"; then
579 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
580 fi
581 fi
583 AC_ARG_WITH(perl-options,
584 [ --with-perl-options=[OPTIONS] options to pass on command-line when
585 generating Makefile from Makefile.PL. If you set this
586 option, interesting things may happen unless you know
587 what you are doing!],
588 [PERL_MAKE_OPTIONS=$withval])
590 AC_SUBST(PERL_MAKE_OPTIONS)
591 AC_SUBST(PERL)
592 AC_SUBST(COMP_PERL)
593 AC_SUBST(PERL_VERSION)
595 dnl Check for Ruby.
596 AC_PATH_PROG(RUBY, ruby, no)
598 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
599 [],[enable_ruby=yes])
601 AC_MSG_CHECKING(if ruby modules can be built)
603 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
604 COMP_RUBY=
605 AC_MSG_RESULT(No .. Ruby not found or disabled)
606 else
607 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
608 COMP_RUBY="ruby"
609 AC_MSG_RESULT(YES)
610 else
611 COMP_RUBY=
612 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
613 fi
614 fi
616 dnl pass additional ruby options when generating Makefile from Makefile.PL
617 AC_ARG_ENABLE(ruby-site-install,
618 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
619 together with rrdtool in $prefix/lib/ruby. You have to
620 add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable
621 for ruby to find the RRD.so file.],
622 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
625 AC_ARG_WITH(ruby-options,
626 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
627 generating Makefile from extconf.rb. If you set this
628 option, interesting things may happen unless you know
629 what you are doing!],
630 [RUBY_MAKE_OPTIONS=$withval])
632 AC_SUBST(RUBY_MAKE_OPTIONS)
633 AC_SUBST(RUBY)
634 AC_SUBST(COMP_RUBY)
636 dnl Check for Lua.
637 AC_PATH_PROG(LUA, lua, no)
639 AC_ARG_ENABLE(lua,[ --disable-lua do not build the lua modules],
640 [],[enable_lua=yes])
642 AC_MSG_CHECKING(if lua modules can be built)
644 COMP_LUA=
645 if test "x$LUA" = "xno" -o x$enable_lua = xno; then
646 AC_MSG_RESULT(No .. Lua not found or disabled)
647 else
648 for dir in /usr/include/lua /usr/include/lua5.1 /usr/local/include/lua5.1 /usr/include/lua5.2 /usr/local/include/lua5.2 ; do
649 if test -f "$dir/lualib.h" ; then
650 enable_lua=yes
651 COMP_LUA="lua"
652 break
653 fi
654 done
656 if test "$COMP_LUA" = "lua" ; then
657 AC_MSG_RESULT(YES)
658 else
659 AC_MSG_RESULT(Lua found but lualib.h is missing! Install the -dev package)
660 fi
661 fi
663 dnl pass additional lua options
664 # if lua-site-install is set, don't set 'LIB' and let Lua setup decide
665 # the best place.
666 AC_ARG_ENABLE(lua-site-install,
667 [ --enable-lua-site-install by default the rrdtool lua modules are installed
668 together with rrdtool in $prefix/lib/lua. You have to
669 add $prefix/lib/lua/$lua_version/?.so to package.cpath
670 for lua to find the rrd.so file.]. When you set this
671 option the Lua module will get installed wherever
672 your Lua setup thinks it is best.],
673 [LUA_MAKE_OPTIONS=],[LUA_MAKE_OPTIONS="LIB=$langpref/lib/lua"])
675 AC_SUBST(LUA_MAKE_OPTIONS)
676 AC_SUBST(LUA)
677 AC_SUBST(COMP_LUA)
680 enable_tcl_site=no
682 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
683 [],[enable_tcl=yes])
685 if test "$enable_tcl" = "yes"; then
686 dnl Check for Tcl.
687 withval=""
688 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
689 enable_tcl=no
690 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
691 AC_MSG_CHECKING(for tclConfig.sh in $dir)
692 if test -f "$dir/tclConfig.sh" ; then
693 tcl_config=$dir/tclConfig.sh
694 enable_tcl=yes
695 AC_MSG_RESULT(yes)
696 break
697 else
698 AC_MSG_RESULT(no)
699 fi
700 done
702 if test "$enable_tcl" = "no"; then
703 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
704 else
705 . $tcl_config
706 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
707 if test -n "$TCL_INC_DIR"; then
708 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
709 fi
710 fi
711 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
712 [],[enable_tcl_site=yes])
714 fi
716 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
717 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
720 AC_SUBST(TCL_PREFIX)
721 AC_SUBST(TCL_SHLIB_CFLAGS)
722 AC_SUBST(TCL_SHLIB_LD)
723 AC_SUBST(TCL_SHLIB_SUFFIX)
724 AC_SUBST(TCL_PACKAGE_PATH)
725 AC_SUBST(TCL_LD_SEARCH_FLAGS)
726 AC_SUBST(TCL_STUB_LIB_SPEC)
727 AC_SUBST(TCL_VERSION)
728 AC_SUBST(TCL_PACKAGE_DIR)
729 AC_SUBST(TCL_INCLUDE_SPEC)
731 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
732 [],[enable_python=yes])
734 if test "$enable_python" = "yes"; then
735 dnl Check for python
736 AM_PATH_PYTHON(2.3,[],[enable_python=no])
737 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
738 fi
740 if test x$enable_python = xno; then
741 COMP_PYTHON=
742 else
743 COMP_PYTHON="python"
744 fi
746 AC_SUBST(COMP_PYTHON)
748 dnl Check for nroff
749 AC_PATH_PROGS(NROFF, gnroff nroff)
750 AC_PATH_PROGS(TROFF, groff troff)
752 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
753 if test -z "$RRDDOCDIR"; then
754 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
757 CONFIGURE_PART(Apply Configuration Information)
759 AC_CONFIG_FILES([examples/shared-demo.pl])
760 AC_CONFIG_FILES([examples/piped-demo.pl])
761 AC_CONFIG_FILES([examples/stripes.pl])
762 AC_CONFIG_FILES([examples/bigtops.pl])
763 AC_CONFIG_FILES([examples/minmax.pl])
764 AC_CONFIG_FILES([examples/4charts.pl])
765 AC_CONFIG_FILES([examples/perftest.pl])
766 AC_CONFIG_FILES([examples/Makefile])
767 AC_CONFIG_FILES([doc/Makefile])
768 AC_CONFIG_FILES([po/Makefile.in])
769 AC_CONFIG_FILES([src/Makefile])
770 AC_CONFIG_FILES([src/librrd.sym])
771 AC_CONFIG_FILES([src/librrd.pc])
772 AC_CONFIG_FILES([bindings/Makefile])
773 AC_CONFIG_FILES([bindings/tcl/Makefile])
774 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
775 AC_CONFIG_FILES([Makefile])
777 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
778 AC_OUTPUT
780 AC_MSG_CHECKING(in)
781 AC_MSG_RESULT(and out again)
783 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
784 sleep 1
785 echo $ECHO_N ".$ECHO_C" 1>&6
786 sleep 1
787 echo $ECHO_N ".$ECHO_C" 1>&6
788 sleep 1
789 echo $ECHO_N ".$ECHO_C" 1>&6
790 sleep 1
791 echo $ECHO_N ".$ECHO_C" 1>&6
792 sleep 1
793 AC_MSG_RESULT([ just kidding ;-)])
794 echo
795 echo "----------------------------------------------------------------"
796 echo "Config is DONE!"
797 echo
798 echo " With MMAP IO: $enable_mmap"
799 echo " Build rrd_getopt: $build_getopt"
800 echo " Static programs: $staticprogs"
801 echo " Perl Modules: $COMP_PERL"
802 echo " Perl Binary: $PERL"
803 echo " Perl Version: $PERL_VERSION"
804 echo " Perl Options: $PERL_MAKE_OPTIONS"
805 echo " Ruby Modules: $COMP_RUBY"
806 echo " Ruby Binary: $RUBY"
807 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
808 echo " Lua Modules: $COMP_LUA"
809 echo " Lua Binary: $LUA"
810 echo " Lua Options: $LUA_MAKE_OPTIONS"
811 echo " Build Tcl Bindings: $enable_tcl"
812 echo " Build Python Bindings: $enable_python"
813 echo " Build rrdcgi: $enable_rrdcgi"
814 echo " Build librrd MT: $enable_pthread"
815 echo " Link with libintl: $enable_libintl"
816 echo
817 echo " Libraries: $ALL_LIBS"
818 echo
819 echo "Type 'make' to compile the software and use 'make install' to "
820 echo "install everything to: $prefix."
821 echo
822 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
823 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
824 echo "place an order."
825 echo
826 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
827 echo "----------------------------------------------------------------"