1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.12])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devl versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.2012
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
30 AC_SUBST(VERSION)
32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
34 dnl Minimum Autoconf version required.
35 AC_PREREQ(2.59)
37 dnl At the TOP of the HEADER
39 AH_TOP([
41 #ifndef CONFIG_H
42 #define CONFIG_H
43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
44 #undef MUST_DISABLE_FPMASK
46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
48 #undef MUST_DISABLE_SIGFPE
50 /* realloc does not support NULL as argument */
51 #undef NO_NULL_REALLOC
53 ])
55 AH_BOTTOM([
57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
58 make sure you are NOT using bcopy, index or rindex in the code */
60 #if STDC_HEADERS
61 # include <string.h>
62 #else
63 # ifndef HAVE_STRCHR
64 # define strchr index
65 # define strrchr rindex
66 # endif
67 char *strchr (), *strrchr ();
68 # ifndef HAVE_MEMMOVE
69 # define memcpy(d, s, n) bcopy ((s), (d), (n))
70 # define memmove(d, s, n) bcopy ((s), (d), (n))
71 # endif
72 #endif
75 #if NO_NULL_REALLOC
76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
77 #else
78 # define rrd_realloc(a,b) realloc((a), (b))
79 #endif
81 #if NEED_MALLOC_MALLOC_H
82 # include <malloc/malloc.h>
83 #endif
85 #if HAVE_MATH_H
86 # include <math.h>
87 #endif
89 #if HAVE_FLOAT_H
90 # include <float.h>
91 #endif
93 #if HAVE_IEEEFP_H
94 # include <ieeefp.h>
95 #endif
97 #if HAVE_FP_CLASS_H
98 # include <fp_class.h>
99 #endif
101 /* for Solaris */
102 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
103 # define HAVE_ISINF 1
104 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
105 #endif
107 /* for OSF1 Digital Unix */
108 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
109 # define HAVE_ISINF 1
110 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
111 #endif
113 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
114 # define HAVE_ISINF 1
115 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
116 #endif
118 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
119 # define HAVE_ISINF 1
120 # define isinf(a) (fpclassify(a) == FP_INFINITE)
121 #endif
123 /* for AIX */
124 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
125 # define HAVE_ISINF 1
126 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
127 #endif
129 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
130 # define HAVE_FINITE 1
131 # define finite(a) isfinite(a)
132 #endif
134 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
135 # define HAVE_FINITE 1
136 # define finite(a) (! isnan(a) && ! isinf(a))
137 #endif
139 #ifndef HAVE_FINITE
140 #error "Can't compile without finite function"
141 #endif
143 #ifndef HAVE_ISINF
144 #error "Can't compile without isinf function"
145 #endif
147 #endif /* CONFIG_H */
148 ])
150 dnl Process Special Options
151 dnl -----------------------------------
153 dnl How the vertical axis label is printed
154 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
155 [Vertical label angle: 90.0 (default) or 270.0])
156 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
157 [Vertical label angle: 90.0 (default) or 270.0])
159 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
160 [],[enable_rrdcgi=yes])
162 dnl Check if we run on a system that has fonts
163 AC_ARG_WITH(rrd-default-font,
164 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
165 [RRD_DEFAULT_FONT=$withval],[
166 if test -d ${WINDIR:-nodir}/cour.ttf ; then
167 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
168 else
169 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
170 fi
171 ])
173 dnl Use mmap in rrd_update instead of seek+write
174 AC_ARG_ENABLE([mmap],
175 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
176 [],
177 [enable_mmap=yes])
180 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
181 [],[enable_pthread=yes])
185 CONFIGURE_PART(Audit Compilation Environment)
188 dnl Check for the compiler and static/shared library creation.
189 AC_PROG_CC
190 AC_PROG_CPP
191 AC_PROG_LIBTOOL
194 AC_SUBST(RRD_DEFAULT_FONT)
196 CONFIGURE_PART(Checking for Header Files)
198 dnl Checks for header files.
199 AC_HEADER_STDC
200 AC_HEADER_DIRENT
201 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
203 dnl Checks for typedefs, structures, and compiler characteristics.
204 AC_C_CONST
205 AC_HEADER_TIME
206 AC_STRUCT_TM
208 dnl Checks for libraries.
209 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
211 dnl add pic flag in any case this makes sure all our code is relocatable
212 eval `./libtool --config | grep pic_flag`
213 CFLAGS="$CFLAGS $pic_flag"
215 CONFIGURE_PART(Test Library Functions)
217 dnl Checks for library functions.
218 AC_FUNC_STRFTIME
219 AC_FUNC_VPRINTF
221 AC_C_BIGENDIAN
223 dnl for each function found we get a definition in config.h
224 dnl of the form HAVE_FUNCTION
226 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
229 if test "x$enable_mmap" = xyes; then
230 case "$host" in
231 *cygwin*)
232 # the normal mmap test does not work in cygwin
233 AC_CHECK_FUNCS(mmap)
234 if [ "x${ac_cv_func_mmap}" = xyes ]; then
235 ac_cv_func_mmap_fixed_mapped=yes
236 fi
237 ;;
238 *)
239 AC_FUNC_MMAP
240 ;;
241 esac
242 fi
245 CONFIGURE_PART(IEEE Math Checks)
247 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
248 dnl actual code to check if this works
249 AC_CHECK_FUNCS(fpclassify, ,
250 [AC_MSG_CHECKING(for fpclassify with <math.h>)
251 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
252 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
253 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
254 AC_CHECK_FUNCS(finite, ,
255 [AC_CHECK_FUNCS(isfinite, ,
256 [AC_MSG_CHECKING(for isfinite with <math.h>)
257 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
258 volatile int x;volatile float f; ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
259 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
260 AC_CHECK_FUNCS(isinf, ,
261 [AC_MSG_CHECKING(for isinf with <math.h>)
262 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
263 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
264 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
266 AC_FULL_IEEE
268 CONFIGURE_PART(Resolve Portability Issues)
270 dnl what does realloc do if it gets called with a NULL pointer
272 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
273 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
274 int main(void){
275 char *x = NULL;
276 x = realloc (x,10);
277 if (x==NULL) return 1;
278 return 0;
279 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
281 if test x"$rd_cv_null_realloc" = xnope; then
282 AC_DEFINE(NO_NULL_REALLOC)
283 fi
285 AC_LANG_PUSH(C)
286 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
287 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
288 AC_LINK_IFELSE(
289 AC_LANG_PROGRAM(
290 [[#include <time.h>]],
291 [[ctime_r(NULL,NULL,0)]]
292 ),
293 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
294 AC_LINK_IFELSE(
295 AC_LANG_PROGRAM(
296 [[#include <time.h>]],
297 [[ctime_r(NULL,NULL)]]
298 ),
299 [AC_MSG_RESULT([yes, this seems to be solaris style])],
300 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
301 )
302 ],
303 [ AC_LINK_IFELSE(
304 AC_LANG_PROGRAM(
305 [[#include <time.h>]],
306 [[ctime_r(NULL,NULL)]]
307 ),
308 [AC_MSG_RESULT(no)],
309 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
310 )
311 ]
312 )
313 AC_LANG_POP(C)
315 dnl Check for pthreads
316 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
318 AC_SUBST(MULTITHREAD_CFLAGS)
319 AC_SUBST(MULTITHREAD_LDFLAGS)
321 if test $enable_pthread != no; then
322 ACX_PTHREAD([
323 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
324 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
325 ],
326 [])
327 fi
329 dnl since we use lots of *_r functions all over the code we better
330 dnl make sure they are known
332 if test "x$x_rflag" != "xno"; then
333 CPPFLAGS="$CPPFLAGS $x_rflag"
334 fi
336 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
338 AC_LANG_PUSH(C)
339 dnl see if we have to include malloc/malloc.h
340 AC_MSG_CHECKING([do we need malloc/malloc.h])
341 AC_LINK_IFELSE(
342 AC_LANG_PROGRAM(
343 [[#include <stdlib.h>]],
344 [[malloc(1)]]
345 ),
346 [ AC_MSG_RESULT([nope, works out of the box]) ],
347 [ AC_LINK_IFELSE(
348 AC_LANG_PROGRAM(
349 [[#include <stdlib.h>
350 #include <malloc/malloc.h>]],
351 [[malloc(1)]]
352 ),
353 [AC_DEFINE(NEED_MALLOC_MALLOC_H)
354 AC_MSG_RESULT([yes we do])],
355 [AC_MSG_ERROR([Can't figure how to compile malloc])]
356 )
357 ]
358 )
359 AC_LANG_POP(C)
361 CONFIGURE_PART(Findr 3rd-Party Libraries)
364 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
366 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
367 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.2, http://www.gzip.org/zlib/, "")
368 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.8, http://prdownloads.sourceforge.net/libpng/, "")
369 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.9, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
371 if test "$EX_CHECK_ALL_ERR" = "YES"; then
372 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
373 fi
376 CONFIGURE_PART(Prep for Building Language Bindings)
378 dnl Check for Perl.
379 AC_PATH_PROG(PERL, perl, no)
381 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
382 [],[enable_perl=yes])
385 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
386 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
387 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
388 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
390 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
391 COMP_PERL=
392 else
393 COMP_PERL="perl_piped perl_shared"
394 AC_MSG_CHECKING(for the perl version you are running)
395 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
396 AC_MSG_RESULT($PERL_VERSION)
397 if test -z "$PERLCC"; then
398 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
399 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
400 AC_MSG_RESULT($perlcc)
401 if test ! -x "$perlcc"; then
402 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
403 if test "$PERL_CC" = "no"; then
404 AC_MSG_WARN([
405 I would not find the Compiler ($perlcc) that was originally used to compile
406 your perl binary. You should either make sure that this compiler is
407 available on your system, pick an other compiler and set PERLCC
408 appropriately, or use a different perl setup that was compiled locally.
410 I will disable the compilation of the RRDs perl module for now.
411 ])
412 COMP_PERL="perl_piped"
413 fi
414 fi
415 fi
416 fi
418 AC_MSG_CHECKING(Perl Modules to build)
419 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
421 # Options to pass when configuring perl module
422 ppref=$prefix
423 test "$ppref" = "NONE" && ppref=$ac_default_prefix
425 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
427 dnl pass additional perl options when generating Makefile from Makefile.PL
428 AC_ARG_ENABLE(perl-site-install,
429 [ --enable-perl-site-install by default the rrdtool perl modules are installed
430 together with rrdtool in $prefix/lib/perl. You have to
431 put a 'use lib qw($prefix/lib/perl)' into your scripts
432 when you want to use them. When you set this option
433 the perl modules will get installed wherever
434 your perl setup thinks it is best.],
435 [PERL_MAKE_OPTIONS=],[])
437 if test ! -z "$PERLCC"; then
438 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
440 if test ! -z "$PERLCCFLAGS"; then
441 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
442 fi
444 if test -z "$PERLLD"; then
445 PERLLD=$PERLCC
446 fi
447 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
449 if test ! -z "$PERLLDFLAGS"; then
450 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
451 fi
452 fi
454 AC_ARG_WITH(perl-options,
455 [ --with-perl-options=[OPTIONS] options to pass on command-line when
456 generating Makefile from Makefile.PL. If you set this
457 option, interesting things may happen unless you know
458 what you are doing!],
459 [PERL_MAKE_OPTIONS=$withval])
461 AC_SUBST(PERL_MAKE_OPTIONS)
462 AC_SUBST(PERL)
463 AC_SUBST(COMP_PERL)
464 AC_SUBST(PERL_VERSION)
466 enable_tcl_site=no
468 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
469 [],[enable_tcl=yes])
471 if test "$enable_tcl" = "yes"; then
472 dnl Check for Tcl.
473 withval=""
474 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
475 enable_tcl=no
476 for dir in $withval /usr/lib /usr/local/lib; do
477 AC_MSG_CHECKING(for tclConfig.sh in $dir)
478 if test -f "$dir/tclConfig.sh" ; then
479 tcl_config=$dir/tclConfig.sh
480 enable_tcl=yes
481 AC_MSG_RESULT(yes)
482 break
483 else
484 AC_MSG_RESULT(no)
485 fi
486 done
488 if test "$enable_tcl" = "no"; then
489 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
490 else
491 . $tcl_config
492 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
493 fi
494 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
495 [],[enable_tcl_site=yes])
497 fi
499 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
500 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
502 AC_SUBST(TCL_PREFIX)
503 AC_SUBST(TCL_SHLIB_CFLAGS)
504 AC_SUBST(TCL_SHLIB_LD)
505 AC_SUBST(TCL_SHLIB_SUFFIX)
506 AC_SUBST(TCL_PACKAGE_PATH)
507 AC_SUBST(TCL_LD_SEARCH_FLAGS)
508 AC_SUBST(TCL_STUB_LIB_SPEC)
509 AC_SUBST(TCL_VERSION)
510 AC_SUBST(TCL_PACKAGE_DIR)
512 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
513 [],[enable_python=yes])
515 if test "$enable_python" = "yes"; then
516 dnl Check for python
517 AM_PATH_PYTHON(2.3,[],[enable_python=no])
518 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
519 fi
521 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
523 dnl Check for nroff
524 AC_PATH_PROGS(NROFF, gnroff nroff)
525 AC_PATH_PROGS(TROFF, groff troff)
527 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
528 if test -z "$RRDDOCDIR"; then
529 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
531 dnl Does the compiler like -Wall and -pedantic?
532 if test "$GCC" = "yes"; then
533 oCFLAGS=$CFLAGS
534 CFLAGS="$CFLAGS -fno-strict-aliasing -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
535 AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
536 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
537 ]
538 )
539 if test $rd_cv_gcc_opt = no; then
540 CFLAGS=$oCFLAGS
541 fi
542 fi
545 CONFIGURE_PART(Apply Configuration Information)
547 AC_CONFIG_FILES([examples/shared-demo.pl])
548 AC_CONFIG_FILES([examples/piped-demo.pl])
549 AC_CONFIG_FILES([examples/stripes.pl])
550 AC_CONFIG_FILES([examples/bigtops.pl])
551 AC_CONFIG_FILES([examples/minmax.pl])
552 AC_CONFIG_FILES([examples/cgi-demo.cgi])
553 AC_CONFIG_FILES([examples/4charts.pl])
554 AC_CONFIG_FILES([examples/Makefile])
555 AC_CONFIG_FILES([doc/Makefile])
556 AC_CONFIG_FILES([src/Makefile])
557 AC_CONFIG_FILES([bindings/Makefile])
558 AC_CONFIG_FILES([bindings/tcl/Makefile])
559 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
560 AC_CONFIG_FILES([bindings/python/Makefile])
561 AC_CONFIG_FILES([Makefile])
563 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.cgi examples/*.pl]],[[]])
564 AC_OUTPUT
566 AC_MSG_CHECKING(in)
567 AC_MSG_RESULT(and out again)
569 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
570 sleep 1
571 echo $ECHO_N ".$ECHO_C" 1>&6
572 sleep 1
573 echo $ECHO_N ".$ECHO_C" 1>&6
574 sleep 1
575 echo $ECHO_N ".$ECHO_C" 1>&6
576 sleep 1
577 echo $ECHO_N ".$ECHO_C" 1>&6
578 sleep 1
579 AC_MSG_RESULT([ just kidding ;-)])
580 echo
581 echo "----------------------------------------------------------------"
582 echo "Config is DONE!"
583 echo
584 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
585 echo " Perl Modules: $COMP_PERL"
586 echo " Perl Binary: $PERL"
587 echo " Perl Version: $PERL_VERSION"
588 echo " Perl Options: $PERL_MAKE_OPTIONS"
589 echo " Build Tcl Bindings: $enable_tcl"
590 echo " Build Python Bindings: $enable_python"
591 echo " Build rrdcgi: $enable_rrdcgi"
592 echo " Build librrd MT: $enable_pthread"
593 echo
594 echo
595 echo "Type 'make' to compile the software and use 'make install' to "
596 echo "install everything to: $prefix."
597 echo
598 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
599 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
600 echo "place an order."
601 echo
602 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
603 echo "----------------------------------------------------------------"