1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 AC_INIT([rrdtool],[1.2.7])
10 AC_CANONICAL_TARGET
11 AM_INIT_AUTOMAKE
12 AC_CONFIG_HEADERS([config.h])
14 dnl all our local stuff like install scripts and include files
15 dnl is in there
18 dnl determine the type of system we are running on
21 AC_SUBST(VERSION)
23 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
25 dnl Minimum Autoconf version required.
26 AC_PREREQ(2.59)
28 dnl At the TOP of the HEADER
30 AH_TOP([
32 #ifndef CONFIG_H
33 #define CONFIG_H
34 /* IEEE can be prevented from raising signals with fpsetmask(0) */
35 #undef MUST_DISABLE_FPMASK
37 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
39 #undef MUST_DISABLE_SIGFPE
41 /* realloc does not support NULL as argument */
42 #undef NO_NULL_REALLOC
44 ])
46 AH_BOTTOM([
48 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
49 make sure you are NOT using bcopy, index or rindex in the code */
51 #if STDC_HEADERS
52 # include <string.h>
53 #else
54 # ifndef HAVE_STRCHR
55 # define strchr index
56 # define strrchr rindex
57 # endif
58 char *strchr (), *strrchr ();
59 # ifndef HAVE_MEMMOVE
60 # define memcpy(d, s, n) bcopy ((s), (d), (n))
61 # define memmove(d, s, n) bcopy ((s), (d), (n))
62 # endif
63 #endif
66 #if NO_NULL_REALLOC
67 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
68 #else
69 # define rrd_realloc(a,b) realloc((a), (b))
70 #endif
72 #if HAVE_MATH_H
73 # include <math.h>
74 #endif
76 #if HAVE_FLOAT_H
77 # include <float.h>
78 #endif
80 #if HAVE_IEEEFP_H
81 # include <ieeefp.h>
82 #endif
84 #if HAVE_FP_CLASS_H
85 # include <fp_class.h>
86 #endif
88 /* for Solaris */
89 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
90 # define HAVE_ISINF 1
91 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
92 #endif
94 /* for OSF1 Digital Unix */
95 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
96 # define HAVE_ISINF 1
97 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
98 #endif
100 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
101 # define HAVE_ISINF 1
102 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
103 #endif
105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
106 # define HAVE_ISINF 1
107 # define isinf(a) (fpclassify(a) == FP_INFINITE)
108 #endif
110 /* for AIX */
111 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
112 # define HAVE_ISINF 1
113 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
114 #endif
116 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
117 # define HAVE_FINITE 1
118 # define finite(a) isfinite(a)
119 #endif
121 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
122 # define HAVE_FINITE 1
123 # define finite(a) (! isnan(a) && ! isinf(a))
124 #endif
126 #ifndef HAVE_FINITE
127 #error "Can't compile without finite function"
128 #endif
130 #ifndef HAVE_ISINF
131 #error "Can't compile without isinf function"
132 #endif
134 #endif /* CONFIG_H */
135 ])
139 dnl Check for the compiler and static/shared library creation.
140 AC_PROG_CC
141 AC_PROG_CPP
142 AC_PROG_LIBTOOL
144 dnl Check if we run on a system that has fonts
145 AC_ARG_WITH(rrd-default-font,
146 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
147 [RRD_DEFAULT_FONT=$withval],[
148 if test -d ${WINDIR:-nodir}/cour.ttf ; then
149 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
150 else
151 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
152 fi
153 ])
155 AC_SUBST(RRD_DEFAULT_FONT)
157 dnl Checks for header files.
158 AC_HEADER_STDC
159 AC_HEADER_DIRENT
160 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
162 dnl Checks for typedefs, structures, and compiler characteristics.
163 AC_C_CONST
164 AC_HEADER_TIME
165 AC_STRUCT_TM
167 dnl Checks for libraries.
168 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
169 dnl Use libiconv if we have one but fall back to libc otherwhise
170 AC_CHECK_LIB(iconv, iconv_open, , [
171 AC_CHECK_FUNC(iconv_open,,)
172 ])
174 dnl add pic flag in any case this makes sure all our code is relocatable
175 eval `./libtool --config | grep pic_flag`
176 CFLAGS="$CFLAGS $pic_flag"
178 dnl Checks for library functions.
179 AC_FUNC_STRFTIME
180 AC_FUNC_VPRINTF
182 AC_C_BIGENDIAN
184 dnl for each function found we get a definition in config.h
185 dnl of the form HAVE_FUNCTION
187 AC_CHECK_FUNCS(tzset opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
189 dnl Use mmap in rrd_update instead of seek+write
190 AC_ARG_ENABLE([mmap],
191 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
192 [],
193 [enable_mmap=yes])
195 if test "x$enable_mmap" = xyes; then
196 AC_FUNC_MMAP
197 fi
199 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
200 dnl actual code to check if this works
201 AC_CHECK_FUNCS(fpclassify, ,
202 [AC_MSG_CHECKING(for fpclassify with <math.h>)
203 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
204 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
205 AC_CHECK_FUNCS(finite, ,
206 [AC_CHECK_FUNCS(isfinite, ,
207 [AC_MSG_CHECKING(for isfinite with <math.h>)
208 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
209 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
210 AC_CHECK_FUNCS(isinf, ,
211 [AC_MSG_CHECKING(for isinf with <math.h>)
212 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
213 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
215 AC_FULL_IEEE
217 dnl How the vertical axis label is printed
218 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
219 [Vertical label angle: 90.0 (default) or 270.0])
220 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
221 [Vertical label angle: 90.0 (default) or 270.0])
224 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
225 [],[enable_rrdcgi=yes])
226 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
228 if test $enable_rrdcgi != no; then
229 EX_CHECK_ALL(cgi, cgiInit, cgi.h, cgilib, 0.5, http://www.infodrom.org/projects/cgilib, "")
230 fi
231 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
232 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.2, http://www.gzip.org/zlib/, "")
233 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.8, http://prdownloads.sourceforge.net/libpng/, "")
234 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.9, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
236 if test "$EX_CHECK_ALL_ERR" = "YES"; then
237 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
238 fi
240 AC_LANG_PUSH(C)
241 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
242 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
243 AC_LINK_IFELSE(
244 AC_LANG_PROGRAM(
245 [[#include <time.h>]],
246 [[ctime_r(NULL,NULL,0)]]
247 ),
248 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
249 AC_LINK_IFELSE(
250 AC_LANG_PROGRAM(
251 [[#include <time.h>]],
252 [[ctime_r(NULL,NULL)]]
253 ),
254 [AC_MSG_RESULT([yes, this seems to be solaris style])],
255 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
256 )
257 ],
258 [ AC_LINK_IFELSE(
259 AC_LANG_PROGRAM(
260 [[#include <time.h>]],
261 [[ctime_r(NULL,NULL)]]
262 ),
263 [AC_MSG_RESULT(yes)],
264 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
265 )
266 ]
267 )
268 AC_LANG_POP(C)
270 dnl Check for pthreads
271 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
273 AC_SUBST(MULTITHREAD_CFLAGS)
274 AC_SUBST(MULTITHREAD_LDFLAGS)
277 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
278 [],[enable_pthread=yes])
281 if test $enable_pthread != no; then
282 ACX_PTHREAD([
283 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
284 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
285 ],
286 [])
287 fi
289 dnl since we use lots of *_r functions all over the code we better
290 dnl make sure they are known
292 if test "x$x_rflag" != "xno"; then
293 CPPFLAGS="$CPPFLAGS $x_rflag"
294 fi
297 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
299 dnl Check for Perl.
300 AC_PATH_PROG(PERL, perl, no)
302 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
303 [],[enable_perl=yes])
306 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
307 COMP_PERL=
308 else
309 COMP_PERL="perl_piped perl_shared"
310 AC_MSG_CHECKING(for the perl version you are running)
311 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
312 AC_MSG_RESULT($PERL_VERSION)
313 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
314 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
315 AC_MSG_RESULT($perlcc)
316 if test ! -x "$perlcc"; then
317 AC_PATH_PROG(PERLCC, "${perlcc}", no)
318 if test "$PERLCC" = "no"; then
319 AC_MSG_WARN([
320 I would not find the Compiler ($perlcc) that was originally used to compile your
321 perl binary. You should either make sure that this compiler is available on your
322 system, or use a different perl setup that was compiled with $CC.
324 I will disable the compilation of the RRDs perl module.
325 ])
326 COMP_PERL="perl_piped"
327 fi
328 fi
329 fi
330 AC_MSG_CHECKING(Perl Modules to build)
331 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
333 # Options to pass when configuring perl module
334 ppref=$prefix
335 test "$ppref" = "NONE" && ppref=$ac_default_prefix
337 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
339 dnl pass additional perl options when generating Makefile from Makefile.PL
340 AC_ARG_ENABLE(perl-site-install,
341 [ --enable-perl-site-install by default the rrdtool perl modules are installed
342 together with rrdtool in $prefix/lib/perl. You have to
343 put a 'use lib qw($prefix/lib/perl)' into your scripts
344 when you want to use them. When you set this option
345 the perl modules will get installed wherever
346 your perl setup thinks it is best.],
347 [PERL_MAKE_OPTIONS=],[])
349 AC_ARG_WITH(perl-options,
350 [ --with-perl-options=[OPTIONS] options to pass on command-line when
351 generating Makefile from Makefile.PL. If you set this
352 option, interesting things may happen unless you know
353 what you are doing!],
354 [PERL_MAKE_OPTIONS=$withval])
356 AC_SUBST(PERL_MAKE_OPTIONS)
357 AC_SUBST(PERL)
358 AC_SUBST(COMP_PERL)
359 AC_SUBST(PERL_VERSION)
361 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
362 [],[enable_tcl=yes])
364 if test "$enable_tcl" = "yes"; then
365 dnl Check for Tcl.
366 withval=""
367 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
368 enable_tcl=no
369 AC_MSG_CHECKING(for tclConfig.sh in $withval)
370 if test -f "$withval/tclConfig.sh" ; then
371 tcl_config=$withval/tclConfig.sh
372 enable_tcl=yes
373 AC_MSG_RESULT(yes)
374 break
375 else
376 AC_MSG_RESULT(no)
377 fi
379 if test "$enable_tcl" = "no"; then
380 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
381 else
382 . $tcl_config
383 fi
384 fi
386 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
388 AC_SUBST(TCL_PREFIX)
389 AC_SUBST(TCL_SHLIB_CFLAGS)
390 AC_SUBST(TCL_SHLIB_LD)
391 AC_SUBST(TCL_SHLIB_SUFFIX)
392 AC_SUBST(TCL_PACKAGE_PATH)
393 AC_SUBST(TCL_LD_SEARCH_FLAGS)
395 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
396 [],[enable_python=yes])
398 if test "$enable_python" = "yes"; then
399 dnl Check for python
400 AM_PATH_PYTHON(2.3,[],[enable_python=no])
401 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
402 fi
404 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
406 dnl Check for nroff
407 AC_PATH_PROGS(NROFF, gnroff nroff)
408 AC_PATH_PROGS(TROFF, groff troff)
410 dnl Does the compiler like -Wall and -pedantic?
411 if test "$GCC" = "yes"; then
412 oCFLAGS=$CFLAGS
413 CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
414 AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
415 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
416 ]
417 )
418 if test $rd_cv_gcc_opt = no; then
419 CFLAGS=$oCFLAGS
420 fi
421 fi
423 dnl what does realloc do if it gets called with a NULL pointer
425 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
426 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
427 int main(void){
428 char *x = NULL;
429 x = realloc (x,10);
430 if (x==NULL) return 1;
431 return 0;
432 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
434 if test x"$rd_cv_null_realloc" = xnope; then
435 AC_DEFINE(NO_NULL_REALLOC)
436 fi
438 AC_CONFIG_FILES([examples/shared-demo.pl \
439 examples/piped-demo.pl \
440 examples/stripes.pl \
441 examples/bigtops.pl \
442 examples/minmax.pl \
443 examples/cgi-demo.cgi \
444 examples/4charts.pl \
445 examples/Makefile \
446 doc/Makefile \
447 src/Makefile \
448 bindings/Makefile \
449 bindings/tcl/Makefile \
450 bindings/python/Makefile \
451 Makefile])
452 AC_CONFIG_COMMANDS([default],[[\
453 chmod +x examples/*.cgi examples/*.pl]],[[]])
454 AC_OUTPUT
456 AC_MSG_CHECKING(in)
457 AC_MSG_RESULT(and out again)
459 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
460 sleep 1
461 echo $ECHO_N ".$ECHO_C" 1>&6
462 sleep 1
463 echo $ECHO_N ".$ECHO_C" 1>&6
464 sleep 1
465 echo $ECHO_N ".$ECHO_C" 1>&6
466 sleep 1
467 echo $ECHO_N ".$ECHO_C" 1>&6
468 sleep 1
469 AC_MSG_RESULT([ just kidding ;-)])
470 echo
471 echo "----------------------------------------------------------------"
472 echo "Config is DONE!"
473 echo
474 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
475 echo " Perl Modules: $COMP_PERL"
476 echo " Perl Binary: $PERL"
477 echo " Perl Version: $PERL_VERSION"
478 echo " Perl Options: $PERL_MAKE_OPTIONS"
479 echo " Build Tcl Bindings: $enable_tcl"
480 echo " Build Python Bindings: $enable_python"
481 echo " Build rrdcgi: $enable_rrdcgi"
482 echo " Build librrd MT: $enable_pthread"
483 echo
484 echo
485 echo "Type 'make' to compile the software and use 'make install' to "
486 echo "install everything to: $prefix."
487 echo
488 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
489 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
490 echo "place an order."
491 echo
492 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
493 echo "----------------------------------------------------------------"