1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.13])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devl versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.2013
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
29 AC_SUBST(VERSION)
31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
33 dnl Minimum Autoconf version required.
34 AC_PREREQ(2.59)
36 dnl At the TOP of the HEADER
38 AH_TOP([
40 #ifndef CONFIG_H
41 #define CONFIG_H
42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
43 #undef MUST_DISABLE_FPMASK
45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
47 #undef MUST_DISABLE_SIGFPE
49 /* realloc does not support NULL as argument */
50 #undef NO_NULL_REALLOC
52 ])
54 AH_BOTTOM([
56 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
57 make sure you are NOT using bcopy, index or rindex in the code */
59 #if STDC_HEADERS
60 # include <string.h>
61 #else
62 # ifndef HAVE_STRCHR
63 # define strchr index
64 # define strrchr rindex
65 # endif
66 char *strchr (), *strrchr ();
67 # ifndef HAVE_MEMMOVE
68 # define memcpy(d, s, n) bcopy ((s), (d), (n))
69 # define memmove(d, s, n) bcopy ((s), (d), (n))
70 # endif
71 #endif
74 #if NO_NULL_REALLOC
75 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
76 #else
77 # define rrd_realloc(a,b) realloc((a), (b))
78 #endif
80 #if NEED_MALLOC_MALLOC_H
81 # include <malloc/malloc.h>
82 #endif
84 #if HAVE_MATH_H
85 # include <math.h>
86 #endif
88 #if HAVE_FLOAT_H
89 # include <float.h>
90 #endif
92 #if HAVE_IEEEFP_H
93 # include <ieeefp.h>
94 #endif
96 #if HAVE_FP_CLASS_H
97 # include <fp_class.h>
98 #endif
100 /* for Solaris */
101 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
102 # define HAVE_ISINF 1
103 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
104 #endif
106 /* for OSF1 Digital Unix */
107 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
108 # define HAVE_ISINF 1
109 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
110 #endif
112 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
113 # define HAVE_ISINF 1
114 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
115 #endif
117 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
118 # define HAVE_ISINF 1
119 # define isinf(a) (fpclassify(a) == FP_INFINITE)
120 #endif
122 /* for AIX */
123 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
124 # define HAVE_ISINF 1
125 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
126 #endif
128 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
129 # define HAVE_FINITE 1
130 # define finite(a) isfinite(a)
131 #endif
133 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
134 # define HAVE_FINITE 1
135 # define finite(a) (! isnan(a) && ! isinf(a))
136 #endif
138 #ifndef HAVE_FINITE
139 #error "Can't compile without finite function"
140 #endif
142 #ifndef HAVE_ISINF
143 #error "Can't compile without isinf function"
144 #endif
146 #endif /* CONFIG_H */
147 ])
149 dnl Process Special Options
150 dnl -----------------------------------
152 dnl How the vertical axis label is printed
153 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
154 [Vertical label angle: 90.0 (default) or 270.0])
155 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
156 [Vertical label angle: 90.0 (default) or 270.0])
158 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
159 [],[enable_rrdcgi=yes])
161 dnl Check if we run on a system that has fonts
162 AC_ARG_WITH(rrd-default-font,
163 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
164 [RRD_DEFAULT_FONT=$withval],[
165 if test -d ${WINDIR:-nodir}/cour.ttf ; then
166 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
167 else
168 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
169 fi
170 ])
172 dnl Use mmap in rrd_update instead of seek+write
173 AC_ARG_ENABLE([mmap],
174 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
175 [],
176 [enable_mmap=yes])
179 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
180 [],[enable_pthread=yes])
184 CONFIGURE_PART(Audit Compilation Environment)
187 dnl Check for the compiler and static/shared library creation.
188 AC_PROG_CC
189 AC_PROG_CPP
190 AC_PROG_LIBTOOL
192 dnl which flags does the compile support?
193 if test "$GCC" = "yes"; then
194 for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
195 oCFLAGS=$CFLAGS
196 CFLAGS="$CFLAGS $flag"
197 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
198 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
199 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
200 if eval test \$$cachename = no; then
201 CFLAGS=$oCFLAGS
202 fi
203 done
204 fi
208 AC_SUBST(RRD_DEFAULT_FONT)
210 CONFIGURE_PART(Checking for Header Files)
212 dnl Checks for header files.
213 AC_HEADER_STDC
214 AC_HEADER_DIRENT
215 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
217 dnl Checks for typedefs, structures, and compiler characteristics.
218 AC_C_CONST
219 AC_HEADER_TIME
220 AC_STRUCT_TM
222 dnl Checks for libraries.
223 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
225 dnl add pic flag in any case this makes sure all our code is relocatable
226 eval `./libtool --config | grep pic_flag`
227 CFLAGS="$CFLAGS $pic_flag"
229 CONFIGURE_PART(Test Library Functions)
231 dnl Checks for library functions.
232 AC_FUNC_STRFTIME
233 AC_FUNC_VPRINTF
235 AC_C_BIGENDIAN
237 dnl for each function found we get a definition in config.h
238 dnl of the form HAVE_FUNCTION
240 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
243 if test "x$enable_mmap" = xyes; then
244 case "$host" in
245 *cygwin*)
246 # the normal mmap test does not work in cygwin
247 AC_CHECK_FUNCS(mmap)
248 if [ "x${ac_cv_func_mmap}" = xyes ]; then
249 ac_cv_func_mmap_fixed_mapped=yes
250 fi
251 ;;
252 *)
253 AC_FUNC_MMAP
254 ;;
255 esac
256 fi
259 CONFIGURE_PART(IEEE Math Checks)
261 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
262 dnl actual code to check if this works
263 AC_CHECK_FUNCS(fpclassify, ,
264 [AC_MSG_CHECKING(for fpclassify with <math.h>)
265 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
266 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
267 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
268 AC_CHECK_FUNCS(finite, ,
269 [AC_CHECK_FUNCS(isfinite, ,
270 [AC_MSG_CHECKING(for isfinite with <math.h>)
271 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
272 volatile int x;volatile float f; ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
273 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
274 AC_CHECK_FUNCS(isinf, ,
275 [AC_MSG_CHECKING(for isinf with <math.h>)
276 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
277 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
278 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
280 AC_FULL_IEEE
282 CONFIGURE_PART(Resolve Portability Issues)
284 dnl what does realloc do if it gets called with a NULL pointer
286 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
287 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
288 int main(void){
289 char *x = NULL;
290 x = realloc (x,10);
291 if (x==NULL) return 1;
292 return 0;
293 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
295 if test x"$rd_cv_null_realloc" = xnope; then
296 AC_DEFINE(NO_NULL_REALLOC)
297 fi
299 AC_LANG_PUSH(C)
300 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
301 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
302 AC_LINK_IFELSE(
303 AC_LANG_PROGRAM(
304 [[#include <time.h>]],
305 [[ctime_r(NULL,NULL,0)]]
306 ),
307 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
308 AC_LINK_IFELSE(
309 AC_LANG_PROGRAM(
310 [[#include <time.h>]],
311 [[ctime_r(NULL,NULL)]]
312 ),
313 [AC_MSG_RESULT([yes, this seems to be solaris style])],
314 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
315 )
316 ],
317 [ AC_LINK_IFELSE(
318 AC_LANG_PROGRAM(
319 [[#include <time.h>]],
320 [[ctime_r(NULL,NULL)]]
321 ),
322 [AC_MSG_RESULT(no)],
323 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
324 )
325 ]
326 )
327 AC_LANG_POP(C)
329 dnl Check for pthreads
330 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
332 AC_SUBST(MULTITHREAD_CFLAGS)
333 AC_SUBST(MULTITHREAD_LDFLAGS)
335 if test $enable_pthread != no; then
336 ACX_PTHREAD([
337 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
338 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
339 ],
340 [])
341 fi
343 dnl since we use lots of *_r functions all over the code we better
344 dnl make sure they are known
346 if test "x$x_rflag" != "xno"; then
347 CPPFLAGS="$CPPFLAGS $x_rflag"
348 fi
350 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
352 AC_LANG_PUSH(C)
353 dnl see if we have to include malloc/malloc.h
354 AC_MSG_CHECKING([do we need malloc/malloc.h])
355 AC_LINK_IFELSE(
356 AC_LANG_PROGRAM(
357 [[#include <stdlib.h>]],
358 [[malloc(1)]]
359 ),
360 [ AC_MSG_RESULT([nope, works out of the box]) ],
361 [ AC_LINK_IFELSE(
362 AC_LANG_PROGRAM(
363 [[#include <stdlib.h>
364 #include <malloc/malloc.h>]],
365 [[malloc(1)]]
366 ),
367 [AC_DEFINE(NEED_MALLOC_MALLOC_H)
368 AC_MSG_RESULT([yes we do])],
369 [AC_MSG_ERROR([Can't figure how to compile malloc])]
370 )
371 ]
372 )
373 AC_LANG_POP(C)
375 CONFIGURE_PART(Findr 3rd-Party Libraries)
378 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
380 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
381 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
382 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
383 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
385 if test "$EX_CHECK_ALL_ERR" = "YES"; then
386 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
387 fi
390 CONFIGURE_PART(Prep for Building Language Bindings)
392 dnl Check for Perl.
393 AC_PATH_PROG(PERL, perl, no)
395 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
396 [],[enable_perl=yes])
399 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
400 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
401 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
402 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
404 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
405 COMP_PERL=
406 else
407 COMP_PERL="perl_piped perl_shared"
408 AC_MSG_CHECKING(for the perl version you are running)
409 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
410 AC_MSG_RESULT($PERL_VERSION)
411 if test -z "$PERLCC"; then
412 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
413 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
414 AC_MSG_RESULT($perlcc)
415 if test ! -x "$perlcc"; then
416 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
417 if test "$PERL_CC" = "no"; then
418 AC_MSG_WARN([
419 I would not find the Compiler ($perlcc) that was originally used to compile
420 your perl binary. You should either make sure that this compiler is
421 available on your system, pick an other compiler and set PERLCC
422 appropriately, or use a different perl setup that was compiled locally.
424 I will disable the compilation of the RRDs perl module for now.
425 ])
426 COMP_PERL="perl_piped"
427 fi
428 fi
429 fi
430 fi
432 AC_MSG_CHECKING(Perl Modules to build)
433 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
435 # Options to pass when configuring perl module
436 ppref=$prefix
437 test "$ppref" = "NONE" && ppref=$ac_default_prefix
439 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
441 dnl pass additional perl options when generating Makefile from Makefile.PL
442 AC_ARG_ENABLE(perl-site-install,
443 [ --enable-perl-site-install by default the rrdtool perl modules are installed
444 together with rrdtool in $prefix/lib/perl. You have to
445 put a 'use lib qw($prefix/lib/perl)' into your scripts
446 when you want to use them. When you set this option
447 the perl modules will get installed wherever
448 your perl setup thinks it is best.],
449 [PERL_MAKE_OPTIONS=],[])
451 if test ! -z "$PERLCC"; then
452 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
454 if test ! -z "$PERLCCFLAGS"; then
455 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
456 fi
458 if test -z "$PERLLD"; then
459 PERLLD=$PERLCC
460 fi
461 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
463 if test ! -z "$PERLLDFLAGS"; then
464 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
465 fi
466 fi
468 AC_ARG_WITH(perl-options,
469 [ --with-perl-options=[OPTIONS] options to pass on command-line when
470 generating Makefile from Makefile.PL. If you set this
471 option, interesting things may happen unless you know
472 what you are doing!],
473 [PERL_MAKE_OPTIONS=$withval])
475 AC_SUBST(PERL_MAKE_OPTIONS)
476 AC_SUBST(PERL)
477 AC_SUBST(COMP_PERL)
478 AC_SUBST(PERL_VERSION)
480 enable_tcl_site=no
482 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
483 [],[enable_tcl=yes])
485 if test "$enable_tcl" = "yes"; then
486 dnl Check for Tcl.
487 withval=""
488 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
489 enable_tcl=no
490 for dir in $withval /usr/lib /usr/local/lib; do
491 AC_MSG_CHECKING(for tclConfig.sh in $dir)
492 if test -f "$dir/tclConfig.sh" ; then
493 tcl_config=$dir/tclConfig.sh
494 enable_tcl=yes
495 AC_MSG_RESULT(yes)
496 break
497 else
498 AC_MSG_RESULT(no)
499 fi
500 done
502 if test "$enable_tcl" = "no"; then
503 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
504 else
505 . $tcl_config
506 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
507 fi
508 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
509 [],[enable_tcl_site=yes])
511 fi
513 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
514 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
516 AC_SUBST(TCL_PREFIX)
517 AC_SUBST(TCL_SHLIB_CFLAGS)
518 AC_SUBST(TCL_SHLIB_LD)
519 AC_SUBST(TCL_SHLIB_SUFFIX)
520 AC_SUBST(TCL_PACKAGE_PATH)
521 AC_SUBST(TCL_LD_SEARCH_FLAGS)
522 AC_SUBST(TCL_STUB_LIB_SPEC)
523 AC_SUBST(TCL_VERSION)
524 AC_SUBST(TCL_PACKAGE_DIR)
526 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
527 [],[enable_python=yes])
529 if test "$enable_python" = "yes"; then
530 dnl Check for python
531 AM_PATH_PYTHON(2.3,[],[enable_python=no])
532 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
533 fi
535 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
537 dnl Check for nroff
538 AC_PATH_PROGS(NROFF, gnroff nroff)
539 AC_PATH_PROGS(TROFF, groff troff)
541 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
542 if test -z "$RRDDOCDIR"; then
543 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
546 CONFIGURE_PART(Apply Configuration Information)
548 AC_CONFIG_FILES([examples/shared-demo.pl])
549 AC_CONFIG_FILES([examples/piped-demo.pl])
550 AC_CONFIG_FILES([examples/stripes.pl])
551 AC_CONFIG_FILES([examples/bigtops.pl])
552 AC_CONFIG_FILES([examples/minmax.pl])
553 AC_CONFIG_FILES([examples/cgi-demo.cgi])
554 AC_CONFIG_FILES([examples/4charts.pl])
555 AC_CONFIG_FILES([examples/Makefile])
556 AC_CONFIG_FILES([doc/Makefile])
557 AC_CONFIG_FILES([src/Makefile])
558 AC_CONFIG_FILES([bindings/Makefile])
559 AC_CONFIG_FILES([bindings/tcl/Makefile])
560 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
561 AC_CONFIG_FILES([bindings/python/Makefile])
562 AC_CONFIG_FILES([Makefile])
564 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.cgi examples/*.pl]],[[]])
565 AC_OUTPUT
567 AC_MSG_CHECKING(in)
568 AC_MSG_RESULT(and out again)
570 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/oetiker/wish $ECHO_C" 1>&6
571 sleep 1
572 echo $ECHO_N ".$ECHO_C" 1>&6
573 sleep 1
574 echo $ECHO_N ".$ECHO_C" 1>&6
575 sleep 1
576 echo $ECHO_N ".$ECHO_C" 1>&6
577 sleep 1
578 echo $ECHO_N ".$ECHO_C" 1>&6
579 sleep 1
580 AC_MSG_RESULT([ just kidding ;-)])
581 echo
582 echo "----------------------------------------------------------------"
583 echo "Config is DONE!"
584 echo
585 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
586 echo " Perl Modules: $COMP_PERL"
587 echo " Perl Binary: $PERL"
588 echo " Perl Version: $PERL_VERSION"
589 echo " Perl Options: $PERL_MAKE_OPTIONS"
590 echo " Build Tcl Bindings: $enable_tcl"
591 echo " Build Python Bindings: $enable_python"
592 echo " Build rrdcgi: $enable_rrdcgi"
593 echo " Build librrd MT: $enable_pthread"
594 echo
595 echo
596 echo "Type 'make' to compile the software and use 'make install' to "
597 echo "install everything to: $prefix."
598 echo
599 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
600 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
601 echo "place an order."
602 echo
603 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
604 echo "----------------------------------------------------------------"