8482501635b22fec404b073f305f7df71da6f409
1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.8])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devl versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.2008
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
30 AC_SUBST(VERSION)
32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
34 dnl Minimum Autoconf version required.
35 AC_PREREQ(2.59)
37 dnl At the TOP of the HEADER
39 AH_TOP([
41 #ifndef CONFIG_H
42 #define CONFIG_H
43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
44 #undef MUST_DISABLE_FPMASK
46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
48 #undef MUST_DISABLE_SIGFPE
50 /* realloc does not support NULL as argument */
51 #undef NO_NULL_REALLOC
53 ])
55 AH_BOTTOM([
57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
58 make sure you are NOT using bcopy, index or rindex in the code */
60 #if STDC_HEADERS
61 # include <string.h>
62 #else
63 # ifndef HAVE_STRCHR
64 # define strchr index
65 # define strrchr rindex
66 # endif
67 char *strchr (), *strrchr ();
68 # ifndef HAVE_MEMMOVE
69 # define memcpy(d, s, n) bcopy ((s), (d), (n))
70 # define memmove(d, s, n) bcopy ((s), (d), (n))
71 # endif
72 #endif
75 #if NO_NULL_REALLOC
76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
77 #else
78 # define rrd_realloc(a,b) realloc((a), (b))
79 #endif
81 #if HAVE_MATH_H
82 # include <math.h>
83 #endif
85 #if HAVE_FLOAT_H
86 # include <float.h>
87 #endif
89 #if HAVE_IEEEFP_H
90 # include <ieeefp.h>
91 #endif
93 #if HAVE_FP_CLASS_H
94 # include <fp_class.h>
95 #endif
97 /* for Solaris */
98 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
99 # define HAVE_ISINF 1
100 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
101 #endif
103 /* for OSF1 Digital Unix */
104 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
105 # define HAVE_ISINF 1
106 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
107 #endif
109 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
110 # define HAVE_ISINF 1
111 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
112 #endif
114 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
115 # define HAVE_ISINF 1
116 # define isinf(a) (fpclassify(a) == FP_INFINITE)
117 #endif
119 /* for AIX */
120 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
121 # define HAVE_ISINF 1
122 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
123 #endif
125 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
126 # define HAVE_FINITE 1
127 # define finite(a) isfinite(a)
128 #endif
130 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
131 # define HAVE_FINITE 1
132 # define finite(a) (! isnan(a) && ! isinf(a))
133 #endif
135 #ifndef HAVE_FINITE
136 #error "Can't compile without finite function"
137 #endif
139 #ifndef HAVE_ISINF
140 #error "Can't compile without isinf function"
141 #endif
143 #endif /* CONFIG_H */
144 ])
148 dnl Check for the compiler and static/shared library creation.
149 AC_PROG_CC
150 AC_PROG_CPP
151 AC_PROG_LIBTOOL
153 dnl Check if we run on a system that has fonts
154 AC_ARG_WITH(rrd-default-font,
155 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
156 [RRD_DEFAULT_FONT=$withval],[
157 if test -d ${WINDIR:-nodir}/cour.ttf ; then
158 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
159 else
160 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
161 fi
162 ])
164 AC_SUBST(RRD_DEFAULT_FONT)
166 dnl Checks for header files.
167 AC_HEADER_STDC
168 AC_HEADER_DIRENT
169 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
171 dnl Checks for typedefs, structures, and compiler characteristics.
172 AC_C_CONST
173 AC_HEADER_TIME
174 AC_STRUCT_TM
176 dnl Checks for libraries.
177 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
179 dnl add pic flag in any case this makes sure all our code is relocatable
180 eval `./libtool --config | grep pic_flag`
181 CFLAGS="$CFLAGS $pic_flag"
183 dnl Checks for library functions.
184 AC_FUNC_STRFTIME
185 AC_FUNC_VPRINTF
187 AC_C_BIGENDIAN
189 dnl for each function found we get a definition in config.h
190 dnl of the form HAVE_FUNCTION
192 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
194 dnl Use mmap in rrd_update instead of seek+write
195 AC_ARG_ENABLE([mmap],
196 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
197 [],
198 [enable_mmap=yes])
200 if test "x$enable_mmap" = xyes; then
201 AC_FUNC_MMAP
202 fi
204 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
205 dnl actual code to check if this works
206 AC_CHECK_FUNCS(fpclassify, ,
207 [AC_MSG_CHECKING(for fpclassify with <math.h>)
208 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
209 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
210 AC_CHECK_FUNCS(finite, ,
211 [AC_CHECK_FUNCS(isfinite, ,
212 [AC_MSG_CHECKING(for isfinite with <math.h>)
213 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
214 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
215 AC_CHECK_FUNCS(isinf, ,
216 [AC_MSG_CHECKING(for isinf with <math.h>)
217 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
218 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
220 AC_FULL_IEEE
222 dnl How the vertical axis label is printed
223 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
224 [Vertical label angle: 90.0 (default) or 270.0])
225 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
226 [Vertical label angle: 90.0 (default) or 270.0])
229 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
230 [],[enable_rrdcgi=yes])
231 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
233 if test $enable_rrdcgi != no; then
234 EX_CHECK_ALL(cgi, cgiInit, cgi.h, cgilib, 0.5, http://www.infodrom.org/projects/cgilib, "")
235 fi
236 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
237 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.2, http://www.gzip.org/zlib/, "")
238 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.8, http://prdownloads.sourceforge.net/libpng/, "")
239 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.9, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
241 if test "$EX_CHECK_ALL_ERR" = "YES"; then
242 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
243 fi
245 AC_LANG_PUSH(C)
246 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
247 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
248 AC_LINK_IFELSE(
249 AC_LANG_PROGRAM(
250 [[#include <time.h>]],
251 [[ctime_r(NULL,NULL,0)]]
252 ),
253 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
254 AC_LINK_IFELSE(
255 AC_LANG_PROGRAM(
256 [[#include <time.h>]],
257 [[ctime_r(NULL,NULL)]]
258 ),
259 [AC_MSG_RESULT([yes, this seems to be solaris style])],
260 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
261 )
262 ],
263 [ AC_LINK_IFELSE(
264 AC_LANG_PROGRAM(
265 [[#include <time.h>]],
266 [[ctime_r(NULL,NULL)]]
267 ),
268 [AC_MSG_RESULT(yes)],
269 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
270 )
271 ]
272 )
273 AC_LANG_POP(C)
275 dnl Check for pthreads
276 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
278 AC_SUBST(MULTITHREAD_CFLAGS)
279 AC_SUBST(MULTITHREAD_LDFLAGS)
282 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
283 [],[enable_pthread=yes])
286 if test $enable_pthread != no; then
287 ACX_PTHREAD([
288 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
289 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
290 ],
291 [])
292 fi
294 dnl since we use lots of *_r functions all over the code we better
295 dnl make sure they are known
297 if test "x$x_rflag" != "xno"; then
298 CPPFLAGS="$CPPFLAGS $x_rflag"
299 fi
302 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
304 dnl Check for Perl.
305 AC_PATH_PROG(PERL, perl, no)
307 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
308 [],[enable_perl=yes])
311 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
312 COMP_PERL=
313 else
314 COMP_PERL="perl_piped perl_shared"
315 AC_MSG_CHECKING(for the perl version you are running)
316 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
317 AC_MSG_RESULT($PERL_VERSION)
318 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
319 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
320 AC_MSG_RESULT($perlcc)
321 if test ! -x "$perlcc"; then
322 AC_PATH_PROG(PERLCC, "${perlcc}", no)
323 if test "$PERLCC" = "no"; then
324 AC_MSG_WARN([
325 I would not find the Compiler ($perlcc) that was originally used to compile your
326 perl binary. You should either make sure that this compiler is available on your
327 system, or use a different perl setup that was compiled with $CC.
329 I will disable the compilation of the RRDs perl module.
330 ])
331 COMP_PERL="perl_piped"
332 fi
333 fi
334 fi
335 AC_MSG_CHECKING(Perl Modules to build)
336 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
338 # Options to pass when configuring perl module
339 ppref=$prefix
340 test "$ppref" = "NONE" && ppref=$ac_default_prefix
342 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
344 dnl pass additional perl options when generating Makefile from Makefile.PL
345 AC_ARG_ENABLE(perl-site-install,
346 [ --enable-perl-site-install by default the rrdtool perl modules are installed
347 together with rrdtool in $prefix/lib/perl. You have to
348 put a 'use lib qw($prefix/lib/perl)' into your scripts
349 when you want to use them. When you set this option
350 the perl modules will get installed wherever
351 your perl setup thinks it is best.],
352 [PERL_MAKE_OPTIONS=],[])
354 AC_ARG_WITH(perl-options,
355 [ --with-perl-options=[OPTIONS] options to pass on command-line when
356 generating Makefile from Makefile.PL. If you set this
357 option, interesting things may happen unless you know
358 what you are doing!],
359 [PERL_MAKE_OPTIONS=$withval])
361 AC_SUBST(PERL_MAKE_OPTIONS)
362 AC_SUBST(PERL)
363 AC_SUBST(COMP_PERL)
364 AC_SUBST(PERL_VERSION)
366 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
367 [],[enable_tcl=yes])
369 if test "$enable_tcl" = "yes"; then
370 dnl Check for Tcl.
371 withval=""
372 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
373 enable_tcl=no
374 AC_MSG_CHECKING(for tclConfig.sh in $withval)
375 if test -f "$withval/tclConfig.sh" ; then
376 tcl_config=$withval/tclConfig.sh
377 enable_tcl=yes
378 AC_MSG_RESULT(yes)
379 break
380 else
381 AC_MSG_RESULT(no)
382 fi
384 if test "$enable_tcl" = "no"; then
385 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
386 else
387 . $tcl_config
388 fi
389 fi
391 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
393 AC_SUBST(TCL_PREFIX)
394 AC_SUBST(TCL_SHLIB_CFLAGS)
395 AC_SUBST(TCL_SHLIB_LD)
396 AC_SUBST(TCL_SHLIB_SUFFIX)
397 AC_SUBST(TCL_PACKAGE_PATH)
398 AC_SUBST(TCL_LD_SEARCH_FLAGS)
400 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
401 [],[enable_python=yes])
403 if test "$enable_python" = "yes"; then
404 dnl Check for python
405 AM_PATH_PYTHON(2.3,[],[enable_python=no])
406 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
407 fi
409 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
411 dnl Check for nroff
412 AC_PATH_PROGS(NROFF, gnroff nroff)
413 AC_PATH_PROGS(TROFF, groff troff)
415 dnl Does the compiler like -Wall and -pedantic?
416 if test "$GCC" = "yes"; then
417 oCFLAGS=$CFLAGS
418 CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
419 AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
420 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
421 ]
422 )
423 if test $rd_cv_gcc_opt = no; then
424 CFLAGS=$oCFLAGS
425 fi
426 fi
428 dnl what does realloc do if it gets called with a NULL pointer
430 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
431 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
432 int main(void){
433 char *x = NULL;
434 x = realloc (x,10);
435 if (x==NULL) return 1;
436 return 0;
437 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
439 if test x"$rd_cv_null_realloc" = xnope; then
440 AC_DEFINE(NO_NULL_REALLOC)
441 fi
443 AC_CONFIG_FILES([examples/shared-demo.pl \
444 examples/piped-demo.pl \
445 examples/stripes.pl \
446 examples/bigtops.pl \
447 examples/minmax.pl \
448 examples/cgi-demo.cgi \
449 examples/4charts.pl \
450 examples/Makefile \
451 doc/Makefile \
452 src/Makefile \
453 bindings/Makefile \
454 bindings/tcl/Makefile \
455 bindings/python/Makefile \
456 Makefile])
457 AC_CONFIG_COMMANDS([default],[[\
458 chmod +x examples/*.cgi examples/*.pl]],[[]])
459 AC_OUTPUT
461 AC_MSG_CHECKING(in)
462 AC_MSG_RESULT(and out again)
464 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
465 sleep 1
466 echo $ECHO_N ".$ECHO_C" 1>&6
467 sleep 1
468 echo $ECHO_N ".$ECHO_C" 1>&6
469 sleep 1
470 echo $ECHO_N ".$ECHO_C" 1>&6
471 sleep 1
472 echo $ECHO_N ".$ECHO_C" 1>&6
473 sleep 1
474 AC_MSG_RESULT([ just kidding ;-)])
475 echo
476 echo "----------------------------------------------------------------"
477 echo "Config is DONE!"
478 echo
479 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
480 echo " Perl Modules: $COMP_PERL"
481 echo " Perl Binary: $PERL"
482 echo " Perl Version: $PERL_VERSION"
483 echo " Perl Options: $PERL_MAKE_OPTIONS"
484 echo " Build Tcl Bindings: $enable_tcl"
485 echo " Build Python Bindings: $enable_python"
486 echo " Build rrdcgi: $enable_rrdcgi"
487 echo " Build librrd MT: $enable_pthread"
488 echo
489 echo
490 echo "Type 'make' to compile the software and use 'make install' to "
491 echo "install everything to: $prefix."
492 echo
493 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
494 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
495 echo "place an order."
496 echo
497 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
498 echo "----------------------------------------------------------------"