09e026058c7e55b9273f38936f3c596ea7a09931
1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.23])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devl versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.2023
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([rrd_config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
29 AC_SUBST(VERSION)
31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
33 dnl Minimum Autoconf version required.
34 AC_PREREQ(2.59)
36 dnl At the TOP of the HEADER
38 AH_TOP([
40 #ifndef RRD_CONFIG_H
41 #define RRD_CONFIG_H
42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
43 #undef MUST_DISABLE_FPMASK
45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
47 #undef MUST_DISABLE_SIGFPE
49 /* realloc does not support NULL as argument */
50 #undef NO_NULL_REALLOC
52 ])
54 AH_BOTTOM([
55 /* enable posix_fadvise on linux */
56 #if defined(HAVE_POSIX_FADVISE) && defined(HAVE_FCNTL_H)
57 #define _XOPEN_SOURCE 600
58 #include <fcntl.h>
59 #endif
61 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
62 make sure you are NOT using bcopy, index or rindex in the code */
64 #ifdef STDC_HEADERS
65 # include <string.h>
66 #else
67 # ifndef HAVE_STRCHR
68 # define strchr index
69 # define strrchr rindex
70 # endif
71 char *strchr (), *strrchr ();
72 # ifndef HAVE_MEMMOVE
73 # define memcpy(d, s, n) bcopy ((s), (d), (n))
74 # define memmove(d, s, n) bcopy ((s), (d), (n))
75 # endif
76 #endif
78 #ifdef NO_NULL_REALLOC
79 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
80 #else
81 # define rrd_realloc(a,b) realloc((a), (b))
82 #endif
84 #ifdef NEED_MALLOC_MALLOC_H
85 # include <malloc/malloc.h>
86 #endif
88 #ifdef HAVE_MATH_H
89 # include <math.h>
90 #endif
92 #ifdef HAVE_FLOAT_H
93 # include <float.h>
94 #endif
96 #ifdef HAVE_IEEEFP_H
97 # include <ieeefp.h>
98 #endif
100 #ifdef HAVE_FP_CLASS_H
101 # include <fp_class.h>
102 #endif
104 /* for Solaris */
105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
106 # define HAVE_ISINF 1
107 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
108 #endif
110 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad */
111 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
112 # undef isnan
113 # define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
114 #endif
116 /* for OSF1 Digital Unix */
117 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
118 # define HAVE_ISINF 1
119 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
120 #endif
122 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
123 # define HAVE_ISINF 1
124 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
125 #endif
127 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
128 # define HAVE_ISINF 1
129 # define isinf(a) (fpclassify(a) == FP_INFINITE)
130 #endif
132 /* for AIX */
133 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
134 # define HAVE_ISINF 1
135 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
136 #endif
138 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
139 # define HAVE_FINITE 1
140 # define finite(a) isfinite(a)
141 #endif
143 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
144 # define HAVE_FINITE 1
145 # define finite(a) (! isnan(a) && ! isinf(a))
146 #endif
148 #ifndef HAVE_FINITE
149 #error "Can't compile without finite function"
150 #endif
152 #ifndef HAVE_ISINF
153 #error "Can't compile without isinf function"
154 #endif
156 #endif /* RRD_CONFIG_H */
157 ])
159 dnl Process Special Options
160 dnl -----------------------------------
162 dnl How the vertical axis label is printed
163 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
164 [Vertical label angle: 90.0 (default) or 270.0])
165 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
166 [Vertical label angle: 90.0 (default) or 270.0])
168 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
169 [],[enable_rrdcgi=yes])
171 dnl Check if we run on a system that has fonts
172 AC_ARG_WITH(rrd-default-font,
173 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
174 [RRD_DEFAULT_FONT=$withval],[
175 if test -d ${WINDIR:-nodir}/cour.ttf ; then
176 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
177 else
178 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
179 fi
180 ])
182 dnl Use mmap in rrd_update instead of seek+write
183 AC_ARG_ENABLE([mmap],
184 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
185 [],
186 [enable_mmap=yes])
189 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
190 [],[enable_pthread=yes])
194 CONFIGURE_PART(Audit Compilation Environment)
197 dnl Check for the compiler and static/shared library creation.
198 AC_PROG_CC
199 AC_PROG_CPP
200 AC_PROG_LIBTOOL
202 dnl which flags does the compile support?
203 if test "$GCC" = "yes"; then
204 for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
205 oCFLAGS=$CFLAGS
206 CFLAGS="$CFLAGS $flag"
207 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
208 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
209 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
210 if eval test \$$cachename = no; then
211 CFLAGS=$oCFLAGS
212 fi
213 done
214 fi
218 AC_SUBST(RRD_DEFAULT_FONT)
220 CONFIGURE_PART(Checking for Header Files)
222 dnl Checks for header files.
223 AC_HEADER_STDC
224 AC_HEADER_DIRENT
225 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h float.h)
227 dnl Checks for typedefs, structures, and compiler characteristics.
228 AC_C_CONST
229 AC_HEADER_TIME
230 AC_STRUCT_TM
232 dnl Checks for libraries.
233 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
235 dnl add pic flag in any case this makes sure all our code is relocatable
236 eval `./libtool --config | grep pic_flag`
237 CFLAGS="$CFLAGS $pic_flag"
239 CONFIGURE_PART(Test Library Functions)
241 dnl Checks for library functions.
242 AC_FUNC_STRFTIME
243 AC_FUNC_VPRINTF
245 AC_C_BIGENDIAN
247 dnl for each function found we get a definition in config.h
248 dnl of the form HAVE_FUNCTION
250 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday posix_fadvise madvise)
252 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
253 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
254 #include <fcntl.h>])
255 AC_CHECK_DECLS(madvise, [], [], [#include <sys/mman.h>])
257 if test "x$enable_mmap" = xyes; then
258 case "$host" in
259 *cygwin*)
260 # the normal mmap test does not work in cygwin
261 AC_CHECK_FUNCS(mmap)
262 if [ "x${ac_cv_func_mmap}" = xyes ]; then
263 ac_cv_func_mmap_fixed_mapped=yes
264 fi
265 ;;
266 *)
267 AC_FUNC_MMAP
268 ;;
269 esac
270 fi
273 CONFIGURE_PART(IEEE Math Checks)
275 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
276 dnl actual code to check if this works
277 AC_CHECK_FUNCS(fpclassify, ,
278 [AC_MSG_CHECKING(for fpclassify with <math.h>)
279 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
280 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
281 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
282 AC_CHECK_FUNCS(finite, ,
283 [AC_CHECK_FUNCS(isfinite, ,
284 [AC_MSG_CHECKING(for isfinite with <math.h>)
285 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
286 volatile int x;volatile float f; ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
287 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
288 AC_CHECK_FUNCS(isinf, ,
289 [AC_MSG_CHECKING(for isinf with <math.h>)
290 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
291 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
292 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
294 AC_FULL_IEEE
296 CONFIGURE_PART(Resolve Portability Issues)
298 dnl what does realloc do if it gets called with a NULL pointer
300 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
301 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
302 int main(void){
303 char *x = NULL;
304 x = realloc (x,10);
305 if (x==NULL) return 1;
306 return 0;
307 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
309 if test x"$rd_cv_null_realloc" = xnope; then
310 AC_DEFINE(NO_NULL_REALLOC)
311 fi
313 AC_LANG_PUSH(C)
314 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
315 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
316 AC_LINK_IFELSE(
317 AC_LANG_PROGRAM(
318 [[#include <time.h>]],
319 [[ctime_r(NULL,NULL,0)]]
320 ),
321 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
322 AC_LINK_IFELSE(
323 AC_LANG_PROGRAM(
324 [[#include <time.h>]],
325 [[ctime_r(NULL,NULL)]]
326 ),
327 [AC_MSG_RESULT([yes, this seems to be solaris style])],
328 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
329 )
330 ],
331 [ AC_LINK_IFELSE(
332 AC_LANG_PROGRAM(
333 [[#include <time.h>]],
334 [[ctime_r(NULL,NULL)]]
335 ),
336 [AC_MSG_RESULT(no)],
337 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
338 )
339 ]
340 )
341 AC_LANG_POP(C)
343 dnl Check for pthreads
344 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
346 AC_SUBST(MULTITHREAD_CFLAGS)
347 AC_SUBST(MULTITHREAD_LDFLAGS)
349 if test $enable_pthread != no; then
350 ACX_PTHREAD([
351 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
352 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
353 ],
354 [])
355 fi
357 dnl since we use lots of *_r functions all over the code we better
358 dnl make sure they are known
360 if test "x$x_rflag" != "xno"; then
361 CPPFLAGS="$CPPFLAGS $x_rflag"
362 fi
364 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
366 AC_LANG_PUSH(C)
367 dnl see if we have to include malloc/malloc.h
368 AC_MSG_CHECKING([do we need malloc/malloc.h])
369 AC_LINK_IFELSE(
370 AC_LANG_PROGRAM(
371 [[#include <stdlib.h>]],
372 [[malloc(1)]]
373 ),
374 [ AC_MSG_RESULT([nope, works out of the box]) ],
375 [ AC_LINK_IFELSE(
376 AC_LANG_PROGRAM(
377 [[#include <stdlib.h>
378 #include <malloc/malloc.h>]],
379 [[malloc(1)]]
380 ),
381 [AC_DEFINE(NEED_MALLOC_MALLOC_H)
382 AC_MSG_RESULT([yes we do])],
383 [AC_MSG_ERROR([Can not figure how to compile malloc])]
384 )
385 ]
386 )
387 AC_LANG_POP(C)
389 CONFIGURE_PART(Find 3rd-Party Libraries)
392 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
394 CORE_LIBS="$LIBS"
396 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
397 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
398 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
399 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
401 if test "$EX_CHECK_ALL_ERR" = "YES"; then
402 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
403 fi
405 ALL_LIBS="$LIBS"
406 LIBS=
408 AC_SUBST(CORE_LIBS)
409 AC_SUBST(ALL_LIBS)
411 CONFIGURE_PART(Prep for Building Language Bindings)
413 dnl Check for Perl.
414 AC_PATH_PROG(PERL, perl, no)
416 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
417 [],[enable_perl=yes])
420 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
421 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
422 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
423 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
425 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
426 COMP_PERL=
427 else
428 COMP_PERL="perl_piped perl_shared"
429 AC_MSG_CHECKING(for the perl version you are running)
430 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
431 AC_MSG_RESULT($PERL_VERSION)
432 if test -z "$PERLCC"; then
433 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
434 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
435 AC_MSG_RESULT($perlcc)
436 if test ! -x "$perlcc"; then
437 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
438 if test "$PERL_CC" = "no"; then
439 AC_MSG_WARN([
440 I would not find the Compiler ($perlcc) that was originally used to compile
441 your perl binary. You should either make sure that this compiler is
442 available on your system, pick an other compiler and set PERLCC
443 appropriately, or use a different perl setup that was compiled locally.
445 I will disable the compilation of the RRDs perl module for now.
446 ])
447 COMP_PERL="perl_piped"
448 fi
449 fi
450 fi
451 fi
453 AC_MSG_CHECKING(Perl Modules to build)
454 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
456 # Options to pass when configuring perl module
457 ppref=$prefix
458 test "$ppref" = "NONE" && ppref=$ac_default_prefix
460 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
462 dnl pass additional perl options when generating Makefile from Makefile.PL
463 AC_ARG_ENABLE(perl-site-install,
464 [ --enable-perl-site-install by default the rrdtool perl modules are installed
465 together with rrdtool in $prefix/lib/perl. You have to
466 put a 'use lib qw($prefix/lib/perl)' into your scripts
467 when you want to use them. When you set this option
468 the perl modules will get installed wherever
469 your perl setup thinks it is best.],
470 [PERL_MAKE_OPTIONS=],[])
472 if test ! -z "$PERLCC"; then
473 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
475 if test ! -z "$PERLCCFLAGS"; then
476 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
477 fi
479 if test -z "$PERLLD"; then
480 PERLLD=$PERLCC
481 fi
482 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
484 if test ! -z "$PERLLDFLAGS"; then
485 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
486 fi
487 fi
489 AC_ARG_WITH(perl-options,
490 [ --with-perl-options=[OPTIONS] options to pass on command-line when
491 generating Makefile from Makefile.PL. If you set this
492 option, interesting things may happen unless you know
493 what you are doing!],
494 [PERL_MAKE_OPTIONS=$withval])
496 AC_SUBST(PERL_MAKE_OPTIONS)
497 AC_SUBST(PERL)
498 AC_SUBST(COMP_PERL)
499 AC_SUBST(PERL_VERSION)
501 dnl Check for Ruby.
502 AC_PATH_PROG(RUBY, ruby, no)
504 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
505 [],[enable_ruby=yes])
507 AC_MSG_CHECKING(if ruby modules can be built)
509 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
510 COMP_RUBY=
511 AC_MSG_RESULT(No .. Ruby not found or disabled)
512 else
513 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
514 COMP_RUBY="ruby"
515 AC_MSG_RESULT(YES)
516 else
517 COMP_RUBY=
518 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
519 fi
520 fi
523 dnl pass additional ruby options when generating Makefile from Makefile.PL
524 AC_ARG_ENABLE(ruby-site-install,
525 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
526 together with rrdtool in $prefix/lib/ruby. You have to
527 add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
528 for ruby to find the RRD.so file.],
529 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
532 AC_ARG_WITH(ruby-options,
533 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
534 generating Makefile from extconf.rb. If you set this
535 option, interesting things may happen unless you know
536 what you are doing!],
537 [RUBY_MAKE_OPTIONS=$withval])
539 AC_SUBST(RUBY_MAKE_OPTIONS)
540 AC_SUBST(RUBY)
541 AC_SUBST(COMP_RUBY)
544 enable_tcl_site=no
546 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
547 [],[enable_tcl=yes])
549 if test "$enable_tcl" = "yes"; then
550 dnl Check for Tcl.
551 withval=""
552 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
553 enable_tcl=no
554 for dir in $withval /usr/lib /usr/local/lib; do
555 AC_MSG_CHECKING(for tclConfig.sh in $dir)
556 if test -f "$dir/tclConfig.sh" ; then
557 tcl_config=$dir/tclConfig.sh
558 enable_tcl=yes
559 AC_MSG_RESULT(yes)
560 break
561 else
562 AC_MSG_RESULT(no)
563 fi
564 done
566 if test "$enable_tcl" = "no"; then
567 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
568 else
569 . $tcl_config
570 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
571 fi
572 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
573 [],[enable_tcl_site=yes])
575 fi
577 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
578 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
580 AC_SUBST(TCL_PREFIX)
581 AC_SUBST(TCL_SHLIB_CFLAGS)
582 AC_SUBST(TCL_SHLIB_LD)
583 AC_SUBST(TCL_SHLIB_SUFFIX)
584 AC_SUBST(TCL_PACKAGE_PATH)
585 AC_SUBST(TCL_LD_SEARCH_FLAGS)
586 AC_SUBST(TCL_STUB_LIB_SPEC)
587 AC_SUBST(TCL_VERSION)
588 AC_SUBST(TCL_PACKAGE_DIR)
590 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
591 [],[enable_python=yes])
593 if test "$enable_python" = "yes"; then
594 dnl Check for python
595 AM_PATH_PYTHON(2.3,[],[enable_python=no])
596 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
597 fi
599 if test x$enable_python = xno; then
600 COMP_PYTHON=
601 else
602 COMP_PYTHON="python"
603 fi
605 AC_SUBST(COMP_PYTHON)
607 dnl Check for nroff
608 AC_PATH_PROGS(NROFF, gnroff nroff)
609 AC_PATH_PROGS(TROFF, groff troff)
611 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
612 if test -z "$RRDDOCDIR"; then
613 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
616 CONFIGURE_PART(Apply Configuration Information)
618 AC_CONFIG_FILES([examples/shared-demo.pl])
619 AC_CONFIG_FILES([examples/piped-demo.pl])
620 AC_CONFIG_FILES([examples/stripes.pl])
621 AC_CONFIG_FILES([examples/bigtops.pl])
622 AC_CONFIG_FILES([examples/minmax.pl])
623 AC_CONFIG_FILES([examples/4charts.pl])
624 AC_CONFIG_FILES([examples/perftest.pl])
625 AC_CONFIG_FILES([examples/Makefile])
626 AC_CONFIG_FILES([doc/Makefile])
627 AC_CONFIG_FILES([src/Makefile])
628 AC_CONFIG_FILES([bindings/Makefile])
629 AC_CONFIG_FILES([bindings/tcl/Makefile])
630 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
631 AC_CONFIG_FILES([Makefile])
633 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
634 AC_OUTPUT
636 AC_MSG_CHECKING(in)
637 AC_MSG_RESULT(and out again)
639 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
640 sleep 1
641 echo $ECHO_N ".$ECHO_C" 1>&6
642 sleep 1
643 echo $ECHO_N ".$ECHO_C" 1>&6
644 sleep 1
645 echo $ECHO_N ".$ECHO_C" 1>&6
646 sleep 1
647 echo $ECHO_N ".$ECHO_C" 1>&6
648 sleep 1
649 AC_MSG_RESULT([ just kidding ;-)])
650 echo
651 echo "----------------------------------------------------------------"
652 echo "Config is DONE!"
653 echo
654 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
655 echo " Perl Modules: $COMP_PERL"
656 echo " Perl Binary: $PERL"
657 echo " Perl Version: $PERL_VERSION"
658 echo " Perl Options: $PERL_MAKE_OPTIONS"
659 echo " Ruby Modules: $COMP_RUBY"
660 echo " Ruby Binary: $RUBY"
661 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
662 echo " Build Tcl Bindings: $enable_tcl"
663 echo " Build Python Bindings: $enable_python"
664 echo " Build rrdcgi: $enable_rrdcgi"
665 echo " Build librrd MT: $enable_pthread"
666 echo
667 echo
668 echo "Type 'make' to compile the software and use 'make install' to "
669 echo "install everything to: $prefix."
670 echo
671 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
672 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
673 echo "place an order."
674 echo
675 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
676 echo "----------------------------------------------------------------"