1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.10])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devl versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.2010
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
30 AC_SUBST(VERSION)
32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
34 dnl Minimum Autoconf version required.
35 AC_PREREQ(2.59)
37 dnl At the TOP of the HEADER
39 AH_TOP([
41 #ifndef CONFIG_H
42 #define CONFIG_H
43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
44 #undef MUST_DISABLE_FPMASK
46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
48 #undef MUST_DISABLE_SIGFPE
50 /* realloc does not support NULL as argument */
51 #undef NO_NULL_REALLOC
53 ])
55 AH_BOTTOM([
57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
58 make sure you are NOT using bcopy, index or rindex in the code */
60 #if STDC_HEADERS
61 # include <string.h>
62 #else
63 # ifndef HAVE_STRCHR
64 # define strchr index
65 # define strrchr rindex
66 # endif
67 char *strchr (), *strrchr ();
68 # ifndef HAVE_MEMMOVE
69 # define memcpy(d, s, n) bcopy ((s), (d), (n))
70 # define memmove(d, s, n) bcopy ((s), (d), (n))
71 # endif
72 #endif
75 #if NO_NULL_REALLOC
76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
77 #else
78 # define rrd_realloc(a,b) realloc((a), (b))
79 #endif
81 #if HAVE_MATH_H
82 # include <math.h>
83 #endif
85 #if HAVE_FLOAT_H
86 # include <float.h>
87 #endif
89 #if HAVE_IEEEFP_H
90 # include <ieeefp.h>
91 #endif
93 #if HAVE_FP_CLASS_H
94 # include <fp_class.h>
95 #endif
97 /* for Solaris */
98 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
99 # define HAVE_ISINF 1
100 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
101 #endif
103 /* for OSF1 Digital Unix */
104 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
105 # define HAVE_ISINF 1
106 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
107 #endif
109 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
110 # define HAVE_ISINF 1
111 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
112 #endif
114 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
115 # define HAVE_ISINF 1
116 # define isinf(a) (fpclassify(a) == FP_INFINITE)
117 #endif
119 /* for AIX */
120 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
121 # define HAVE_ISINF 1
122 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
123 #endif
125 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
126 # define HAVE_FINITE 1
127 # define finite(a) isfinite(a)
128 #endif
130 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
131 # define HAVE_FINITE 1
132 # define finite(a) (! isnan(a) && ! isinf(a))
133 #endif
135 #ifndef HAVE_FINITE
136 #error "Can't compile without finite function"
137 #endif
139 #ifndef HAVE_ISINF
140 #error "Can't compile without isinf function"
141 #endif
143 #endif /* CONFIG_H */
144 ])
148 dnl Check for the compiler and static/shared library creation.
149 AC_PROG_CC
150 AC_PROG_CPP
151 AC_PROG_LIBTOOL
153 dnl Check if we run on a system that has fonts
154 AC_ARG_WITH(rrd-default-font,
155 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
156 [RRD_DEFAULT_FONT=$withval],[
157 if test -d ${WINDIR:-nodir}/cour.ttf ; then
158 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
159 else
160 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
161 fi
162 ])
164 AC_SUBST(RRD_DEFAULT_FONT)
166 dnl Checks for header files.
167 AC_HEADER_STDC
168 AC_HEADER_DIRENT
169 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
171 dnl Checks for typedefs, structures, and compiler characteristics.
172 AC_C_CONST
173 AC_HEADER_TIME
174 AC_STRUCT_TM
176 dnl Checks for libraries.
177 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
179 dnl add pic flag in any case this makes sure all our code is relocatable
180 eval `./libtool --config | grep pic_flag`
181 CFLAGS="$CFLAGS $pic_flag"
183 dnl Checks for library functions.
184 AC_FUNC_STRFTIME
185 AC_FUNC_VPRINTF
187 AC_C_BIGENDIAN
189 dnl for each function found we get a definition in config.h
190 dnl of the form HAVE_FUNCTION
192 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
194 dnl Use mmap in rrd_update instead of seek+write
195 AC_ARG_ENABLE([mmap],
196 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
197 [],
198 [enable_mmap=yes])
200 if test "x$enable_mmap" = xyes; then
201 AC_FUNC_MMAP
202 fi
204 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
205 dnl actual code to check if this works
206 AC_CHECK_FUNCS(fpclassify, ,
207 [AC_MSG_CHECKING(for fpclassify with <math.h>)
208 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
209 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
210 AC_CHECK_FUNCS(finite, ,
211 [AC_CHECK_FUNCS(isfinite, ,
212 [AC_MSG_CHECKING(for isfinite with <math.h>)
213 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
214 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
215 AC_CHECK_FUNCS(isinf, ,
216 [AC_MSG_CHECKING(for isinf with <math.h>)
217 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
218 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
220 AC_FULL_IEEE
222 dnl How the vertical axis label is printed
223 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
224 [Vertical label angle: 90.0 (default) or 270.0])
225 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
226 [Vertical label angle: 90.0 (default) or 270.0])
229 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
230 [],[enable_rrdcgi=yes])
231 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
233 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
234 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.2, http://www.gzip.org/zlib/, "")
235 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.8, http://prdownloads.sourceforge.net/libpng/, "")
236 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.9, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
238 save_LIBS=${LIBS}
239 save_CPPFLAGS=${CPPFLAGS}
240 save_LDFLAGS=${LDFLAGS}
242 if test $enable_rrdcgi != no; then
243 EX_CHECK_ALL(cgi, cgiInit, cgi.h, cgilib, 0.5, http://www.infodrom.org/projects/cgilib, "")
244 fi
246 CGI_LIBS=${LIBS}
247 CGI_CPPFLAGS=${CPPFLAGS}
248 CGI_LDFLAGS=${LDFLAGS}
250 AC_SUBST(CGI_LIBS)
251 AC_SUBST(CGI_CPPFLAGS)
252 AC_SUBST(CGI_LDFLAGS)
254 LIBS=${save_LIBS}
255 CPPFLAGS=${save_CPPFLAGS}
256 LDFLAGS=${save_LDFLAGS}
258 if test "$EX_CHECK_ALL_ERR" = "YES"; then
259 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
260 fi
262 AC_LANG_PUSH(C)
263 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
264 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
265 AC_LINK_IFELSE(
266 AC_LANG_PROGRAM(
267 [[#include <time.h>]],
268 [[ctime_r(NULL,NULL,0)]]
269 ),
270 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
271 AC_LINK_IFELSE(
272 AC_LANG_PROGRAM(
273 [[#include <time.h>]],
274 [[ctime_r(NULL,NULL)]]
275 ),
276 [AC_MSG_RESULT([yes, this seems to be solaris style])],
277 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
278 )
279 ],
280 [ AC_LINK_IFELSE(
281 AC_LANG_PROGRAM(
282 [[#include <time.h>]],
283 [[ctime_r(NULL,NULL)]]
284 ),
285 [AC_MSG_RESULT(no)],
286 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
287 )
288 ]
289 )
290 AC_LANG_POP(C)
292 dnl Check for pthreads
293 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
295 AC_SUBST(MULTITHREAD_CFLAGS)
296 AC_SUBST(MULTITHREAD_LDFLAGS)
299 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
300 [],[enable_pthread=yes])
303 if test $enable_pthread != no; then
304 ACX_PTHREAD([
305 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
306 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
307 ],
308 [])
309 fi
311 dnl since we use lots of *_r functions all over the code we better
312 dnl make sure they are known
314 if test "x$x_rflag" != "xno"; then
315 CPPFLAGS="$CPPFLAGS $x_rflag"
316 fi
319 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
321 dnl Check for Perl.
322 AC_PATH_PROG(PERL, perl, no)
324 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
325 [],[enable_perl=yes])
328 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
329 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
330 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
331 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
333 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
334 COMP_PERL=
335 else
336 COMP_PERL="perl_piped perl_shared"
337 AC_MSG_CHECKING(for the perl version you are running)
338 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
339 AC_MSG_RESULT($PERL_VERSION)
340 if test -z "$PERLCC"; then
341 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
342 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
343 AC_MSG_RESULT($perlcc)
344 if test ! -x "$perlcc"; then
345 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
346 if test "$PERL_CC" = "no"; then
347 AC_MSG_WARN([
348 I would not find the Compiler ($perlcc) that was originally used to compile
349 your perl binary. You should either make sure that this compiler is
350 available on your system, pick an other compiler and set PERLCC
351 appropriately, or use a different perl setup that was compiled locally.
353 I will disable the compilation of the RRDs perl module for now.
354 ])
355 COMP_PERL="perl_piped"
356 fi
357 fi
358 fi
359 fi
360 AC_MSG_CHECKING(Perl Modules to build)
361 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
363 # Options to pass when configuring perl module
364 ppref=$prefix
365 test "$ppref" = "NONE" && ppref=$ac_default_prefix
367 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
369 dnl pass additional perl options when generating Makefile from Makefile.PL
370 AC_ARG_ENABLE(perl-site-install,
371 [ --enable-perl-site-install by default the rrdtool perl modules are installed
372 together with rrdtool in $prefix/lib/perl. You have to
373 put a 'use lib qw($prefix/lib/perl)' into your scripts
374 when you want to use them. When you set this option
375 the perl modules will get installed wherever
376 your perl setup thinks it is best.],
377 [PERL_MAKE_OPTIONS=],[])
379 if test ! -z "$PERLCC"; then
380 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
382 if test ! -z "$PERLCCFLAGS"; then
383 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
384 fi
386 if test -z "$PERLLD"; then
387 PERLLD=$PERLCC
388 fi
389 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
391 if test ! -z "$PERLLDFLAGS"; then
392 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
393 fi
394 fi
396 AC_ARG_WITH(perl-options,
397 [ --with-perl-options=[OPTIONS] options to pass on command-line when
398 generating Makefile from Makefile.PL. If you set this
399 option, interesting things may happen unless you know
400 what you are doing!],
401 [PERL_MAKE_OPTIONS=$withval])
403 AC_SUBST(PERL_MAKE_OPTIONS)
404 AC_SUBST(PERL)
405 AC_SUBST(COMP_PERL)
406 AC_SUBST(PERL_VERSION)
408 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
409 [],[enable_tcl=yes])
411 if test "$enable_tcl" = "yes"; then
412 dnl Check for Tcl.
413 withval=""
414 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
415 enable_tcl=no
416 for dir in $withval /usr/lib /usr/local/lib; do
417 AC_MSG_CHECKING(for tclConfig.sh in $dir)
418 if test -f "$dir/tclConfig.sh" ; then
419 tcl_config=$dir/tclConfig.sh
420 enable_tcl=yes
421 AC_MSG_RESULT(yes)
422 break
423 else
424 AC_MSG_RESULT(no)
425 fi
426 done
428 if test "$enable_tcl" = "no"; then
429 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
430 else
431 . $tcl_config
432 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
433 fi
434 fi
436 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
438 AC_SUBST(TCL_PREFIX)
439 AC_SUBST(TCL_SHLIB_CFLAGS)
440 AC_SUBST(TCL_SHLIB_LD)
441 AC_SUBST(TCL_SHLIB_SUFFIX)
442 AC_SUBST(TCL_PACKAGE_PATH)
443 AC_SUBST(TCL_LD_SEARCH_FLAGS)
444 AC_SUBST(TCL_VERSION)
445 AC_SUBST(TCL_PACKAGE_DIR)
447 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
448 [],[enable_python=yes])
450 if test "$enable_python" = "yes"; then
451 dnl Check for python
452 AM_PATH_PYTHON(2.3,[],[enable_python=no])
453 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
454 fi
456 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
458 dnl Check for nroff
459 AC_PATH_PROGS(NROFF, gnroff nroff)
460 AC_PATH_PROGS(TROFF, groff troff)
462 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
463 if test -z "$RRDDOCDIR"; then
464 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
466 dnl Does the compiler like -Wall and -pedantic?
467 if test "$GCC" = "yes"; then
468 oCFLAGS=$CFLAGS
469 CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
470 AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
471 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
472 ]
473 )
474 if test $rd_cv_gcc_opt = no; then
475 CFLAGS=$oCFLAGS
476 fi
477 fi
479 dnl what does realloc do if it gets called with a NULL pointer
481 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
482 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
483 int main(void){
484 char *x = NULL;
485 x = realloc (x,10);
486 if (x==NULL) return 1;
487 return 0;
488 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
490 if test x"$rd_cv_null_realloc" = xnope; then
491 AC_DEFINE(NO_NULL_REALLOC)
492 fi
494 AC_CONFIG_FILES([examples/shared-demo.pl \
495 examples/piped-demo.pl \
496 examples/stripes.pl \
497 examples/bigtops.pl \
498 examples/minmax.pl \
499 examples/cgi-demo.cgi \
500 examples/4charts.pl \
501 examples/Makefile \
502 doc/Makefile \
503 src/Makefile \
504 bindings/Makefile \
505 bindings/tcl/Makefile \
506 bindings/tcl/ifOctets.tcl \
507 bindings/python/Makefile \
508 Makefile])
509 AC_CONFIG_COMMANDS([default],[[\
510 chmod +x examples/*.cgi examples/*.pl]],[[]])
511 AC_OUTPUT
513 AC_MSG_CHECKING(in)
514 AC_MSG_RESULT(and out again)
516 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
517 sleep 1
518 echo $ECHO_N ".$ECHO_C" 1>&6
519 sleep 1
520 echo $ECHO_N ".$ECHO_C" 1>&6
521 sleep 1
522 echo $ECHO_N ".$ECHO_C" 1>&6
523 sleep 1
524 echo $ECHO_N ".$ECHO_C" 1>&6
525 sleep 1
526 AC_MSG_RESULT([ just kidding ;-)])
527 echo
528 echo "----------------------------------------------------------------"
529 echo "Config is DONE!"
530 echo
531 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
532 echo " Perl Modules: $COMP_PERL"
533 echo " Perl Binary: $PERL"
534 echo " Perl Version: $PERL_VERSION"
535 echo " Perl Options: $PERL_MAKE_OPTIONS"
536 echo " Build Tcl Bindings: $enable_tcl"
537 echo " Build Python Bindings: $enable_python"
538 echo " Build rrdcgi: $enable_rrdcgi"
539 echo " Build librrd MT: $enable_pthread"
540 echo
541 echo
542 echo "Type 'make' to compile the software and use 'make install' to "
543 echo "install everything to: $prefix."
544 echo
545 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
546 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
547 echo "place an order."
548 echo
549 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
550 echo "----------------------------------------------------------------"